lib/ExtUtils/xsubpp

   1 #!./miniperl
   2
   3 =head1 NAME
   4
   5 xsubpp - compiler to convert Perl XS code into C code
   6
   7 =head1 SYNOPSIS
   8
   9 B<xsubpp> [B<-v>] [B<-C++>] [B<-except>] [B<-s pattern>] [B<-prototypes>] [B<-noversioncheck>] [B<-typemap typemap>]... file.xs
  10
  11 =head1 DESCRIPTION
  12
  13 I<xsubpp> will compile XS code into C code by embedding the constructs
  14 necessary to let C functions manipulate Perl values and creates the glue
  15 necessary to let Perl access those functions.  The compiler uses typemaps to
  16 determine how to map C function parameters and variables to Perl values.
  17
  18 The compiler will search for typemap files called I<typemap>.  It will use
  19 the following search path to find default typemaps, with the rightmost
  20 typemap taking precedence.
  21
  22         ../../../typemap:../../typemap:../typemap:typemap
  23
  24 =head1 OPTIONS
  25
  26 =over 5
  27
  28 =item B<-C++>
  29
  30 Adds ``extern "C"'' to the C code.
  31
  32
  33 =item B<-except>
  34
  35 Adds exception handling stubs to the C code.
  36
  37 =item B<-typemap typemap>
  38
  39 Indicates that a user-supplied typemap should take precedence over the
  40 default typemaps.  This option may be used multiple times, with the last
  41 typemap having the highest precedence.
  42
  43 =item B<-v>
  44
  45 Prints the I<xsubpp> version number to standard output, then exits.
  46
  47 =item B<-prototypes>
  48
  49 By default I<xsubpp> will not automatically generate prototype code for
  50 all xsubs. This flag will enable prototypes.
  51
  52 =item B<-noversioncheck>
  53
  54 Disables the run time test that determines if the object file (derived
  55 from the C<.xs> file) and the C<.pm> files have the same version
  56 number.
  57
  58 =back
  59
  60 =head1 ENVIRONMENT
  61
  62 No environment variables are used.
  63
  64 =head1 AUTHOR
  65
  66 Larry Wall
  67
  68 =head1 MODIFICATION HISTORY
  69
  70 See the file F<changes.pod>.
  71
  72 =head1 SEE ALSO
  73
  74 perl(1), perlxs(1), perlxstut(1), perlxs(1)
  75
  76 =cut
  77
  78 # Global Constants
  79 $XSUBPP_version = "1.940";
  80 require 5.002;
  81 use vars '$cplusplus';
  82
  83 sub Q ;
  84
  85 $FH = 'File0000' ;
  86
  87 $usage = "Usage: xsubpp [-v] [-C++] [-except] [-prototypes] [-noversioncheck] [-s pattern] [-typemap typemap]... file.xs\n";
  88
  89 $proto_re = "[" . quotemeta('\$%&*@;') . "]" ;
  90
  91 $except = "";
  92 $WantPrototypes = -1 ;
  93 $WantVersionChk = 1 ;
  94 $ProtoUsed = 0 ;
  95 SWITCH: while (@ARGV and $ARGV[0] =~ /^-./) {
  96     $flag = shift @ARGV;
  97     $flag =~ s/^-// ;
  98     $spat = quotemeta shift,    next SWITCH     if $flag eq 's';
  99     $cplusplus = 1,     next SWITCH     if $flag eq 'C++';
 100     $WantPrototypes = 0, next SWITCH    if $flag eq 'noprototypes';
 101     $WantPrototypes = 1, next SWITCH    if $flag eq 'prototypes';
 102     $WantVersionChk = 0, next SWITCH    if $flag eq 'noversioncheck';
 103     $WantVersionChk = 1, next SWITCH    if $flag eq 'versioncheck';
 104     $except = " TRY",   next SWITCH     if $flag eq 'except';
 105     push(@tm,shift),    next SWITCH     if $flag eq 'typemap';
 106     (print "xsubpp version $XSUBPP_version\n"), exit
 107         if $flag eq 'v';
 108     die $usage;
 109 }
 110 if ($WantPrototypes == -1)
 111   { $WantPrototypes = 0}
 112 else
 113   { $ProtoUsed = 1 }
 114
 115
 116 @ARGV == 1 or die $usage;
 117 ($dir, $filename) = $ARGV[0] =~ m#(.*)/(.*)#
 118         or ($dir, $filename) = $ARGV[0] =~ m#(.*[>\]])(.*)#
 119         or ($dir, $filename) = ('.', $ARGV[0]);
 120 chdir($dir);
 121 # Check for VMS; Config.pm may not be installed yet, but this routine
 122 # is built into VMS perl
 123 if (defined(&VMS::Filespec::vmsify)) { $Is_VMS = 1; $pwd = $ENV{DEFAULT}; }
 124 else                                 { $Is_VMS = 0; chomp($pwd = `pwd`);   }
 125
 126 ++ $IncludedFiles{$ARGV[0]} ;
 127
 128 my(@XSStack) = ({type => 'none'});      # Stack of conditionals and INCLUDEs
 129 my($XSS_work_idx, $cpp_next_tmp) = (0, "XSubPPtmpAAAA");
 130
 131 sub TrimWhitespace
 132 {
 133     $_[0] =~ s/^\s+|\s+$//go ;
 134 }
 135
 136 sub TidyType
 137 {
 138     local ($_) = @_ ;
 139
 140     # rationalise any '*' by joining them into bunches and removing whitespace
 141     s#\s*(\*+)\s*#$1#g;
 142     s#(\*+)# $1 #g ;
 143
 144     # change multiple whitespace into a single space
 145     s/\s+/ /g ;
 146
 147     # trim leading & trailing whitespace
 148     TrimWhitespace($_) ;
 149
 150     $_ ;
 151 }
 152
 153 $typemap = shift @ARGV;
 154 foreach $typemap (@tm) {
 155     die "Can't find $typemap in $pwd\n" unless -r $typemap;
 156 }
 157 unshift @tm, qw(../../../../lib/ExtUtils/typemap ../../../lib/ExtUtils/typemap
 158                 ../../lib/ExtUtils/typemap ../../../typemap ../../typemap
 159                 ../typemap typemap);
 160 foreach $typemap (@tm) {
 161     next unless -e $typemap ;
 162     # skip directories, binary files etc.
 163     warn("Warning: ignoring non-text typemap file '$typemap'\n"), next
 164         unless -T $typemap ;
 165     open(TYPEMAP, $typemap)
 166         or warn ("Warning: could not open typemap file '$typemap': $!\n"), next;
 167     $mode = 'Typemap';
 168     $junk = "" ;
 169     $current = \$junk;
 170     while (<TYPEMAP>) {
 171         next if /^\s*#/;
 172         if (/^INPUT\s*$/)   { $mode = 'Input';   $current = \$junk;  next; }
 173         if (/^OUTPUT\s*$/)  { $mode = 'Output';  $current = \$junk;  next; }
 174         if (/^TYPEMAP\s*$/) { $mode = 'Typemap'; $current = \$junk;  next; }
 175         if ($mode eq 'Typemap') {
 176             chomp;
 177             my $line = $_ ;
 178             TrimWhitespace($_) ;
 179             # skip blank lines and comment lines
 180             next if /^$/ or /^#/ ;
 181             my($type,$kind, $proto) = /^\s*(.*?\S)\s+(\S+)\s*($proto_re*)\s*$/ or
 182                 warn("Warning: File '$typemap' Line $. '$line' TYPEMAP entry needs 2 or 3 columns\n"), next;
 183             $type = TidyType($type) ;
 184             $type_kind{$type} = $kind ;
 185             # prototype defaults to '$'
 186             $proto = "\$" unless $proto ;
 187             warn("Warning: File '$typemap' Line $. '$line' Invalid prototype '$proto'\n")
 188                 unless ValidProtoString($proto) ;
 189             $proto_letter{$type} = C_string($proto) ;
 190         }
 191         elsif (/^\s/) {
 192             $$current .= $_;
 193         }
 194         elsif ($mode eq 'Input') {
 195             s/\s+$//;
 196             $input_expr{$_} = '';
 197             $current = \$input_expr{$_};
 198         }
 199         else {
 200             s/\s+$//;
 201             $output_expr{$_} = '';
 202             $current = \$output_expr{$_};
 203         }
 204     }
 205     close(TYPEMAP);
 206 }
 207
 208 foreach $key (keys %input_expr) {
 209     $input_expr{$key} =~ s/\n+$//;
 210 }
 211
 212 $END = "!End!\n\n";             # "impossible" keyword (multiple newline)
 213
 214 # Match an XS keyword
 215 $BLOCK_re= '\s*(' . join('|', qw(
 216         REQUIRE BOOT CASE PREINIT INPUT INIT CODE PPCODE OUTPUT
 217         CLEANUP ALIAS PROTOTYPES PROTOTYPE VERSIONCHECK INCLUDE
 218         SCOPE
 219         )) . "|$END)\\s*:";
 220
 221 # Input:  ($_, @line) == unparsed input.
 222 # Output: ($_, @line) == (rest of line, following lines).
 223 # Return: the matched keyword if found, otherwise 0
 224 sub check_keyword {
 225         $_ = shift(@line) while !/\S/ && @line;
 226         s/^(\s*)($_[0])\s*:\s*(?:#.*)?/$1/s && $2;
 227 }
 228
 229
 230 sub print_section {
 231     $_ = shift(@line) while !/\S/ && @line;
 232     for (;  defined($_) && !/^$BLOCK_re/o;  $_ = shift(@line)) {
 233         print "$_\n";
 234     }
 235 }
 236
 237 sub process_keyword($)
 238 {
 239     my($pattern) = @_ ;
 240     my $kwd ;
 241
 242     &{"${kwd}_handler"}()
 243         while $kwd = check_keyword($pattern) ;
 244 }
 245
 246 sub CASE_handler {
 247     blurt ("Error: `CASE:' after unconditional `CASE:'")
 248         if $condnum && $cond eq '';
 249     $cond = $_;
 250     TrimWhitespace($cond);
 251     print "   ", ($condnum++ ? " else" : ""), ($cond ? " if ($cond)\n" : "\n");
 252     $_ = '' ;
 253 }
 254
 255 sub INPUT_handler {
 256     for (;  !/^$BLOCK_re/o;  $_ = shift(@line)) {
 257         last if /^\s*NOT_IMPLEMENTED_YET/;
 258         next unless /\S/;       # skip blank lines
 259
 260         TrimWhitespace($_) ;
 261         my $line = $_ ;
 262
 263         # remove trailing semicolon if no initialisation
 264         s/\s*;$//g unless /=/ ;
 265
 266         # check for optional initialisation code
 267         my $var_init = '' ;
 268         $var_init = $1 if s/\s*(=.*)$//s ;
 269         $var_init =~ s/"/\\"/g;
 270
 271         s/\s+/ /g;
 272         my ($var_type, $var_addr, $var_name) = /^(.*?[^& ]) *(\&?) *\b(\w+)$/s
 273             or blurt("Error: invalid argument declaration '$line'"), next;
 274
 275         # Check for duplicate definitions
 276         blurt ("Error: duplicate definition of argument '$var_name' ignored"), next
 277             if $arg_list{$var_name} ++  ;
 278
 279         $thisdone |= $var_name eq "THIS";
 280         $retvaldone |= $var_name eq "RETVAL";
 281         $var_types{$var_name} = $var_type;
 282         print "\t" . &map_type($var_type);
 283         $var_num = $args_match{$var_name};
 284
 285         $proto_arg[$var_num] = ProtoString($var_type)
 286             if $var_num ;
 287         if ($var_addr) {
 288             $var_addr{$var_name} = 1;
 289             $func_args =~ s/\b($var_name)\b/&$1/;
 290         }
 291         if ($var_init =~ /^=\s*NO_INIT\s*;?\s*$/) {
 292             print "\t$var_name;\n";
 293         } elsif ($var_init =~ /\S/) {
 294             &output_init($var_type, $var_num, "$var_name $var_init");
 295         } elsif ($var_num) {
 296             # generate initialization code
 297             &generate_init($var_type, $var_num, $var_name);
 298         } else {
 299             print ";\n";
 300         }
 301     }
 302 }
 303
 304 sub OUTPUT_handler {
 305     for (;  !/^$BLOCK_re/o;  $_ = shift(@line)) {
 306         next unless /\S/;
 307         my ($outarg, $outcode) = /^\s*(\S+)\s*(.*?)\s*$/s ;
 308         blurt ("Error: duplicate OUTPUT argument '$outarg' ignored"), next
 309             if $outargs{$outarg} ++ ;
 310         if (!$gotRETVAL and $outarg eq 'RETVAL') {
 311             # deal with RETVAL last
 312             $RETVAL_code = $outcode ;
 313             $gotRETVAL = 1 ;
 314             next ;
 315         }
 316         blurt ("Error: OUTPUT $outarg not an argument"), next
 317             unless defined($args_match{$outarg});
 318         blurt("Error: No input definition for OUTPUT argument '$outarg' - ignored"), next
 319             unless defined $var_types{$outarg} ;
 320         if ($outcode) {
 321             print "\t$outcode\n";
 322         } else {
 323             $var_num = $args_match{$outarg};
 324             &generate_output($var_types{$outarg}, $var_num, $outarg);
 325         }
 326     }
 327 }
 328
 329 sub CLEANUP_handler() { print_section() }
 330 sub PREINIT_handler() { print_section() }
 331 sub INIT_handler()    { print_section() }
 332
 333 sub GetAliases
 334 {
 335     my ($line) = @_ ;
 336     my ($orig) = $line ;
 337     my ($alias) ;
 338     my ($value) ;
 339
 340     # Parse alias definitions
 341     # format is
 342     #    alias = value alias = value ...
 343
 344     while ($line =~ s/^\s*([\w:]+)\s*=\s*(\w+)\s*//) {
 345         $alias = $1 ;
 346         $orig_alias = $alias ;
 347         $value = $2 ;
 348
 349         # check for optional package definition in the alias
 350         $alias = $Packprefix . $alias if $alias !~ /::/ ;
 351
 352         # check for duplicate alias name & duplicate value
 353         Warn("Warning: Ignoring duplicate alias '$orig_alias'")
 354             if defined $XsubAliases{$alias} ;
 355
 356         Warn("Warning: Aliases '$orig_alias' and '$XsubAliasValues{$value}' have identical values")
 357             if $XsubAliasValues{$value} ;
 358
 359         $XsubAliases = 1;
 360         $XsubAliases{$alias} = $value ;
 361         $XsubAliasValues{$value} = $orig_alias ;
 362     }
 363
 364     blurt("Error: Cannot parse ALIAS definitions from '$orig'")
 365         if $line ;
 366 }
 367
 368 sub ALIAS_handler ()
 369 {
 370     for (;  !/^$BLOCK_re/o;  $_ = shift(@line)) {
 371         next unless /\S/;
 372         TrimWhitespace($_) ;
 373         GetAliases($_) if $_ ;
 374     }
 375 }
 376
 377 sub REQUIRE_handler ()
 378 {
 379     # the rest of the current line should contain a version number
 380     my ($Ver) = $_ ;
 381
 382     TrimWhitespace($Ver) ;
 383
 384     death ("Error: REQUIRE expects a version number")
 385         unless $Ver ;
 386
 387     # check that the version number is of the form n.n
 388     death ("Error: REQUIRE: expected a number, got '$Ver'")
 389         unless $Ver =~ /^\d+(\.\d*)?/ ;
 390
 391     death ("Error: xsubpp $Ver (or better) required--this is only $XSUBPP_version.")
 392         unless $XSUBPP_version >= $Ver ;
 393 }
 394
 395 sub VERSIONCHECK_handler ()
 396 {
 397     # the rest of the current line should contain either ENABLE or
 398     # DISABLE
 399
 400     TrimWhitespace($_) ;
 401
 402     # check for ENABLE/DISABLE
 403     death ("Error: VERSIONCHECK: ENABLE/DISABLE")
 404         unless /^(ENABLE|DISABLE)/i ;
 405
 406     $WantVersionChk = 1 if $1 eq 'ENABLE' ;
 407     $WantVersionChk = 0 if $1 eq 'DISABLE' ;
 408
 409 }
 410
 411 sub PROTOTYPE_handler ()
 412 {
 413     my $specified ;
 414
 415     death("Error: Only 1 PROTOTYPE definition allowed per xsub")
 416         if $proto_in_this_xsub ++ ;
 417
 418     for (;  !/^$BLOCK_re/o;  $_ = shift(@line)) {
 419         next unless /\S/;
 420         $specified = 1 ;
 421         TrimWhitespace($_) ;
 422         if ($_ eq 'DISABLE') {
 423            $ProtoThisXSUB = 0
 424         }
 425         elsif ($_ eq 'ENABLE') {
 426            $ProtoThisXSUB = 1
 427         }
 428         else {
 429             # remove any whitespace
 430             s/\s+//g ;
 431             death("Error: Invalid prototype '$_'")
 432                 unless ValidProtoString($_) ;
 433             $ProtoThisXSUB = C_string($_) ;
 434         }
 435     }
 436
 437     # If no prototype specified, then assume empty prototype ""
 438     $ProtoThisXSUB = 2 unless $specified ;
 439
 440     $ProtoUsed = 1 ;
 441
 442 }
 443
 444 sub SCOPE_handler ()
 445 {
 446     death("Error: Only 1 SCOPE declaration allowed per xsub")
 447         if $scope_in_this_xsub ++ ;
 448
 449     for (;  !/^$BLOCK_re/o;  $_ = shift(@line)) {
 450                 next unless /\S/;
 451                 TrimWhitespace($_) ;
 452         if ($_ =~ /^DISABLE/i) {
 453                    $ScopeThisXSUB = 0
 454         }
 455         elsif ($_ =~ /^ENABLE/i) {
 456                    $ScopeThisXSUB = 1
 457         }
 458     }
 459
 460 }
 461
 462 sub PROTOTYPES_handler ()
 463 {
 464     # the rest of the current line should contain either ENABLE or
 465     # DISABLE
 466
 467     TrimWhitespace($_) ;
 468
 469     # check for ENABLE/DISABLE
 470     death ("Error: PROTOTYPES: ENABLE/DISABLE")
 471         unless /^(ENABLE|DISABLE)/i ;
 472
 473     $WantPrototypes = 1 if $1 eq 'ENABLE' ;
 474     $WantPrototypes = 0 if $1 eq 'DISABLE' ;
 475     $ProtoUsed = 1 ;
 476
 477 }
 478
 479 sub INCLUDE_handler ()
 480 {
 481     # the rest of the current line should contain a valid filename
 482
 483     TrimWhitespace($_) ;
 484
 485     death("INCLUDE: filename missing")
 486         unless $_ ;
 487
 488     death("INCLUDE: output pipe is illegal")
 489         if /^\s*\|/ ;
 490
 491     # simple minded recursion detector
 492     death("INCLUDE loop detected")
 493         if $IncludedFiles{$_} ;
 494
 495     ++ $IncludedFiles{$_} unless /\|\s*$/ ;
 496
 497     # Save the current file context.
 498     push(@XSStack, {
 499         type            => 'file',
 500         LastLine        => $lastline,
 501         LastLineNo      => $lastline_no,
 502         Line            => \@line,
 503         LineNo          => \@line_no,
 504         Filename        => $filename,
 505         Handle          => $FH,
 506         }) ;
 507
 508     ++ $FH ;
 509
 510     # open the new file
 511     open ($FH, "$_") or death("Cannot open '$_': $!") ;
 512
 513     print Q<<"EOF" ;
 514 #
 515 #/* INCLUDE:  Including '$_' from '$filename' */
 516 #
 517 EOF
 518
 519     $filename = $_ ;
 520
 521     # Prime the pump by reading the first
 522     # non-blank line
 523
 524     # skip leading blank lines
 525     while (<$FH>) {
 526         last unless /^\s*$/ ;
 527     }
 528
 529     $lastline = $_ ;
 530     $lastline_no = $. ;
 531
 532 }
 533
 534 sub PopFile()
 535 {
 536     return 0 unless $XSStack[-1]{type} eq 'file' ;
 537
 538     my $data     = pop @XSStack ;
 539     my $ThisFile = $filename ;
 540     my $isPipe   = ($filename =~ /\|\s*$/) ;
 541
 542     -- $IncludedFiles{$filename}
 543         unless $isPipe ;
 544
 545     close $FH ;
 546
 547     $FH         = $data->{Handle} ;
 548     $filename   = $data->{Filename} ;
 549     $lastline   = $data->{LastLine} ;
 550     $lastline_no = $data->{LastLineNo} ;
 551     @line       = @{ $data->{Line} } ;
 552     @line_no    = @{ $data->{LineNo} } ;
 553
 554     if ($isPipe and $? ) {
 555         -- $lastline_no ;
 556         print STDERR "Error reading from pipe '$ThisFile': $! in $filename, line $lastline_no\n"  ;
 557         exit 1 ;
 558     }
 559
 560     print Q<<"EOF" ;
 561 #
 562 #/* INCLUDE: Returning to '$filename' from '$ThisFile' */
 563 #
 564 EOF
 565
 566     return 1 ;
 567 }
 568
 569 sub ValidProtoString ($)
 570 {
 571     my($string) = @_ ;
 572
 573     if ( $string =~ /^$proto_re+$/ ) {
 574         return $string ;
 575     }
 576
 577     return 0 ;
 578 }
 579
 580 sub C_string ($)
 581 {
 582     my($string) = @_ ;
 583
 584     $string =~ s[\\][\\\\]g ;
 585     $string ;
 586 }
 587
 588 sub ProtoString ($)
 589 {
 590     my ($type) = @_ ;
 591
 592     $proto_letter{$type} or "\$" ;
 593 }
 594
 595 sub check_cpp {
 596     my @cpp = grep(/^\#\s*(?:if|e\w+)/, @line);
 597     if (@cpp) {
 598         my ($cpp, $cpplevel);
 599         for $cpp (@cpp) {
 600             if ($cpp =~ /^\#\s*if/) {
 601                 $cpplevel++;
 602             } elsif (!$cpplevel) {
 603                 Warn("Warning: #else/elif/endif without #if in this function");
 604                 print STDERR "    (precede it with a blank line if the matching #if is outside the function)\n"
 605                     if $XSStack[-1]{type} eq 'if';
 606                 return;
 607             } elsif ($cpp =~ /^\#\s*endif/) {
 608                 $cpplevel--;
 609             }
 610         }
 611         Warn("Warning: #if without #endif in this function") if $cpplevel;
 612     }
 613 }
 614
 615
 616 sub Q {
 617     my($text) = @_;
 618     $text =~ s/^#//gm;
 619     $text =~ s/\[\[/{/g;
 620     $text =~ s/\]\]/}/g;
 621     $text;
 622 }
 623
 624 open($FH, $filename) or die "cannot open $filename: $!\n";
 625
 626 # Identify the version of xsubpp used
 627 print <<EOM ;
 628 /*
 629  * This file was generated automatically by xsubpp version $XSUBPP_version from the
 630  * contents of $filename. Do not edit this file, edit $filename instead.
 631  *
 632  *      ANY CHANGES MADE HERE WILL BE LOST!
 633  *
 634  */
 635
 636 EOM
 637
 638
 639 while (<$FH>) {
 640     last if ($Module, $Package, $Prefix) =
 641         /^MODULE\s*=\s*([\w:]+)(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/;
 642     print $_;
 643 }
 644 &Exit unless defined $_;
 645
 646 $lastline    = $_;
 647 $lastline_no = $.;
 648
 649
 650 # Read next xsub into @line from ($lastline, <$FH>).
 651 sub fetch_para {
 652     # parse paragraph
 653     death ("Error: Unterminated `#if/#ifdef/#ifndef'")
 654         if !defined $lastline && $XSStack[-1]{type} eq 'if';
 655     @line = ();
 656     @line_no = () ;
 657     return PopFile() if !defined $lastline;
 658
 659     if ($lastline =~
 660         /^MODULE\s*=\s*([\w:]+)(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/) {
 661         $Module = $1;
 662         $Package = defined($2) ? $2 : '';       # keep -w happy
 663         $Prefix  = defined($3) ? $3 : '';       # keep -w happy
 664         $Prefix = quotemeta $Prefix ;
 665         ($Module_cname = $Module) =~ s/\W/_/g;
 666         ($Packid = $Package) =~ tr/:/_/;
 667         $Packprefix = $Package;
 668         $Packprefix .= "::" if $Packprefix ne "";
 669         $lastline = "";
 670     }
 671
 672     for(;;) {
 673         if ($lastline !~ /^\s*#/ ||
 674             # CPP directives:
 675             #   ANSI:   if ifdef ifndef elif else endif define undef
 676             #           line error pragma
 677             #   gcc:    warning include_next
 678             #   obj-c:  import
 679             #   others: ident (gcc notes that some cpps have this one)
 680             $lastline =~ /^#[ \t]*(?:(?:if|ifn?def|elif|else|endif|define|undef|pragma|error|warning|line\s+\d+|ident)\b|(?:include(?:_next)?|import)\s*["<].*[>"])/) {
 681             last if $lastline =~ /^\S/ && @line && $line[-1] eq "";
 682             push(@line, $lastline);
 683             push(@line_no, $lastline_no) ;
 684         }
 685
 686         # Read next line and continuation lines
 687         last unless defined($lastline = <$FH>);
 688         $lastline_no = $.;
 689         my $tmp_line;
 690         $lastline .= $tmp_line
 691             while ($lastline =~ /\\$/ && defined($tmp_line = <$FH>));
 692
 693         chomp $lastline;
 694         $lastline =~ s/^\s+$//;
 695     }
 696     pop(@line), pop(@line_no) while @line && $line[-1] eq "";
 697     1;
 698 }
 699
 700 PARAGRAPH:
 701 while (fetch_para()) {
 702     # Print initial preprocessor statements and blank lines
 703     while (@line && $line[0] !~ /^[^\#]/) {
 704         my $line = shift(@line);
 705         print $line, "\n";
 706         next unless $line =~ /^\#\s*((if)(?:n?def)?|elsif|else|endif)\b/;
 707         my $statement = $+;
 708         if ($statement eq 'if') {
 709             $XSS_work_idx = @XSStack;
 710             push(@XSStack, {type => 'if'});
 711         } else {
 712             death ("Error: `$statement' with no matching `if'")
 713                 if $XSStack[-1]{type} ne 'if';
 714             if ($XSStack[-1]{varname}) {
 715                 push(@InitFileCode, "#endif\n");
 716                 push(@BootCode,     "#endif");
 717             }
 718
 719             my(@fns) = keys %{$XSStack[-1]{functions}};
 720             if ($statement ne 'endif') {
 721                 # Hide the functions defined in other #if branches, and reset.
 722                 @{$XSStack[-1]{other_functions}}{@fns} = (1) x @fns;
 723                 @{$XSStack[-1]}{qw(varname functions)} = ('', {});
 724             } else {
 725                 my($tmp) = pop(@XSStack);
 726                 0 while (--$XSS_work_idx
 727                          && $XSStack[$XSS_work_idx]{type} ne 'if');
 728                 # Keep all new defined functions
 729                 push(@fns, keys %{$tmp->{other_functions}});
 730                 @{$XSStack[$XSS_work_idx]{functions}}{@fns} = (1) x @fns;
 731             }
 732         }
 733     }
 734
 735     next PARAGRAPH unless @line;
 736
 737     if ($XSS_work_idx && !$XSStack[$XSS_work_idx]{varname}) {
 738         # We are inside an #if, but have not yet #defined its xsubpp variable.
 739         print "#define $cpp_next_tmp 1\n\n";
 740         push(@InitFileCode, "#if $cpp_next_tmp\n");
 741         push(@BootCode,     "#if $cpp_next_tmp");
 742         $XSStack[$XSS_work_idx]{varname} = $cpp_next_tmp++;
 743     }
 744
 745     death ("Code is not inside a function"
 746            ." (maybe last function was ended by a blank line "
 747            ." followed by a a statement on column one?)")
 748         if $line[0] =~ /^\s/;
 749
 750     # initialize info arrays
 751     undef(%args_match);
 752     undef(%var_types);
 753     undef(%var_addr);
 754     undef(%defaults);
 755     undef($class);
 756     undef($static);
 757     undef($elipsis);
 758     undef($wantRETVAL) ;
 759     undef(%arg_list) ;
 760     undef(@proto_arg) ;
 761     undef($proto_in_this_xsub) ;
 762     undef($scope_in_this_xsub) ;
 763     $ProtoThisXSUB = $WantPrototypes ;
 764     $ScopeThisXSUB = 0;
 765
 766     $_ = shift(@line);
 767     while ($kwd = check_keyword("REQUIRE|PROTOTYPES|VERSIONCHECK|INCLUDE")) {
 768         &{"${kwd}_handler"}() ;
 769         next PARAGRAPH unless @line ;
 770         $_ = shift(@line);
 771     }
 772
 773     if (check_keyword("BOOT")) {
 774         &check_cpp;
 775         push (@BootCode, $_, @line, "") ;
 776         next PARAGRAPH ;
 777     }
 778
 779
 780     # extract return type, function name and arguments
 781     my($ret_type) = TidyType($_);
 782
 783     # a function definition needs at least 2 lines
 784     blurt ("Error: Function definition too short '$ret_type'"), next PARAGRAPH
 785         unless @line ;
 786
 787     $static = 1 if $ret_type =~ s/^static\s+//;
 788
 789     $func_header = shift(@line);
 790     blurt ("Error: Cannot parse function definition from '$func_header'"), next PARAGRAPH
 791         unless $func_header =~ /^(?:([\w:]*)::)?(\w+)\s*\(\s*(.*?)\s*\)\s*$/s;
 792
 793     ($class, $func_name, $orig_args) =  ($1, $2, $3) ;
 794     ($pname = $func_name) =~ s/^($Prefix)?/$Packprefix/;
 795     ($clean_func_name = $func_name) =~ s/^$Prefix//;
 796     $Full_func_name = "${Packid}_$clean_func_name";
 797
 798     # Check for duplicate function definition
 799     for $tmp (@XSStack) {
 800         next unless defined $tmp->{functions}{$Full_func_name};
 801         Warn("Warning: duplicate function definition '$clean_func_name' detected");
 802         last;
 803     }
 804     $XSStack[$XSS_work_idx]{functions}{$Full_func_name} ++ ;
 805     %XsubAliases = %XsubAliasValues = ();
 806
 807     @args = split(/\s*,\s*/, $orig_args);
 808     if (defined($class)) {
 809         my $arg0 = ((defined($static) or $func_name =~ /^new/) ? "CLASS" : "THIS");
 810         unshift(@args, $arg0);
 811         ($orig_args = "$arg0, $orig_args") =~ s/^$arg0, $/$arg0/;
 812     }
 813     $orig_args =~ s/"/\\"/g;
 814     $min_args = $num_args = @args;
 815     foreach $i (0..$num_args-1) {
 816             if ($args[$i] =~ s/\.\.\.//) {
 817                     $elipsis = 1;
 818                     $min_args--;
 819                     if ($args[$i] eq '' && $i == $num_args - 1) {
 820                         pop(@args);
 821                         last;
 822                     }
 823             }
 824             if ($args[$i] =~ /^([^=]*[^\s=])\s*=\s*(.*)/s) {
 825                     $min_args--;
 826                     $args[$i] = $1;
 827                     $defaults{$args[$i]} = $2;
 828                     $defaults{$args[$i]} =~ s/"/\\"/g;
 829             }
 830             $proto_arg[$i+1] = "\$" ;
 831     }
 832     if (defined($class)) {
 833             $func_args = join(", ", @args[1..$#args]);
 834     } else {
 835             $func_args = join(", ", @args);
 836     }
 837     @args_match{@args} = 1..@args;
 838
 839     $PPCODE = grep(/^\s*PPCODE\s*:/, @line);
 840     $CODE = grep(/^\s*CODE\s*:/, @line);
 841     $ALIAS  = grep(/^\s*ALIAS\s*:/,  @line);
 842
 843     # print function header
 844     print Q<<"EOF";
 845 #XS(XS_${Full_func_name})
 846 #[[
 847 #    dXSARGS;
 848 EOF
 849     print Q<<"EOF" if $ALIAS ;
 850 #    dXSI32;
 851 EOF
 852     if ($elipsis) {
 853         $cond = ($min_args ? qq(items < $min_args) : 0);
 854     }
 855     elsif ($min_args == $num_args) {
 856         $cond = qq(items != $min_args);
 857     }
 858     else {
 859         $cond = qq(items < $min_args || items > $num_args);
 860     }
 861
 862     print Q<<"EOF" if $except;
 863 #    char errbuf[1024];
 864 #    *errbuf = '\0';
 865 EOF
 866
 867     if ($ALIAS)
 868       { print Q<<"EOF" if $cond }
 869 #    if ($cond)
 870 #       croak("Usage: %s($orig_args)", GvNAME(CvGV(cv)));
 871 EOF
 872     else
 873       { print Q<<"EOF" if $cond }
 874 #    if ($cond)
 875 #       croak("Usage: $pname($orig_args)");
 876 EOF
 877
 878     print Q<<"EOF" if $PPCODE;
 879 #    SP -= items;
 880 EOF
 881
 882     # Now do a block of some sort.
 883
 884     $condnum = 0;
 885     $cond = '';                 # last CASE: condidional
 886     push(@line, "$END:");
 887     push(@line_no, $line_no[-1]);
 888     $_ = '';
 889     &check_cpp;
 890     while (@line) {
 891         &CASE_handler if check_keyword("CASE");
 892         print Q<<"EOF";
 893 #   $except [[
 894 EOF
 895
 896         # do initialization of input variables
 897         $thisdone = 0;
 898         $retvaldone = 0;
 899         $deferred = "";
 900         %arg_list = () ;
 901         $gotRETVAL = 0;
 902
 903         INPUT_handler() ;
 904         process_keyword("INPUT|PREINIT|ALIAS|PROTOTYPE|SCOPE") ;
 905
 906         print Q<<"EOF" if $ScopeThisXSUB;
 907 #   ENTER;
 908 #   [[
 909 EOF
 910
 911         if (!$thisdone && defined($class)) {
 912             if (defined($static) or $func_name =~ /^new/) {
 913                 print "\tchar *";
 914                 $var_types{"CLASS"} = "char *";
 915                 &generate_init("char *", 1, "CLASS");
 916             }
 917             else {
 918                 print "\t$class *";
 919                 $var_types{"THIS"} = "$class *";
 920                 &generate_init("$class *", 1, "THIS");
 921             }
 922         }
 923
 924         # do code
 925         if (/^\s*NOT_IMPLEMENTED_YET/) {
 926                 print "\n\tcroak(\"$pname: not implemented yet\");\n";
 927                 $_ = '' ;
 928         } else {
 929                 if ($ret_type ne "void") {
 930                         print "\t" . &map_type($ret_type) . "\tRETVAL;\n"
 931                                 if !$retvaldone;
 932                         $args_match{"RETVAL"} = 0;
 933                         $var_types{"RETVAL"} = $ret_type;
 934                 }
 935
 936                 print $deferred;
 937
 938         process_keyword("INIT|ALIAS|PROTOTYPE") ;
 939
 940                 if (check_keyword("PPCODE")) {
 941                         print_section();
 942                         death ("PPCODE must be last thing") if @line;
 943                         print "\tLEAVE;\n" if $ScopeThisXSUB;
 944                         print "\tPUTBACK;\n\treturn;\n";
 945                 } elsif (check_keyword("CODE")) {
 946                         print_section() ;
 947                 } elsif (defined($class) and $func_name eq "DESTROY") {
 948                         print "\n\t";
 949                         print "delete THIS;\n";
 950                 } else {
 951                         print "\n\t";
 952                         if ($ret_type ne "void") {
 953                                 print "RETVAL = ";
 954                                 $wantRETVAL = 1;
 955                         }
 956                         if (defined($static)) {
 957                             if ($func_name =~ /^new/) {
 958                                 $func_name = "$class";
 959                             } else {
 960                                 print "${class}::";
 961                             }
 962                         } elsif (defined($class)) {
 963                             if ($func_name =~ /^new/) {
 964                                 $func_name .= " $class";
 965                             } else {
 966                                 print "THIS->";
 967                             }
 968                         }
 969                         $func_name =~ s/^($spat)//
 970                             if defined($spat);
 971                         print "$func_name($func_args);\n";
 972                 }
 973         }
 974
 975         # do output variables
 976         $gotRETVAL = 0;
 977         undef $RETVAL_code ;
 978         undef %outargs ;
 979         process_keyword("OUTPUT|ALIAS|PROTOTYPE");
 980
 981         # all OUTPUT done, so now push the return value on the stack
 982         if ($gotRETVAL && $RETVAL_code) {
 983             print "\t$RETVAL_code\n";
 984         } elsif ($gotRETVAL || $wantRETVAL) {
 985             &generate_output($ret_type, 0, 'RETVAL');
 986         }
 987
 988         # do cleanup
 989         process_keyword("CLEANUP|ALIAS|PROTOTYPE") ;
 990
 991         print Q<<"EOF" if $ScopeThisXSUB;
 992 #   ]]
 993 EOF
 994         print Q<<"EOF" if $ScopeThisXSUB and not $PPCODE;
 995 #   LEAVE;
 996 EOF
 997
 998         # print function trailer
 999         print Q<<EOF;
1000 #    ]]
1001 EOF
1002         print Q<<EOF if $except;
1003 #    BEGHANDLERS
1004 #    CATCHALL
1005 #       sprintf(errbuf, "%s: %s\\tpropagated", Xname, Xreason);
1006 #    ENDHANDLERS
1007 EOF
1008         if (check_keyword("CASE")) {
1009             blurt ("Error: No `CASE:' at top of function")
1010                 unless $condnum;
1011             $_ = "CASE: $_";    # Restore CASE: label
1012             next;
1013         }
1014         last if $_ eq "$END:";
1015         death(/^$BLOCK_re/o ? "Misplaced `$1:'" : "Junk at end of function");
1016     }
1017
1018     print Q<<EOF if $except;
1019 #    if (errbuf[0])
1020 #       croak(errbuf);
1021 EOF
1022
1023     if ($ret_type ne "void" or $CODE) {
1024         print Q<<EOF unless $PPCODE;
1025 #    XSRETURN(1);
1026 EOF
1027     } else {
1028         print Q<<EOF unless $PPCODE;
1029 #    XSRETURN_EMPTY;
1030 EOF
1031     }
1032
1033     print Q<<EOF;
1034 #]]
1035 #
1036 EOF
1037
1038     my $newXS = "newXS" ;
1039     my $proto = "" ;
1040
1041     # Build the prototype string for the xsub
1042     if ($ProtoThisXSUB) {
1043         $newXS = "newXSproto";
1044
1045         if ($ProtoThisXSUB == 2) {
1046             # User has specified empty prototype
1047             $proto = ', ""' ;
1048         }
1049         elsif ($ProtoThisXSUB != 1) {
1050             # User has specified a prototype
1051             $proto = ', "' . $ProtoThisXSUB . '"';
1052         }
1053         else {
1054             my $s = ';';
1055             if ($min_args < $num_args)  {
1056                 $s = '';
1057                 $proto_arg[$min_args] .= ";" ;
1058             }
1059             push @proto_arg, "$s\@"
1060                 if $elipsis ;
1061
1062             $proto = ', "' . join ("", @proto_arg) . '"';
1063         }
1064     }
1065
1066     if (%XsubAliases) {
1067         $XsubAliases{$pname} = 0
1068             unless defined $XsubAliases{$pname} ;
1069         while ( ($name, $value) = each %XsubAliases) {
1070             push(@InitFileCode, Q<<"EOF");
1071 #        cv = newXS(\"$name\", XS_$Full_func_name, file);
1072 #        XSANY.any_i32 = $value ;
1073 EOF
1074         push(@InitFileCode, Q<<"EOF") if $proto;
1075 #        sv_setpv((SV*)cv$proto) ;
1076 EOF
1077         }
1078     }
1079     else {
1080         push(@InitFileCode,
1081              "        ${newXS}(\"$pname\", XS_$Full_func_name, file$proto);\n");
1082     }
1083 }
1084
1085 # print initialization routine
1086 print Q<<"EOF";
1087 ##ifdef __cplusplus
1088 #extern "C"
1089 ##endif
1090 #XS(boot_$Module_cname)
1091 #[[
1092 #    dXSARGS;
1093 #    char* file = __FILE__;
1094 #
1095 EOF
1096
1097 print Q<<"EOF" if $WantVersionChk ;
1098 #    XS_VERSION_BOOTCHECK ;
1099 #
1100 EOF
1101
1102 print Q<<"EOF" if defined $XsubAliases ;
1103 #    {
1104 #        CV * cv ;
1105 #
1106 EOF
1107
1108 print @InitFileCode;
1109
1110 print Q<<"EOF" if defined $XsubAliases ;
1111 #    }
1112 EOF
1113
1114 if (@BootCode)
1115 {
1116     print "\n    /* Initialisation Section */\n" ;
1117     print grep (s/$/\n/, @BootCode) ;
1118     print "\n    /* End of Initialisation Section */\n\n" ;
1119 }
1120
1121 print Q<<"EOF";;
1122 #    ST(0) = &sv_yes;
1123 #    XSRETURN(1);
1124 #]]
1125 EOF
1126
1127 warn("Please specify prototyping behavior for $filename (see perlxs manual)\n")
1128     unless $ProtoUsed ;
1129 &Exit;
1130
1131
1132 sub output_init {
1133     local($type, $num, $init) = @_;
1134     local($arg) = "ST(" . ($num - 1) . ")";
1135
1136     eval qq/print " $init\\\n"/;
1137 }
1138
1139 sub Warn
1140 {
1141     # work out the line number
1142     my $line_no = $line_no[@line_no - @line -1] ;
1143
1144     print STDERR "@_ in $filename, line $line_no\n" ;
1145 }
1146
1147 sub blurt
1148 {
1149     Warn @_ ;
1150     $errors ++
1151 }
1152
1153 sub death
1154 {
1155     Warn @_ ;
1156     exit 1 ;
1157 }
1158
1159 sub generate_init {
1160     local($type, $num, $var) = @_;
1161     local($arg) = "ST(" . ($num - 1) . ")";
1162     local($argoff) = $num - 1;
1163     local($ntype);
1164     local($tk);
1165
1166     $type = TidyType($type) ;
1167     blurt("Error: '$type' not in typemap"), return
1168         unless defined($type_kind{$type});
1169
1170     ($ntype = $type) =~ s/\s*\*/Ptr/g;
1171     ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1172     $tk = $type_kind{$type};
1173     $tk =~ s/OBJ$/REF/ if $func_name =~ /DESTROY$/;
1174     $type =~ tr/:/_/;
1175     blurt("Error: No INPUT definition for type '$type' found"), return
1176         unless defined $input_expr{$tk} ;
1177     $expr = $input_expr{$tk};
1178     if ($expr =~ /DO_ARRAY_ELEM/) {
1179         blurt("Error: '$subtype' not in typemap"), return
1180             unless defined($type_kind{$subtype});
1181         blurt("Error: No INPUT definition for type '$subtype' found"), return
1182             unless defined $input_expr{$type_kind{$subtype}} ;
1183         $subexpr = $input_expr{$type_kind{$subtype}};
1184         $subexpr =~ s/ntype/subtype/g;
1185         $subexpr =~ s/\$arg/ST(ix_$var)/g;
1186         $subexpr =~ s/\n\t/\n\t\t/g;
1187         $subexpr =~ s/is not of (.*\")/[arg %d] is not of $1, ix_$var + 1/g;
1188         $subexpr =~ s/\$var/${var}[ix_$var - $argoff]/;
1189         $expr =~ s/DO_ARRAY_ELEM/$subexpr/;
1190     }
1191     if ($expr =~ m#/\*.*scope.*\*/#i) { # "scope" in C comments
1192         $ScopeThisXSUB = 1;
1193     }
1194     if (defined($defaults{$var})) {
1195             $expr =~ s/(\t+)/$1    /g;
1196             $expr =~ s/        /\t/g;
1197             eval qq/print "\\t$var;\\n"/;
1198             $deferred .= eval qq/"\\n\\tif (items < $num)\\n\\t    $var = $defaults{$var};\\n\\telse {\\n$expr;\\n\\t}\\n"/;
1199     } elsif ($ScopeThisXSUB or $expr !~ /^\t\$var =/) {
1200             eval qq/print "\\t$var;\\n"/;
1201             $deferred .= eval qq/"\\n$expr;\\n"/;
1202     } else {
1203             eval qq/print "$expr;\\n"/;
1204     }
1205 }
1206
1207 sub generate_output {
1208     local($type, $num, $var) = @_;
1209     local($arg) = "ST(" . ($num - ($num != 0)) . ")";
1210     local($argoff) = $num - 1;
1211     local($ntype);
1212
1213     $type = TidyType($type) ;
1214     if ($type =~ /^array\(([^,]*),(.*)\)/) {
1215             print "\tsv_setpvn($arg, (char *)$var, $2 * sizeof($1)), XFree((char *)$var);\n";
1216     } else {
1217             blurt("Error: '$type' not in typemap"), return
1218                 unless defined($type_kind{$type});
1219             blurt("Error: No OUTPUT definition for type '$type' found"), return
1220                 unless defined $output_expr{$type_kind{$type}} ;
1221             ($ntype = $type) =~ s/\s*\*/Ptr/g;
1222             $ntype =~ s/\(\)//g;
1223             ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1224             $expr = $output_expr{$type_kind{$type}};
1225             if ($expr =~ /DO_ARRAY_ELEM/) {
1226                 blurt("Error: '$subtype' not in typemap"), return
1227                     unless defined($type_kind{$subtype});
1228                 blurt("Error: No OUTPUT definition for type '$subtype' found"), return
1229                     unless defined $output_expr{$type_kind{$subtype}} ;
1230                 $subexpr = $output_expr{$type_kind{$subtype}};
1231                 $subexpr =~ s/ntype/subtype/g;
1232                 $subexpr =~ s/\$arg/ST(ix_$var)/g;
1233                 $subexpr =~ s/\$var/${var}[ix_$var]/g;
1234                 $subexpr =~ s/\n\t/\n\t\t/g;
1235                 $expr =~ s/DO_ARRAY_ELEM\n/$subexpr/;
1236                 eval "print qq\a$expr\a";
1237             }
1238             elsif ($var eq 'RETVAL') {
1239                 if ($expr =~ /^\t\$arg = new/) {
1240                     # We expect that $arg has refcnt 1, so we need to
1241                     # mortalize it.
1242                     eval "print qq\a$expr\a";
1243                     print "\tsv_2mortal(ST(0));\n";
1244                 }
1245                 elsif ($expr =~ /^\s*\$arg\s*=/) {
1246                     # We expect that $arg has refcnt >=1, so we need
1247                     # to mortalize it. However, the extension may have
1248                     # returned the built-in perl value, which is
1249                     # read-only, thus not mortalizable. However, it is
1250                     # safe to leave it as it is, since it would be
1251                     # ignored by REFCNT_dec. Builtin values have REFCNT==0.
1252                     eval "print qq\a$expr\a";
1253                     print "\tif (SvREFCNT(ST(0))) sv_2mortal(ST(0));\n";
1254                 }
1255                 else {
1256                     # Just hope that the entry would safely write it
1257                     # over an already mortalized value. By
1258                     # coincidence, something like $arg = &sv_undef
1259                     # works too.
1260                     print "\tST(0) = sv_newmortal();\n";
1261                     eval "print qq\a$expr\a";
1262                 }
1263             }
1264             elsif ($arg =~ /^ST\(\d+\)$/) {
1265                 eval "print qq\a$expr\a";
1266             }
1267     }
1268 }
1269
1270 sub map_type {
1271     my($type) = @_;
1272
1273     $type =~ tr/:/_/;
1274     $type =~ s/^array\(([^,]*),(.*)\).*/$1 */s;
1275     $type;
1276 }
1277
1278
1279 sub Exit {
1280 # If this is VMS, the exit status has meaning to the shell, so we
1281 # use a predictable value (SS$_Normal or SS$_Abort) rather than an
1282 # arbitrary number.
1283     exit ($Is_VMS ? ($errors ? 44 : 1) : $errors) ;
1284 }