lib/File/Copy.pm

   1 # File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
   2 # source code has been placed in the public domain by the author.
   3 # Please be kind and preserve the documentation.
   4 #
   5 # Additions copyright 1996 by Charles Bailey.  Permission is granted
   6 # to distribute the revised code under the same terms as Perl itself.
   7
   8 package File::Copy;
   9
  10 use 5.006;
  11 use strict;
  12 use warnings;
  13 use Carp;
  14 use File::Spec;
  15 use Config;
  16 our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
  17 sub copy;
  18 sub syscopy;
  19 sub cp;
  20 sub mv;
  21
  22 # Note that this module implements only *part* of the API defined by
  23 # the File/Copy.pm module of the File-Tools-2.0 package.  However, that
  24 # package has not yet been updated to work with Perl 5.004, and so it
  25 # would be a Bad Thing for the CPAN module to grab it and replace this
  26 # module.  Therefore, we set this module's version higher than 2.0.
  27 $VERSION = '2.05';
  28
  29 require Exporter;
  30 @ISA = qw(Exporter);
  31 @EXPORT = qw(copy move);
  32 @EXPORT_OK = qw(cp mv);
  33
  34 $Too_Big = 1024 * 1024 * 2;
  35
  36 my $macfiles;
  37 if ($^O eq 'MacOS') {
  38         $macfiles = eval { require Mac::MoreFiles };
  39         warn 'Mac::MoreFiles could not be loaded; using non-native syscopy'
  40                 if $^W;
  41 }
  42
  43 sub _catname {
  44     my($from, $to) = @_;
  45     if (not defined &basename) {
  46         require File::Basename;
  47         import  File::Basename 'basename';
  48     }
  49
  50     if ($^O eq 'MacOS') {
  51         # a partial dir name that's valid only in the cwd (e.g. 'tmp')
  52         $to = ':' . $to if $to !~ /:/;
  53     }
  54
  55     return File::Spec->catfile($to, basename($from));
  56 }
  57
  58 sub copy {
  59     croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
  60       unless(@_ == 2 || @_ == 3);
  61
  62     my $from = shift;
  63     my $to = shift;
  64
  65     my $from_a_handle = (ref($from)
  66                          ? (ref($from) eq 'GLOB'
  67                             || UNIVERSAL::isa($from, 'GLOB')
  68                             || UNIVERSAL::isa($from, 'IO::Handle'))
  69                          : (ref(\$from) eq 'GLOB'));
  70     my $to_a_handle =   (ref($to)
  71                          ? (ref($to) eq 'GLOB'
  72                             || UNIVERSAL::isa($to, 'GLOB')
  73                             || UNIVERSAL::isa($to, 'IO::Handle'))
  74                          : (ref(\$to) eq 'GLOB'));
  75
  76     if ($from eq $to) { # works for references, too
  77         croak("'$from' and '$to' are identical (not copied)");
  78     }
  79
  80     if ($Config{d_symlink} && $Config{d_readlink} &&
  81         !($^O eq 'Win32' || $^O eq 'os2' || $^O eq 'vms')) {
  82         no warnings 'io'; # don't warn if -l on filehandle
  83         if ((-e $from && -l $from) || (-e $to && -l $to)) {
  84             my @fs = stat($from);
  85             my @ts = stat($to);
  86             if (@fs && @ts && $fs[0] == $ts[0] && $fs[1] == $ts[1]) {
  87                 croak("'$from' and '$to' are identical (not copied)");
  88             }
  89         }
  90     }
  91
  92     if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
  93         $to = _catname($from, $to);
  94     }
  95
  96     if (defined &syscopy && !$Syscopy_is_copy
  97         && !$to_a_handle
  98         && !($from_a_handle && $^O eq 'os2' )   # OS/2 cannot handle handles
  99         && !($from_a_handle && $^O eq 'mpeix')  # and neither can MPE/iX.
 100         && !($from_a_handle && $^O eq 'MSWin32')
 101         && !($from_a_handle && $^O eq 'MacOS')
 102         && !($from_a_handle && $^O eq 'NetWare')
 103        )
 104     {
 105         return syscopy($from, $to);
 106     }
 107
 108     my $closefrom = 0;
 109     my $closeto = 0;
 110     my ($size, $status, $r, $buf);
 111     local($\) = '';
 112
 113     my $from_h;
 114     if ($from_a_handle) {
 115        $from_h = $from;
 116     } else {
 117         $from = _protect($from) if $from =~ /^\s/s;
 118        $from_h = \do { local *FH };
 119        open($from_h, "< $from\0") or goto fail_open1;
 120        binmode $from_h or die "($!,$^E)";
 121         $closefrom = 1;
 122     }
 123
 124     my $to_h;
 125     if ($to_a_handle) {
 126        $to_h = $to;
 127     } else {
 128         $to = _protect($to) if $to =~ /^\s/s;
 129        $to_h = \do { local *FH };
 130        open($to_h,"> $to\0") or goto fail_open2;
 131        binmode $to_h or die "($!,$^E)";
 132         $closeto = 1;
 133     }
 134
 135     if (@_) {
 136         $size = shift(@_) + 0;
 137         croak("Bad buffer size for copy: $size\n") unless ($size > 0);
 138     } else {
 139         $size = tied(*$from_h) ? 0 : -s $from_h || 0;
 140         $size = 1024 if ($size < 512);
 141         $size = $Too_Big if ($size > $Too_Big);
 142     }
 143
 144     $! = 0;
 145     for (;;) {
 146         my ($r, $w, $t);
 147        defined($r = sysread($from_h, $buf, $size))
 148             or goto fail_inner;
 149         last unless $r;
 150         for ($w = 0; $w < $r; $w += $t) {
 151            $t = syswrite($to_h, $buf, $r - $w, $w)
 152                 or goto fail_inner;
 153         }
 154     }
 155
 156     close($to_h) || goto fail_open2 if $closeto;
 157     close($from_h) || goto fail_open1 if $closefrom;
 158
 159     # Use this idiom to avoid uninitialized value warning.
 160     return 1;
 161
 162     # All of these contortions try to preserve error messages...
 163   fail_inner:
 164     if ($closeto) {
 165         $status = $!;
 166         $! = 0;
 167        close $to_h;
 168         $! = $status unless $!;
 169     }
 170   fail_open2:
 171     if ($closefrom) {
 172         $status = $!;
 173         $! = 0;
 174        close $from_h;
 175         $! = $status unless $!;
 176     }
 177   fail_open1:
 178     return 0;
 179 }
 180
 181 sub move {
 182     my($from,$to) = @_;
 183     my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
 184
 185     if (-d $to && ! -d $from) {
 186         $to = _catname($from, $to);
 187     }
 188
 189     ($tosz1,$tomt1) = (stat($to))[7,9];
 190     $fromsz = -s $from;
 191     if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
 192       # will not rename with overwrite
 193       unlink $to;
 194     }
 195     return 1 if rename $from, $to;
 196
 197     ($sts,$ossts) = ($! + 0, $^E + 0);
 198     # Did rename return an error even though it succeeded, because $to
 199     # is on a remote NFS file system, and NFS lost the server's ack?
 200     return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
 201                 (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
 202                 ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
 203                 $tosz2 == $fromsz;                         # it's all there
 204
 205     ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
 206     return 1 if ($copied = copy($from,$to)) && unlink($from);
 207
 208     ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
 209     unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
 210     ($!,$^E) = ($sts,$ossts);
 211     return 0;
 212 }
 213
 214 *cp = \&copy;
 215 *mv = \&move;
 216
 217
 218 if ($^O eq 'MacOS') {
 219     *_protect = sub { MacPerl::MakeFSSpec($_[0]) };
 220 } else {
 221     *_protect = sub { "./$_[0]" };
 222 }
 223
 224 # &syscopy is an XSUB under OS/2
 225 unless (defined &syscopy) {
 226     if ($^O eq 'VMS') {
 227         *syscopy = \&rmscopy;
 228     } elsif ($^O eq 'mpeix') {
 229         *syscopy = sub {
 230             return 0 unless @_ == 2;
 231             # Use the MPE cp program in order to
 232             # preserve MPE file attributes.
 233             return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
 234         };
 235     } elsif ($^O eq 'MSWin32') {
 236         *syscopy = sub {
 237             return 0 unless @_ == 2;
 238             return Win32::CopyFile(@_, 1);
 239         };
 240     } elsif ($macfiles) {
 241         *syscopy = sub {
 242             my($from, $to) = @_;
 243             my($dir, $toname);
 244
 245             return 0 unless -e $from;
 246
 247             if ($to =~ /(.*:)([^:]+):?$/) {
 248                 ($dir, $toname) = ($1, $2);
 249             } else {
 250                 ($dir, $toname) = (":", $to);
 251             }
 252
 253             unlink($to);
 254             Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
 255         };
 256     } else {
 257         $Syscopy_is_copy = 1;
 258         *syscopy = \&copy;
 259     }
 260 }
 261
 262 1;
 263
 264 __END__
 265
 266 =head1 NAME
 267
 268 File::Copy - Copy files or filehandles
 269
 270 =head1 SYNOPSIS
 271
 272         use File::Copy;
 273
 274         copy("file1","file2");
 275         copy("Copy.pm",\*STDOUT);'
 276         move("/dev1/fileA","/dev2/fileB");
 277
 278         use POSIX;
 279         use File::Copy cp;
 280
 281         $n = FileHandle->new("/a/file","r");
 282         cp($n,"x");'
 283
 284 =head1 DESCRIPTION
 285
 286 The File::Copy module provides two basic functions, C<copy> and
 287 C<move>, which are useful for getting the contents of a file from
 288 one place to another.
 289
 290 =over 4
 291
 292 =item *
 293
 294 The C<copy> function takes two
 295 parameters: a file to copy from and a file to copy to. Either
 296 argument may be a string, a FileHandle reference or a FileHandle
 297 glob. Obviously, if the first argument is a filehandle of some
 298 sort, it will be read from, and if it is a file I<name> it will
 299 be opened for reading. Likewise, the second argument will be
 300 written to (and created if need be).  Trying to copy a file on top
 301 of itself is a fatal error.
 302
 303 B<Note that passing in
 304 files as handles instead of names may lead to loss of information
 305 on some operating systems; it is recommended that you use file
 306 names whenever possible.>  Files are opened in binary mode where
 307 applicable.  To get a consistent behaviour when copying from a
 308 filehandle to a file, use C<binmode> on the filehandle.
 309
 310 An optional third parameter can be used to specify the buffer
 311 size used for copying. This is the number of bytes from the
 312 first file, that wil be held in memory at any given time, before
 313 being written to the second file. The default buffer size depends
 314 upon the file, but will generally be the whole file (up to 2Mb), or
 315 1k for filehandles that do not reference files (eg. sockets).
 316
 317 You may use the syntax C<use File::Copy "cp"> to get at the
 318 "cp" alias for this function. The syntax is I<exactly> the same.
 319
 320 =item *
 321
 322 The C<move> function also takes two parameters: the current name
 323 and the intended name of the file to be moved.  If the destination
 324 already exists and is a directory, and the source is not a
 325 directory, then the source file will be renamed into the directory
 326 specified by the destination.
 327
 328 If possible, move() will simply rename the file.  Otherwise, it copies
 329 the file to the new location and deletes the original.  If an error occurs
 330 during this copy-and-delete process, you may be left with a (possibly partial)
 331 copy of the file under the destination name.
 332
 333 You may use the "mv" alias for this function in the same way that
 334 you may use the "cp" alias for C<copy>.
 335
 336 =back
 337
 338 File::Copy also provides the C<syscopy> routine, which copies the
 339 file specified in the first parameter to the file specified in the
 340 second parameter, preserving OS-specific attributes and file
 341 structure.  For Unix systems, this is equivalent to the simple
 342 C<copy> routine, which doesn't preserve OS-specific attributes.  For
 343 VMS systems, this calls the C<rmscopy> routine (see below).  For OS/2
 344 systems, this calls the C<syscopy> XSUB directly. For Win32 systems,
 345 this calls C<Win32::CopyFile>.
 346
 347 On Mac OS (Classic), C<syscopy> calls C<Mac::MoreFiles::FSpFileCopy>,
 348 if available.
 349
 350 =head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)
 351
 352 If both arguments to C<copy> are not file handles,
 353 then C<copy> will perform a "system copy" of
 354 the input file to a new output file, in order to preserve file
 355 attributes, indexed file structure, I<etc.>  The buffer size
 356 parameter is ignored.  If either argument to C<copy> is a
 357 handle to an opened file, then data is copied using Perl
 358 operators, and no effort is made to preserve file attributes
 359 or record structure.
 360
 361 The system copy routine may also be called directly under VMS and OS/2
 362 as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
 363 is the routine that does the actual work for syscopy).
 364
 365 =over 4
 366
 367 =item rmscopy($from,$to[,$date_flag])
 368
 369 The first and second arguments may be strings, typeglobs, typeglob
 370 references, or objects inheriting from IO::Handle;
 371 they are used in all cases to obtain the
 372 I<filespec> of the input and output files, respectively.  The
 373 name and type of the input file are used as defaults for the
 374 output file, if necessary.
 375
 376 A new version of the output file is always created, which
 377 inherits the structure and RMS attributes of the input file,
 378 except for owner and protections (and possibly timestamps;
 379 see below).  All data from the input file is copied to the
 380 output file; if either of the first two parameters to C<rmscopy>
 381 is a file handle, its position is unchanged.  (Note that this
 382 means a file handle pointing to the output file will be
 383 associated with an old version of that file after C<rmscopy>
 384 returns, not the newly created version.)
 385
 386 The third parameter is an integer flag, which tells C<rmscopy>
 387 how to handle timestamps.  If it is E<lt> 0, none of the input file's
 388 timestamps are propagated to the output file.  If it is E<gt> 0, then
 389 it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
 390 timestamps other than the revision date are propagated; if bit 1
 391 is set, the revision date is propagated.  If the third parameter
 392 to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
 393 if the name or type of the output file was explicitly specified,
 394 then no timestamps are propagated, but if they were taken implicitly
 395 from the input filespec, then all timestamps other than the
 396 revision date are propagated.  If this parameter is not supplied,
 397 it defaults to 0.
 398
 399 Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
 400 it sets C<$!>, deletes the output file, and returns 0.
 401
 402 =back
 403
 404 =head1 RETURN
 405
 406 All functions return 1 on success, 0 on failure.
 407 $! will be set if an error was encountered.
 408
 409 =head1 NOTES
 410
 411 =over 4
 412
 413 =item *
 414
 415 On Mac OS (Classic), the path separator is ':', not '/', and the
 416 current directory is denoted as ':', not '.'. You should be careful
 417 about specifying relative pathnames. While a full path always begins
 418 with a volume name, a relative pathname should always begin with a
 419 ':'.  If specifying a volume name only, a trailing ':' is required.
 420
 421 E.g.
 422
 423   copy("file1", "tmp");        # creates the file 'tmp' in the current directory
 424   copy("file1", ":tmp:");      # creates :tmp:file1
 425   copy("file1", ":tmp");       # same as above
 426   copy("file1", "tmp");        # same as above, if 'tmp' is a directory (but don't do
 427                                # that, since it may cause confusion, see example #1)
 428   copy("file1", "tmp:file1");  # error, since 'tmp:' is not a volume
 429   copy("file1", ":tmp:file1"); # ok, partial path
 430   copy("file1", "DataHD:");    # creates DataHD:file1
 431
 432   move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one
 433                                              # volume to another
 434
 435 =back
 436
 437 =head1 AUTHOR
 438
 439 File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
 440 and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
 441
 442 =cut
 443