lib/ExtUtils/t/INST_PREFIX.t

   1 #!/usr/bin/perl -w
   2
   3 # Wherein we ensure the INST_* and INSTALL* variables are set correctly
   4 # when various PREFIX variables are set.
   5 #
   6 # Essentially, this test is a Makefile.PL.
   7
   8 BEGIN {
   9     if( $ENV{PERL_CORE} ) {
  10         chdir 't' if -d 't';
  11         @INC = ('../lib', 'lib');
  12     }
  13     else {
  14         unshift @INC, 't/lib';
  15     }
  16 }
  17
  18 use strict;
  19 use Test::More tests => 52;
  20 use MakeMaker::Test::Utils;
  21 use MakeMaker::Test::Setup::BFD;
  22 use ExtUtils::MakeMaker;
  23 use File::Spec;
  24 use TieOut;
  25 use ExtUtils::MakeMaker::Config;
  26
  27 my $Is_VMS = $^O eq 'VMS';
  28
  29 chdir 't';
  30
  31 perl_lib;
  32
  33 $| = 1;
  34
  35 my $Makefile = makefile_name;
  36 my $Curdir = File::Spec->curdir;
  37 my $Updir  = File::Spec->updir;
  38
  39 ok( setup_recurs(), 'setup' );
  40 END {
  41     ok( chdir File::Spec->updir );
  42     ok( teardown_recurs(), 'teardown' );
  43 }
  44
  45 ok( chdir 'Big-Dummy', "chdir'd to Big-Dummy" ) ||
  46   diag("chdir failed: $!");
  47
  48 my $stdout = tie *STDOUT, 'TieOut' or die;
  49
  50 my $mm = WriteMakefile(
  51     NAME          => 'Big::Dummy',
  52     VERSION_FROM  => 'lib/Big/Dummy.pm',
  53     PREREQ_PM     => {},
  54     PERL_CORE     => $ENV{PERL_CORE},
  55 );
  56
  57 like( $stdout->read, qr{
  58                         Writing\ $Makefile\ for\ Big::Liar\n
  59                         Big::Liar's\ vars\n
  60                         INST_LIB\ =\ \S+\n
  61                         INST_ARCHLIB\ =\ \S+\n
  62                         Writing\ $Makefile\ for\ Big::Dummy\n
  63 }x );
  64
  65 is( $mm->{PREFIX}, '$(SITEPREFIX)', 'PREFIX set based on INSTALLDIRS' );
  66
  67 isa_ok( $mm, 'ExtUtils::MakeMaker' );
  68
  69 is( $mm->{NAME}, 'Big::Dummy',  'NAME' );
  70 is( $mm->{VERSION}, 0.01,            'VERSION' );
  71
  72 foreach my $prefix (qw(PREFIX PERLPREFIX SITEPREFIX VENDORPREFIX)) {
  73     unlike( $mm->{$prefix}, qr/\$\(PREFIX\)/ );
  74 }
  75
  76
  77 my $PREFIX = File::Spec->catdir('foo', 'bar');
  78 $mm = WriteMakefile(
  79     NAME          => 'Big::Dummy',
  80     VERSION_FROM  => 'lib/Big/Dummy.pm',
  81     PREREQ_PM     => {},
  82     PERL_CORE     => $ENV{PERL_CORE},
  83     PREFIX        => $PREFIX,
  84 );
  85 like( $stdout->read, qr{
  86                         Writing\ $Makefile\ for\ Big::Liar\n
  87                         Big::Liar's\ vars\n
  88                         INST_LIB\ =\ \S+\n
  89                         INST_ARCHLIB\ =\ \S+\n
  90                         Writing\ $Makefile\ for\ Big::Dummy\n
  91 }x );
  92 undef $stdout;
  93 untie *STDOUT;
  94
  95 is( $mm->{PREFIX}, $PREFIX,   'PREFIX' );
  96
  97 foreach my $prefix (qw(PERLPREFIX SITEPREFIX VENDORPREFIX)) {
  98     is( $mm->{$prefix}, '$(PREFIX)', "\$(PREFIX) overrides $prefix" );
  99 }
 100
 101 is( !!$mm->{PERL_CORE}, !!$ENV{PERL_CORE}, 'PERL_CORE' );
 102
 103 my($perl_src, $mm_perl_src);
 104 if( $ENV{PERL_CORE} ) {
 105     $perl_src = File::Spec->catdir($Updir, $Updir);
 106     $perl_src = File::Spec->canonpath($perl_src);
 107     $mm_perl_src = File::Spec->canonpath($mm->{PERL_SRC});
 108 }
 109 else {
 110     $mm_perl_src = $mm->{PERL_SRC};
 111 }
 112
 113 is( $mm_perl_src, $perl_src,     'PERL_SRC' );
 114
 115
 116 # Every INSTALL* variable must start with some PREFIX.
 117 my %Install_Vars = (
 118  PERL   => [qw(archlib    privlib   bin       man1dir       man3dir   script)],
 119  SITE   => [qw(sitearch   sitelib   sitebin   siteman1dir   siteman3dir)],
 120  VENDOR => [qw(vendorarch vendorlib vendorbin vendorman1dir vendorman3dir)]
 121 );
 122
 123 while( my($type, $vars) = each %Install_Vars) {
 124     SKIP: {
 125         skip "VMS must expand macros in INSTALL* vars", scalar @$vars
 126           if $Is_VMS;
 127         skip '$Config{usevendorprefix} not set', scalar @$vars
 128           if $type eq 'VENDOR' and !$Config{usevendorprefix};
 129
 130         foreach my $var (@$vars) {
 131             my $installvar = "install$var";
 132             my $prefix = '$('.$type.'PREFIX)';
 133
 134             SKIP: {
 135                 skip uc($installvar).' set to another INSTALL variable', 1
 136                   if $mm->{uc $installvar} =~ /^\$\(INSTALL.*\)$/;
 137
 138                 # support for man page skipping
 139                 $prefix = 'none' if $type eq 'PERL' &&
 140                                     $var =~ /man/ &&
 141                                     !$Config{$installvar};
 142                 like( $mm->{uc $installvar}, qr/^\Q$prefix\E/,
 143                       "$prefix + $var" );
 144             }
 145         }
 146     }
 147 }
 148
 149 # Check that when installman*dir isn't set in Config no man pages
 150 # are generated.
 151 {
 152     _set_config(installman1dir => '');
 153     _set_config(installman3dir => '');
 154
 155     my $wibble = File::Spec->catdir(qw(wibble and such));
 156     my $stdout = tie *STDOUT, 'TieOut' or die;
 157     my $mm = WriteMakefile(
 158                            NAME          => 'Big::Dummy',
 159                            VERSION_FROM  => 'lib/Big/Dummy.pm',
 160                            PREREQ_PM     => {},
 161                            PERL_CORE     => $ENV{PERL_CORE},
 162                            PREFIX        => $PREFIX,
 163                            INSTALLMAN1DIR=> $wibble,
 164                           );
 165
 166     is( $mm->{INSTALLMAN1DIR}, $wibble );
 167     is( $mm->{INSTALLMAN3DIR}, 'none'  );
 168 }
 169
 170 # Check that when installvendorman*dir is set in Config it is honored
 171 # [rt.cpan.org 2949]
 172 {
 173     _set_config(installvendorman1dir => File::Spec->catdir('foo','bar') );
 174     _set_config(installvendorman3dir => '' );
 175     _set_config(usevendorprefix => 1 );
 176     _set_config(vendorprefixexp => 'something' );
 177
 178     my $stdout = tie *STDOUT, 'TieOut' or die;
 179     my $mm = WriteMakefile(
 180                    NAME          => 'Big::Dummy',
 181                    VERSION_FROM  => 'lib/Big/Dummy.pm',
 182                    PREREQ_PM     => {},
 183                    PERL_CORE     => $ENV{PERL_CORE},
 184
 185                    # In case the local installation doesn't have man pages.
 186                    INSTALLMAN1DIR=> 'foo/bar/baz',
 187                    INSTALLMAN3DIR=> 'foo/bar/baz',
 188                   );
 189
 190     is( $mm->{INSTALLVENDORMAN1DIR}, File::Spec->catdir('foo','bar'),
 191                       'installvendorman1dir (in %Config) not modified' );
 192     isnt( $mm->{INSTALLVENDORMAN3DIR}, '',
 193                       'installvendorman3dir (not in %Config) set'  );
 194 }
 195
 196 # Check that when installsiteman*dir isn't set in Config it falls back
 197 # to installman*dir
 198 {
 199     _set_config(installman1dir => File::Spec->catdir('foo', 'bar') );
 200     _set_config(installman3dir => File::Spec->catdir('foo', 'baz') );
 201     _set_config(installsiteman1dir => '' );
 202     _set_config(installsiteman3dir => '' );
 203     _set_config(installvendorman1dir => '' );
 204     _set_config(installvendorman3dir => '' );
 205     _set_config(usevendorprefix => 'define' );
 206     _set_config(vendorprefixexp => 'something' );
 207
 208     my $wibble = File::Spec->catdir(qw(wibble and such));
 209     my $stdout = tie *STDOUT, 'TieOut' or die;
 210     my $mm = WriteMakefile(
 211                            NAME          => 'Big::Dummy',
 212                            VERSION_FROM  => 'lib/Big/Dummy.pm',
 213                            PERL_CORE     => $ENV{PERL_CORE},
 214                           );
 215
 216     is( $mm->{INSTALLMAN1DIR}, File::Spec->catdir('foo', 'bar') );
 217     is( $mm->{INSTALLMAN3DIR}, File::Spec->catdir('foo', 'baz') );
 218     SKIP: {
 219         skip "VMS must expand macros in INSTALL* vars", 4 if $Is_VMS;
 220
 221         is( $mm->{INSTALLSITEMAN1DIR},   '$(INSTALLMAN1DIR)' );
 222         is( $mm->{INSTALLSITEMAN3DIR},   '$(INSTALLMAN3DIR)' );
 223         is( $mm->{INSTALLVENDORMAN1DIR}, '$(INSTALLMAN1DIR)' );
 224         is( $mm->{INSTALLVENDORMAN3DIR}, '$(INSTALLMAN3DIR)' );
 225     }
 226 }
 227
 228
 229 # Check that when usevendoprefix and installvendorman*dir aren't set in
 230 # Config it leaves them unset.
 231 {
 232     _set_config(installman1dir => File::Spec->catdir('foo', 'bar') );
 233     _set_config(installman3dir => File::Spec->catdir('foo', 'baz') );
 234     _set_config(installsiteman1dir => '' );
 235     _set_config(installsiteman3dir => '' );
 236     _set_config(installvendorman1dir => '' );
 237     _set_config(installvendorman3dir => '' );
 238     _set_config(usevendorprefix => '' );
 239     _set_config(vendorprefixexp => '' );
 240
 241     my $wibble = File::Spec->catdir(qw(wibble and such));
 242     my $stdout = tie *STDOUT, 'TieOut' or die;
 243     my $mm = WriteMakefile(
 244                            NAME          => 'Big::Dummy',
 245                            VERSION_FROM  => 'lib/Big/Dummy.pm',
 246                            PERL_CORE     => $ENV{PERL_CORE},
 247                           );
 248
 249     is( $mm->{INSTALLMAN1DIR}, File::Spec->catdir('foo', 'bar') );
 250     is( $mm->{INSTALLMAN3DIR}, File::Spec->catdir('foo', 'baz') );
 251     SKIP: {
 252         skip "VMS must expand macros in INSTALL* vars", 2 if $Is_VMS;
 253         is( $mm->{INSTALLSITEMAN1DIR},   '$(INSTALLMAN1DIR)' );
 254         is( $mm->{INSTALLSITEMAN3DIR},   '$(INSTALLMAN3DIR)' );
 255     }
 256     is( $mm->{INSTALLVENDORMAN1DIR}, '' );
 257     is( $mm->{INSTALLVENDORMAN3DIR}, '' );
 258 }
 259
 260
 261 sub _set_config {
 262     my($k,$v) = @_;
 263     (my $k_no_install = $k) =~ s/^install//i;
 264     $Config{$k} = $v;
 265
 266     # Because VMS's config has traditionally been underpopulated, it will
 267     # fall back to the install-less versions in desperation.
 268     $Config{$k_no_install} = $v if $Is_VMS;
 269     return;
 270 }