lib/ExtUtils/t/Install.t

   1 #!/usr/bin/perl -w
   2
   3 # Test ExtUtils::Install.
   4
   5 BEGIN {
   6     if( $ENV{PERL_CORE} ) {
   7         @INC = ('../lib', 'lib');
   8     }
   9     else {
  10         unshift @INC, 't/lib';
  11     }
  12 }
  13 chdir 't';
  14
  15 use strict;
  16 use TieOut;
  17 use File::Path;
  18 use File::Spec;
  19
  20 use Test::More tests => 18;
  21
  22 BEGIN { use_ok('ExtUtils::Install') }
  23
  24 # Check exports.
  25 foreach my $func (qw(install uninstall pm_to_blib install_default)) {
  26     can_ok(__PACKAGE__, $func);
  27 }
  28
  29
  30 chdir 'Big-Dummy';
  31
  32 my $stdout = tie *STDOUT, 'TieOut';
  33 pm_to_blib( { 'lib/Big/Dummy.pm' => 'blib/lib/Big/Dummy.pm' },
  34             'blib/lib/auto'
  35           );
  36 ok( -d 'blib/lib',              'pm_to_blib created blib dir' );
  37 ok( -r 'blib/lib/Big/Dummy.pm', '  copied .pm file' );
  38 ok( -r 'blib/lib/auto',         '  created autosplit dir' );
  39 is( $stdout->read, "cp lib/Big/Dummy.pm blib/lib/Big/Dummy.pm\n" );
  40
  41 pm_to_blib( { 'lib/Big/Dummy.pm' => 'blib/lib/Big/Dummy.pm' },
  42             'blib/lib/auto'
  43           );
  44 ok( -d 'blib/lib',              'second run, blib dir still there' );
  45 ok( -r 'blib/lib/Big/Dummy.pm', '  .pm file still there' );
  46 ok( -r 'blib/lib/auto',         '  autosplit still there' );
  47 is( $stdout->read, "Skip blib/lib/Big/Dummy.pm (unchanged)\n" );
  48
  49
  50 install( { 'blib/lib' => 'install-test/lib/perl',
  51            read   => 'install-test/packlist',
  52            write  => 'install-test/packlist'
  53          } );
  54 ok( -d 'install-test/lib/perl',                 'install made dir' );
  55 ok( -r 'install-test/lib/perl/Big/Dummy.pm',    '  .pm file installed' );
  56 ok( -r 'install-test/packlist',                 '  packlist exists' );
  57
  58 open(PACKLIST, 'install-test/packlist' );
  59 my %packlist = map { chomp;  ($_ => 1) } <PACKLIST>;
  60 close PACKLIST;
  61
  62 # On case-insensitive filesystems (ie. VMS), the keys of the packlist might
  63 # be lowercase. :(
  64 my $native_dummy = File::Spec->catfile(qw(install-test lib perl Big Dummy.pm));
  65 is( keys %packlist, 1 );
  66 is( lc((keys %packlist)[0]), lc $native_dummy, 'packlist written' );
  67
  68 END { rmtree 'blib' }