lib/File/Copy.pm

   1 # File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
   2 # source code has been placed in the public domain by the author.
   3 # Please be kind and preserve the documentation.
   4 #
   5 # Additions copyright 1996 by Charles Bailey.  Permission is granted
   6 # to distribute the revised code under the same terms as Perl itself.
   7
   8 package File::Copy;
   9
  10 use 5.006;
  11 use strict;
  12 use warnings;
  13 use Carp;
  14 use File::Spec;
  15 use Config;
  16 our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
  17 sub copy;
  18 sub syscopy;
  19 sub cp;
  20 sub mv;
  21
  22 # Note that this module implements only *part* of the API defined by
  23 # the File/Copy.pm module of the File-Tools-2.0 package.  However, that
  24 # package has not yet been updated to work with Perl 5.004, and so it
  25 # would be a Bad Thing for the CPAN module to grab it and replace this
  26 # module.  Therefore, we set this module's version higher than 2.0.
  27 $VERSION = '2.05';
  28
  29 require Exporter;
  30 @ISA = qw(Exporter);
  31 @EXPORT = qw(copy move);
  32 @EXPORT_OK = qw(cp mv);
  33
  34 $Too_Big = 1024 * 1024 * 2;
  35
  36 sub _catname {
  37     my($from, $to) = @_;
  38     if (not defined &basename) {
  39         require File::Basename;
  40         import  File::Basename 'basename';
  41     }
  42
  43     if ($^O eq 'MacOS') {
  44         # a partial dir name that's valid only in the cwd (e.g. 'tmp')
  45         $to = ':' . $to if $to !~ /:/;
  46     }
  47
  48     return File::Spec->catfile($to, basename($from));
  49 }
  50
  51 sub copy {
  52     croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
  53       unless(@_ == 2 || @_ == 3);
  54
  55     my $from = shift;
  56     my $to = shift;
  57
  58     my $from_a_handle = (ref($from)
  59                          ? (ref($from) eq 'GLOB'
  60                             || UNIVERSAL::isa($from, 'GLOB')
  61                             || UNIVERSAL::isa($from, 'IO::Handle'))
  62                          : (ref(\$from) eq 'GLOB'));
  63     my $to_a_handle =   (ref($to)
  64                          ? (ref($to) eq 'GLOB'
  65                             || UNIVERSAL::isa($to, 'GLOB')
  66                             || UNIVERSAL::isa($to, 'IO::Handle'))
  67                          : (ref(\$to) eq 'GLOB'));
  68
  69     if ($from eq $to) { # works for references, too
  70         croak("'$from' and '$to' are identical (not copied)");
  71     }
  72
  73     if ($Config{d_symlink} && $Config{d_readlink} &&
  74         !($^O eq 'Win32' || $^O eq 'os2' || $^O eq 'vms')) {
  75         if ((-e $from && -l $from) || (-e $to && -l $to)) {
  76             my @fs = stat($from);
  77             my @ts = stat($to);
  78             if (@fs && @ts && $fs[0] == $ts[0] && $fs[1] == $ts[1]) {
  79                 croak("'$from' and '$to' are identical (not copied)");
  80             }
  81         }
  82     }
  83
  84     if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
  85         $to = _catname($from, $to);
  86     }
  87
  88     if (defined &syscopy && !$Syscopy_is_copy
  89         && !$to_a_handle
  90         && !($from_a_handle && $^O eq 'os2' )   # OS/2 cannot handle handles
  91         && !($from_a_handle && $^O eq 'mpeix')  # and neither can MPE/iX.
  92         && !($from_a_handle && $^O eq 'MSWin32')
  93         && !($from_a_handle && $^O eq 'MacOS')
  94         && !($from_a_handle && $^O eq 'NetWare')
  95        )
  96     {
  97         return syscopy($from, $to);
  98     }
  99
 100     my $closefrom = 0;
 101     my $closeto = 0;
 102     my ($size, $status, $r, $buf);
 103     local($\) = '';
 104
 105     my $from_h;
 106     if ($from_a_handle) {
 107        $from_h = $from;
 108     } else {
 109         $from = _protect($from) if $from =~ /^\s/s;
 110        $from_h = \do { local *FH };
 111        open($from_h, "< $from\0") or goto fail_open1;
 112        binmode $from_h or die "($!,$^E)";
 113         $closefrom = 1;
 114     }
 115
 116     my $to_h;
 117     if ($to_a_handle) {
 118        $to_h = $to;
 119     } else {
 120         $to = _protect($to) if $to =~ /^\s/s;
 121        $to_h = \do { local *FH };
 122        open($to_h,"> $to\0") or goto fail_open2;
 123        binmode $to_h or die "($!,$^E)";
 124         $closeto = 1;
 125     }
 126
 127     if (@_) {
 128         $size = shift(@_) + 0;
 129         croak("Bad buffer size for copy: $size\n") unless ($size > 0);
 130     } else {
 131        no warnings 'uninitialized';
 132        $size = -s $from_h;
 133         $size = 1024 if ($size < 512);
 134         $size = $Too_Big if ($size > $Too_Big);
 135     }
 136
 137     $! = 0;
 138     for (;;) {
 139         my ($r, $w, $t);
 140        defined($r = sysread($from_h, $buf, $size))
 141             or goto fail_inner;
 142         last unless $r;
 143         for ($w = 0; $w < $r; $w += $t) {
 144            $t = syswrite($to_h, $buf, $r - $w, $w)
 145                 or goto fail_inner;
 146         }
 147     }
 148
 149     close($to_h) || goto fail_open2 if $closeto;
 150     close($from_h) || goto fail_open1 if $closefrom;
 151
 152     # Use this idiom to avoid uninitialized value warning.
 153     return 1;
 154
 155     # All of these contortions try to preserve error messages...
 156   fail_inner:
 157     if ($closeto) {
 158         $status = $!;
 159         $! = 0;
 160        close $to_h;
 161         $! = $status unless $!;
 162     }
 163   fail_open2:
 164     if ($closefrom) {
 165         $status = $!;
 166         $! = 0;
 167        close $from_h;
 168         $! = $status unless $!;
 169     }
 170   fail_open1:
 171     return 0;
 172 }
 173
 174 sub move {
 175     my($from,$to) = @_;
 176     my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
 177
 178     if (-d $to && ! -d $from) {
 179         $to = _catname($from, $to);
 180     }
 181
 182     ($tosz1,$tomt1) = (stat($to))[7,9];
 183     $fromsz = -s $from;
 184     if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
 185       # will not rename with overwrite
 186       unlink $to;
 187     }
 188     return 1 if rename $from, $to;
 189
 190     ($sts,$ossts) = ($! + 0, $^E + 0);
 191     # Did rename return an error even though it succeeded, because $to
 192     # is on a remote NFS file system, and NFS lost the server's ack?
 193     return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
 194                 (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
 195                 ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
 196                 $tosz2 == $fromsz;                         # it's all there
 197
 198     ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
 199     return 1 if ($copied = copy($from,$to)) && unlink($from);
 200
 201     ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
 202     unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
 203     ($!,$^E) = ($sts,$ossts);
 204     return 0;
 205 }
 206
 207 *cp = \&copy;
 208 *mv = \&move;
 209
 210
 211 if ($^O eq 'MacOS') {
 212     *_protect = sub { MacPerl::MakeFSSpec($_[0]) };
 213 } else {
 214     *_protect = sub { "./$_[0]" };
 215 }
 216
 217 # &syscopy is an XSUB under OS/2
 218 unless (defined &syscopy) {
 219     if ($^O eq 'VMS') {
 220         *syscopy = \&rmscopy;
 221     } elsif ($^O eq 'mpeix') {
 222         *syscopy = sub {
 223             return 0 unless @_ == 2;
 224             # Use the MPE cp program in order to
 225             # preserve MPE file attributes.
 226             return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
 227         };
 228     } elsif ($^O eq 'MSWin32') {
 229         *syscopy = sub {
 230             return 0 unless @_ == 2;
 231             return Win32::CopyFile(@_, 1);
 232         };
 233     } elsif ($^O eq 'MacOS') {
 234         require Mac::MoreFiles;
 235         *syscopy = sub {
 236             my($from, $to) = @_;
 237             my($dir, $toname);
 238
 239             return 0 unless -e $from;
 240
 241             if ($to =~ /(.*:)([^:]+):?$/) {
 242                 ($dir, $toname) = ($1, $2);
 243             } else {
 244                 ($dir, $toname) = (":", $to);
 245             }
 246
 247             unlink($to);
 248             Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
 249         };
 250     } else {
 251         $Syscopy_is_copy = 1;
 252         *syscopy = \&copy;
 253     }
 254 }
 255
 256 1;
 257
 258 __END__
 259
 260 =head1 NAME
 261
 262 File::Copy - Copy files or filehandles
 263
 264 =head1 SYNOPSIS
 265
 266         use File::Copy;
 267
 268         copy("file1","file2");
 269         copy("Copy.pm",\*STDOUT);'
 270         move("/dev1/fileA","/dev2/fileB");
 271
 272         use POSIX;
 273         use File::Copy cp;
 274
 275         $n = FileHandle->new("/a/file","r");
 276         cp($n,"x");'
 277
 278 =head1 DESCRIPTION
 279
 280 The File::Copy module provides two basic functions, C<copy> and
 281 C<move>, which are useful for getting the contents of a file from
 282 one place to another.
 283
 284 =over 4
 285
 286 =item *
 287
 288 The C<copy> function takes two
 289 parameters: a file to copy from and a file to copy to. Either
 290 argument may be a string, a FileHandle reference or a FileHandle
 291 glob. Obviously, if the first argument is a filehandle of some
 292 sort, it will be read from, and if it is a file I<name> it will
 293 be opened for reading. Likewise, the second argument will be
 294 written to (and created if need be).  Trying to copy a file on top
 295 of itself is a fatal error.
 296
 297 B<Note that passing in
 298 files as handles instead of names may lead to loss of information
 299 on some operating systems; it is recommended that you use file
 300 names whenever possible.>  Files are opened in binary mode where
 301 applicable.  To get a consistent behaviour when copying from a
 302 filehandle to a file, use C<binmode> on the filehandle.
 303
 304 An optional third parameter can be used to specify the buffer
 305 size used for copying. This is the number of bytes from the
 306 first file, that wil be held in memory at any given time, before
 307 being written to the second file. The default buffer size depends
 308 upon the file, but will generally be the whole file (up to 2Mb), or
 309 1k for filehandles that do not reference files (eg. sockets).
 310
 311 You may use the syntax C<use File::Copy "cp"> to get at the
 312 "cp" alias for this function. The syntax is I<exactly> the same.
 313
 314 =item *
 315
 316 The C<move> function also takes two parameters: the current name
 317 and the intended name of the file to be moved.  If the destination
 318 already exists and is a directory, and the source is not a
 319 directory, then the source file will be renamed into the directory
 320 specified by the destination.
 321
 322 If possible, move() will simply rename the file.  Otherwise, it copies
 323 the file to the new location and deletes the original.  If an error occurs
 324 during this copy-and-delete process, you may be left with a (possibly partial)
 325 copy of the file under the destination name.
 326
 327 You may use the "mv" alias for this function in the same way that
 328 you may use the "cp" alias for C<copy>.
 329
 330 =back
 331
 332 File::Copy also provides the C<syscopy> routine, which copies the
 333 file specified in the first parameter to the file specified in the
 334 second parameter, preserving OS-specific attributes and file
 335 structure.  For Unix systems, this is equivalent to the simple
 336 C<copy> routine.  For VMS systems, this calls the C<rmscopy>
 337 routine (see below).  For OS/2 systems, this calls the C<syscopy>
 338 XSUB directly. For Win32 systems, this calls C<Win32::CopyFile>.
 339
 340 =head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)
 341
 342 If both arguments to C<copy> are not file handles,
 343 then C<copy> will perform a "system copy" of
 344 the input file to a new output file, in order to preserve file
 345 attributes, indexed file structure, I<etc.>  The buffer size
 346 parameter is ignored.  If either argument to C<copy> is a
 347 handle to an opened file, then data is copied using Perl
 348 operators, and no effort is made to preserve file attributes
 349 or record structure.
 350
 351 The system copy routine may also be called directly under VMS and OS/2
 352 as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
 353 is the routine that does the actual work for syscopy).
 354
 355 =over 4
 356
 357 =item rmscopy($from,$to[,$date_flag])
 358
 359 The first and second arguments may be strings, typeglobs, typeglob
 360 references, or objects inheriting from IO::Handle;
 361 they are used in all cases to obtain the
 362 I<filespec> of the input and output files, respectively.  The
 363 name and type of the input file are used as defaults for the
 364 output file, if necessary.
 365
 366 A new version of the output file is always created, which
 367 inherits the structure and RMS attributes of the input file,
 368 except for owner and protections (and possibly timestamps;
 369 see below).  All data from the input file is copied to the
 370 output file; if either of the first two parameters to C<rmscopy>
 371 is a file handle, its position is unchanged.  (Note that this
 372 means a file handle pointing to the output file will be
 373 associated with an old version of that file after C<rmscopy>
 374 returns, not the newly created version.)
 375
 376 The third parameter is an integer flag, which tells C<rmscopy>
 377 how to handle timestamps.  If it is E<lt> 0, none of the input file's
 378 timestamps are propagated to the output file.  If it is E<gt> 0, then
 379 it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
 380 timestamps other than the revision date are propagated; if bit 1
 381 is set, the revision date is propagated.  If the third parameter
 382 to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
 383 if the name or type of the output file was explicitly specified,
 384 then no timestamps are propagated, but if they were taken implicitly
 385 from the input filespec, then all timestamps other than the
 386 revision date are propagated.  If this parameter is not supplied,
 387 it defaults to 0.
 388
 389 Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
 390 it sets C<$!>, deletes the output file, and returns 0.
 391
 392 =back
 393
 394 =head1 RETURN
 395
 396 All functions return 1 on success, 0 on failure.
 397 $! will be set if an error was encountered.
 398
 399 =head1 NOTES
 400
 401 =over 4
 402
 403 =item *
 404
 405 On Mac OS (Classic), the path separator is ':', not '/', and the
 406 current directory is denoted as ':', not '.'. You should be careful
 407 about specifying relative pathnames. While a full path always begins
 408 with a volume name, a relative pathname should always begin with a
 409 ':'.  If specifying a volume name only, a trailing ':' is required.
 410
 411 E.g.
 412
 413   copy("file1", "tmp");        # creates the file 'tmp' in the current directory
 414   copy("file1", ":tmp:");      # creates :tmp:file1
 415   copy("file1", ":tmp");       # same as above
 416   copy("file1", "tmp");        # same as above, if 'tmp' is a directory (but don't do
 417                                # that, since it may cause confusion, see example #1)
 418   copy("file1", "tmp:file1");  # error, since 'tmp:' is not a volume
 419   copy("file1", ":tmp:file1"); # ok, partial path
 420   copy("file1", "DataHD:");    # creates DataHD:file1
 421
 422   move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one
 423                                              # volume to another
 424
 425 =back
 426
 427 =head1 AUTHOR
 428
 429 File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
 430 and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
 431
 432 =cut
 433