lib/ExtUtils/t/parse_version.t

   1 #!/usr/bin/perl -w
   2
   3 BEGIN {
   4     if( $ENV{PERL_CORE} ) {
   5         chdir 't';
   6         @INC = '../lib';
   7     }
   8     else {
   9         unshift @INC, 't/lib';
  10     }
  11 }
  12 chdir 't';
  13
  14 use Test::More;
  15 use ExtUtils::MakeMaker;
  16
  17 my $Has_Version = eval 'require version; "version"->import';
  18 my $Has_Our     = eval 'our $foo';
  19
  20 my %versions = (q[$VERSION = '1.00']        => '1.00',
  21                 q[*VERSION = \'1.01']       => '1.01',
  22                 q[($VERSION) = q$Revision: 32208 $ =~ /(\d+)/g;] => 32208,
  23                 q[$FOO::VERSION = '1.10';]  => '1.10',
  24                 q[*FOO::VERSION = \'1.11';] => '1.11',
  25                 '$VERSION = 0.02'   => 0.02,
  26                 '$VERSION = 0.0'    => 0.0,
  27                 '$VERSION = -1.0'   => -1.0,
  28                 '$VERSION = undef'  => 'undef',
  29                 '$wibble  = 1.0'    => 'undef',
  30                 q[my $VERSION = '1.01']         => 'undef',
  31                 q[local $VERISON = '1.02']      => 'undef',
  32                 q[local $FOO::VERSION = '1.30'] => 'undef',
  33                );
  34
  35 if( $Has_Our ) {
  36     $versions{q[our $VERSION = '1.23';]}   = '1.23',
  37 }
  38
  39 if( $Has_Version ) {
  40     $versions{q[use version; $VERSION = qv(1.2.3);]} = qv(1.2.3);
  41     $versions{q[$VERSION = qv(1.2.3)]}               = qv(1.2.3);
  42 }
  43
  44 plan tests => (2 * keys %versions) + 4;
  45
  46 while( my($code, $expect) = each %versions ) {
  47     is( parse_version_string($code), $expect, $code );
  48 }
  49
  50
  51 sub parse_version_string {
  52     my $code = shift;
  53
  54     open(FILE, ">VERSION.tmp") || die $!;
  55     print FILE "$code\n";
  56     close FILE;
  57
  58     $_ = 'foo';
  59     my $version = MM->parse_version('VERSION.tmp');
  60     is( $_, 'foo', '$_ not leaked by parse_version' );
  61
  62     unlink "VERSION.tmp";
  63
  64     return $version;
  65 }
  66
  67
  68 SKIP: {
  69     skip "need version.pm", 2 unless $Has_Version;
  70     is parse_version_string(q[ $VERSION = '1.00'; sub version { $VERSION } ]),
  71        '1.00';
  72     is parse_version_string(q[ use version; $VERSION = version->new(1.23) ]),
  73        '1.23';
  74 }