lib/File/Copy.pm

   1 # File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
   2 # source code has been placed in the public domain by the author.
   3 # Please be kind and preserve the documentation.
   4 #
   5 # Additions copyright 1996 by Charles Bailey.  Permission is granted
   6 # to distribute the revised code under the same terms as Perl itself.
   7
   8 package File::Copy;
   9
  10 use strict;
  11 use Carp;
  12 use vars qw(@ISA @EXPORT @EXPORT_OK $VERSION $Too_Big
  13             &copy &syscopy &cp &mv $Syscopy_is_copy);
  14
  15 # Note that this module implements only *part* of the API defined by
  16 # the File/Copy.pm module of the File-Tools-2.0 package.  However, that
  17 # package has not yet been updated to work with Perl 5.004, and so it
  18 # would be a Bad Thing for the CPAN module to grab it and replace this
  19 # module.  Therefore, we set this module's version higher than 2.0.
  20 $VERSION = '2.03';
  21
  22 require Exporter;
  23 @ISA = qw(Exporter);
  24 @EXPORT = qw(copy move);
  25 @EXPORT_OK = qw(cp mv);
  26
  27 $Too_Big = 1024 * 1024 * 2;
  28
  29 sub _catname { #  Will be replaced by File::Spec when it arrives
  30     my($from, $to) = @_;
  31     if (not defined &basename) {
  32         require File::Basename;
  33         import  File::Basename 'basename';
  34     }
  35     if ($^O eq 'VMS')  { $to = VMS::Filespec::vmspath($to) . basename($from); }
  36     elsif ($^O eq 'MacOS') { $to .= ':' . basename($from); }
  37     elsif ($to =~ m|\\|)   { $to .= '\\' . basename($from); }
  38     else                   { $to .= '/' . basename($from); }
  39 }
  40
  41 sub copy {
  42     croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
  43       unless(@_ == 2 || @_ == 3);
  44
  45     my $from = shift;
  46     my $to = shift;
  47
  48     my $from_a_handle = (ref($from)
  49                          ? (ref($from) eq 'GLOB'
  50                             || UNIVERSAL::isa($from, 'GLOB')
  51                             || UNIVERSAL::isa($from, 'IO::Handle'))
  52                          : (ref(\$from) eq 'GLOB'));
  53     my $to_a_handle =   (ref($to)
  54                          ? (ref($to) eq 'GLOB'
  55                             || UNIVERSAL::isa($to, 'GLOB')
  56                             || UNIVERSAL::isa($to, 'IO::Handle'))
  57                          : (ref(\$to) eq 'GLOB'));
  58
  59     if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
  60         $to = _catname($from, $to);
  61     }
  62
  63     if (defined &syscopy && !$Syscopy_is_copy
  64         && !$to_a_handle
  65         && !($from_a_handle && $^O eq 'os2' )   # OS/2 cannot handle handles
  66         && !($from_a_handle && $^O eq 'mpeix')  # and neither can MPE/iX.
  67         && !($from_a_handle && $^O eq 'MSWin32')
  68        )
  69     {
  70         return syscopy($from, $to);
  71     }
  72
  73     my $closefrom = 0;
  74     my $closeto = 0;
  75     my ($size, $status, $r, $buf);
  76     local(*FROM, *TO);
  77     local($\) = '';
  78
  79     if ($from_a_handle) {
  80         *FROM = *$from{FILEHANDLE};
  81     } else {
  82         $from = "./$from" if $from =~ /^\s/;
  83         open(FROM, "< $from\0") or goto fail_open1;
  84         binmode FROM or die "($!,$^E)";
  85         $closefrom = 1;
  86     }
  87
  88     if ($to_a_handle) {
  89         *TO = *$to{FILEHANDLE};
  90     } else {
  91         $to = "./$to" if $to =~ /^\s/;
  92         open(TO,"> $to\0") or goto fail_open2;
  93         binmode TO or die "($!,$^E)";
  94         $closeto = 1;
  95     }
  96
  97     if (@_) {
  98         $size = shift(@_) + 0;
  99         croak("Bad buffer size for copy: $size\n") unless ($size > 0);
 100     } else {
 101         $size = -s FROM;
 102         $size = 1024 if ($size < 512);
 103         $size = $Too_Big if ($size > $Too_Big);
 104     }
 105
 106     $! = 0;
 107     for (;;) {
 108         my ($r, $w, $t);
 109         defined($r = sysread(FROM, $buf, $size))
 110             or goto fail_inner;
 111         last unless $r;
 112         for ($w = 0; $w < $r; $w += $t) {
 113             $t = syswrite(TO, $buf, $r - $w, $w)
 114                 or goto fail_inner;
 115         }
 116     }
 117
 118     close(TO) || goto fail_open2 if $closeto;
 119     close(FROM) || goto fail_open1 if $closefrom;
 120
 121     # Use this idiom to avoid uninitialized value warning.
 122     return 1;
 123
 124     # All of these contortions try to preserve error messages...
 125   fail_inner:
 126     if ($closeto) {
 127         $status = $!;
 128         $! = 0;
 129         close TO;
 130         $! = $status unless $!;
 131     }
 132   fail_open2:
 133     if ($closefrom) {
 134         $status = $!;
 135         $! = 0;
 136         close FROM;
 137         $! = $status unless $!;
 138     }
 139   fail_open1:
 140     return 0;
 141 }
 142
 143 sub move {
 144     my($from,$to) = @_;
 145     my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
 146
 147     if (-d $to && ! -d $from) {
 148         $to = _catname($from, $to);
 149     }
 150
 151     ($tosz1,$tomt1) = (stat($to))[7,9];
 152     $fromsz = -s $from;
 153     if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
 154       # will not rename with overwrite
 155       unlink $to;
 156     }
 157     return 1 if rename $from, $to;
 158
 159     ($sts,$ossts) = ($! + 0, $^E + 0);
 160     # Did rename return an error even though it succeeded, because $to
 161     # is on a remote NFS file system, and NFS lost the server's ack?
 162     return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
 163                 (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
 164                 ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
 165                 $tosz2 == $fromsz;                         # it's all there
 166
 167     ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
 168     return 1 if ($copied = copy($from,$to)) && unlink($from);
 169
 170     ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
 171     unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
 172     ($!,$^E) = ($sts,$ossts);
 173     return 0;
 174 }
 175
 176 *cp = \&copy;
 177 *mv = \&move;
 178
 179 # &syscopy is an XSUB under OS/2
 180 unless (defined &syscopy) {
 181     if ($^O eq 'VMS') {
 182         *syscopy = \&rmscopy;
 183     } elsif ($^O eq 'mpeix') {
 184         *syscopy = sub {
 185             return 0 unless @_ == 2;
 186             # Use the MPE cp program in order to
 187             # preserve MPE file attributes.
 188             return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
 189         };
 190     } elsif ($^O eq 'MSWin32') {
 191         *syscopy = sub {
 192             return 0 unless @_ == 2;
 193             return Win32::CopyFile(@_, 1);
 194         };
 195     } else {
 196         $Syscopy_is_copy = 1;
 197         *syscopy = \&copy;
 198     }
 199 }
 200
 201 1;
 202
 203 __END__
 204
 205 =head1 NAME
 206
 207 File::Copy - Copy files or filehandles
 208
 209 =head1 SYNOPSIS
 210
 211         use File::Copy;
 212
 213         copy("file1","file2");
 214         copy("Copy.pm",\*STDOUT);'
 215         move("/dev1/fileA","/dev2/fileB");
 216
 217         use POSIX;
 218         use File::Copy cp;
 219
 220         $n=FileHandle->new("/dev/null","r");
 221         cp($n,"x");'
 222
 223 =head1 DESCRIPTION
 224
 225 The File::Copy module provides two basic functions, C<copy> and
 226 C<move>, which are useful for getting the contents of a file from
 227 one place to another.
 228
 229 =over 4
 230
 231 =item *
 232
 233 The C<copy> function takes two
 234 parameters: a file to copy from and a file to copy to. Either
 235 argument may be a string, a FileHandle reference or a FileHandle
 236 glob. Obviously, if the first argument is a filehandle of some
 237 sort, it will be read from, and if it is a file I<name> it will
 238 be opened for reading. Likewise, the second argument will be
 239 written to (and created if need be).
 240
 241 B<Note that passing in
 242 files as handles instead of names may lead to loss of information
 243 on some operating systems; it is recommended that you use file
 244 names whenever possible.>  Files are opened in binary mode where
 245 applicable.  To get a consistent behaviour when copying from a
 246 filehandle to a file, use C<binmode> on the filehandle.
 247
 248 An optional third parameter can be used to specify the buffer
 249 size used for copying. This is the number of bytes from the
 250 first file, that wil be held in memory at any given time, before
 251 being written to the second file. The default buffer size depends
 252 upon the file, but will generally be the whole file (up to 2Mb), or
 253 1k for filehandles that do not reference files (eg. sockets).
 254
 255 You may use the syntax C<use File::Copy "cp"> to get at the
 256 "cp" alias for this function. The syntax is I<exactly> the same.
 257
 258 =item *
 259
 260 The C<move> function also takes two parameters: the current name
 261 and the intended name of the file to be moved.  If the destination
 262 already exists and is a directory, and the source is not a
 263 directory, then the source file will be renamed into the directory
 264 specified by the destination.
 265
 266 If possible, move() will simply rename the file.  Otherwise, it copies
 267 the file to the new location and deletes the original.  If an error occurs
 268 during this copy-and-delete process, you may be left with a (possibly partial)
 269 copy of the file under the destination name.
 270
 271 You may use the "mv" alias for this function in the same way that
 272 you may use the "cp" alias for C<copy>.
 273
 274 =back
 275
 276 File::Copy also provides the C<syscopy> routine, which copies the
 277 file specified in the first parameter to the file specified in the
 278 second parameter, preserving OS-specific attributes and file
 279 structure.  For Unix systems, this is equivalent to the simple
 280 C<copy> routine.  For VMS systems, this calls the C<rmscopy>
 281 routine (see below).  For OS/2 systems, this calls the C<syscopy>
 282 XSUB directly. For Win32 systems, this calls C<Win32::CopyFile>.
 283
 284 =head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)
 285
 286 If both arguments to C<copy> are not file handles,
 287 then C<copy> will perform a "system copy" of
 288 the input file to a new output file, in order to preserve file
 289 attributes, indexed file structure, I<etc.>  The buffer size
 290 parameter is ignored.  If either argument to C<copy> is a
 291 handle to an opened file, then data is copied using Perl
 292 operators, and no effort is made to preserve file attributes
 293 or record structure.
 294
 295 The system copy routine may also be called directly under VMS and OS/2
 296 as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
 297 is the routine that does the actual work for syscopy).
 298
 299 =over 4
 300
 301 =item rmscopy($from,$to[,$date_flag])
 302
 303 The first and second arguments may be strings, typeglobs, typeglob
 304 references, or objects inheriting from IO::Handle;
 305 they are used in all cases to obtain the
 306 I<filespec> of the input and output files, respectively.  The
 307 name and type of the input file are used as defaults for the
 308 output file, if necessary.
 309
 310 A new version of the output file is always created, which
 311 inherits the structure and RMS attributes of the input file,
 312 except for owner and protections (and possibly timestamps;
 313 see below).  All data from the input file is copied to the
 314 output file; if either of the first two parameters to C<rmscopy>
 315 is a file handle, its position is unchanged.  (Note that this
 316 means a file handle pointing to the output file will be
 317 associated with an old version of that file after C<rmscopy>
 318 returns, not the newly created version.)
 319
 320 The third parameter is an integer flag, which tells C<rmscopy>
 321 how to handle timestamps.  If it is E<lt> 0, none of the input file's
 322 timestamps are propagated to the output file.  If it is E<gt> 0, then
 323 it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
 324 timestamps other than the revision date are propagated; if bit 1
 325 is set, the revision date is propagated.  If the third parameter
 326 to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
 327 if the name or type of the output file was explicitly specified,
 328 then no timestamps are propagated, but if they were taken implicitly
 329 from the input filespec, then all timestamps other than the
 330 revision date are propagated.  If this parameter is not supplied,
 331 it defaults to 0.
 332
 333 Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
 334 it sets C<$!>, deletes the output file, and returns 0.
 335
 336 =back
 337
 338 =head1 RETURN
 339
 340 All functions return 1 on success, 0 on failure.
 341 $! will be set if an error was encountered.
 342
 343 =head1 AUTHOR
 344
 345 File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
 346 and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
 347
 348 =cut
 349