lib/File/Copy.pm

   1 # File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
   2 # source code has been placed in the public domain by the author.
   3 # Please be kind and preserve the documentation.
   4 #
   5 # Additions copyright 1996 by Charles Bailey.  Permission is granted
   6 # to distribute the revised code under the same terms as Perl itself.
   7
   8 package File::Copy;
   9
  10 use 5.006;
  11 use strict;
  12 use warnings;
  13 use File::Spec;
  14 use Config;
  15 our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
  16 sub copy;
  17 sub syscopy;
  18 sub cp;
  19 sub mv;
  20
  21 # Note that this module implements only *part* of the API defined by
  22 # the File/Copy.pm module of the File-Tools-2.0 package.  However, that
  23 # package has not yet been updated to work with Perl 5.004, and so it
  24 # would be a Bad Thing for the CPAN module to grab it and replace this
  25 # module.  Therefore, we set this module's version higher than 2.0.
  26 $VERSION = '2.09';
  27
  28 require Exporter;
  29 @ISA = qw(Exporter);
  30 @EXPORT = qw(copy move);
  31 @EXPORT_OK = qw(cp mv);
  32
  33 $Too_Big = 1024 * 1024 * 2;
  34
  35 sub croak {
  36     require Carp;
  37     goto &Carp::croak;
  38 }
  39
  40 sub carp {
  41     require Carp;
  42     goto &Carp::carp;
  43 }
  44
  45 my $macfiles;
  46 if ($^O eq 'MacOS') {
  47         $macfiles = eval { require Mac::MoreFiles };
  48         warn 'Mac::MoreFiles could not be loaded; using non-native syscopy'
  49                 if $@ && $^W;
  50 }
  51
  52 sub _catname {
  53     my($from, $to) = @_;
  54     if (not defined &basename) {
  55         require File::Basename;
  56         import  File::Basename 'basename';
  57     }
  58
  59     if ($^O eq 'MacOS') {
  60         # a partial dir name that's valid only in the cwd (e.g. 'tmp')
  61         $to = ':' . $to if $to !~ /:/;
  62     }
  63
  64     return File::Spec->catfile($to, basename($from));
  65 }
  66
  67 sub copy {
  68     croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
  69       unless(@_ == 2 || @_ == 3);
  70
  71     my $from = shift;
  72     my $to = shift;
  73
  74     my $from_a_handle = (ref($from)
  75                          ? (ref($from) eq 'GLOB'
  76                             || UNIVERSAL::isa($from, 'GLOB')
  77                             || UNIVERSAL::isa($from, 'IO::Handle'))
  78                          : (ref(\$from) eq 'GLOB'));
  79     my $to_a_handle =   (ref($to)
  80                          ? (ref($to) eq 'GLOB'
  81                             || UNIVERSAL::isa($to, 'GLOB')
  82                             || UNIVERSAL::isa($to, 'IO::Handle'))
  83                          : (ref(\$to) eq 'GLOB'));
  84
  85     if ($from eq $to) { # works for references, too
  86         carp("'$from' and '$to' are identical (not copied)");
  87         # The "copy" was a success as the source and destination contain
  88         # the same data.
  89         return 1;
  90     }
  91
  92     if ((($Config{d_symlink} && $Config{d_readlink}) || $Config{d_link}) &&
  93         !($^O eq 'MSWin32' || $^O eq 'os2' || $^O eq 'vms')) {
  94         my @fs = stat($from);
  95         if (@fs) {
  96             my @ts = stat($to);
  97             if (@ts && $fs[0] == $ts[0] && $fs[1] == $ts[1]) {
  98                 carp("'$from' and '$to' are identical (not copied)");
  99                 return 0;
 100             }
 101         }
 102     }
 103
 104     if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
 105         $to = _catname($from, $to);
 106     }
 107
 108     if (defined &syscopy && !$Syscopy_is_copy
 109         && !$to_a_handle
 110         && !($from_a_handle && $^O eq 'os2' )   # OS/2 cannot handle handles
 111         && !($from_a_handle && $^O eq 'mpeix')  # and neither can MPE/iX.
 112         && !($from_a_handle && $^O eq 'MSWin32')
 113         && !($from_a_handle && $^O eq 'MacOS')
 114         && !($from_a_handle && $^O eq 'NetWare')
 115        )
 116     {
 117         return syscopy($from, $to);
 118     }
 119
 120     my $closefrom = 0;
 121     my $closeto = 0;
 122     my ($size, $status, $r, $buf);
 123     local($\) = '';
 124
 125     my $from_h;
 126     if ($from_a_handle) {
 127        $from_h = $from;
 128     } else {
 129         $from = _protect($from) if $from =~ /^\s/s;
 130        $from_h = \do { local *FH };
 131        open($from_h, "< $from\0") or goto fail_open1;
 132        binmode $from_h or die "($!,$^E)";
 133         $closefrom = 1;
 134     }
 135
 136     my $to_h;
 137     if ($to_a_handle) {
 138        $to_h = $to;
 139     } else {
 140         $to = _protect($to) if $to =~ /^\s/s;
 141        $to_h = \do { local *FH };
 142        open($to_h,"> $to\0") or goto fail_open2;
 143        binmode $to_h or die "($!,$^E)";
 144         $closeto = 1;
 145     }
 146
 147     if (@_) {
 148         $size = shift(@_) + 0;
 149         croak("Bad buffer size for copy: $size\n") unless ($size > 0);
 150     } else {
 151         $size = tied(*$from_h) ? 0 : -s $from_h || 0;
 152         $size = 1024 if ($size < 512);
 153         $size = $Too_Big if ($size > $Too_Big);
 154     }
 155
 156     $! = 0;
 157     for (;;) {
 158         my ($r, $w, $t);
 159        defined($r = sysread($from_h, $buf, $size))
 160             or goto fail_inner;
 161         last unless $r;
 162         for ($w = 0; $w < $r; $w += $t) {
 163            $t = syswrite($to_h, $buf, $r - $w, $w)
 164                 or goto fail_inner;
 165         }
 166     }
 167
 168     close($to_h) || goto fail_open2 if $closeto;
 169     close($from_h) || goto fail_open1 if $closefrom;
 170
 171     # Use this idiom to avoid uninitialized value warning.
 172     return 1;
 173
 174     # All of these contortions try to preserve error messages...
 175   fail_inner:
 176     if ($closeto) {
 177         $status = $!;
 178         $! = 0;
 179        close $to_h;
 180         $! = $status unless $!;
 181     }
 182   fail_open2:
 183     if ($closefrom) {
 184         $status = $!;
 185         $! = 0;
 186        close $from_h;
 187         $! = $status unless $!;
 188     }
 189   fail_open1:
 190     return 0;
 191 }
 192
 193 sub move {
 194     croak("Usage: move(FROM, TO) ") unless @_ == 2;
 195
 196     my($from,$to) = @_;
 197
 198     my($fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
 199
 200     if (-d $to && ! -d $from) {
 201         $to = _catname($from, $to);
 202     }
 203
 204     ($tosz1,$tomt1) = (stat($to))[7,9];
 205     $fromsz = -s $from;
 206     if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
 207       # will not rename with overwrite
 208       unlink $to;
 209     }
 210     return 1 if rename $from, $to;
 211
 212     # Did rename return an error even though it succeeded, because $to
 213     # is on a remote NFS file system, and NFS lost the server's ack?
 214     return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
 215                 (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
 216                 ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
 217                 $tosz2 == $fromsz;                         # it's all there
 218
 219     ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
 220
 221     {
 222         local $@;
 223         eval {
 224             local $SIG{__DIE__};
 225             copy($from,$to) or die;
 226             my($atime, $mtime) = (stat($from))[8,9];
 227             utime($atime, $mtime, $to);
 228             unlink($from)   or die;
 229         };
 230         return 1 unless $@;
 231     }
 232     ($sts,$ossts) = ($! + 0, $^E + 0);
 233
 234     ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
 235     unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
 236     ($!,$^E) = ($sts,$ossts);
 237     return 0;
 238 }
 239
 240 *cp = \&copy;
 241 *mv = \&move;
 242
 243
 244 if ($^O eq 'MacOS') {
 245     *_protect = sub { MacPerl::MakeFSSpec($_[0]) };
 246 } else {
 247     *_protect = sub { "./$_[0]" };
 248 }
 249
 250 # &syscopy is an XSUB under OS/2
 251 unless (defined &syscopy) {
 252     if ($^O eq 'VMS') {
 253         *syscopy = \&rmscopy;
 254     } elsif ($^O eq 'mpeix') {
 255         *syscopy = sub {
 256             return 0 unless @_ == 2;
 257             # Use the MPE cp program in order to
 258             # preserve MPE file attributes.
 259             return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
 260         };
 261     } elsif ($^O eq 'MSWin32') {
 262         *syscopy = sub {
 263             return 0 unless @_ == 2;
 264             return Win32::CopyFile(@_, 1);
 265         };
 266     } elsif ($macfiles) {
 267         *syscopy = sub {
 268             my($from, $to) = @_;
 269             my($dir, $toname);
 270
 271             return 0 unless -e $from;
 272
 273             if ($to =~ /(.*:)([^:]+):?$/) {
 274                 ($dir, $toname) = ($1, $2);
 275             } else {
 276                 ($dir, $toname) = (":", $to);
 277             }
 278
 279             unlink($to);
 280             Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
 281         };
 282     } else {
 283         $Syscopy_is_copy = 1;
 284         *syscopy = \&copy;
 285     }
 286 }
 287
 288 1;
 289
 290 __END__
 291
 292 =head1 NAME
 293
 294 File::Copy - Copy files or filehandles
 295
 296 =head1 SYNOPSIS
 297
 298         use File::Copy;
 299
 300         copy("file1","file2") or die "Copy failed: $!";
 301         copy("Copy.pm",\*STDOUT);
 302         move("/dev1/fileA","/dev2/fileB");
 303
 304         use File::Copy "cp";
 305
 306         $n = FileHandle->new("/a/file","r");
 307         cp($n,"x");
 308
 309 =head1 DESCRIPTION
 310
 311 The File::Copy module provides two basic functions, C<copy> and
 312 C<move>, which are useful for getting the contents of a file from
 313 one place to another.
 314
 315 =over 4
 316
 317 =item copy
 318 X<copy> X<cp>
 319
 320 The C<copy> function takes two
 321 parameters: a file to copy from and a file to copy to. Either
 322 argument may be a string, a FileHandle reference or a FileHandle
 323 glob. Obviously, if the first argument is a filehandle of some
 324 sort, it will be read from, and if it is a file I<name> it will
 325 be opened for reading. Likewise, the second argument will be
 326 written to (and created if need be).  Trying to copy a file on top
 327 of itself is a fatal error.
 328
 329 B<Note that passing in
 330 files as handles instead of names may lead to loss of information
 331 on some operating systems; it is recommended that you use file
 332 names whenever possible.>  Files are opened in binary mode where
 333 applicable.  To get a consistent behaviour when copying from a
 334 filehandle to a file, use C<binmode> on the filehandle.
 335
 336 An optional third parameter can be used to specify the buffer
 337 size used for copying. This is the number of bytes from the
 338 first file, that wil be held in memory at any given time, before
 339 being written to the second file. The default buffer size depends
 340 upon the file, but will generally be the whole file (up to 2Mb), or
 341 1k for filehandles that do not reference files (eg. sockets).
 342
 343 You may use the syntax C<use File::Copy "cp"> to get at the
 344 "cp" alias for this function. The syntax is I<exactly> the same.
 345
 346 =item move
 347 X<move> X<mv> X<rename>
 348
 349 The C<move> function also takes two parameters: the current name
 350 and the intended name of the file to be moved.  If the destination
 351 already exists and is a directory, and the source is not a
 352 directory, then the source file will be renamed into the directory
 353 specified by the destination.
 354
 355 If possible, move() will simply rename the file.  Otherwise, it copies
 356 the file to the new location and deletes the original.  If an error occurs
 357 during this copy-and-delete process, you may be left with a (possibly partial)
 358 copy of the file under the destination name.
 359
 360 You may use the "mv" alias for this function in the same way that
 361 you may use the "cp" alias for C<copy>.
 362
 363 =item syscopy
 364 X<syscopy>
 365
 366 File::Copy also provides the C<syscopy> routine, which copies the
 367 file specified in the first parameter to the file specified in the
 368 second parameter, preserving OS-specific attributes and file
 369 structure.  For Unix systems, this is equivalent to the simple
 370 C<copy> routine, which doesn't preserve OS-specific attributes.  For
 371 VMS systems, this calls the C<rmscopy> routine (see below).  For OS/2
 372 systems, this calls the C<syscopy> XSUB directly. For Win32 systems,
 373 this calls C<Win32::CopyFile>.
 374
 375 On Mac OS (Classic), C<syscopy> calls C<Mac::MoreFiles::FSpFileCopy>,
 376 if available.
 377
 378 B<Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)>
 379
 380 If both arguments to C<copy> are not file handles,
 381 then C<copy> will perform a "system copy" of
 382 the input file to a new output file, in order to preserve file
 383 attributes, indexed file structure, I<etc.>  The buffer size
 384 parameter is ignored.  If either argument to C<copy> is a
 385 handle to an opened file, then data is copied using Perl
 386 operators, and no effort is made to preserve file attributes
 387 or record structure.
 388
 389 The system copy routine may also be called directly under VMS and OS/2
 390 as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
 391 is the routine that does the actual work for syscopy).
 392
 393 =item rmscopy($from,$to[,$date_flag])
 394 X<rmscopy>
 395
 396 The first and second arguments may be strings, typeglobs, typeglob
 397 references, or objects inheriting from IO::Handle;
 398 they are used in all cases to obtain the
 399 I<filespec> of the input and output files, respectively.  The
 400 name and type of the input file are used as defaults for the
 401 output file, if necessary.
 402
 403 A new version of the output file is always created, which
 404 inherits the structure and RMS attributes of the input file,
 405 except for owner and protections (and possibly timestamps;
 406 see below).  All data from the input file is copied to the
 407 output file; if either of the first two parameters to C<rmscopy>
 408 is a file handle, its position is unchanged.  (Note that this
 409 means a file handle pointing to the output file will be
 410 associated with an old version of that file after C<rmscopy>
 411 returns, not the newly created version.)
 412
 413 The third parameter is an integer flag, which tells C<rmscopy>
 414 how to handle timestamps.  If it is E<lt> 0, none of the input file's
 415 timestamps are propagated to the output file.  If it is E<gt> 0, then
 416 it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
 417 timestamps other than the revision date are propagated; if bit 1
 418 is set, the revision date is propagated.  If the third parameter
 419 to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
 420 if the name or type of the output file was explicitly specified,
 421 then no timestamps are propagated, but if they were taken implicitly
 422 from the input filespec, then all timestamps other than the
 423 revision date are propagated.  If this parameter is not supplied,
 424 it defaults to 0.
 425
 426 Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
 427 it sets C<$!>, deletes the output file, and returns 0.
 428
 429 =back
 430
 431 =head1 RETURN
 432
 433 All functions return 1 on success, 0 on failure.
 434 $! will be set if an error was encountered.
 435
 436 =head1 NOTES
 437
 438 =over 4
 439
 440 =item *
 441
 442 On Mac OS (Classic), the path separator is ':', not '/', and the
 443 current directory is denoted as ':', not '.'. You should be careful
 444 about specifying relative pathnames. While a full path always begins
 445 with a volume name, a relative pathname should always begin with a
 446 ':'.  If specifying a volume name only, a trailing ':' is required.
 447
 448 E.g.
 449
 450   copy("file1", "tmp");        # creates the file 'tmp' in the current directory
 451   copy("file1", ":tmp:");      # creates :tmp:file1
 452   copy("file1", ":tmp");       # same as above
 453   copy("file1", "tmp");        # same as above, if 'tmp' is a directory (but don't do
 454                                # that, since it may cause confusion, see example #1)
 455   copy("file1", "tmp:file1");  # error, since 'tmp:' is not a volume
 456   copy("file1", ":tmp:file1"); # ok, partial path
 457   copy("file1", "DataHD:");    # creates DataHD:file1
 458
 459   move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one
 460                                              # volume to another
 461
 462 =back
 463
 464 =head1 AUTHOR
 465
 466 File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
 467 and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
 468
 469 =cut
 470