lib/File/Basename.pm

   1 package File::Basename;
   2
   3 =head1 NAME
   4
   5 fileparse - split a pathname into pieces
   6
   7 basename - extract just the filename from a path
   8
   9 dirname - extract just the directory from a path
  10
  11 =head1 SYNOPSIS
  12
  13     use File::Basename;
  14
  15     ($name,$path,$suffix) = fileparse($fullname,@suffixlist)
  16     fileparse_set_fstype($os_string);
  17     $basename = basename($fullname,@suffixlist);
  18     $dirname = dirname($fullname);
  19
  20     ($name,$path,$suffix) = fileparse("lib/File/Basename.pm","\.pm");
  21     fileparse_set_fstype("VMS");
  22     $basename = basename("lib/File/Basename.pm",".pm");
  23     $dirname = dirname("lib/File/Basename.pm");
  24
  25 =head1 DESCRIPTION
  26
  27 These routines allow you to parse file specifications into useful
  28 pieces using the syntax of different operating systems.
  29
  30 =over 4
  31
  32 =item fileparse_set_fstype
  33
  34 You select the syntax via the routine fileparse_set_fstype().
  35 If the argument passed to it contains one of the substrings
  36 "VMS", "MSDOS", "MacOS" or "AmigaOS", the file specification
  37 syntax of that operating system is used in future calls to
  38 fileparse(), basename(), and dirname().  If it contains none of
  39 these substrings, UNIX syntax is used.  This pattern matching is
  40 case-insensitive.  If you've selected VMS syntax, and the file
  41 specification you pass to one of these routines contains a "/",
  42 they assume you are using UNIX emulation and apply the UNIX syntax
  43 rules instead, for that function call only.
  44
  45 If you haven't called fileparse_set_fstype(), the syntax is chosen
  46 by examining the builtin variable C<$^O> according to these rules.
  47
  48 =item fileparse
  49
  50 The fileparse() routine divides a file specification into three
  51 parts: a leading B<path>, a file B<name>, and a B<suffix>.  The
  52 B<path> contains everything up to and including the last directory
  53 separator in the input file specification.  The remainder of the input
  54 file specification is then divided into B<name> and B<suffix> based on
  55 the optional patterns you specify in C<@suffixlist>.  Each element of
  56 this list is interpreted as a regular expression, and is matched
  57 against the end of B<name>.  If this succeeds, the matching portion of
  58 B<name> is removed and prepended to B<suffix>.  By proper use of
  59 C<@suffixlist>, you can remove file types or versions for examination.
  60
  61 You are guaranteed that if you concatenate B<path>, B<name>, and
  62 B<suffix> together in that order, the result will denote the same
  63 file as the input file specification.
  64
  65 =back
  66
  67 =head1 EXAMPLES
  68
  69 Using UNIX file syntax:
  70
  71     ($base,$path,$type) = fileparse('/virgil/aeneid/draft.book7',
  72                                     '\.book\d+');
  73
  74 would yield
  75
  76     $base eq 'draft'
  77     $path eq '/virgil/aeneid/',
  78     $type eq '.book7'
  79
  80 Similarly, using VMS syntax:
  81
  82     ($name,$dir,$type) = fileparse('Doc_Root:[Help]Rhetoric.Rnh',
  83                                    '\..*');
  84
  85 would yield
  86
  87     $name eq 'Rhetoric'
  88     $dir  eq 'Doc_Root:[Help]'
  89     $type eq '.Rnh'
  90
  91 =item C<basename>
  92
  93 The basename() routine returns the first element of the list produced
  94 by calling fileparse() with the same arguments.  It is provided for
  95 compatibility with the UNIX shell command basename(1).
  96
  97 =item C<dirname>
  98
  99 The dirname() routine returns the directory portion of the input file
 100 specification.  When using VMS or MacOS syntax, this is identical to the
 101 second element of the list produced by calling fileparse() with the same
 102 input file specification.  (Under VMS, if there is no directory information
 103 in the input file specification, then the current default device and
 104 directory are returned.)  When using UNIX or MSDOS syntax, the return
 105 value conforms to the behavior of the UNIX shell command dirname(1).  This
 106 is usually the same as the behavior of fileparse(), but differs in some
 107 cases.  For example, for the input file specification F<lib/>, fileparse()
 108 considers the directory name to be F<lib/>, while dirname() considers the
 109 directory name to be F<.>).
 110
 111 =cut
 112
 113 require 5.002;
 114 require Exporter;
 115 @ISA = qw(Exporter);
 116 @EXPORT = qw(fileparse fileparse_set_fstype basename dirname);
 117 #use strict;
 118 #use vars qw($VERSION $Fileparse_fstype);
 119 $VERSION = "2.4";
 120
 121
 122 #   fileparse_set_fstype() - specify OS-based rules used in future
 123 #                            calls to routines in this package
 124 #
 125 #   Currently recognized values: VMS, MSDOS, MacOS
 126 #       Any other name uses Unix-style rules
 127
 128 sub fileparse_set_fstype {
 129   my($old) = $Fileparse_fstype;
 130   $Fileparse_fstype = $_[0] if $_[0];
 131   $old;
 132 }
 133
 134 #   fileparse() - parse file specification
 135 #
 136 #   Version 2.4  27-Sep-1996  Charles Bailey  bailey@genetics.upenn.edu
 137
 138
 139 sub fileparse {
 140   my($fullname,@suffices) = @_;
 141   my($fstype) = $Fileparse_fstype;
 142   my($dirpath,$tail,$suffix,$basename);
 143
 144   if ($fstype =~ /^VMS/i) {
 145     if ($fullname =~ m#/#) { $fstype = '' }  # We're doing Unix emulation
 146     else {
 147       ($dirpath,$basename) = ($fullname =~ /^(.*[:>\]])?(.*)/);
 148     }
 149   }
 150   if ($fstype =~ /^MSDOS/i) {
 151     ($dirpath,$basename) = ($fullname =~ /^(.*[:\\\/])?(.*)/);
 152     $dirpath .= '.\\' unless $dirpath =~ /[\\\/]$/;
 153   }
 154   elsif ($fstype =~ /^MacOS/i) {
 155     ($dirpath,$basename) = ($fullname =~ /^(.*:)?(.*)/);
 156   }
 157   elsif ($fstype =~ /^AmigaOS/i) {
 158     ($dirpath,$basename) = ($fullname =~ /(.*[:\/])?(.*)/);
 159   }
 160   elsif ($fstype !~ /^VMS/i) {  # default to Unix
 161     ($dirpath,$basename) = ($fullname =~ m#^(.*/)?(.*)#);
 162     $dirpath = './' unless $dirpath;
 163   }
 164
 165   if (@suffices) {
 166     $tail = '';
 167     foreach $suffix (@suffices) {
 168       if ($basename =~ /([\x00-\xff]*?)($suffix)$/) {
 169         $tail = $2 . $tail;
 170         $basename = $1;
 171       }
 172     }
 173   }
 174
 175   wantarray ? ($basename,$dirpath,$tail) : $basename;
 176
 177 }
 178
 179
 180 #   basename() - returns first element of list returned by fileparse()
 181
 182 sub basename {
 183   my($name) = shift;
 184   (fileparse($name, map("\Q$_\E",@_)))[0];
 185 }
 186
 187
 188 #    dirname() - returns device and directory portion of file specification
 189 #        Behavior matches that of Unix dirname(1) exactly for Unix and MSDOS
 190 #        filespecs except for names ending with a separator, e.g., "/xx/yy/".
 191 #        This differs from the second element of the list returned
 192 #        by fileparse() in that the trailing '/' (Unix) or '\' (MSDOS) (and
 193 #        the last directory name if the filespec ends in a '/' or '\'), is lost.
 194
 195 sub dirname {
 196     my($basename,$dirname) = fileparse($_[0]);
 197     my($fstype) = $Fileparse_fstype;
 198
 199     if ($fstype =~ /VMS/i) {
 200         if ($_[0] =~ m#/#) { $fstype = '' }
 201         else { return $dirname || $ENV{DEFAULT} }
 202     }
 203     if ($fstype =~ /MacOS/i) { return $dirname }
 204     elsif ($fstype =~ /MSDOS/i) {
 205         $dirname =~ s/([^:])[\\\/]*$/$1/;
 206         unless( length($basename) ) {
 207             ($basename,$dirname) = fileparse $dirname;
 208             $dirname =~ s/([^:])[\\\/]*$/$1/;
 209         }
 210     }
 211     elsif ($fstype =~ /AmigaOS/i) {
 212         if ( $dirname =~ /:$/) { return $dirname }
 213         chop $dirname;
 214         $dirname =~ s#[^:/]+$## unless length($basename);
 215     }
 216     else {
 217         $dirname =~ s:(.)/*$:$1:;
 218         unless( length($basename) ) {
 219             local($File::Basename::Fileparse_fstype) = $fstype;
 220             ($basename,$dirname) = fileparse $dirname;
 221             $dirname =~ s:(.)/*$:$1:;
 222         }
 223     }
 224
 225     $dirname;
 226 }
 227
 228 $Fileparse_fstype = $^O;
 229
 230 1;