lib/File/Copy.pm

   1 # File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
   2 # source code has been placed in the public domain by the author.
   3 # Please be kind and preserve the documentation.
   4 #
   5 # Additions copyright 1996 by Charles Bailey.  Permission is granted
   6 # to distribute the revised code under the same terms as Perl itself.
   7
   8 package File::Copy;
   9
  10 use 5.6.0;
  11 use strict;
  12 use warnings;
  13 use Carp;
  14 use File::Spec;
  15 our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
  16 sub copy;
  17 sub syscopy;
  18 sub cp;
  19 sub mv;
  20
  21 # Note that this module implements only *part* of the API defined by
  22 # the File/Copy.pm module of the File-Tools-2.0 package.  However, that
  23 # package has not yet been updated to work with Perl 5.004, and so it
  24 # would be a Bad Thing for the CPAN module to grab it and replace this
  25 # module.  Therefore, we set this module's version higher than 2.0.
  26 $VERSION = '2.04';
  27
  28 require Exporter;
  29 @ISA = qw(Exporter);
  30 @EXPORT = qw(copy move);
  31 @EXPORT_OK = qw(cp mv);
  32
  33 $Too_Big = 1024 * 1024 * 2;
  34
  35 sub _catname {
  36     my($from, $to) = @_;
  37     if (not defined &basename) {
  38         require File::Basename;
  39         import  File::Basename 'basename';
  40     }
  41
  42     if ($^O eq 'MacOS') {
  43         # a partial dir name that's valid only in the cwd (e.g. 'tmp')
  44         $to = ':' . $to if $to !~ /:/;
  45     }
  46
  47     return File::Spec->catfile($to, basename($from));
  48 }
  49
  50 sub copy {
  51     croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
  52       unless(@_ == 2 || @_ == 3);
  53
  54     my $from = shift;
  55     my $to = shift;
  56
  57     my $from_a_handle = (ref($from)
  58                          ? (ref($from) eq 'GLOB'
  59                             || UNIVERSAL::isa($from, 'GLOB')
  60                             || UNIVERSAL::isa($from, 'IO::Handle'))
  61                          : (ref(\$from) eq 'GLOB'));
  62     my $to_a_handle =   (ref($to)
  63                          ? (ref($to) eq 'GLOB'
  64                             || UNIVERSAL::isa($to, 'GLOB')
  65                             || UNIVERSAL::isa($to, 'IO::Handle'))
  66                          : (ref(\$to) eq 'GLOB'));
  67
  68     if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
  69         $to = _catname($from, $to);
  70     }
  71
  72     if (defined &syscopy && !$Syscopy_is_copy
  73         && !$to_a_handle
  74         && !($from_a_handle && $^O eq 'os2' )   # OS/2 cannot handle handles
  75         && !($from_a_handle && $^O eq 'mpeix')  # and neither can MPE/iX.
  76         && !($from_a_handle && $^O eq 'MSWin32')
  77         && !($from_a_handle && $^O eq 'MacOS')
  78         && !($from_a_handle && $^O eq 'NetWare')
  79        )
  80     {
  81         return syscopy($from, $to);
  82     }
  83
  84     my $closefrom = 0;
  85     my $closeto = 0;
  86     my ($size, $status, $r, $buf);
  87     local(*FROM, *TO);
  88     local($\) = '';
  89
  90     if ($from_a_handle) {
  91         *FROM = *$from{FILEHANDLE};
  92     } else {
  93         $from = _protect($from) if $from =~ /^\s/s;
  94         open(FROM, "< $from\0") or goto fail_open1;
  95         binmode FROM or die "($!,$^E)";
  96         $closefrom = 1;
  97     }
  98
  99     if ($to_a_handle) {
 100         *TO = *$to{FILEHANDLE};
 101     } else {
 102         $to = _protect($to) if $to =~ /^\s/s;
 103         open(TO,"> $to\0") or goto fail_open2;
 104         binmode TO or die "($!,$^E)";
 105         $closeto = 1;
 106     }
 107
 108     if (@_) {
 109         $size = shift(@_) + 0;
 110         croak("Bad buffer size for copy: $size\n") unless ($size > 0);
 111     } else {
 112         $size = -s FROM;
 113         $size = 1024 if ($size < 512);
 114         $size = $Too_Big if ($size > $Too_Big);
 115     }
 116
 117     $! = 0;
 118     for (;;) {
 119         my ($r, $w, $t);
 120         defined($r = sysread(FROM, $buf, $size))
 121             or goto fail_inner;
 122         last unless $r;
 123         for ($w = 0; $w < $r; $w += $t) {
 124             $t = syswrite(TO, $buf, $r - $w, $w)
 125                 or goto fail_inner;
 126         }
 127     }
 128
 129     close(TO) || goto fail_open2 if $closeto;
 130     close(FROM) || goto fail_open1 if $closefrom;
 131
 132     # Use this idiom to avoid uninitialized value warning.
 133     return 1;
 134
 135     # All of these contortions try to preserve error messages...
 136   fail_inner:
 137     if ($closeto) {
 138         $status = $!;
 139         $! = 0;
 140         close TO;
 141         $! = $status unless $!;
 142     }
 143   fail_open2:
 144     if ($closefrom) {
 145         $status = $!;
 146         $! = 0;
 147         close FROM;
 148         $! = $status unless $!;
 149     }
 150   fail_open1:
 151     return 0;
 152 }
 153
 154 sub move {
 155     my($from,$to) = @_;
 156     my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
 157
 158     if (-d $to && ! -d $from) {
 159         $to = _catname($from, $to);
 160     }
 161
 162     ($tosz1,$tomt1) = (stat($to))[7,9];
 163     $fromsz = -s $from;
 164     if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
 165       # will not rename with overwrite
 166       unlink $to;
 167     }
 168     return 1 if rename $from, $to;
 169
 170     ($sts,$ossts) = ($! + 0, $^E + 0);
 171     # Did rename return an error even though it succeeded, because $to
 172     # is on a remote NFS file system, and NFS lost the server's ack?
 173     return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
 174                 (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
 175                 ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
 176                 $tosz2 == $fromsz;                         # it's all there
 177
 178     ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
 179     return 1 if ($copied = copy($from,$to)) && unlink($from);
 180
 181     ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
 182     unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
 183     ($!,$^E) = ($sts,$ossts);
 184     return 0;
 185 }
 186
 187 *cp = \&copy;
 188 *mv = \&move;
 189
 190
 191 if ($^O eq 'MacOS') {
 192     *_protect = sub { MacPerl::MakeFSSpec($_[0]) };
 193 } else {
 194     *_protect = sub { "./$_[0]" };
 195 }
 196
 197 # &syscopy is an XSUB under OS/2
 198 unless (defined &syscopy) {
 199     if ($^O eq 'VMS') {
 200         *syscopy = \&rmscopy;
 201     } elsif ($^O eq 'mpeix') {
 202         *syscopy = sub {
 203             return 0 unless @_ == 2;
 204             # Use the MPE cp program in order to
 205             # preserve MPE file attributes.
 206             return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
 207         };
 208     } elsif ($^O eq 'MSWin32') {
 209         *syscopy = sub {
 210             return 0 unless @_ == 2;
 211             return Win32::CopyFile(@_, 1);
 212         };
 213     } elsif ($^O eq 'MacOS') {
 214         require Mac::MoreFiles;
 215         *syscopy = sub {
 216             my($from, $to) = @_;
 217             my($dir, $toname);
 218
 219             return 0 unless -e $from;
 220
 221             if ($to =~ /(.*:)([^:]+):?$/) {
 222                 ($dir, $toname) = ($1, $2);
 223             } else {
 224                 ($dir, $toname) = (":", $to);
 225             }
 226
 227             unlink($to);
 228             Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
 229         };
 230     } else {
 231         $Syscopy_is_copy = 1;
 232         *syscopy = \&copy;
 233     }
 234 }
 235
 236 1;
 237
 238 __END__
 239
 240 =head1 NAME
 241
 242 File::Copy - Copy files or filehandles
 243
 244 =head1 SYNOPSIS
 245
 246         use File::Copy;
 247
 248         copy("file1","file2");
 249         copy("Copy.pm",\*STDOUT);'
 250         move("/dev1/fileA","/dev2/fileB");
 251
 252         use POSIX;
 253         use File::Copy cp;
 254
 255         $n = FileHandle->new("/a/file","r");
 256         cp($n,"x");'
 257
 258 =head1 DESCRIPTION
 259
 260 The File::Copy module provides two basic functions, C<copy> and
 261 C<move>, which are useful for getting the contents of a file from
 262 one place to another.
 263
 264 =over 4
 265
 266 =item *
 267
 268 The C<copy> function takes two
 269 parameters: a file to copy from and a file to copy to. Either
 270 argument may be a string, a FileHandle reference or a FileHandle
 271 glob. Obviously, if the first argument is a filehandle of some
 272 sort, it will be read from, and if it is a file I<name> it will
 273 be opened for reading. Likewise, the second argument will be
 274 written to (and created if need be).
 275
 276 B<Note that passing in
 277 files as handles instead of names may lead to loss of information
 278 on some operating systems; it is recommended that you use file
 279 names whenever possible.>  Files are opened in binary mode where
 280 applicable.  To get a consistent behaviour when copying from a
 281 filehandle to a file, use C<binmode> on the filehandle.
 282
 283 An optional third parameter can be used to specify the buffer
 284 size used for copying. This is the number of bytes from the
 285 first file, that wil be held in memory at any given time, before
 286 being written to the second file. The default buffer size depends
 287 upon the file, but will generally be the whole file (up to 2Mb), or
 288 1k for filehandles that do not reference files (eg. sockets).
 289
 290 You may use the syntax C<use File::Copy "cp"> to get at the
 291 "cp" alias for this function. The syntax is I<exactly> the same.
 292
 293 =item *
 294
 295 The C<move> function also takes two parameters: the current name
 296 and the intended name of the file to be moved.  If the destination
 297 already exists and is a directory, and the source is not a
 298 directory, then the source file will be renamed into the directory
 299 specified by the destination.
 300
 301 If possible, move() will simply rename the file.  Otherwise, it copies
 302 the file to the new location and deletes the original.  If an error occurs
 303 during this copy-and-delete process, you may be left with a (possibly partial)
 304 copy of the file under the destination name.
 305
 306 You may use the "mv" alias for this function in the same way that
 307 you may use the "cp" alias for C<copy>.
 308
 309 =back
 310
 311 File::Copy also provides the C<syscopy> routine, which copies the
 312 file specified in the first parameter to the file specified in the
 313 second parameter, preserving OS-specific attributes and file
 314 structure.  For Unix systems, this is equivalent to the simple
 315 C<copy> routine.  For VMS systems, this calls the C<rmscopy>
 316 routine (see below).  For OS/2 systems, this calls the C<syscopy>
 317 XSUB directly. For Win32 systems, this calls C<Win32::CopyFile>.
 318
 319 =head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)
 320
 321 If both arguments to C<copy> are not file handles,
 322 then C<copy> will perform a "system copy" of
 323 the input file to a new output file, in order to preserve file
 324 attributes, indexed file structure, I<etc.>  The buffer size
 325 parameter is ignored.  If either argument to C<copy> is a
 326 handle to an opened file, then data is copied using Perl
 327 operators, and no effort is made to preserve file attributes
 328 or record structure.
 329
 330 The system copy routine may also be called directly under VMS and OS/2
 331 as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
 332 is the routine that does the actual work for syscopy).
 333
 334 =over 4
 335
 336 =item rmscopy($from,$to[,$date_flag])
 337
 338 The first and second arguments may be strings, typeglobs, typeglob
 339 references, or objects inheriting from IO::Handle;
 340 they are used in all cases to obtain the
 341 I<filespec> of the input and output files, respectively.  The
 342 name and type of the input file are used as defaults for the
 343 output file, if necessary.
 344
 345 A new version of the output file is always created, which
 346 inherits the structure and RMS attributes of the input file,
 347 except for owner and protections (and possibly timestamps;
 348 see below).  All data from the input file is copied to the
 349 output file; if either of the first two parameters to C<rmscopy>
 350 is a file handle, its position is unchanged.  (Note that this
 351 means a file handle pointing to the output file will be
 352 associated with an old version of that file after C<rmscopy>
 353 returns, not the newly created version.)
 354
 355 The third parameter is an integer flag, which tells C<rmscopy>
 356 how to handle timestamps.  If it is E<lt> 0, none of the input file's
 357 timestamps are propagated to the output file.  If it is E<gt> 0, then
 358 it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
 359 timestamps other than the revision date are propagated; if bit 1
 360 is set, the revision date is propagated.  If the third parameter
 361 to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
 362 if the name or type of the output file was explicitly specified,
 363 then no timestamps are propagated, but if they were taken implicitly
 364 from the input filespec, then all timestamps other than the
 365 revision date are propagated.  If this parameter is not supplied,
 366 it defaults to 0.
 367
 368 Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
 369 it sets C<$!>, deletes the output file, and returns 0.
 370
 371 =back
 372
 373 =head1 RETURN
 374
 375 All functions return 1 on success, 0 on failure.
 376 $! will be set if an error was encountered.
 377
 378 =head1 NOTES
 379
 380 =over 4
 381
 382 =item *
 383
 384 On Mac OS (Classic), the path separator is ':', not '/', and the
 385 current directory is denoted as ':', not '.'. You should be careful
 386 about specifying relative pathnames. While a full path always begins
 387 with a volume name, a relative pathname should always begin with a
 388 ':'.  If specifying a volume name only, a trailing ':' is required.
 389
 390 E.g.
 391
 392   copy("file1", "tmp");        # creates the file 'tmp' in the current directory
 393   copy("file1", ":tmp:");      # creates :tmp:file1
 394   copy("file1", ":tmp");       # same as above
 395   copy("file1", "tmp");        # same as above, if 'tmp' is a directory (but don't do
 396                                # that, since it may cause confusion, see example #1)
 397   copy("file1", "tmp:file1");  # error, since 'tmp:' is not a volume
 398   copy("file1", ":tmp:file1"); # ok, partial path
 399   copy("file1", "DataHD:");    # creates DataHD:file1
 400
 401   move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one
 402                                              # volume to another
 403
 404 =back
 405
 406 =head1 AUTHOR
 407
 408 File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
 409 and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
 410
 411 =cut
 412