lib/File/Copy.pm

   1 # File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
   2 # source code has been placed in the public domain by the author.
   3 # Please be kind and preserve the documentation.
   4 #
   5 # Additions copyright 1996 by Charles Bailey.  Permission is granted
   6 # to distribute the revised code under the same terms as Perl itself.
   7
   8 package File::Copy;
   9
  10 use 5.006;
  11 use strict;
  12 use warnings;
  13 use File::Spec;
  14 use Config;
  15 our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
  16 sub copy;
  17 sub syscopy;
  18 sub cp;
  19 sub mv;
  20
  21 # Note that this module implements only *part* of the API defined by
  22 # the File/Copy.pm module of the File-Tools-2.0 package.  However, that
  23 # package has not yet been updated to work with Perl 5.004, and so it
  24 # would be a Bad Thing for the CPAN module to grab it and replace this
  25 # module.  Therefore, we set this module's version higher than 2.0.
  26 $VERSION = '2.10';
  27
  28 require Exporter;
  29 @ISA = qw(Exporter);
  30 @EXPORT = qw(copy move);
  31 @EXPORT_OK = qw(cp mv);
  32
  33 $Too_Big = 1024 * 1024 * 2;
  34
  35 sub croak {
  36     require Carp;
  37     goto &Carp::croak;
  38 }
  39
  40 sub carp {
  41     require Carp;
  42     goto &Carp::carp;
  43 }
  44
  45 my $macfiles;
  46 if ($^O eq 'MacOS') {
  47         $macfiles = eval { require Mac::MoreFiles };
  48         warn 'Mac::MoreFiles could not be loaded; using non-native syscopy'
  49                 if $@ && $^W;
  50 }
  51
  52 sub _catname {
  53     my($from, $to) = @_;
  54     if (not defined &basename) {
  55         require File::Basename;
  56         import  File::Basename 'basename';
  57     }
  58
  59     if ($^O eq 'MacOS') {
  60         # a partial dir name that's valid only in the cwd (e.g. 'tmp')
  61         $to = ':' . $to if $to !~ /:/;
  62     }
  63
  64     return File::Spec->catfile($to, basename($from));
  65 }
  66
  67 # _eq($from, $to) tells whether $from and $to are identical
  68 # works for strings and references
  69 sub _eq {
  70     return $_[0] == $_[1] if ref $_[0] && ref $_[1];
  71     return $_[0] eq $_[1] if !ref $_[0] && !ref $_[1];
  72     return "";
  73 }
  74
  75 sub copy {
  76     croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
  77       unless(@_ == 2 || @_ == 3);
  78
  79     my $from = shift;
  80     my $to = shift;
  81
  82     my $from_a_handle = (ref($from)
  83                          ? (ref($from) eq 'GLOB'
  84                             || UNIVERSAL::isa($from, 'GLOB')
  85                             || UNIVERSAL::isa($from, 'IO::Handle'))
  86                          : (ref(\$from) eq 'GLOB'));
  87     my $to_a_handle =   (ref($to)
  88                          ? (ref($to) eq 'GLOB'
  89                             || UNIVERSAL::isa($to, 'GLOB')
  90                             || UNIVERSAL::isa($to, 'IO::Handle'))
  91                          : (ref(\$to) eq 'GLOB'));
  92
  93     if (_eq($from, $to)) { # works for references, too
  94         carp("'$from' and '$to' are identical (not copied)");
  95         # The "copy" was a success as the source and destination contain
  96         # the same data.
  97         return 1;
  98     }
  99
 100     if ((($Config{d_symlink} && $Config{d_readlink}) || $Config{d_link}) &&
 101         !($^O eq 'MSWin32' || $^O eq 'os2' || $^O eq 'vms')) {
 102         my @fs = stat($from);
 103         if (@fs) {
 104             my @ts = stat($to);
 105             if (@ts && $fs[0] == $ts[0] && $fs[1] == $ts[1]) {
 106                 carp("'$from' and '$to' are identical (not copied)");
 107                 return 0;
 108             }
 109         }
 110     }
 111
 112     if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
 113         $to = _catname($from, $to);
 114     }
 115
 116     if (defined &syscopy && !$Syscopy_is_copy
 117         && !$to_a_handle
 118         && !($from_a_handle && $^O eq 'os2' )   # OS/2 cannot handle handles
 119         && !($from_a_handle && $^O eq 'mpeix')  # and neither can MPE/iX.
 120         && !($from_a_handle && $^O eq 'MSWin32')
 121         && !($from_a_handle && $^O eq 'MacOS')
 122         && !($from_a_handle && $^O eq 'NetWare')
 123        )
 124     {
 125         return syscopy($from, $to);
 126     }
 127
 128     my $closefrom = 0;
 129     my $closeto = 0;
 130     my ($size, $status, $r, $buf);
 131     local($\) = '';
 132
 133     my $from_h;
 134     if ($from_a_handle) {
 135        $from_h = $from;
 136     } else {
 137         $from = _protect($from) if $from =~ /^\s/s;
 138        $from_h = \do { local *FH };
 139        open($from_h, "< $from\0") or goto fail_open1;
 140        binmode $from_h or die "($!,$^E)";
 141         $closefrom = 1;
 142     }
 143
 144     my $to_h;
 145     if ($to_a_handle) {
 146        $to_h = $to;
 147     } else {
 148         $to = _protect($to) if $to =~ /^\s/s;
 149        $to_h = \do { local *FH };
 150        open($to_h,"> $to\0") or goto fail_open2;
 151        binmode $to_h or die "($!,$^E)";
 152         $closeto = 1;
 153     }
 154
 155     if (@_) {
 156         $size = shift(@_) + 0;
 157         croak("Bad buffer size for copy: $size\n") unless ($size > 0);
 158     } else {
 159         $size = tied(*$from_h) ? 0 : -s $from_h || 0;
 160         $size = 1024 if ($size < 512);
 161         $size = $Too_Big if ($size > $Too_Big);
 162     }
 163
 164     $! = 0;
 165     for (;;) {
 166         my ($r, $w, $t);
 167        defined($r = sysread($from_h, $buf, $size))
 168             or goto fail_inner;
 169         last unless $r;
 170         for ($w = 0; $w < $r; $w += $t) {
 171            $t = syswrite($to_h, $buf, $r - $w, $w)
 172                 or goto fail_inner;
 173         }
 174     }
 175
 176     close($to_h) || goto fail_open2 if $closeto;
 177     close($from_h) || goto fail_open1 if $closefrom;
 178
 179     # Use this idiom to avoid uninitialized value warning.
 180     return 1;
 181
 182     # All of these contortions try to preserve error messages...
 183   fail_inner:
 184     if ($closeto) {
 185         $status = $!;
 186         $! = 0;
 187        close $to_h;
 188         $! = $status unless $!;
 189     }
 190   fail_open2:
 191     if ($closefrom) {
 192         $status = $!;
 193         $! = 0;
 194        close $from_h;
 195         $! = $status unless $!;
 196     }
 197   fail_open1:
 198     return 0;
 199 }
 200
 201 sub move {
 202     croak("Usage: move(FROM, TO) ") unless @_ == 2;
 203
 204     my($from,$to) = @_;
 205
 206     my($fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
 207
 208     if (-d $to && ! -d $from) {
 209         $to = _catname($from, $to);
 210     }
 211
 212     ($tosz1,$tomt1) = (stat($to))[7,9];
 213     $fromsz = -s $from;
 214     if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
 215       # will not rename with overwrite
 216       unlink $to;
 217     }
 218     return 1 if rename $from, $to;
 219
 220     # Did rename return an error even though it succeeded, because $to
 221     # is on a remote NFS file system, and NFS lost the server's ack?
 222     return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
 223                 (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
 224                 ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
 225                 $tosz2 == $fromsz;                         # it's all there
 226
 227     ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
 228
 229     {
 230         local $@;
 231         eval {
 232             local $SIG{__DIE__};
 233             copy($from,$to) or die;
 234             my($atime, $mtime) = (stat($from))[8,9];
 235             utime($atime, $mtime, $to);
 236             unlink($from)   or die;
 237         };
 238         return 1 unless $@;
 239     }
 240     ($sts,$ossts) = ($! + 0, $^E + 0);
 241
 242     ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
 243     unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
 244     ($!,$^E) = ($sts,$ossts);
 245     return 0;
 246 }
 247
 248 *cp = \&copy;
 249 *mv = \&move;
 250
 251
 252 if ($^O eq 'MacOS') {
 253     *_protect = sub { MacPerl::MakeFSSpec($_[0]) };
 254 } else {
 255     *_protect = sub { "./$_[0]" };
 256 }
 257
 258 # &syscopy is an XSUB under OS/2
 259 unless (defined &syscopy) {
 260     if ($^O eq 'VMS') {
 261         *syscopy = \&rmscopy;
 262     } elsif ($^O eq 'mpeix') {
 263         *syscopy = sub {
 264             return 0 unless @_ == 2;
 265             # Use the MPE cp program in order to
 266             # preserve MPE file attributes.
 267             return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
 268         };
 269     } elsif ($^O eq 'MSWin32' && defined &DynaLoader::boot_DynaLoader) {
 270         # Win32::CopyFile() fill only work if we can load Win32.xs
 271         *syscopy = sub {
 272             return 0 unless @_ == 2;
 273             return Win32::CopyFile(@_, 1);
 274         };
 275     } elsif ($macfiles) {
 276         *syscopy = sub {
 277             my($from, $to) = @_;
 278             my($dir, $toname);
 279
 280             return 0 unless -e $from;
 281
 282             if ($to =~ /(.*:)([^:]+):?$/) {
 283                 ($dir, $toname) = ($1, $2);
 284             } else {
 285                 ($dir, $toname) = (":", $to);
 286             }
 287
 288             unlink($to);
 289             Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
 290         };
 291     } else {
 292         $Syscopy_is_copy = 1;
 293         *syscopy = \&copy;
 294     }
 295 }
 296
 297 1;
 298
 299 __END__
 300
 301 =head1 NAME
 302
 303 File::Copy - Copy files or filehandles
 304
 305 =head1 SYNOPSIS
 306
 307         use File::Copy;
 308
 309         copy("file1","file2") or die "Copy failed: $!";
 310         copy("Copy.pm",\*STDOUT);
 311         move("/dev1/fileA","/dev2/fileB");
 312
 313         use File::Copy "cp";
 314
 315         $n = FileHandle->new("/a/file","r");
 316         cp($n,"x");
 317
 318 =head1 DESCRIPTION
 319
 320 The File::Copy module provides two basic functions, C<copy> and
 321 C<move>, which are useful for getting the contents of a file from
 322 one place to another.
 323
 324 =over 4
 325
 326 =item copy
 327 X<copy> X<cp>
 328
 329 The C<copy> function takes two
 330 parameters: a file to copy from and a file to copy to. Either
 331 argument may be a string, a FileHandle reference or a FileHandle
 332 glob. Obviously, if the first argument is a filehandle of some
 333 sort, it will be read from, and if it is a file I<name> it will
 334 be opened for reading. Likewise, the second argument will be
 335 written to (and created if need be).  Trying to copy a file on top
 336 of itself is a fatal error.
 337
 338 B<Note that passing in
 339 files as handles instead of names may lead to loss of information
 340 on some operating systems; it is recommended that you use file
 341 names whenever possible.>  Files are opened in binary mode where
 342 applicable.  To get a consistent behaviour when copying from a
 343 filehandle to a file, use C<binmode> on the filehandle.
 344
 345 An optional third parameter can be used to specify the buffer
 346 size used for copying. This is the number of bytes from the
 347 first file, that will be held in memory at any given time, before
 348 being written to the second file. The default buffer size depends
 349 upon the file, but will generally be the whole file (up to 2MB), or
 350 1k for filehandles that do not reference files (eg. sockets).
 351
 352 You may use the syntax C<use File::Copy "cp"> to get at the
 353 "cp" alias for this function. The syntax is I<exactly> the same.
 354
 355 =item move
 356 X<move> X<mv> X<rename>
 357
 358 The C<move> function also takes two parameters: the current name
 359 and the intended name of the file to be moved.  If the destination
 360 already exists and is a directory, and the source is not a
 361 directory, then the source file will be renamed into the directory
 362 specified by the destination.
 363
 364 If possible, move() will simply rename the file.  Otherwise, it copies
 365 the file to the new location and deletes the original.  If an error occurs
 366 during this copy-and-delete process, you may be left with a (possibly partial)
 367 copy of the file under the destination name.
 368
 369 You may use the "mv" alias for this function in the same way that
 370 you may use the "cp" alias for C<copy>.
 371
 372 =item syscopy
 373 X<syscopy>
 374
 375 File::Copy also provides the C<syscopy> routine, which copies the
 376 file specified in the first parameter to the file specified in the
 377 second parameter, preserving OS-specific attributes and file
 378 structure.  For Unix systems, this is equivalent to the simple
 379 C<copy> routine, which doesn't preserve OS-specific attributes.  For
 380 VMS systems, this calls the C<rmscopy> routine (see below).  For OS/2
 381 systems, this calls the C<syscopy> XSUB directly. For Win32 systems,
 382 this calls C<Win32::CopyFile>.
 383
 384 On Mac OS (Classic), C<syscopy> calls C<Mac::MoreFiles::FSpFileCopy>,
 385 if available.
 386
 387 B<Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)>:
 388
 389 If both arguments to C<copy> are not file handles,
 390 then C<copy> will perform a "system copy" of
 391 the input file to a new output file, in order to preserve file
 392 attributes, indexed file structure, I<etc.>  The buffer size
 393 parameter is ignored.  If either argument to C<copy> is a
 394 handle to an opened file, then data is copied using Perl
 395 operators, and no effort is made to preserve file attributes
 396 or record structure.
 397
 398 The system copy routine may also be called directly under VMS and OS/2
 399 as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
 400 is the routine that does the actual work for syscopy).
 401
 402 =item rmscopy($from,$to[,$date_flag])
 403 X<rmscopy>
 404
 405 The first and second arguments may be strings, typeglobs, typeglob
 406 references, or objects inheriting from IO::Handle;
 407 they are used in all cases to obtain the
 408 I<filespec> of the input and output files, respectively.  The
 409 name and type of the input file are used as defaults for the
 410 output file, if necessary.
 411
 412 A new version of the output file is always created, which
 413 inherits the structure and RMS attributes of the input file,
 414 except for owner and protections (and possibly timestamps;
 415 see below).  All data from the input file is copied to the
 416 output file; if either of the first two parameters to C<rmscopy>
 417 is a file handle, its position is unchanged.  (Note that this
 418 means a file handle pointing to the output file will be
 419 associated with an old version of that file after C<rmscopy>
 420 returns, not the newly created version.)
 421
 422 The third parameter is an integer flag, which tells C<rmscopy>
 423 how to handle timestamps.  If it is E<lt> 0, none of the input file's
 424 timestamps are propagated to the output file.  If it is E<gt> 0, then
 425 it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
 426 timestamps other than the revision date are propagated; if bit 1
 427 is set, the revision date is propagated.  If the third parameter
 428 to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
 429 if the name or type of the output file was explicitly specified,
 430 then no timestamps are propagated, but if they were taken implicitly
 431 from the input filespec, then all timestamps other than the
 432 revision date are propagated.  If this parameter is not supplied,
 433 it defaults to 0.
 434
 435 Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
 436 it sets C<$!>, deletes the output file, and returns 0.
 437
 438 =back
 439
 440 =head1 RETURN
 441
 442 All functions return 1 on success, 0 on failure.
 443 $! will be set if an error was encountered.
 444
 445 =head1 NOTES
 446
 447 =over 4
 448
 449 =item *
 450
 451 On Mac OS (Classic), the path separator is ':', not '/', and the
 452 current directory is denoted as ':', not '.'. You should be careful
 453 about specifying relative pathnames. While a full path always begins
 454 with a volume name, a relative pathname should always begin with a
 455 ':'.  If specifying a volume name only, a trailing ':' is required.
 456
 457 E.g.
 458
 459   copy("file1", "tmp");        # creates the file 'tmp' in the current directory
 460   copy("file1", ":tmp:");      # creates :tmp:file1
 461   copy("file1", ":tmp");       # same as above
 462   copy("file1", "tmp");        # same as above, if 'tmp' is a directory (but don't do
 463                                # that, since it may cause confusion, see example #1)
 464   copy("file1", "tmp:file1");  # error, since 'tmp:' is not a volume
 465   copy("file1", ":tmp:file1"); # ok, partial path
 466   copy("file1", "DataHD:");    # creates DataHD:file1
 467
 468   move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one
 469                                              # volume to another
 470
 471 =back
 472
 473 =head1 AUTHOR
 474
 475 File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
 476 and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
 477
 478 =cut
 479