lib/File/Basename.pm

   1 package File::Basename;
   2
   3 =head1 NAME
   4
   5 fileparse - split a pathname into pieces
   6
   7 basename - extract just the filename from a path
   8
   9 dirname - extract just the directory from a path
  10
  11 =head1 SYNOPSIS
  12
  13     use File::Basename;
  14
  15     ($name,$path,$suffix) = fileparse($fullname,@suffixlist)
  16     fileparse_set_fstype($os_string);
  17     $basename = basename($fullname,@suffixlist);
  18     $dirname = dirname($fullname);
  19
  20     ($name,$path,$suffix) = fileparse("lib/File/Basename.pm","\.pm");
  21     fileparse_set_fstype("VMS");
  22     $basename = basename("lib/File/Basename.pm",".pm");
  23     $dirname = dirname("lib/File/Basename.pm");
  24
  25 =head1 DESCRIPTION
  26
  27 These routines allow you to parse file specifications into useful
  28 pieces using the syntax of different operating systems.
  29
  30 =over 4
  31
  32 =item fileparse_set_fstype
  33
  34 You select the syntax via the routine fileparse_set_fstype().
  35
  36 If the argument passed to it contains one of the substrings
  37 "VMS", "MSDOS", "MacOS", "AmigaOS" or "MSWin32", the file specification
  38 syntax of that operating system is used in future calls to
  39 fileparse(), basename(), and dirname().  If it contains none of
  40 these substrings, UNIX syntax is used.  This pattern matching is
  41 case-insensitive.  If you've selected VMS syntax, and the file
  42 specification you pass to one of these routines contains a "/",
  43 they assume you are using UNIX emulation and apply the UNIX syntax
  44 rules instead, for that function call only.
  45
  46 If the argument passed to it contains one of the substrings "VMS",
  47 "MSDOS", "MacOS", "AmigaOS", "os2", "MSWin32" or "RISCOS", then the pattern
  48 matching for suffix removal is performed without regard for case,
  49 since those systems are not case-sensitive when opening existing files
  50 (though some of them preserve case on file creation).
  51
  52 If you haven't called fileparse_set_fstype(), the syntax is chosen
  53 by examining the builtin variable C<$^O> according to these rules.
  54
  55 =item fileparse
  56
  57 The fileparse() routine divides a file specification into three
  58 parts: a leading B<path>, a file B<name>, and a B<suffix>.  The
  59 B<path> contains everything up to and including the last directory
  60 separator in the input file specification.  The remainder of the input
  61 file specification is then divided into B<name> and B<suffix> based on
  62 the optional patterns you specify in C<@suffixlist>.  Each element of
  63 this list is interpreted as a regular expression, and is matched
  64 against the end of B<name>.  If this succeeds, the matching portion of
  65 B<name> is removed and prepended to B<suffix>.  By proper use of
  66 C<@suffixlist>, you can remove file types or versions for examination.
  67
  68 You are guaranteed that if you concatenate B<path>, B<name>, and
  69 B<suffix> together in that order, the result will denote the same
  70 file as the input file specification.
  71
  72 =back
  73
  74 =head1 EXAMPLES
  75
  76 Using UNIX file syntax:
  77
  78     ($base,$path,$type) = fileparse('/virgil/aeneid/draft.book7',
  79                                     '\.book\d+');
  80
  81 would yield
  82
  83     $base eq 'draft'
  84     $path eq '/virgil/aeneid/',
  85     $type eq '.book7'
  86
  87 Similarly, using VMS syntax:
  88
  89     ($name,$dir,$type) = fileparse('Doc_Root:[Help]Rhetoric.Rnh',
  90                                    '\..*');
  91
  92 would yield
  93
  94     $name eq 'Rhetoric'
  95     $dir  eq 'Doc_Root:[Help]'
  96     $type eq '.Rnh'
  97
  98 =over
  99
 100 =item C<basename>
 101
 102 The basename() routine returns the first element of the list produced
 103 by calling fileparse() with the same arguments, except that it always
 104 quotes metacharacters in the given suffixes.  It is provided for
 105 programmer compatibility with the UNIX shell command basename(1).
 106
 107 =item C<dirname>
 108
 109 The dirname() routine returns the directory portion of the input file
 110 specification.  When using VMS or MacOS syntax, this is identical to the
 111 second element of the list produced by calling fileparse() with the same
 112 input file specification.  (Under VMS, if there is no directory information
 113 in the input file specification, then the current default device and
 114 directory are returned.)  When using UNIX or MSDOS syntax, the return
 115 value conforms to the behavior of the UNIX shell command dirname(1).  This
 116 is usually the same as the behavior of fileparse(), but differs in some
 117 cases.  For example, for the input file specification F<lib/>, fileparse()
 118 considers the directory name to be F<lib/>, while dirname() considers the
 119 directory name to be F<.>).
 120
 121 =back
 122
 123 =cut
 124
 125 require 5.002;
 126 require Exporter;
 127 @ISA = qw(Exporter);
 128 @EXPORT = qw(fileparse fileparse_set_fstype basename dirname);
 129 #use strict;
 130 use vars qw($VERSION $Fileparse_fstype $Fileparse_igncase);
 131 $VERSION = "2.6";
 132
 133
 134 #   fileparse_set_fstype() - specify OS-based rules used in future
 135 #                            calls to routines in this package
 136 #
 137 #   Currently recognized values: VMS, MSDOS, MacOS, AmigaOS, os2, RISCOS
 138 #       Any other name uses Unix-style rules and is case-sensitive
 139
 140 sub fileparse_set_fstype {
 141   my @old = ($Fileparse_fstype, $Fileparse_igncase);
 142   if (@_) {
 143     $Fileparse_fstype = $_[0];
 144     $Fileparse_igncase = ($_[0] =~ /^(?:MacOS|VMS|AmigaOS|os2|RISCOS|MSWin32|MSDOS)/i);
 145   }
 146   wantarray ? @old : $old[0];
 147 }
 148
 149 #   fileparse() - parse file specification
 150 #
 151 #   Version 2.4  27-Sep-1996  Charles Bailey  bailey@genetics.upenn.edu
 152
 153
 154 sub fileparse {
 155   my($fullname,@suffices) = @_;
 156   my($fstype,$igncase) = ($Fileparse_fstype, $Fileparse_igncase);
 157   my($dirpath,$tail,$suffix,$basename);
 158   my($taint) = substr($fullname,0,0);  # Is $fullname tainted?
 159
 160   if ($fstype =~ /^VMS/i) {
 161     if ($fullname =~ m#/#) { $fstype = '' }  # We're doing Unix emulation
 162     else {
 163       ($dirpath,$basename) = ($fullname =~ /^(.*[:>\]])?(.*)/);
 164       $dirpath ||= '';  # should always be defined
 165     }
 166   }
 167   if ($fstype =~ /^MS(DOS|Win32)/i) {
 168     ($dirpath,$basename) = ($fullname =~ /^((?:.*[:\\\/])?)(.*)/);
 169     $dirpath .= '.\\' unless $dirpath =~ /[\\\/]$/;
 170   }
 171   elsif ($fstype =~ /^MacOS/i) {
 172     ($dirpath,$basename) = ($fullname =~ /^(.*:)?(.*)/);
 173   }
 174   elsif ($fstype =~ /^AmigaOS/i) {
 175     ($dirpath,$basename) = ($fullname =~ /(.*[:\/])?(.*)/);
 176     $dirpath = './' unless $dirpath;
 177   }
 178   elsif ($fstype !~ /^VMS/i) {  # default to Unix
 179     ($dirpath,$basename) = ($fullname =~ m#^(.*/)?(.*)#);
 180     if ($^O eq 'VMS' and $fullname =~ m:/[^/]+/000000/?:) {
 181       # dev:[000000] is top of VMS tree, similar to Unix '/'
 182       ($basename,$dirpath) = ('',$fullname);
 183     }
 184     $dirpath = './' unless $dirpath;
 185   }
 186
 187   if (@suffices) {
 188     $tail = '';
 189     foreach $suffix (@suffices) {
 190       my $pat = ($igncase ? '(?i)' : '') . "($suffix)\$";
 191       if ($basename =~ s/$pat//) {
 192         $taint .= substr($suffix,0,0);
 193         $tail = $1 . $tail;
 194       }
 195     }
 196   }
 197
 198   $tail .= $taint if defined $tail; # avoid warning if $tail == undef
 199   wantarray ? ($basename . $taint, $dirpath . $taint, $tail)
 200             : $basename . $taint;
 201 }
 202
 203
 204 #   basename() - returns first element of list returned by fileparse()
 205
 206 sub basename {
 207   my($name) = shift;
 208   (fileparse($name, map("\Q$_\E",@_)))[0];
 209 }
 210
 211
 212 #    dirname() - returns device and directory portion of file specification
 213 #        Behavior matches that of Unix dirname(1) exactly for Unix and MSDOS
 214 #        filespecs except for names ending with a separator, e.g., "/xx/yy/".
 215 #        This differs from the second element of the list returned
 216 #        by fileparse() in that the trailing '/' (Unix) or '\' (MSDOS) (and
 217 #        the last directory name if the filespec ends in a '/' or '\'), is lost.
 218
 219 sub dirname {
 220     my($basename,$dirname) = fileparse($_[0]);
 221     my($fstype) = $Fileparse_fstype;
 222
 223     if ($fstype =~ /VMS/i) {
 224         if ($_[0] =~ m#/#) { $fstype = '' }
 225         else { return $dirname || $ENV{DEFAULT} }
 226     }
 227     if ($fstype =~ /MacOS/i) { return $dirname }
 228     elsif ($fstype =~ /MSDOS/i) {
 229         $dirname =~ s/([^:])[\\\/]*$/$1/;
 230         unless( length($basename) ) {
 231             ($basename,$dirname) = fileparse $dirname;
 232             $dirname =~ s/([^:])[\\\/]*$/$1/;
 233         }
 234     }
 235     elsif ($fstype =~ /MSWin32/i) {
 236         $dirname =~ s/([^:])[\\\/]*$/$1/;
 237         unless( length($basename) ) {
 238             ($basename,$dirname) = fileparse $dirname;
 239             $dirname =~ s/([^:])[\\\/]*$/$1/;
 240         }
 241     }
 242     elsif ($fstype =~ /AmigaOS/i) {
 243         if ( $dirname =~ /:$/) { return $dirname }
 244         chop $dirname;
 245         $dirname =~ s#[^:/]+$## unless length($basename);
 246     }
 247     else {
 248         $dirname =~ s:(.)/*$:$1:;
 249         unless( length($basename) ) {
 250             local($File::Basename::Fileparse_fstype) = $fstype;
 251             ($basename,$dirname) = fileparse $dirname;
 252             $dirname =~ s:(.)/*$:$1:;
 253         }
 254     }
 255
 256     $dirname;
 257 }
 258
 259 fileparse_set_fstype $^O;
 260
 261 1;