lib/ExtUtils/t/MM_Win32.t

   1 #!/usr/bin/perl
   2
   3 BEGIN {
   4     if( $ENV{PERL_CORE} ) {
   5         chdir 't' if -d 't';
   6         @INC = '../lib';
   7     }
   8     else {
   9         unshift @INC, 't/lib';
  10     }
  11 }
  12 chdir 't';
  13
  14 use strict;
  15 use Test::More;
  16
  17 BEGIN {
  18         if ($^O =~ /MSWin32/i) {
  19                 plan tests => 42;
  20         } else {
  21                 plan skip_all => 'This is not Win32';
  22         }
  23 }
  24
  25 use Config;
  26 use File::Spec;
  27 use File::Basename;
  28 use ExtUtils::MM;
  29
  30 require_ok( 'ExtUtils::MM_Win32' );
  31
  32 # Dummy MM object until we have a real MM init method.
  33 my $MM = bless {
  34                 DIR     => [],
  35                 NOECHO  => '@',
  36                 XS      => {},
  37                 MAKEFILE => 'Makefile',
  38                 RM_RF   => 'rm -rf',
  39                 MV      => 'mv',
  40                }, 'MM';
  41
  42
  43 # replace_manpage_separator() => tr|/|.|s ?
  44 {
  45     my $man = 'a/path/to//something';
  46     ( my $replaced = $man ) =~ tr|/|.|s;
  47     is( $MM->replace_manpage_separator( $man ),
  48         $replaced, 'replace_manpage_separator()' );
  49 }
  50
  51 # maybe_command()
  52 SKIP: {
  53     skip( '$ENV{COMSPEC} not set', 2 )
  54         unless $ENV{COMSPEC} =~ m!((?:[a-z]:)?[^|<>]+)!i;
  55     my $comspec = $1;
  56     is( $MM->maybe_command( $comspec ),
  57         $comspec, 'COMSPEC is a maybe_command()' );
  58     ( my $comspec2 = $comspec ) =~ s|\..{3}$||;
  59     like( $MM->maybe_command( $comspec2 ),
  60           qr/\Q$comspec/i,
  61           'maybe_command() without extension' );
  62 }
  63
  64 my $had_pathext = exists $ENV{PATHEXT};
  65 {
  66     local $ENV{PATHEXT} = '.exe';
  67     ok( ! $MM->maybe_command( 'not_a_command.com' ),
  68         'not a maybe_command()' );
  69 }
  70 # Bug in Perl.  local $ENV{FOO} won't delete the key afterward.
  71 delete $ENV{PATHEXT} unless $had_pathext;
  72
  73 # file_name_is_absolute() [Does not support UNC-paths]
  74 {
  75     ok( $MM->file_name_is_absolute( 'C:/' ),
  76         'file_name_is_absolute()' );
  77     ok( ! $MM->file_name_is_absolute( 'some/path/' ),
  78         'not file_name_is_absolute()' );
  79
  80 }
  81
  82 # find_perl()
  83 # Should be able to find running perl... $^X is OK on Win32
  84 {
  85     my $my_perl = $1 if $^X  =~ /(.*)/; # are we in -T or -t?
  86     my( $perl, $path ) = fileparse( $my_perl );
  87     like( $MM->find_perl( $], [ $perl ], [ $path ], 0 ),
  88           qr/^\Q$my_perl\E$/i, 'find_perl() finds this perl' );
  89 }
  90
  91 # catdir() (calls MM_Win32->canonpath)
  92 {
  93     my @path_eg = qw( c: trick dir/now_OK );
  94
  95     is( $MM->catdir( @path_eg ),
  96          'C:\\trick\\dir\\now_OK', 'catdir()' );
  97     is( $MM->catdir( @path_eg ),
  98         File::Spec->catdir( @path_eg ),
  99         'catdir() eq File::Spec->catdir()' );
 100
 101 # catfile() (calls MM_Win32->catdir)
 102     push @path_eg, 'file.ext';
 103
 104     is( $MM->catfile( @path_eg ),
 105         'C:\\trick\\dir\\now_OK\\file.ext', 'catfile()' );
 106
 107     is( $MM->catfile( @path_eg ),
 108         File::Spec->catfile( @path_eg ),
 109         'catfile() eq File::Spec->catfile()' );
 110 }
 111
 112 # init_others(): check if all keys are created and set?
 113 # qw( TOUCH CHMOD CP RM_F RM_RF MV NOOP TEST_F LD AR LDLOADLIBS DEV_NUL )
 114 {
 115     my $mm_w32 = bless( { BASEEXT => 'Foo' }, 'MM' );
 116     $mm_w32->init_others();
 117     my @keys = qw( TOUCH CHMOD CP RM_F RM_RF MV NOOP
 118                    TEST_F LD AR LDLOADLIBS DEV_NULL );
 119     for my $key ( @keys ) {
 120         ok( $mm_w32->{ $key }, "init_others: $key" );
 121     }
 122 }
 123
 124 # constants()
 125 # XXX this test is probably useless now that we can call individual
 126 # init_* methods and check the keys in $mm_w32 directly
 127 {
 128     my $mm_w32 = bless {
 129         NAME         => 'TestMM_Win32',
 130         VERSION      => '1.00',
 131         PM           => { 'MM_Win32.pm' => 1 },
 132     }, 'MM';
 133
 134     # XXX Hack until we have a proper init method.
 135     # Flesh out some necessary keys in the MM object.
 136     @{$mm_w32}{qw(XS MAN1PODS MAN3PODS)} = ({}) x 3;
 137     @{$mm_w32}{qw(C O_FILES H)}          = ([]) x 3;
 138     @{$mm_w32}{qw(PARENT_NAME)}          = ('') x 3;
 139     $mm_w32->{FULLEXT} = 'TestMM_Win32';
 140     $mm_w32->{BASEEXT} = 'TestMM_Win32';
 141
 142     $mm_w32->init_VERSION;
 143     $mm_w32->init_linker;
 144     $mm_w32->init_INST;
 145     $mm_w32->init_xs;
 146
 147     my $s_PM = join( " \\\n\t", sort keys %{$mm_w32->{PM}} );
 148     my $k_PM = join( " \\\n\t", %{$mm_w32->{PM}} );
 149
 150     my $constants = $mm_w32->constants;
 151
 152     foreach my $regex (
 153          qr|^NAME       \s* = \s* TestMM_Win32 \s* $|xms,
 154          qr|^VERSION    \s* = \s* 1\.00 \s* $|xms,
 155          qr|^MAKEMAKER  \s* = \s* \Q$INC{'ExtUtils/MakeMaker.pm'}\E \s* $|xms,
 156          qr|^MM_VERSION \s* = \s* \Q$ExtUtils::MakeMaker::VERSION\E \s* $|xms,
 157          qr|^TO_INST_PM \s* = \s* \Q$s_PM\E \s* $|xms,
 158          qr|^PM_TO_BLIB \s* = \s* \Q$k_PM\E \s* $|xms,
 159         )
 160     {
 161         like( $constants, $regex, 'constants() check' );
 162     }
 163 }
 164
 165 # path()
 166 my $had_path = exists $ENV{PATH};
 167 {
 168     my @path_eg = ( qw( . .. ), 'C:\\Program Files' );
 169     local $ENV{PATH} = join ';', @path_eg;
 170     ok( eq_array( [ $MM->path() ], [ @path_eg ] ),
 171         'path() [preset]' );
 172 }
 173 # Bug in Perl.  local $ENV{FOO} will not delete key afterwards.
 174 delete $ENV{PATH} unless $had_path;
 175
 176 # static_lib() should look into that
 177 # dynamic_bs() should look into that
 178 # dynamic_lib() should look into that
 179
 180 # clean()
 181 {
 182     my $clean = $Config{cc} =~ /^gcc/i ? 'dll.base dll.exp' : '*.pdb';
 183     like( $MM->clean(), qr/^clean ::\s+\Q-$(RM_F) $clean\E\s+$/m,
 184           'clean() Makefile target' );
 185 }
 186
 187 # init_linker
 188 {
 189     my $libperl = File::Spec->catfile('$(PERL_INC)',
 190                                       $Config{libperl} || 'libperl.a');
 191     my $export  = '$(BASEEXT).def';
 192     my $after   = '';
 193     $MM->init_linker;
 194
 195     is( $MM->{PERL_ARCHIVE},        $libperl,   'PERL_ARCHIVE' );
 196     is( $MM->{PERL_ARCHIVE_AFTER},  $after,     'PERL_ARCHIVE_AFTER' );
 197     is( $MM->{EXPORT_LIST},         $export,    'EXPORT_LIST' );
 198 }
 199
 200 # canonpath()
 201 {
 202     my $path = 'c:\\Program Files/SomeApp\\Progje.exe';
 203     is( $MM->canonpath( $path ), File::Spec->canonpath( $path ),
 204             'canonpath() eq File::Spec->canonpath' );
 205 }
 206
 207 # perl_script()
 208 my $script_ext  = '';
 209 my $script_name = 'mm_w32tmp';
 210 SKIP: {
 211     local *SCRIPT;
 212     skip( "Can't create temp file: $!", 4 )
 213         unless open SCRIPT, "> $script_name";
 214     print SCRIPT <<'EOSCRIPT';
 215 #! perl
 216 __END__
 217 EOSCRIPT
 218     skip( "Can't write to temp file: $!", 4 )
 219         unless close SCRIPT;
 220     # now start tests:
 221     is( $MM->perl_script( $script_name ),
 222         "${script_name}$script_ext", "perl_script ($script_ext)" );
 223
 224     skip( "Can't rename temp file: $!", 3 )
 225         unless rename $script_name, "${script_name}.pl";
 226     $script_ext = '.pl';
 227     is( $MM->perl_script( $script_name ),
 228         "${script_name}$script_ext", "perl_script ($script_ext)" );
 229
 230     skip( "Can't rename temp file: $!", 2 )
 231         unless rename "${script_name}$script_ext", "${script_name}.bat";
 232     $script_ext = '.bat';
 233     is( $MM->perl_script( $script_name ),
 234         "${script_name}$script_ext", "perl_script ($script_ext)" );
 235
 236     skip( "Can't rename temp file: $!", 1 )
 237         unless rename "${script_name}$script_ext", "${script_name}.noscript";
 238     $script_ext = '.noscript';
 239
 240     isnt( $MM->perl_script( $script_name ),
 241           "${script_name}$script_ext",
 242           "not a perl_script anymore ($script_ext)" );
 243     is( $MM->perl_script( $script_name ), undef,
 244         "perl_script ($script_ext) returns empty" );
 245 }
 246 unlink "${script_name}$script_ext" if -f "${script_name}$script_ext";
 247
 248
 249 # xs_o() should look into that
 250 # top_targets() should look into that
 251
 252 # dist_ci() should look into that
 253 # dist_core() should look into that
 254
 255 # pasthru()
 256 {
 257     my $pastru = "PASTHRU = " . ($Config{make} =~ /^nmake/i ? "-nologo" : "");
 258     is( $MM->pasthru(), $pastru, 'pasthru()' );
 259 }
 260
 261 package FakeOut;
 262
 263 sub TIEHANDLE {
 264         bless(\(my $scalar), $_[0]);
 265 }
 266
 267 sub PRINT {
 268         my $self = shift;
 269         $$self .= shift;
 270 }
 271
 272 __END__
 273
 274 =head1 NAME
 275
 276 MM_Win32.t - Tests for ExtUtils::MM_Win32
 277
 278 =head1 TODO
 279
 280  - Methods to still be checked:
 281  # static_lib() should look into that
 282  # dynamic_bs() should look into that
 283  # dynamic_lib() should look into that
 284  # xs_o() should look into that
 285  # top_targets() should look into that
 286  # dist_ci() should look into that
 287  # dist_core() should look into that
 288
 289 =head1 AUTHOR
 290
 291 20011228 Abe Timmerman <abe@ztreet.demon.nl>
 292
 293 =cut