lib/ExtUtils/t/INST_PREFIX.t

   1 #!/usr/bin/perl -w
   2
   3 # Wherein we ensure the INST_* and INSTALL* variables are set correctly
   4 # when various PREFIX variables are set.
   5 #
   6 # Essentially, this test is a Makefile.PL.
   7
   8 BEGIN {
   9     if( $ENV{PERL_CORE} ) {
  10         chdir 't' if -d 't';
  11         @INC = ('../lib', 'lib');
  12     }
  13     else {
  14         unshift @INC, 't/lib';
  15     }
  16 }
  17
  18 use strict;
  19 use Test::More tests => 38;
  20 use MakeMaker::Test::Utils;
  21 use ExtUtils::MakeMaker;
  22 use File::Spec;
  23 use TieOut;
  24 use Config;
  25
  26 my $Is_VMS = $^O eq 'VMS';
  27
  28 chdir 't';
  29
  30 perl_lib;
  31
  32 $| = 1;
  33
  34 my $Makefile = makefile_name;
  35 my $Curdir = File::Spec->curdir;
  36 my $Updir  = File::Spec->updir;
  37
  38 ok( chdir 'Big-Dummy', "chdir'd to Big-Dummy" ) ||
  39   diag("chdir failed: $!");
  40
  41 my $stdout = tie *STDOUT, 'TieOut' or die;
  42
  43 my $mm = WriteMakefile(
  44     NAME          => 'Big::Dummy',
  45     VERSION_FROM  => 'lib/Big/Dummy.pm',
  46     PREREQ_PM     => {},
  47     PERL_CORE     => $ENV{PERL_CORE},
  48 );
  49
  50 like( $stdout->read, qr{
  51                         Writing\ $Makefile\ for\ Big::Liar\n
  52                         Big::Liar's\ vars\n
  53                         INST_LIB\ =\ \S+\n
  54                         INST_ARCHLIB\ =\ \S+\n
  55                         Writing\ $Makefile\ for\ Big::Dummy\n
  56 }x );
  57
  58 isa_ok( $mm, 'ExtUtils::MakeMaker' );
  59
  60 is( $mm->{NAME}, 'Big::Dummy',  'NAME' );
  61 is( $mm->{VERSION}, 0.01,            'VERSION' );
  62
  63 foreach my $prefix (qw(PREFIX PERLPREFIX SITEPREFIX VENDORPREFIX)) {
  64     unlike( $mm->{$prefix}, qr/\$\(PREFIX\)/ );
  65     like( $mm->{$prefix}, qr/^\$\(DESTDIR\)/,
  66                                    "\$(DESTDIR) prepended to $prefix" );
  67 }
  68
  69
  70 my $PREFIX = File::Spec->catdir('foo', 'bar');
  71 $mm = WriteMakefile(
  72     NAME          => 'Big::Dummy',
  73     VERSION_FROM  => 'lib/Big/Dummy.pm',
  74     PREREQ_PM     => {},
  75     PERL_CORE     => $ENV{PERL_CORE},
  76     PREFIX        => $PREFIX,
  77 );
  78 like( $stdout->read, qr{
  79                         Writing\ $Makefile\ for\ Big::Liar\n
  80                         Big::Liar's\ vars\n
  81                         INST_LIB\ =\ \S+\n
  82                         INST_ARCHLIB\ =\ \S+\n
  83                         Writing\ $Makefile\ for\ Big::Dummy\n
  84 }x );
  85 undef $stdout;
  86 untie *STDOUT;
  87
  88 is( $mm->{PREFIX}, '$(DESTDIR)'.$PREFIX,   'PREFIX' );
  89
  90 foreach my $prefix (qw(PERLPREFIX SITEPREFIX VENDORPREFIX)) {
  91     is( $mm->{$prefix}, '$(DESTDIR)$(PREFIX)',
  92                                        "\$(PREFIX) overrides $prefix" );
  93 }
  94
  95 is( !!$mm->{PERL_CORE}, !!$ENV{PERL_CORE}, 'PERL_CORE' );
  96
  97 my($perl_src, $mm_perl_src);
  98 if( $ENV{PERL_CORE} ) {
  99     $perl_src = File::Spec->catdir($Updir, $Updir);
 100     $perl_src = File::Spec->canonpath($perl_src);
 101     $mm_perl_src = File::Spec->canonpath($mm->{PERL_SRC});
 102 }
 103 else {
 104     $mm_perl_src = $mm->{PERL_SRC};
 105 }
 106
 107 is( $mm_perl_src, $perl_src,     'PERL_SRC' );
 108
 109
 110 # Every INSTALL* variable must start with some PREFIX.
 111 my %Install_Vars = (
 112  PERL   => [qw(archlib    privlib   bin       man1dir       man3dir   script)],
 113  SITE   => [qw(sitearch   sitelib   sitebin   siteman1dir   siteman3dir)],
 114  VENDOR => [qw(vendorarch vendorlib vendorbin vendorman1dir vendorman3dir)]
 115 );
 116
 117 while( my($type, $vars) = each %Install_Vars) {
 118
 119     SKIP: foreach my $var (@$vars) {
 120         skip "VMS must expand macros in INSTALL* vars", scalar @$vars
 121           if $Is_VMS;
 122
 123         my $prefix = '$('.$type.'PREFIX)';
 124
 125         # support for man page skipping
 126         $prefix = 'none' if $type eq 'PERL' &&
 127                             $var =~ /man/ &&
 128                             !$Config{"install$var"};
 129         like( $mm->{uc "install$var"}, qr/^\Q$prefix\E/, "$prefix + $var" );
 130     }
 131 }
 132
 133 # Check that when installman*dir isn't set in Config no man pages
 134 # are generated.
 135 {
 136     undef *ExtUtils::MM_Unix::Config;
 137     %ExtUtils::MM_Unix::Config = %Config;
 138     $ExtUtils::MM_Unix::Config{installman1dir} = '';
 139     $ExtUtils::MM_Unix::Config{installman3dir} = '';
 140
 141     my $wibble = File::Spec->catdir(qw(wibble and such));
 142     my $stdout = tie *STDOUT, 'TieOut' or die;
 143     my $mm = WriteMakefile(
 144                            NAME          => 'Big::Dummy',
 145                            VERSION_FROM  => 'lib/Big/Dummy.pm',
 146                            PREREQ_PM     => {},
 147                            PERL_CORE     => $ENV{PERL_CORE},
 148                            PREFIX        => $PREFIX,
 149                            INSTALLMAN1DIR=> $wibble,
 150                           );
 151
 152     is( $mm->{INSTALLMAN1DIR}, $wibble );
 153     is( $mm->{INSTALLMAN3DIR}, 'none'  );
 154 }