lib/File/Copy.t

   1 #!./perl -w
   2
   3 BEGIN {
   4    if( $ENV{PERL_CORE} ) {
   5         chdir 't' if -d 't';
   6         @INC = '../lib';
   7     }
   8 }
   9
  10 use strict;
  11 use warnings;
  12
  13 use Test::More;
  14
  15 my $TB = Test::More->builder;
  16
  17 plan tests => 463;
  18
  19 # We're going to override rename() later on but Perl has to see an override
  20 # at compile time to honor it.
  21 BEGIN { *CORE::GLOBAL::rename = sub { CORE::rename($_[0], $_[1]) }; }
  22
  23
  24 use File::Copy qw(copy move cp);
  25 use Config;
  26
  27
  28 foreach my $code ("copy()", "copy('arg')", "copy('arg', 'arg', 'arg', 'arg')",
  29                   "move()", "move('arg')", "move('arg', 'arg', 'arg')"
  30                  )
  31 {
  32     eval $code;
  33     like $@, qr/^Usage: /, "'$code' is a usage error";
  34 }
  35
  36
  37 for my $cross_partition_test (0..1) {
  38   {
  39     # Simulate a cross-partition copy/move by forcing rename to
  40     # fail.
  41     no warnings 'redefine';
  42     *CORE::GLOBAL::rename = sub { 0 } if $cross_partition_test;
  43   }
  44
  45   # First we create a file
  46   open(F, ">file-$$") or die $!;
  47   binmode F; # for DOSISH platforms, because test 3 copies to stdout
  48   printf F "ok\n";
  49   close F;
  50
  51   copy "file-$$", "copy-$$";
  52
  53   open(F, "copy-$$") or die $!;
  54   my $foo = <F>;
  55   close(F);
  56
  57   is -s "file-$$", -s "copy-$$", 'copy(fn, fn): files of the same size';
  58
  59   is $foo, "ok\n", 'copy(fn, fn): same contents';
  60
  61   print("# next test checks copying to STDOUT\n");
  62   binmode STDOUT unless $^O eq 'VMS'; # Copy::copy works in binary mode
  63   # This outputs "ok" so its a test.
  64   copy "copy-$$", \*STDOUT;
  65   $TB->current_test($TB->current_test + 1);
  66   unlink "copy-$$" or die "unlink: $!";
  67
  68   open(F,"file-$$");
  69   copy(*F, "copy-$$");
  70   open(R, "copy-$$") or die "open copy-$$: $!"; $foo = <R>; close(R);
  71   is $foo, "ok\n", 'copy(*F, fn): same contents';
  72   unlink "copy-$$" or die "unlink: $!";
  73
  74   open(F,"file-$$");
  75   copy(\*F, "copy-$$");
  76   close(F) or die "close: $!";
  77   open(R, "copy-$$") or die; $foo = <R>; close(R) or die "close: $!";
  78   is $foo, "ok\n", 'copy(\*F, fn): same contents';
  79   unlink "copy-$$" or die "unlink: $!";
  80
  81   require IO::File;
  82   my $fh = IO::File->new(">copy-$$") or die "Cannot open copy-$$:$!";
  83   binmode $fh or die $!;
  84   copy("file-$$",$fh);
  85   $fh->close or die "close: $!";
  86   open(R, "copy-$$") or die; $foo = <R>; close(R);
  87   is $foo, "ok\n", 'copy(fn, io): same contents';
  88   unlink "copy-$$" or die "unlink: $!";
  89
  90   require FileHandle;
  91   $fh = FileHandle->new(">copy-$$") or die "Cannot open copy-$$:$!";
  92   binmode $fh or die $!;
  93   copy("file-$$",$fh);
  94   $fh->close;
  95   open(R, "copy-$$") or die $!; $foo = <R>; close(R);
  96   is $foo, "ok\n", 'copy(fn, fh): same contents';
  97   unlink "file-$$" or die "unlink: $!";
  98
  99   ok !move("file-$$", "copy-$$"), "move on missing file";
 100   ok -e "copy-$$",                '  target still there';
 101
 102   # Doesn't really matter what time it is as long as its not now.
 103   my $time = 1000000000;
 104   utime( $time, $time, "copy-$$" );
 105
 106   # Recheck the mtime rather than rely on utime in case we're on a
 107   # system where utime doesn't work or there's no mtime at all.
 108   # The destination file will reflect the same difficulties.
 109   my $mtime = (stat("copy-$$"))[9];
 110
 111   ok move("copy-$$", "file-$$"), 'move';
 112   ok -e "file-$$",              '  destination exists';
 113   ok !-e "copy-$$",              '  source does not';
 114   open(R, "file-$$") or die $!; $foo = <R>; close(R);
 115   is $foo, "ok\n", 'contents preserved';
 116
 117   TODO: {
 118     local $TODO = 'mtime only preserved on ODS-5 with POSIX dates and DECC$EFS_FILE_TIMESTAMPS enabled' if $^O eq 'VMS';
 119
 120     my $dest_mtime = (stat("file-$$"))[9];
 121     is $dest_mtime, $mtime,
 122       "mtime preserved by copy()".
 123       ($cross_partition_test ? " while testing cross-partition" : "");
 124   }
 125
 126   # trick: create lib/ if not exists - not needed in Perl core
 127   unless (-d 'lib') { mkdir 'lib' or die $!; }
 128   copy "file-$$", "lib";
 129   open(R, "lib/file-$$") or die $!; $foo = <R>; close(R);
 130   is $foo, "ok\n", 'copy(fn, dir): same contents';
 131   unlink "lib/file-$$" or die "unlink: $!";
 132
 133   # Do it twice to ensure copying over the same file works.
 134   copy "file-$$", "lib";
 135   open(R, "lib/file-$$") or die $!; $foo = <R>; close(R);
 136   is $foo, "ok\n", 'copy over the same file works';
 137   unlink "lib/file-$$" or die "unlink: $!";
 138
 139   {
 140     my $warnings = '';
 141     local $SIG{__WARN__} = sub { $warnings .= join '', @_ };
 142     ok copy("file-$$", "file-$$"), 'copy(fn, fn) succeeds';
 143
 144     like $warnings, qr/are identical/, 'but warns';
 145     ok -s "file-$$", 'contents preserved';
 146   }
 147
 148   move "file-$$", "lib";
 149   open(R, "lib/file-$$") or die "open lib/file-$$: $!"; $foo = <R>; close(R);
 150   is $foo, "ok\n", 'move(fn, dir): same contents';
 151   ok !-e "file-$$", 'file moved indeed';
 152   unlink "lib/file-$$" or die "unlink: $!";
 153
 154   SKIP: {
 155     skip "Testing symlinks", 3 unless $Config{d_symlink};
 156
 157     open(F, ">file-$$") or die $!;
 158     print F "dummy content\n";
 159     close F;
 160     symlink("file-$$", "symlink-$$") or die $!;
 161
 162     my $warnings = '';
 163     local $SIG{__WARN__} = sub { $warnings .= join '', @_ };
 164     ok !copy("file-$$", "symlink-$$"), 'copy to itself (via symlink) fails';
 165
 166     like $warnings, qr/are identical/, 'emits a warning';
 167     ok !-z "file-$$",
 168       'rt.perl.org 5196: copying to itself would truncate the file';
 169
 170     unlink "symlink-$$" or die $!;
 171     unlink "file-$$" or die $!;
 172   }
 173
 174   SKIP: {
 175     skip "Testing hard links", 3
 176          if !$Config{d_link} or $^O eq 'MSWin32' or $^O eq 'cygwin';
 177
 178     open(F, ">file-$$") or die $!;
 179     print F "dummy content\n";
 180     close F;
 181     link("file-$$", "hardlink-$$") or die $!;
 182
 183     my $warnings = '';
 184     local $SIG{__WARN__} = sub { $warnings .= join '', @_ };
 185     ok !copy("file-$$", "hardlink-$$"), 'copy to itself (via hardlink) fails';
 186
 187     like $warnings, qr/are identical/, 'emits a warning';
 188     ok ! -z "file-$$",
 189       'rt.perl.org 5196: copying to itself would truncate the file';
 190
 191     unlink "hardlink-$$" or die $!;
 192     unlink "file-$$" or die $!;
 193   }
 194
 195   open(F, ">file-$$") or die $!;
 196   binmode F;
 197   print F "this is file\n";
 198   close F;
 199
 200   my $copy_msg = "this is copy\n";
 201   open(F, ">copy-$$") or die $!;
 202   binmode F;
 203   print F $copy_msg;
 204   close F;
 205
 206   my @warnings;
 207   local $SIG{__WARN__} = sub { push @warnings, join '', @_ };
 208
 209   # pie-$$ so that we force a non-constant, else the numeric conversion (of 0)
 210   # is cached and we don't get a warning the second time round
 211   is eval { copy("file-$$", "copy-$$", "pie-$$"); 1 }, undef,
 212     "a bad buffer size fails to copy";
 213   like $@, qr/Bad buffer size for copy/, "with a helpful error message";
 214   unless (is scalar @warnings, 1, "There is 1 warning") {
 215     diag $_ foreach @warnings;
 216   }
 217
 218   is -s "copy-$$", length $copy_msg, "but does not truncate the destination";
 219   open(F, "copy-$$") or die $!;
 220   $foo = <F>;
 221   close(F);
 222   is $foo, $copy_msg, "nor change the destination's contents";
 223
 224   unlink "file-$$" or die $!;
 225   unlink "copy-$$" or die $!;
 226
 227   # RT #73714 copy to file with leading whitespace failed
 228
 229   open(F, ">file-$$") or die $!;
 230   close F;
 231   copy "file-$$", " copy-$$";
 232   warn "XXX\n";
 233   ok -e " copy-$$", "copy with leading whitespace";
 234   unlink "file-$$" or die "unlink: $!";
 235   unlink " copy-$$" or die "unlink: $!";
 236
 237 }
 238
 239
 240 SKIP: {
 241     my @tests = (
 242         [0000,  0777,  0777,  0777],
 243         [0000,  0751,  0751,  0644],
 244         [0022,  0777,  0755,  0206],
 245         [0022,  0415,  0415,  0666],
 246         [0077,  0777,  0700,  0333],
 247         [0027,  0755,  0750,  0251],
 248         [0777,  0751,  0000,  0215],
 249     );
 250
 251     my $skips = @tests * 6 * 8;
 252
 253     # TODO - make this skip fire if we're on a nosuid filesystem rather than guessing by OS
 254     skip "OpenBSD filesystems default to nosuid breaking these tests", $skips
 255           if $^O eq 'openbsd';
 256     skip "-- Copy preserves RMS defaults, not POSIX permissions.", $skips
 257           if $^O eq 'VMS';
 258     skip "Copy doesn't set file permissions correctly on Win32.",  $skips
 259           if $^O eq "MSWin32";
 260
 261     # Just a sub to get better failure messages.
 262     sub __ ($) {
 263         my $perm   = shift;
 264         my $id     = 07000 & $perm;
 265            $id   >>= 9;
 266         $perm     &= 0777;
 267         my @chunks = map {(qw [--- --x -w- -wx r-- r-x rw- rwx]) [$_]}
 268                      split // => sprintf "%03o" => $perm;
 269         if ($id & 4) {$chunks [0] =~ s/(.)$/$1 eq '-' ? 'S' : 's'/e;}
 270         if ($id & 2) {$chunks [1] =~ s/(.)$/$1 eq '-' ? 'S' : 's'/e;}
 271         if ($id & 1) {$chunks [2] =~ s/(.)$/$1 eq '-' ? 'T' : 't'/e;}
 272         join "" => @chunks;
 273     }
 274     # Testing permission bits.
 275     my $src   = "file-$$";
 276     my $copy1 = "copy1-$$";
 277     my $copy2 = "copy2-$$";
 278     my $copy3 = "copy3-$$";
 279     my $copy4 = "copy4-$$";
 280     my $copy5 = "copy5-$$";
 281     my $copy6 = "copy6-$$";
 282
 283     open my $fh => ">", $src   or die $!;
 284     close   $fh                or die $!;
 285
 286     open    $fh => ">", $copy3 or die $!;
 287     close   $fh                or die $!;
 288
 289     open    $fh => ">", $copy6 or die $!;
 290     close   $fh                or die $!;
 291
 292     my $old_mask = umask;
 293     foreach my $test (@tests) {
 294         foreach my $id (0 .. 7) {
 295             my ($umask, $s_perm, $c_perm1, $c_perm3) = @$test;
 296             # Make sure the copies doesn't exist.
 297             ! -e $_ or unlink $_ or die $! for $copy1, $copy2, $copy4, $copy5;
 298
 299             $s_perm  |= $id << 9;
 300             $c_perm1 |= $id << 9;
 301             diag(sprintf "Src permission: %04o; umask %03o\n", $s_perm, $umask)
 302                 unless ($ENV{PERL_CORE});
 303
 304             # Test that we can actually set a file to the correct permission.
 305             # Slightly convoluted, because some operating systems will let us
 306             # set a directory, but not a file. These should all work:
 307             mkdir $copy1 or die "Can't mkdir $copy1: $!";
 308             chmod $s_perm, $copy1
 309                 or die sprintf "Can't chmod %o $copy1: $!", $s_perm;
 310             rmdir $copy1
 311                 or die sprintf "Can't rmdir $copy1: $!";
 312             open my $fh0, '>', $copy1 or die "Can't open $copy1: $!";
 313             close $fh0 or die "Can't close $copy1: $!";
 314             unless (chmod $s_perm, $copy1) {
 315                 $TB->skip(sprintf "Can't chmod $copy1 to %o: $!", $s_perm)
 316                     for 1..6;
 317                 next;
 318             }
 319             my $perm0 = (stat $copy1) [2] & 07777;
 320             unless ($perm0 == $s_perm) {
 321                 $TB->skip(sprintf "chmod %o $copy1 lies - we actually get %o",
 322                           $s_perm, $perm0)
 323                     for 1..6;
 324                 next;
 325             }
 326             unlink $copy1 or die "Can't unlink $copy1: $!";
 327
 328             (umask $umask) // die $!;
 329             chmod $s_perm  => $src   or die sprintf "$!: $src => %o", $s_perm;
 330             chmod $c_perm3 => $copy3 or die $!;
 331             chmod $c_perm3 => $copy6 or die $!;
 332
 333             open my $fh => "<", $src or die $!;
 334
 335             copy ($src, $copy1);
 336             copy ($fh,  $copy2);
 337             copy ($src, $copy3);
 338             cp   ($src, $copy4);
 339             cp   ($fh,  $copy5);
 340             cp   ($src, $copy6);
 341
 342             my $permdef = 0666 & ~$umask;
 343             my $perm1 = (stat $copy1) [2] & 07777;
 344             my $perm2 = (stat $copy2) [2] & 07777;
 345             my $perm3 = (stat $copy3) [2] & 07777;
 346             my $perm4 = (stat $copy4) [2] & 07777;
 347             my $perm5 = (stat $copy5) [2] & 07777;
 348             my $perm6 = (stat $copy6) [2] & 07777;
 349             is (__$perm1, __$permdef, "Permission bits set correctly");
 350             is (__$perm2, __$permdef, "Permission bits set correctly");
 351             is (__$perm4, __$c_perm1, "Permission bits set correctly");
 352             is (__$perm5, __$c_perm1, "Permission bits set correctly");
 353             TODO: {
 354                 local $TODO = 'Permission bits inconsistent under cygwin'
 355                    if $^O eq 'cygwin';
 356                 is (__$perm3, __$c_perm3, "Permission bits not modified");
 357                 is (__$perm6, __$c_perm3, "Permission bits not modified");
 358             }
 359         }
 360     }
 361     umask $old_mask or die $!;
 362
 363     # Clean up.
 364     ! -e $_ or unlink $_ or die $! for $src, $copy1, $copy2, $copy3,
 365                                              $copy4, $copy5, $copy6;
 366 }
 367
 368 {
 369     package Crash;
 370     # a package overloaded suspiciously like IO::Scalar
 371     use overload '""' => sub { ${$_[0]} };
 372     use overload 'bool' => sub { 1 };
 373     sub new {
 374         my ($class, $name) = @_;
 375         bless \$name, $class;
 376     }
 377
 378     package Zowie;
 379     # a different package overloaded suspiciously like IO::Scalar
 380     use overload '""' => sub { ${$_[0]} };
 381     use overload 'bool' => sub { 1 };
 382     sub new {
 383         my ($class, $name) = @_;
 384         bless \$name, $class;
 385     }
 386 }
 387 {
 388     my $object = Crash->new('whack_eth');
 389     my %what = (plain => "$object",
 390                 object1 => $object,
 391                 object2 => Zowie->new('whack_eth'),
 392                 object2 => Zowie->new('whack_eth'),
 393                );
 394
 395     my @warnings;
 396     local $SIG{__WARN__} = sub {
 397         push @warnings, @_;
 398     };
 399
 400     foreach my $left (qw(plain object1 object2)) {
 401         foreach my $right (qw(plain object1 object2)) {
 402             @warnings = ();
 403             $! = 0;
 404             is eval {copy $what{$left}, $what{$right}}, 1, "copy $left $right";
 405             is $@, '', 'No croaking';
 406             is $!, '', 'No system call errors';
 407             is @warnings, 1, 'Exactly 1 warning';
 408             like $warnings[0],
 409                 qr/'$object' and '$object' are identical \(not copied\)/,
 410                     'with the text we expect';
 411         }
 412     }
 413 }
 414
 415 # On Unix systems, File::Copy always returns 0 to signal failure,
 416 # even when in list context!  On Windows, it always returns "" to signal
 417 # failure.
 418 #
 419 # While returning a list containing a false value is arguably a bad
 420 # API design, at the very least we can make sure it always returns
 421 # the same false value.
 422
 423 my $NO_SUCH_FILE       = "this_file_had_better_not_exist";
 424 my $NO_SUCH_OTHER_FILE = "my_goodness_im_sick_of_airports";
 425
 426 use constant EXPECTED_SCALAR => 0;
 427 use constant EXPECTED_LIST   => [ EXPECTED_SCALAR ];
 428
 429 my %subs = (
 430     copy    =>  \&File::Copy::copy,
 431     cp      =>  \&File::Copy::cp,
 432     move    =>  \&File::Copy::move,
 433     mv      =>  \&File::Copy::mv,
 434 );
 435
 436 SKIP: {
 437     skip( "Test can't run with $NO_SUCH_FILE existing", 2 * keys %subs)
 438         if (-e $NO_SUCH_FILE);
 439
 440     foreach my $name (keys %subs) {
 441
 442         my $sub = $subs{$name};
 443
 444         my $scalar = $sub->( $NO_SUCH_FILE, $NO_SUCH_OTHER_FILE );
 445         is( $scalar, EXPECTED_SCALAR, "$name in scalar context");
 446
 447         my @array  = $sub->( $NO_SUCH_FILE, $NO_SUCH_OTHER_FILE );
 448         is_deeply( \@array, EXPECTED_LIST, "$name in list context");
 449     }
 450 }
 451
 452 SKIP: {
 453     skip("fork required to test pipe copying", 2)
 454         if (!$Config{'d_fork'});
 455
 456     open(my $IN, "-|") || exec $^X, '-e', 'print "Hello, world!\n"';
 457     open(my $OUT, "|-") || exec $^X, '-ne', 'exit(/Hello/ ? 55 : 0)';
 458
 459     ok(copy($IN, $OUT), "copy pipe to another");
 460     close($OUT);
 461     is($? >> 8, 55, "content copied through the pipes");
 462     close($IN);
 463 }
 464
 465 END {
 466     1 while unlink "file-$$";
 467     1 while unlink "lib/file-$$";
 468 }