lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove a series of directories
   6
   7 =head1 SYNOPSIS
   8
   9 C<use File::Path>
  10
  11 C<mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);>
  12
  13 C<rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);>
  14
  15 =head1 DESCRIPTION
  16
  17 The C<mkpath> function provides a convenient way to create directories, even if
  18 your C<mkdir> kernel call won't create more than one level of directory at a
  19 time.  C<mkpath> takes three arguments:
  20
  21 =over 4
  22
  23 =item *
  24
  25 the name of the path to create, or a reference
  26 to a list of paths to create,
  27
  28 =item *
  29
  30 a boolean value, which if TRUE will cause C<mkpath>
  31 to print the name of each directory as it is created
  32 (defaults to FALSE), and
  33
  34 =item *
  35
  36 the numeric mode to use when creating the directories
  37 (defaults to 0777)
  38
  39 =back
  40
  41 It returns a list of all directories (including intermediates, determined using
  42 the Unix '/' separator) created.
  43
  44 Similarly, the C<rmtree> function provides a convenient way to delete a
  45 subtree from the directory structure, much like the Unix command C<rm -r>.
  46 C<rmtree> takes three arguments:
  47
  48 =over 4
  49
  50 =item *
  51
  52 the root of the subtree to delete, or a reference to
  53 a list of roots.  All of the files and directories
  54 below each root, as well as the roots themselves,
  55 will be deleted.
  56
  57 =item *
  58
  59 a boolean value, which if TRUE will cause C<rmtree> to
  60 print a message each time it examines a file, giving the
  61 name of the file, and indicating whether it's using C<rmdir>
  62 or C<unlink> to remove it, or that it's skipping it.
  63 (defaults to FALSE)
  64
  65 =item *
  66
  67 a boolean value, which if TRUE will cause C<rmtree> to
  68 skip any files to which you do not have delete access
  69 (if running under VMS) or write access (if running
  70 under another OS).  This will change in the future when
  71 a criterion for 'delete permission' under OSs other
  72 than VMS is settled. (defaults to FALSE)
  73
  74 =back
  75
  76 It returns the number of files successfully deleted.
  77
  78 =head1 AUTHORS
  79
  80 Tim Bunce <Tim.Bunce@ig.co.uk>
  81 Charles Bailey <bailey@genetics.upenn.edu>
  82
  83 =head1 REVISION
  84
  85 This document was last revised 25-Aug-1995, for perl 5.002
  86
  87 =cut
  88
  89 require 5.000;
  90 use Config;
  91 use Carp;
  92 require Exporter;
  93 @ISA = qw( Exporter );
  94 @EXPORT = qw( mkpath rmtree );
  95
  96 $Is_VMS = $Config{'osname'} eq 'VMS';
  97
  98 sub mkpath{
  99     my($paths, $verbose, $mode) = @_;
 100     # $paths   -- either a path string or ref to list of paths
 101     # $verbose -- optional print "mkdir $path" for each directory created
 102     # $mode    -- optional permissions, defaults to 0777
 103     local($")="/";
 104     $mode = 0777 unless defined($mode);
 105     $paths = [$paths] unless ref $paths;
 106     my(@created);
 107     foreach $path (@$paths){
 108         next if -d $path;
 109         my(@p);
 110         foreach(split(/\//, $path)){
 111             push(@p, $_);
 112             next if -d "@p/";
 113             print "mkdir @p\n" if $verbose;
 114             mkdir("@p",$mode) || croak "mkdir @p: $!";
 115             push(@created, "@p");
 116         }
 117     }
 118     @created;
 119 }
 120
 121 sub rmtree {
 122     my($roots, $verbose, $safe) = @_;
 123     my(@files,$count);
 124     $roots = [$roots] unless ref $roots;
 125
 126     foreach $root (@{$roots}) {
 127        $root =~ s#/$##;
 128        if (-d $root) {
 129            opendir(D,$root);
 130            ($root = VMS::Filespec::unixify($root)) =~ s#\.dir$## if $Is_VMS;
 131            @files = map("$root/$_", grep $_!~/^\.{1,2}$/, readdir(D));
 132            closedir(D);
 133            $count += rmtree(\@files,$verbose,$safe);
 134            if ($safe &&
 135                ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 136                print "skipped $root\n" if $verbose;
 137                next;
 138            }
 139            print "rmdir $root\n" if $verbose;
 140            (rmdir $root && ++$count) or carp "Can't remove directory $root: $!";
 141         }
 142         else {
 143            if ($safe &&
 144                ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 145                print "skipped $root\n" if $verbose;
 146                next;
 147            }
 148            print "unlink $root\n" if $verbose;
 149            while (-e $root) { # delete all versions under VMS
 150                (unlink($root) && ++$count)
 151                    or carp "Can't unlink file $root: $!";
 152            }
 153         }
 154     }
 155
 156     $count;
 157 }
 158
 159 1;
 160
 161 __END__