lib/ExtUtils/t/INST_PREFIX.t

   1 #!/usr/bin/perl -w
   2
   3 # Wherein we ensure the INST_* and INSTALL* variables are set correctly
   4 # when various PREFIX variables are set.
   5 #
   6 # Essentially, this test is a Makefile.PL.
   7
   8 BEGIN {
   9     if( $ENV{PERL_CORE} ) {
  10         chdir 't' if -d 't';
  11         @INC = ('../lib', 'lib');
  12     }
  13     else {
  14         unshift @INC, 't/lib';
  15     }
  16 }
  17
  18 use strict;
  19 use Test::More tests => 26;
  20 use MakeMaker::Test::Utils;
  21 use ExtUtils::MakeMaker;
  22 use File::Spec;
  23 use TieOut;
  24 use Config;
  25
  26 my $Is_VMS = $^O eq 'VMS';
  27
  28 chdir 't';
  29
  30 perl_lib;
  31
  32 $| = 1;
  33
  34 my $Makefile = makefile_name;
  35 my $Curdir = File::Spec->curdir;
  36 my $Updir  = File::Spec->updir;
  37
  38 ok( chdir 'Big-Dummy', "chdir'd to Big-Dummy" ) ||
  39   diag("chdir failed: $!");
  40
  41 my $PREFIX = File::Spec->catdir('foo', 'bar');
  42 my $stdout = tie *STDOUT, 'TieOut' or die;
  43 my $mm = WriteMakefile(
  44     NAME          => 'Big::Dummy',
  45     VERSION_FROM  => 'lib/Big/Dummy.pm',
  46     PREREQ_PM     => {},
  47     PERL_CORE     => $ENV{PERL_CORE},
  48     PREFIX        => $PREFIX,
  49 );
  50 like( $stdout->read, qr{
  51                         Writing\ $Makefile\ for\ Big::Liar\n
  52                         Big::Liar's\ vars\n
  53                         INST_LIB\ =\ \S+\n
  54                         INST_ARCHLIB\ =\ \S+\n
  55                         Writing\ $Makefile\ for\ Big::Dummy\n
  56 }x );
  57 undef $stdout;
  58 untie *STDOUT;
  59
  60 isa_ok( $mm, 'ExtUtils::MakeMaker' );
  61
  62 is( $mm->{NAME}, 'Big::Dummy',  'NAME' );
  63 is( $mm->{VERSION}, 0.01,            'VERSION' );
  64
  65 is( $mm->{PREFIX}, $PREFIX,   'PREFIX' );
  66
  67 is( !!$mm->{PERL_CORE}, !!$ENV{PERL_CORE}, 'PERL_CORE' );
  68
  69 my($perl_src, $mm_perl_src);
  70 if( $ENV{PERL_CORE} ) {
  71     $perl_src = File::Spec->catdir($Updir, $Updir);
  72     $perl_src = File::Spec->canonpath($perl_src);
  73     $mm_perl_src = File::Spec->canonpath($mm->{PERL_SRC});
  74 }
  75 else {
  76     $mm_perl_src = $mm->{PERL_SRC};
  77 }
  78
  79 is( $mm_perl_src, $perl_src,     'PERL_SRC' );
  80
  81
  82 # Every INSTALL* variable must start with some PREFIX.
  83 my @Perl_Install = qw(archlib    privlib   bin     script
  84                       man1dir       man3dir);
  85 my @Site_Install = qw(sitearch   sitelib   sitebin
  86                       siteman1dir siteman3dir);
  87 my @Vend_Install = qw(vendorarch vendorlib vendorbin
  88                       vendorman1dir vendorman3dir);
  89
  90 foreach my $var (@Perl_Install) {
  91     my $prefix = $Is_VMS ? '[.foo.bar' : File::Spec->catdir(qw(foo bar));
  92
  93     # support for man page skipping
  94     $prefix = 'none' if $var =~ /man/ && !$Config{"install$var"};
  95     like( $mm->{uc "install$var"}, qr/^\Q$prefix\E/, "PREFIX + $var" );
  96 }
  97
  98 foreach my $var (@Site_Install) {
  99     my $prefix = $Is_VMS ? '[.foo.bar' : File::Spec->catdir(qw(foo bar));
 100
 101     like( $mm->{uc "install$var"}, qr/^\Q$prefix\E/,
 102                                                     "SITEPREFIX + $var" );
 103 }
 104
 105 foreach my $var (@Vend_Install) {
 106     my $prefix = $Is_VMS ? '[.foo.bar' : File::Spec->catdir(qw(foo bar));
 107
 108     like( $mm->{uc "install$var"}, qr/^\Q$prefix\E/,
 109                                                     "VENDORPREFIX + $var" );
 110 }
 111
 112
 113 # Check that when installman*dir isn't set in Config no man pages
 114 # are generated.
 115 {
 116     undef *ExtUtils::MM_Unix::Config;
 117     %ExtUtils::MM_Unix::Config = %Config;
 118     $ExtUtils::MM_Unix::Config{installman1dir} = '';
 119     $ExtUtils::MM_Unix::Config{installman3dir} = '';
 120
 121     my $wibble = File::Spec->catdir(qw(wibble and such));
 122     my $stdout = tie *STDOUT, 'TieOut' or die;
 123     my $mm = WriteMakefile(
 124                            NAME          => 'Big::Dummy',
 125                            VERSION_FROM  => 'lib/Big/Dummy.pm',
 126                            PREREQ_PM     => {},
 127                            PERL_CORE     => $ENV{PERL_CORE},
 128                            PREFIX        => $PREFIX,
 129                            INSTALLMAN1DIR=> $wibble,
 130                           );
 131
 132     is( $mm->{INSTALLMAN1DIR}, $wibble );
 133     is( $mm->{INSTALLMAN3DIR}, 'none'  );
 134 }