lib/File/Basename.pm

   1 package File::Basename;
   2
   3 =head1 NAME
   4
   5 fileparse - split a pathname into pieces
   6
   7 basename - extract just the filename from a path
   8
   9 dirname - extract just the directory from a path
  10
  11 =head1 SYNOPSIS
  12
  13     use File::Basename;
  14
  15     ($name,$path,$suffix) = fileparse($fullname,@suffixlist)
  16     fileparse_set_fstype($os_string);
  17     $basename = basename($fullname,@suffixlist);
  18     $dirname = dirname($fullname);
  19
  20     ($name,$path,$suffix) = fileparse("lib/File/Basename.pm","\.pm");
  21     fileparse_set_fstype("VMS");
  22     $basename = basename("lib/File/Basename.pm",".pm");
  23     $dirname = dirname("lib/File/Basename.pm");
  24
  25 =head1 DESCRIPTION
  26
  27 These routines allow you to parse file specifications into useful
  28 pieces using the syntax of different operating systems.
  29
  30 =over 4
  31
  32 =item fileparse_set_fstype
  33
  34 You select the syntax via the routine fileparse_set_fstype().
  35
  36 If the argument passed to it contains one of the substrings
  37 "VMS", "MSDOS", "MacOS", or "AmigaOS", the file specification
  38 syntax of that operating system is used in future calls to
  39 fileparse(), basename(), and dirname().  If it contains none of
  40 these substrings, UNIX syntax is used.  This pattern matching is
  41 case-insensitive.  If you've selected VMS syntax, and the file
  42 specification you pass to one of these routines contains a "/",
  43 they assume you are using UNIX emulation and apply the UNIX syntax
  44 rules instead, for that function call only.
  45
  46 If the argument passed to it contains one of the substrings "VMS",
  47 "MSDOS", "MacOS", "AmigaOS", "os2", or "RISCOS", then the pattern
  48 matching for suffix removal is performed without regard for case,
  49 since those systems are not case-sensitive when opening existing files
  50 (though some of them preserve case on file creation).
  51
  52 If you haven't called fileparse_set_fstype(), the syntax is chosen
  53 by examining the builtin variable C<$^O> according to these rules.
  54
  55 =item fileparse
  56
  57 The fileparse() routine divides a file specification into three
  58 parts: a leading B<path>, a file B<name>, and a B<suffix>.  The
  59 B<path> contains everything up to and including the last directory
  60 separator in the input file specification.  The remainder of the input
  61 file specification is then divided into B<name> and B<suffix> based on
  62 the optional patterns you specify in C<@suffixlist>.  Each element of
  63 this list is interpreted as a regular expression, and is matched
  64 against the end of B<name>.  If this succeeds, the matching portion of
  65 B<name> is removed and prepended to B<suffix>.  By proper use of
  66 C<@suffixlist>, you can remove file types or versions for examination.
  67
  68 You are guaranteed that if you concatenate B<path>, B<name>, and
  69 B<suffix> together in that order, the result will denote the same
  70 file as the input file specification.
  71
  72 =back
  73
  74 =head1 EXAMPLES
  75
  76 Using UNIX file syntax:
  77
  78     ($base,$path,$type) = fileparse('/virgil/aeneid/draft.book7',
  79                                     '\.book\d+');
  80
  81 would yield
  82
  83     $base eq 'draft'
  84     $path eq '/virgil/aeneid/',
  85     $type eq '.book7'
  86
  87 Similarly, using VMS syntax:
  88
  89     ($name,$dir,$type) = fileparse('Doc_Root:[Help]Rhetoric.Rnh',
  90                                    '\..*');
  91
  92 would yield
  93
  94     $name eq 'Rhetoric'
  95     $dir  eq 'Doc_Root:[Help]'
  96     $type eq '.Rnh'
  97
  98 =item C<basename>
  99
 100 The basename() routine returns the first element of the list produced
 101 by calling fileparse() with the same arguments, except that it always
 102 quotes metacharacters in the given suffixes.  It is provided for
 103 programmer compatibility with the UNIX shell command basename(1).
 104
 105 =item C<dirname>
 106
 107 The dirname() routine returns the directory portion of the input file
 108 specification.  When using VMS or MacOS syntax, this is identical to the
 109 second element of the list produced by calling fileparse() with the same
 110 input file specification.  (Under VMS, if there is no directory information
 111 in the input file specification, then the current default device and
 112 directory are returned.)  When using UNIX or MSDOS syntax, the return
 113 value conforms to the behavior of the UNIX shell command dirname(1).  This
 114 is usually the same as the behavior of fileparse(), but differs in some
 115 cases.  For example, for the input file specification F<lib/>, fileparse()
 116 considers the directory name to be F<lib/>, while dirname() considers the
 117 directory name to be F<.>).
 118
 119 =cut
 120
 121 require 5.002;
 122 require Exporter;
 123 @ISA = qw(Exporter);
 124 @EXPORT = qw(fileparse fileparse_set_fstype basename dirname);
 125 #use strict;
 126 #use vars qw($VERSION $Fileparse_fstype $Fileparse_igncase);
 127 $VERSION = "2.4";
 128
 129
 130 #   fileparse_set_fstype() - specify OS-based rules used in future
 131 #                            calls to routines in this package
 132 #
 133 #   Currently recognized values: VMS, MSDOS, MacOS, AmigaOS, os2, RISCOS
 134 #       Any other name uses Unix-style rules and is case-sensitive
 135
 136 sub fileparse_set_fstype {
 137   my @old = ($Fileparse_fstype, $Fileparse_igncase);
 138   if (@_) {
 139     $Fileparse_fstype = $_[0];
 140     $Fileparse_igncase = ($_[0] =~ /^(?:MacOS|VMS|AmigaOS|os2|RISCOS)/i);
 141   }
 142   wantarray ? @old : $old[0];
 143 }
 144
 145 #   fileparse() - parse file specification
 146 #
 147 #   Version 2.4  27-Sep-1996  Charles Bailey  bailey@genetics.upenn.edu
 148
 149
 150 sub fileparse {
 151   my($fullname,@suffices) = @_;
 152   my($fstype,$igncase) = ($Fileparse_fstype, $Fileparse_igncase);
 153   my($dirpath,$tail,$suffix,$basename);
 154
 155   if ($fstype =~ /^VMS/i) {
 156     if ($fullname =~ m#/#) { $fstype = '' }  # We're doing Unix emulation
 157     else {
 158       ($dirpath,$basename) = ($fullname =~ /^(.*[:>\]])?(.*)/);
 159     }
 160   }
 161   if ($fstype =~ /^MSDOS/i) {
 162     ($dirpath,$basename) = ($fullname =~ /^(.*[:\\\/])?(.*)/);
 163     $dirpath .= '.\\' unless $dirpath =~ /[\\\/]$/;
 164   }
 165   elsif ($fstype =~ /^MacOS/i) {
 166     ($dirpath,$basename) = ($fullname =~ /^(.*:)?(.*)/);
 167   }
 168   elsif ($fstype =~ /^AmigaOS/i) {
 169     ($dirpath,$basename) = ($fullname =~ /(.*[:\/])?(.*)/);
 170   }
 171   elsif ($fstype !~ /^VMS/i) {  # default to Unix
 172     ($dirpath,$basename) = ($fullname =~ m#^(.*/)?(.*)#);
 173     $dirpath = './' unless $dirpath;
 174   }
 175
 176   if (@suffices) {
 177     $tail = '';
 178     foreach $suffix (@suffices) {
 179       my $pat = ($igncase ? '(?i)' : '') . "($suffix)\$";
 180       if ($basename =~ s/$pat//) {
 181         $tail = $1 . $tail;
 182       }
 183     }
 184   }
 185
 186   wantarray ? ($basename,$dirpath,$tail) : $basename;
 187 }
 188
 189
 190 #   basename() - returns first element of list returned by fileparse()
 191
 192 sub basename {
 193   my($name) = shift;
 194   (fileparse($name, map("\Q$_\E",@_)))[0];
 195 }
 196
 197
 198 #    dirname() - returns device and directory portion of file specification
 199 #        Behavior matches that of Unix dirname(1) exactly for Unix and MSDOS
 200 #        filespecs except for names ending with a separator, e.g., "/xx/yy/".
 201 #        This differs from the second element of the list returned
 202 #        by fileparse() in that the trailing '/' (Unix) or '\' (MSDOS) (and
 203 #        the last directory name if the filespec ends in a '/' or '\'), is lost.
 204
 205 sub dirname {
 206     my($basename,$dirname) = fileparse($_[0]);
 207     my($fstype) = $Fileparse_fstype;
 208
 209     if ($fstype =~ /VMS/i) {
 210         if ($_[0] =~ m#/#) { $fstype = '' }
 211         else { return $dirname || $ENV{DEFAULT} }
 212     }
 213     if ($fstype =~ /MacOS/i) { return $dirname }
 214     elsif ($fstype =~ /MSDOS/i) {
 215         $dirname =~ s/([^:])[\\\/]*$/$1/;
 216         unless( length($basename) ) {
 217             ($basename,$dirname) = fileparse $dirname;
 218             $dirname =~ s/([^:])[\\\/]*$/$1/;
 219         }
 220     }
 221     elsif ($fstype =~ /AmigaOS/i) {
 222         if ( $dirname =~ /:$/) { return $dirname }
 223         chop $dirname;
 224         $dirname =~ s#[^:/]+$## unless length($basename);
 225     }
 226     else {
 227         $dirname =~ s:(.)/*$:$1:;
 228         unless( length($basename) ) {
 229             local($File::Basename::Fileparse_fstype) = $fstype;
 230             ($basename,$dirname) = fileparse $dirname;
 231             $dirname =~ s:(.)/*$:$1:;
 232         }
 233     }
 234
 235     $dirname;
 236 }
 237
 238 fileparse_set_fstype $^O;
 239
 240 1;