lib/File/Copy.pm

   1 # File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
   2 # source code has been placed in the public domain by the author.
   3 # Please be kind and preserve the documentation.
   4 #
   5 # Additions copyright 1996 by Charles Bailey.  Permission is granted
   6 # to distribute the revised code under the same terms as Perl itself.
   7
   8 package File::Copy;
   9
  10 use 5.006;
  11 use strict;
  12 use warnings;
  13 use File::Spec;
  14 use Config;
  15 our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
  16 sub copy;
  17 sub syscopy;
  18 sub cp;
  19 sub mv;
  20
  21 # Note that this module implements only *part* of the API defined by
  22 # the File/Copy.pm module of the File-Tools-2.0 package.  However, that
  23 # package has not yet been updated to work with Perl 5.004, and so it
  24 # would be a Bad Thing for the CPAN module to grab it and replace this
  25 # module.  Therefore, we set this module's version higher than 2.0.
  26 $VERSION = '2.12';
  27
  28 require Exporter;
  29 @ISA = qw(Exporter);
  30 @EXPORT = qw(copy move);
  31 @EXPORT_OK = qw(cp mv);
  32
  33 $Too_Big = 1024 * 1024 * 2;
  34
  35 sub croak {
  36     require Carp;
  37     goto &Carp::croak;
  38 }
  39
  40 sub carp {
  41     require Carp;
  42     goto &Carp::carp;
  43 }
  44
  45 my $macfiles;
  46 if ($^O eq 'MacOS') {
  47         $macfiles = eval { require Mac::MoreFiles };
  48         warn 'Mac::MoreFiles could not be loaded; using non-native syscopy'
  49                 if $@ && $^W;
  50 }
  51
  52 sub _catname {
  53     my($from, $to) = @_;
  54     if (not defined &basename) {
  55         require File::Basename;
  56         import  File::Basename 'basename';
  57     }
  58
  59     if ($^O eq 'MacOS') {
  60         # a partial dir name that's valid only in the cwd (e.g. 'tmp')
  61         $to = ':' . $to if $to !~ /:/;
  62     }
  63
  64     return File::Spec->catfile($to, basename($from));
  65 }
  66
  67 # _eq($from, $to) tells whether $from and $to are identical
  68 # works for strings and references
  69 sub _eq {
  70     return $_[0] == $_[1] if ref $_[0] && ref $_[1];
  71     return $_[0] eq $_[1] if !ref $_[0] && !ref $_[1];
  72     return "";
  73 }
  74
  75 sub copy {
  76     croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
  77       unless(@_ == 2 || @_ == 3);
  78
  79     my $from = shift;
  80     my $to = shift;
  81
  82     my $size;
  83     if (@_) {
  84         $size = shift(@_) + 0;
  85         croak("Bad buffer size for copy: $size\n") unless ($size > 0);
  86     }
  87
  88     my $from_a_handle = (ref($from)
  89                          ? (ref($from) eq 'GLOB'
  90                             || UNIVERSAL::isa($from, 'GLOB')
  91                             || UNIVERSAL::isa($from, 'IO::Handle'))
  92                          : (ref(\$from) eq 'GLOB'));
  93     my $to_a_handle =   (ref($to)
  94                          ? (ref($to) eq 'GLOB'
  95                             || UNIVERSAL::isa($to, 'GLOB')
  96                             || UNIVERSAL::isa($to, 'IO::Handle'))
  97                          : (ref(\$to) eq 'GLOB'));
  98
  99     if (_eq($from, $to)) { # works for references, too
 100         carp("'$from' and '$to' are identical (not copied)");
 101         # The "copy" was a success as the source and destination contain
 102         # the same data.
 103         return 1;
 104     }
 105
 106     if ((($Config{d_symlink} && $Config{d_readlink}) || $Config{d_link}) &&
 107         !($^O eq 'MSWin32' || $^O eq 'os2')) {
 108         my @fs = stat($from);
 109         if (@fs) {
 110             my @ts = stat($to);
 111             if (@ts && $fs[0] == $ts[0] && $fs[1] == $ts[1]) {
 112                 carp("'$from' and '$to' are identical (not copied)");
 113                 return 0;
 114             }
 115         }
 116     }
 117
 118     if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
 119         $to = _catname($from, $to);
 120     }
 121
 122     if (defined &syscopy && !$Syscopy_is_copy
 123         && !$to_a_handle
 124         && !($from_a_handle && $^O eq 'os2' )   # OS/2 cannot handle handles
 125         && !($from_a_handle && $^O eq 'mpeix')  # and neither can MPE/iX.
 126         && !($from_a_handle && $^O eq 'MSWin32')
 127         && !($from_a_handle && $^O eq 'MacOS')
 128         && !($from_a_handle && $^O eq 'NetWare')
 129        )
 130     {
 131         my $copy_to = $to;
 132
 133         if ($^O eq 'VMS' && -e $from) {
 134
 135             if (! -d $to && ! -d $from) {
 136
 137                 # VMS has sticky defaults on extensions, which means that
 138                 # if there is a null extension on the destination file, it
 139                 # will inherit the extension of the source file
 140                 # So add a '.' for a null extension.
 141
 142                 $copy_to = VMS::Filespec::vmsify($to);
 143                 my ($vol, $dirs, $file) = File::Spec->splitpath($copy_to);
 144                 $file = $file . '.' unless ($file =~ /(?<!\^)\./);
 145                 $copy_to = File::Spec->catpath($vol, $dirs, $file);
 146
 147                 # Get rid of the old versions to be like UNIX
 148                 1 while unlink $copy_to;
 149             }
 150         }
 151
 152         return syscopy($from, $copy_to);
 153     }
 154
 155     my $closefrom = 0;
 156     my $closeto = 0;
 157     my ($status, $r, $buf);
 158     local($\) = '';
 159
 160     my $from_h;
 161     if ($from_a_handle) {
 162        $from_h = $from;
 163     } else {
 164         $from = _protect($from) if $from =~ /^\s/s;
 165        $from_h = \do { local *FH };
 166        open $from_h, "<", $from or goto fail_open1;
 167        binmode $from_h or die "($!,$^E)";
 168         $closefrom = 1;
 169     }
 170
 171     # Seems most logical to do this here, in case future changes would want to
 172     # make this croak for some reason.
 173     unless (defined $size) {
 174         $size = tied(*$from_h) ? 0 : -s $from_h || 0;
 175         $size = 1024 if ($size < 512);
 176         $size = $Too_Big if ($size > $Too_Big);
 177     }
 178
 179     my $to_h;
 180     if ($to_a_handle) {
 181        $to_h = $to;
 182     } else {
 183         $to = _protect($to) if $to =~ /^\s/s;
 184        $to_h = \do { local *FH };
 185        open $to_h, ">", $to or goto fail_open2;
 186        binmode $to_h or die "($!,$^E)";
 187         $closeto = 1;
 188     }
 189
 190     $! = 0;
 191     for (;;) {
 192         my ($r, $w, $t);
 193        defined($r = sysread($from_h, $buf, $size))
 194             or goto fail_inner;
 195         last unless $r;
 196         for ($w = 0; $w < $r; $w += $t) {
 197            $t = syswrite($to_h, $buf, $r - $w, $w)
 198                 or goto fail_inner;
 199         }
 200     }
 201
 202     close($to_h) || goto fail_open2 if $closeto;
 203     close($from_h) || goto fail_open1 if $closefrom;
 204
 205     # Use this idiom to avoid uninitialized value warning.
 206     return 1;
 207
 208     # All of these contortions try to preserve error messages...
 209   fail_inner:
 210     if ($closeto) {
 211         $status = $!;
 212         $! = 0;
 213        close $to_h;
 214         $! = $status unless $!;
 215     }
 216   fail_open2:
 217     if ($closefrom) {
 218         $status = $!;
 219         $! = 0;
 220        close $from_h;
 221         $! = $status unless $!;
 222     }
 223   fail_open1:
 224     return 0;
 225 }
 226
 227 sub move {
 228     croak("Usage: move(FROM, TO) ") unless @_ == 2;
 229
 230     my($from,$to) = @_;
 231
 232     my($fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
 233
 234     if (-d $to && ! -d $from) {
 235         $to = _catname($from, $to);
 236     }
 237
 238     ($tosz1,$tomt1) = (stat($to))[7,9];
 239     $fromsz = -s $from;
 240     if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
 241       # will not rename with overwrite
 242       unlink $to;
 243     }
 244
 245     my $rename_to = $to;
 246     if (-$^O eq 'VMS' && -e $from) {
 247
 248         if (! -d $to && ! -d $from) {
 249             # VMS has sticky defaults on extensions, which means that
 250             # if there is a null extension on the destination file, it
 251             # will inherit the extension of the source file
 252             # So add a '.' for a null extension.
 253
 254             $rename_to = VMS::Filespec::vmsify($to);
 255             my ($vol, $dirs, $file) = File::Spec->splitpath($rename_to);
 256             $file = $file . '.' unless ($file =~ /(?<!\^)\./);
 257             $rename_to = File::Spec->catpath($vol, $dirs, $file);
 258
 259             # Get rid of the old versions to be like UNIX
 260             1 while unlink $rename_to;
 261         }
 262     }
 263
 264     return 1 if rename $from, $rename_to;
 265
 266     # Did rename return an error even though it succeeded, because $to
 267     # is on a remote NFS file system, and NFS lost the server's ack?
 268     return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
 269                 (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
 270                   ((!defined $tosz1) ||                    #  not before or
 271                    ($tosz1 != $tosz2 or $tomt1 != $tomt2)) &&  #   was changed
 272                 $tosz2 == $fromsz;                         # it's all there
 273
 274     ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
 275
 276     {
 277         local $@;
 278         eval {
 279             local $SIG{__DIE__};
 280             copy($from,$to) or die;
 281             my($atime, $mtime) = (stat($from))[8,9];
 282             utime($atime, $mtime, $to);
 283             unlink($from)   or die;
 284         };
 285         return 1 unless $@;
 286     }
 287     ($sts,$ossts) = ($! + 0, $^E + 0);
 288
 289     ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
 290     unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
 291     ($!,$^E) = ($sts,$ossts);
 292     return 0;
 293 }
 294
 295 *cp = \&copy;
 296 *mv = \&move;
 297
 298
 299 if ($^O eq 'MacOS') {
 300     *_protect = sub { MacPerl::MakeFSSpec($_[0]) };
 301 } else {
 302     *_protect = sub { "./$_[0]" };
 303 }
 304
 305 # &syscopy is an XSUB under OS/2
 306 unless (defined &syscopy) {
 307     if ($^O eq 'VMS') {
 308         *syscopy = \&rmscopy;
 309     } elsif ($^O eq 'mpeix') {
 310         *syscopy = sub {
 311             return 0 unless @_ == 2;
 312             # Use the MPE cp program in order to
 313             # preserve MPE file attributes.
 314             return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
 315         };
 316     } elsif ($^O eq 'MSWin32' && defined &DynaLoader::boot_DynaLoader) {
 317         # Win32::CopyFile() fill only work if we can load Win32.xs
 318         *syscopy = sub {
 319             return 0 unless @_ == 2;
 320             return Win32::CopyFile(@_, 1);
 321         };
 322     } elsif ($macfiles) {
 323         *syscopy = sub {
 324             my($from, $to) = @_;
 325             my($dir, $toname);
 326
 327             return 0 unless -e $from;
 328
 329             if ($to =~ /(.*:)([^:]+):?$/) {
 330                 ($dir, $toname) = ($1, $2);
 331             } else {
 332                 ($dir, $toname) = (":", $to);
 333             }
 334
 335             unlink($to);
 336             Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
 337         };
 338     } else {
 339         $Syscopy_is_copy = 1;
 340         *syscopy = \&copy;
 341     }
 342 }
 343
 344 1;
 345
 346 __END__
 347
 348 =head1 NAME
 349
 350 File::Copy - Copy files or filehandles
 351
 352 =head1 SYNOPSIS
 353
 354         use File::Copy;
 355
 356         copy("file1","file2") or die "Copy failed: $!";
 357         copy("Copy.pm",\*STDOUT);
 358         move("/dev1/fileA","/dev2/fileB");
 359
 360         use File::Copy "cp";
 361
 362         $n = FileHandle->new("/a/file","r");
 363         cp($n,"x");
 364
 365 =head1 DESCRIPTION
 366
 367 The File::Copy module provides two basic functions, C<copy> and
 368 C<move>, which are useful for getting the contents of a file from
 369 one place to another.
 370
 371 =over 4
 372
 373 =item copy
 374 X<copy> X<cp>
 375
 376 The C<copy> function takes two
 377 parameters: a file to copy from and a file to copy to. Either
 378 argument may be a string, a FileHandle reference or a FileHandle
 379 glob. Obviously, if the first argument is a filehandle of some
 380 sort, it will be read from, and if it is a file I<name> it will
 381 be opened for reading. Likewise, the second argument will be
 382 written to (and created if need be).  Trying to copy a file on top
 383 of itself is a fatal error.
 384
 385 B<Note that passing in
 386 files as handles instead of names may lead to loss of information
 387 on some operating systems; it is recommended that you use file
 388 names whenever possible.>  Files are opened in binary mode where
 389 applicable.  To get a consistent behaviour when copying from a
 390 filehandle to a file, use C<binmode> on the filehandle.
 391
 392 An optional third parameter can be used to specify the buffer
 393 size used for copying. This is the number of bytes from the
 394 first file, that will be held in memory at any given time, before
 395 being written to the second file. The default buffer size depends
 396 upon the file, but will generally be the whole file (up to 2MB), or
 397 1k for filehandles that do not reference files (eg. sockets).
 398
 399 You may use the syntax C<use File::Copy "cp"> to get at the
 400 "cp" alias for this function. The syntax is I<exactly> the same.
 401
 402 =item move
 403 X<move> X<mv> X<rename>
 404
 405 The C<move> function also takes two parameters: the current name
 406 and the intended name of the file to be moved.  If the destination
 407 already exists and is a directory, and the source is not a
 408 directory, then the source file will be renamed into the directory
 409 specified by the destination.
 410
 411 If possible, move() will simply rename the file.  Otherwise, it copies
 412 the file to the new location and deletes the original.  If an error occurs
 413 during this copy-and-delete process, you may be left with a (possibly partial)
 414 copy of the file under the destination name.
 415
 416 You may use the "mv" alias for this function in the same way that
 417 you may use the "cp" alias for C<copy>.
 418
 419 =item syscopy
 420 X<syscopy>
 421
 422 File::Copy also provides the C<syscopy> routine, which copies the
 423 file specified in the first parameter to the file specified in the
 424 second parameter, preserving OS-specific attributes and file
 425 structure.  For Unix systems, this is equivalent to the simple
 426 C<copy> routine, which doesn't preserve OS-specific attributes.  For
 427 VMS systems, this calls the C<rmscopy> routine (see below).  For OS/2
 428 systems, this calls the C<syscopy> XSUB directly. For Win32 systems,
 429 this calls C<Win32::CopyFile>.
 430
 431 On Mac OS (Classic), C<syscopy> calls C<Mac::MoreFiles::FSpFileCopy>,
 432 if available.
 433
 434 B<Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)>:
 435
 436 If both arguments to C<copy> are not file handles,
 437 then C<copy> will perform a "system copy" of
 438 the input file to a new output file, in order to preserve file
 439 attributes, indexed file structure, I<etc.>  The buffer size
 440 parameter is ignored.  If either argument to C<copy> is a
 441 handle to an opened file, then data is copied using Perl
 442 operators, and no effort is made to preserve file attributes
 443 or record structure.
 444
 445 The system copy routine may also be called directly under VMS and OS/2
 446 as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
 447 is the routine that does the actual work for syscopy).
 448
 449 =item rmscopy($from,$to[,$date_flag])
 450 X<rmscopy>
 451
 452 The first and second arguments may be strings, typeglobs, typeglob
 453 references, or objects inheriting from IO::Handle;
 454 they are used in all cases to obtain the
 455 I<filespec> of the input and output files, respectively.  The
 456 name and type of the input file are used as defaults for the
 457 output file, if necessary.
 458
 459 A new version of the output file is always created, which
 460 inherits the structure and RMS attributes of the input file,
 461 except for owner and protections (and possibly timestamps;
 462 see below).  All data from the input file is copied to the
 463 output file; if either of the first two parameters to C<rmscopy>
 464 is a file handle, its position is unchanged.  (Note that this
 465 means a file handle pointing to the output file will be
 466 associated with an old version of that file after C<rmscopy>
 467 returns, not the newly created version.)
 468
 469 The third parameter is an integer flag, which tells C<rmscopy>
 470 how to handle timestamps.  If it is E<lt> 0, none of the input file's
 471 timestamps are propagated to the output file.  If it is E<gt> 0, then
 472 it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
 473 timestamps other than the revision date are propagated; if bit 1
 474 is set, the revision date is propagated.  If the third parameter
 475 to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
 476 if the name or type of the output file was explicitly specified,
 477 then no timestamps are propagated, but if they were taken implicitly
 478 from the input filespec, then all timestamps other than the
 479 revision date are propagated.  If this parameter is not supplied,
 480 it defaults to 0.
 481
 482 Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
 483 it sets C<$!>, deletes the output file, and returns 0.
 484
 485 =back
 486
 487 =head1 RETURN
 488
 489 All functions return 1 on success, 0 on failure.
 490 $! will be set if an error was encountered.
 491
 492 =head1 NOTES
 493
 494 =over 4
 495
 496 =item *
 497
 498 On Mac OS (Classic), the path separator is ':', not '/', and the
 499 current directory is denoted as ':', not '.'. You should be careful
 500 about specifying relative pathnames. While a full path always begins
 501 with a volume name, a relative pathname should always begin with a
 502 ':'.  If specifying a volume name only, a trailing ':' is required.
 503
 504 E.g.
 505
 506   copy("file1", "tmp");        # creates the file 'tmp' in the current directory
 507   copy("file1", ":tmp:");      # creates :tmp:file1
 508   copy("file1", ":tmp");       # same as above
 509   copy("file1", "tmp");        # same as above, if 'tmp' is a directory (but don't do
 510                                # that, since it may cause confusion, see example #1)
 511   copy("file1", "tmp:file1");  # error, since 'tmp:' is not a volume
 512   copy("file1", ":tmp:file1"); # ok, partial path
 513   copy("file1", "DataHD:");    # creates DataHD:file1
 514
 515   move("MacintoshHD:fileA", "DataHD:fileB"); # moves (doesn't copy) files from one
 516                                              # volume to another
 517
 518 =back
 519
 520 =head1 AUTHOR
 521
 522 File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
 523 and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
 524
 525 =cut
 526