lib/ExtUtils/t/Constant.t

   1 #!/usr/bin/perl -w
   2
   3 print "1..51\n";
   4
   5 BEGIN {
   6     if( $ENV{PERL_CORE} ) {
   7         chdir 't' if -d 't';
   8         @INC = '../lib';
   9     }
  10 }
  11
  12 # use warnings;
  13 use strict;
  14 use ExtUtils::MakeMaker;
  15 use ExtUtils::Constant qw (constant_types C_constant XS_constant autoload);
  16 use Config;
  17 use File::Spec::Functions qw(catfile rel2abs);
  18 # Because were are going to be changing directory before running Makefile.PL
  19 my $perl;
  20 $perl = rel2abs( $^X ) unless $] < 5.006; # Hack. Until 5.00503 has rel2abs
  21 # ExtUtils::Constant::C_constant uses $^X inside a comment, and we want to
  22 # compare output to ensure that it is the same. We were probably run as ./perl
  23 # whereas we will run the child with the full path in $perl. So make $^X for
  24 # us the same as our child will see.
  25 $^X = $perl;
  26
  27 print "# perl=$perl\n";
  28 my $runperl = "$perl \"-I../../lib\"";
  29
  30 $| = 1;
  31
  32 my $dir = "ext-$$";
  33 my @files;
  34
  35 print "# $dir being created...\n";
  36 mkdir $dir, 0777 or die "mkdir: $!\n";
  37
  38 my $output = "output";
  39
  40 # For debugging set this to 1.
  41 my $keep_files = 0;
  42
  43 END {
  44     use File::Path;
  45     print "# $dir being removed...\n";
  46     rmtree($dir) unless $keep_files;
  47 }
  48
  49 my $package = "ExtTest";
  50
  51 # Test the code that generates 1 and 2 letter name comparisons.
  52 my %compass = (
  53 N => 0, 'NE' => 45, E => 90, SE => 135, S => 180, SW => 225, W => 270, NW => 315
  54 );
  55
  56 my $parent_rfc1149 =
  57   'A Standard for the Transmission of IP Datagrams on Avian Carriers';
  58 # Check that 8 bit and unicode names don't cause problems.
  59 my $pound;
  60 if (ord('A') == 193) {  # EBCDIC platform
  61     $pound = chr 177; # A pound sign. (Currency)
  62 } else { # ASCII platform
  63     $pound = chr 163; # A pound sign. (Currency)
  64 }
  65 my $inf = chr 0x221E;
  66 # Check that we can distiguish the pathological case of a string, and the
  67 # utf8 representation of that string.
  68 my $pound_bytes = my $pound_utf8 = $pound . '1';
  69 utf8::encode ($pound_bytes);
  70
  71 my @names = ("FIVE", {name=>"OK6", type=>"PV",},
  72              {name=>"OK7", type=>"PVN",
  73               value=>['"not ok 7\\n\\0ok 7\\n"', 15]},
  74              {name => "FARTHING", type=>"NV"},
  75              {name => "NOT_ZERO", type=>"UV", value=>"~(UV)0"},
  76              {name => "OPEN", type=>"PV", value=>'"/*"', macro=>1},
  77              {name => "CLOSE", type=>"PV", value=>'"*/"',
  78               macro=>["#if 1\n", "#endif\n"]},
  79              {name => "ANSWER", default=>["UV", 42]}, "NOTDEF",
  80              {name => "Yes", type=>"YES"},
  81              {name => "No", type=>"NO"},
  82              {name => "Undef", type=>"UNDEF"},
  83 # OK. It wasn't really designed to allow the creation of dual valued constants.
  84 # It was more for INADDR_ANY INADDR_BROADCAST INADDR_LOOPBACK INADDR_NONE
  85              {name=>"RFC1149", type=>"SV", value=>"sv_2mortal(temp_sv)",
  86               pre=>"SV *temp_sv = newSVpv(RFC1149, 0); "
  87                    . "(void) SvUPGRADE(temp_sv,SVt_PVIV); SvIOK_on(temp_sv); "
  88                    . "SvIVX(temp_sv) = 1149;"},
  89              {name=>"perl", type=>"PV",},
  90 );
  91
  92 push @names, $_ foreach keys %compass;
  93
  94 # Automatically compile the list of all the macro names, and make them
  95 # exported constants.
  96 my @names_only = map {(ref $_) ? $_->{name} : $_} @names;
  97
  98 # Exporter::Heavy (currently) isn't able to export these names:
  99 push @names, ({name=>"*/", type=>"PV", value=>'"CLOSE"', macro=>1},
 100               {name=>"/*", type=>"PV", value=>'"OPEN"', macro=>1},
 101               {name=>$pound, type=>"PV", value=>'"Sterling"', macro=>1},
 102               {name=>$inf, type=>"PV", value=>'"Infinity"', macro=>1},
 103               {name=>$pound_utf8, type=>"PV", value=>'"1 Pound"', macro=>1},
 104               {name=>$pound_bytes, type=>"PV", value=>'"1 Pound (as bytes)"',
 105                macro=>1},
 106              );
 107
 108 =pod
 109
 110 The above set of names seems to produce a suitably bad set of compile
 111 problems on a Unicode naive version of ExtUtils::Constant (ie 0.11):
 112
 113 nick@thinking-cap 15439-32-utf$ PERL_CORE=1 ./perl lib/ExtUtils/t/Constant.t
 114 1..33
 115 # perl=/stuff/perl5/15439-32-utf/perl
 116 # ext-30370 being created...
 117 Wide character in print at lib/ExtUtils/t/Constant.t line 140.
 118 ok 1
 119 ok 2
 120 # make = 'make'
 121 ExtTest.xs: In function `constant_1':
 122 ExtTest.xs:80: warning: multi-character character constant
 123 ExtTest.xs:80: warning: case value out of range
 124 ok 3
 125
 126 =cut
 127
 128 my $types = {};
 129 my $constant_types = constant_types(); # macro defs
 130 my $C_constant = join "\n",
 131   C_constant ($package, undef, "IV", $types, undef, undef, @names);
 132 my $XS_constant = XS_constant ($package, $types); # XS for ExtTest::constant
 133
 134 ################ Header
 135 my $header = catfile($dir, "test.h");
 136 push @files, "test.h";
 137 open FH, ">$header" or die "open >$header: $!\n";
 138 print FH <<"EOT";
 139 #define FIVE 5
 140 #define OK6 "ok 6\\n"
 141 #define OK7 1
 142 #define FARTHING 0.25
 143 #define NOT_ZERO 1
 144 #define Yes 0
 145 #define No 1
 146 #define Undef 1
 147 #define RFC1149 "$parent_rfc1149"
 148 #undef NOTDEF
 149 #define perl "rules"
 150 EOT
 151
 152 while (my ($point, $bearing) = each %compass) {
 153   print FH "#define $point $bearing\n"
 154 }
 155 close FH or die "close $header: $!\n";
 156
 157 ################ XS
 158 my $xs = catfile($dir, "$package.xs");
 159 push @files, "$package.xs";
 160 open FH, ">$xs" or die "open >$xs: $!\n";
 161
 162 print FH <<'EOT';
 163 #include "EXTERN.h"
 164 #include "perl.h"
 165 #include "XSUB.h"
 166 EOT
 167
 168 print FH "#include \"test.h\"\n\n";
 169 print FH $constant_types;
 170 print FH $C_constant, "\n";
 171 print FH "MODULE = $package             PACKAGE = $package\n";
 172 print FH "PROTOTYPES: ENABLE\n";
 173 print FH $XS_constant;
 174 close FH or die "close $xs: $!\n";
 175
 176 ################ PM
 177 my $pm = catfile($dir, "$package.pm");
 178 push @files, "$package.pm";
 179 open FH, ">$pm" or die "open >$pm: $!\n";
 180 print FH "package $package;\n";
 181 print FH "use $];\n";
 182
 183 print FH <<'EOT';
 184
 185 use strict;
 186 EOT
 187 printf FH "use warnings;\n" unless $] < 5.006;
 188 print FH <<'EOT';
 189 use Carp;
 190
 191 require Exporter;
 192 require DynaLoader;
 193 use vars qw ($VERSION @ISA @EXPORT_OK $AUTOLOAD);
 194
 195 $VERSION = '0.01';
 196 @ISA = qw(Exporter DynaLoader);
 197 @EXPORT_OK = qw(
 198 EOT
 199
 200 # Print the names of all our autoloaded constants
 201 print FH "\t$_\n" foreach (@names_only);
 202 print FH ");\n";
 203 # Print the AUTOLOAD subroutine ExtUtils::Constant generated for us
 204 print FH autoload ($package, $]);
 205 print FH "bootstrap $package \$VERSION;\n1;\n__END__\n";
 206 close FH or die "close $pm: $!\n";
 207
 208 ################ test.pl
 209 my $testpl = catfile($dir, "test.pl");
 210 push @files, "test.pl";
 211 open FH, ">$testpl" or die "open >$testpl: $!\n";
 212
 213 print FH "use strict;\n";
 214 print FH "use $package qw(@names_only);\n";
 215 print FH <<"EOT";
 216
 217 use utf8;
 218
 219 print "1..1\n";
 220 if (open OUTPUT, ">$output") {
 221   print "ok 1\n";
 222   select OUTPUT;
 223 } else {
 224   print "not ok 1 # Failed to open '$output': $!\n";
 225   exit 1;
 226 }
 227 EOT
 228
 229 print FH << 'EOT';
 230
 231 # What follows goes to the temporary file.
 232 # IV
 233 my $five = FIVE;
 234 if ($five == 5) {
 235   print "ok 5\n";
 236 } else {
 237   print "not ok 5 # $five\n";
 238 }
 239
 240 # PV
 241 print OK6;
 242
 243 # PVN containing embedded \0s
 244 $_ = OK7;
 245 s/.*\0//s;
 246 print;
 247
 248 # NV
 249 my $farthing = FARTHING;
 250 if ($farthing == 0.25) {
 251   print "ok 8\n";
 252 } else {
 253   print "not ok 8 # $farthing\n";
 254 }
 255
 256 # UV
 257 my $not_zero = NOT_ZERO;
 258 if ($not_zero > 0 && $not_zero == ~0) {
 259   print "ok 9\n";
 260 } else {
 261   print "not ok 9 # \$not_zero=$not_zero ~0=" . (~0) . "\n";
 262 }
 263
 264 # Value includes a "*/" in an attempt to bust out of a C comment.
 265 # Also tests custom cpp #if clauses
 266 my $close = CLOSE;
 267 if ($close eq '*/') {
 268   print "ok 10\n";
 269 } else {
 270   print "not ok 10 # \$close='$close'\n";
 271 }
 272
 273 # Default values if macro not defined.
 274 my $answer = ANSWER;
 275 if ($answer == 42) {
 276   print "ok 11\n";
 277 } else {
 278   print "not ok 11 # What do you get if you multiply six by nine? '$answer'\n";
 279 }
 280
 281 # not defined macro
 282 my $notdef = eval { NOTDEF; };
 283 if (defined $notdef) {
 284   print "not ok 12 # \$notdef='$notdef'\n";
 285 } elsif ($@ !~ /Your vendor has not defined ExtTest macro NOTDEF/) {
 286   print "not ok 12 # \$@='$@'\n";
 287 } else {
 288   print "ok 12\n";
 289 }
 290
 291 # not a macro
 292 my $notthere = eval { &ExtTest::NOTTHERE; };
 293 if (defined $notthere) {
 294   print "not ok 13 # \$notthere='$notthere'\n";
 295 } elsif ($@ !~ /NOTTHERE is not a valid ExtTest macro/) {
 296   chomp $@;
 297   print "not ok 13 # \$@='$@'\n";
 298 } else {
 299   print "ok 13\n";
 300 }
 301
 302 # Truth
 303 my $yes = Yes;
 304 if ($yes) {
 305   print "ok 14\n";
 306 } else {
 307   print "not ok 14 # $yes='\$yes'\n";
 308 }
 309
 310 # Falsehood
 311 my $no = No;
 312 if (defined $no and !$no) {
 313   print "ok 15\n";
 314 } else {
 315   print "not ok 15 # \$no=" . defined ($no) ? "'$no'\n" : "undef\n";
 316 }
 317
 318 # Undef
 319 my $undef = Undef;
 320 unless (defined $undef) {
 321   print "ok 16\n";
 322 } else {
 323   print "not ok 16 # \$undef='$undef'\n";
 324 }
 325
 326
 327 # invalid macro (chosen to look like a mix up between No and SW)
 328 $notdef = eval { &ExtTest::So };
 329 if (defined $notdef) {
 330   print "not ok 17 # \$notdef='$notdef'\n";
 331 } elsif ($@ !~ /^So is not a valid ExtTest macro/) {
 332   print "not ok 17 # \$@='$@'\n";
 333 } else {
 334   print "ok 17\n";
 335 }
 336
 337 # invalid defined macro
 338 $notdef = eval { &ExtTest::EW };
 339 if (defined $notdef) {
 340   print "not ok 18 # \$notdef='$notdef'\n";
 341 } elsif ($@ !~ /^EW is not a valid ExtTest macro/) {
 342   print "not ok 18 # \$@='$@'\n";
 343 } else {
 344   print "ok 18\n";
 345 }
 346
 347 my %compass = (
 348 EOT
 349
 350 while (my ($point, $bearing) = each %compass) {
 351   print FH "'$point' => $bearing, "
 352 }
 353
 354 print FH <<'EOT';
 355
 356 );
 357
 358 my $fail;
 359 while (my ($point, $bearing) = each %compass) {
 360   my $val = eval $point;
 361   if ($@) {
 362     print "# $point: \$@='$@'\n";
 363     $fail = 1;
 364   } elsif (!defined $bearing) {
 365     print "# $point: \$val=undef\n";
 366     $fail = 1;
 367   } elsif ($val != $bearing) {
 368     print "# $point: \$val=$val, not $bearing\n";
 369     $fail = 1;
 370   }
 371 }
 372 if ($fail) {
 373   print "not ok 19\n";
 374 } else {
 375   print "ok 19\n";
 376 }
 377
 378 EOT
 379
 380 print FH <<"EOT";
 381 my \$rfc1149 = RFC1149;
 382 if (\$rfc1149 ne "$parent_rfc1149") {
 383   print "not ok 20 # '\$rfc1149' ne '$parent_rfc1149'\n";
 384 } else {
 385   print "ok 20\n";
 386 }
 387
 388 if (\$rfc1149 != 1149) {
 389   printf "not ok 21 # %d != 1149\n", \$rfc1149;
 390 } else {
 391   print "ok 21\n";
 392 }
 393
 394 EOT
 395
 396 print FH <<'EOT';
 397 # test macro=>1
 398 my $open = OPEN;
 399 if ($open eq '/*') {
 400   print "ok 22\n";
 401 } else {
 402   print "not ok 22 # \$open='$open'\n";
 403 }
 404 EOT
 405
 406 # Do this in 7 bit in case someone is testing with some settings that cause
 407 # 8 bit files incapable of storing this character.
 408 my @values
 409  = map {"'" . join (",", unpack "U*", $_) . "'"}
 410  ($pound, $inf, $pound_bytes, $pound_utf8);
 411 # Values is a list of strings, such as ('194,163,49', '163,49')
 412
 413 print FH <<'EOT';
 414
 415 # I can see that this child test program might be about to use parts of
 416 # Test::Builder
 417
 418 my $test = 23;
 419 my ($pound, $inf, $pound_bytes, $pound_utf8) = map {eval "pack 'U*', $_"}
 420 EOT
 421
 422 print FH join ",", @values;
 423
 424 print FH << 'EOT';
 425 ;
 426
 427 foreach (["perl", "rules", "rules"],
 428          ["/*", "OPEN", "OPEN"],
 429          ["*/", "CLOSE", "CLOSE"],
 430          [$pound, 'Sterling', []],
 431          [$inf, 'Infinity', []],
 432          [$pound_utf8, '1 Pound', '1 Pound (as bytes)'],
 433          [$pound_bytes, '1 Pound (as bytes)', []],
 434         ) {
 435   # Flag an expected error with a reference for the expect string.
 436   my ($string, $expect, $expect_bytes) = @$_;
 437   (my $name = $string) =~ s/([^ -~])/sprintf '\x{%X}', ord $1/ges;
 438   print "# \"$name\" => \'$expect\'\n";
 439   # Try to force this to be bytes if possible.
 440   utf8::downgrade ($string, 1);
 441 EOT
 442
 443 print FH  "my (\$error, \$got) = ${package}::constant (\$string);\n";
 444
 445 print FH <<'EOT';
 446   if ($error or $got ne $expect) {
 447     print "not ok $test # error '$error', got '$got'\n";
 448   } else {
 449     print "ok $test\n";
 450   }
 451   $test++;
 452   print "# Now upgrade '$name' to utf8\n";
 453   utf8::upgrade ($string);
 454 EOT
 455
 456 print FH  "my (\$error, \$got) = ${package}::constant (\$string);\n";
 457
 458 print FH <<'EOT';
 459   if ($error or $got ne $expect) {
 460     print "not ok $test # error '$error', got '$got'\n";
 461   } else {
 462     print "ok $test\n";
 463   }
 464   $test++;
 465   if (defined $expect_bytes) {
 466     print "# And now with the utf8 byte sequence for name\n";
 467     # Try the encoded bytes.
 468     utf8::encode ($string);
 469 EOT
 470
 471 print FH "my (\$error, \$got) = ${package}::constant (\$string);\n";
 472
 473 print FH <<'EOT';
 474     if (ref $expect_bytes) {
 475       # Error expected.
 476       if ($error) {
 477         print "ok $test # error='$error' (as expected)\n";
 478       } else {
 479         print "not ok $test # expected error, got no error and '$got'\n";
 480       }
 481     } elsif ($got ne $expect_bytes) {
 482       print "not ok $test # error '$error', expect '$expect_bytes', got '$got'\n";
 483     } else {
 484       print "ok $test\n";
 485     }
 486     $test++;
 487   }
 488 }
 489 EOT
 490
 491 close FH or die "close $testpl: $!\n";
 492
 493 # This is where the test numbers carry on after the test number above are
 494 # relayed
 495 my $test = 44;
 496
 497 ################ Makefile.PL
 498 # We really need a Makefile.PL because make test for a no dynamic linking perl
 499 # will run Makefile.PL again as part of the "make perl" target.
 500 my $makefilePL = catfile($dir, "Makefile.PL");
 501 push @files, "Makefile.PL";
 502 open FH, ">$makefilePL" or die "open >$makefilePL: $!\n";
 503 print FH <<"EOT";
 504 #!$perl -w
 505 use ExtUtils::MakeMaker;
 506 WriteMakefile(
 507               'NAME'            => "$package",
 508               'VERSION_FROM'    => "$package.pm", # finds \$VERSION
 509               (\$] >= 5.005 ?
 510                (#ABSTRACT_FROM => "$package.pm", # XXX add this
 511                 AUTHOR     => "$0") : ())
 512              );
 513 EOT
 514
 515 close FH or die "close $makefilePL: $!\n";
 516
 517 ################ MANIFEST
 518 # We really need a MANIFEST because make distclean checks it.
 519 my $manifest = catfile($dir, "MANIFEST");
 520 push @files, "MANIFEST";
 521 open FH, ">$manifest" or die "open >$manifest: $!\n";
 522 print FH "$_\n" foreach @files;
 523 close FH or die "close $manifest: $!\n";
 524
 525 chdir $dir or die $!; push @INC,  '../../lib';
 526 END {chdir ".." or warn $!};
 527
 528 my @perlout = `$runperl Makefile.PL PERL_CORE=1`;
 529 if ($?) {
 530   print "not ok 1 # $runperl Makefile.PL failed: $?\n";
 531   print "# $_" foreach @perlout;
 532   exit($?);
 533 } else {
 534   print "ok 1\n";
 535 }
 536
 537
 538 my $makefile = ($^O eq 'VMS' ? 'descrip' : 'Makefile');
 539 my $makefile_ext = ($^O eq 'VMS' ? '.mms' : '');
 540 if (-f "$makefile$makefile_ext") {
 541   print "ok 2\n";
 542 } else {
 543   print "not ok 2\n";
 544 }
 545
 546 # Renamed by make clean
 547 my $makefile_rename = $makefile . ($^O eq 'VMS' ? '.mms' : '.old');
 548
 549 my $make = $Config{make};
 550
 551 $make = $ENV{MAKE} if exists $ENV{MAKE};
 552
 553 if ($^O eq 'MSWin32' && $make eq 'nmake') { $make .= " -nologo"; }
 554
 555 my @makeout;
 556
 557 if ($^O eq 'VMS') { $make .= ' all'; }
 558 print "# make = '$make'\n";
 559 @makeout = `$make`;
 560 if ($?) {
 561   print "not ok 3 # $make failed: $?\n";
 562   print "# $_" foreach @makeout;
 563   exit($?);
 564 } else {
 565   print "ok 3\n";
 566 }
 567
 568 if ($^O eq 'VMS') { $make =~ s{ all}{}; }
 569
 570 if ($Config{usedl}) {
 571   print "ok 4\n";
 572 } else {
 573   my $makeperl = "$make perl";
 574   print "# make = '$makeperl'\n";
 575   @makeout = `$makeperl`;
 576   if ($?) {
 577     print "not ok 4 # $makeperl failed: $?\n";
 578   print "# $_" foreach @makeout;
 579     exit($?);
 580   } else {
 581     print "ok 4\n";
 582   }
 583 }
 584
 585 my $maketest = "$make test";
 586 print "# make = '$maketest'\n";
 587
 588 @makeout = `$maketest`;
 589
 590 if (open OUTPUT, "<$output") {
 591   print while <OUTPUT>;
 592   close OUTPUT or print "# Close $output failed: $!\n";
 593 } else {
 594   # Harness will report missing test results at this point.
 595   print "# Open <$output failed: $!\n";
 596 }
 597
 598 if ($?) {
 599   print "not ok $test # $maketest failed: $?\n";
 600   print "# $_" foreach @makeout;
 601 } else {
 602   print "ok $test - maketest\n";
 603 }
 604 $test++;
 605
 606
 607 # -x is busted on Win32 < 5.6.1, so we emulate it.
 608 my $regen;
 609 if( $^O eq 'MSWin32' && $] <= 5.006001 ) {
 610     open(REGENTMP, ">regentmp") or die $!;
 611     open(XS, "$package.xs")     or die $!;
 612     my $saw_shebang;
 613     while(<XS>) {
 614         $saw_shebang++ if /^#!.*/i ;
 615         print REGENTMP $_ if $saw_shebang;
 616     }
 617     close XS;  close REGENTMP;
 618     $regen = `$runperl regentmp`;
 619     unlink 'regentmp';
 620 }
 621 else {
 622     $regen = `$runperl -x $package.xs`;
 623 }
 624 if ($?) {
 625   print "not ok $test # $runperl -x $package.xs failed: $?\n";
 626 } else {
 627   print "ok $test - regen\n";
 628 }
 629 $test++;
 630
 631 my $expect = $constant_types . $C_constant .
 632   "\n#### XS Section:\n" . $XS_constant;
 633
 634 if ($expect eq $regen) {
 635   print "ok $test - regen worked\n";
 636 } else {
 637   print "not ok $test - regen worked\n";
 638   # open FOO, ">expect"; print FOO $expect;
 639   # open FOO, ">regen"; print FOO $regen; close FOO;
 640 }
 641 $test++;
 642
 643 my $makeclean = "$make clean";
 644 print "# make = '$makeclean'\n";
 645 @makeout = `$makeclean`;
 646 if ($?) {
 647   print "not ok $test # $make failed: $?\n";
 648   print "# $_" foreach @makeout;
 649 } else {
 650   print "ok $test\n";
 651 }
 652 $test++;
 653
 654 sub check_for_bonus_files {
 655   my $dir = shift;
 656   my %expect = map {($^O eq 'VMS' ? lc($_) : $_), 1} @_;
 657
 658   my $fail;
 659   opendir DIR, $dir or die "opendir '$dir': $!";
 660   while (defined (my $entry = readdir DIR)) {
 661     $entry =~ s/\.$// if $^O eq 'VMS';  # delete trailing dot that indicates no extension
 662     next if $expect{$entry};
 663     print "# Extra file '$entry'\n";
 664     $fail = 1;
 665   }
 666
 667   closedir DIR or warn "closedir '.': $!";
 668   if ($fail) {
 669     print "not ok $test\n";
 670   } else {
 671     print "ok $test\n";
 672   }
 673   $test++;
 674 }
 675
 676 check_for_bonus_files ('.', @files, $output, $makefile_rename, '.', '..');
 677
 678 rename $makefile_rename, $makefile
 679  or die "Can't rename '$makefile_rename' to '$makefile': $!";
 680
 681 unlink $output or warn "Can't unlink '$output': $!";
 682
 683 # Need to make distclean to remove ../../lib/ExtTest.pm
 684 my $makedistclean = "$make distclean";
 685 print "# make = '$makedistclean'\n";
 686 @makeout = `$makedistclean`;
 687 if ($?) {
 688   print "not ok $test # $make failed: $?\n";
 689   print "# $_" foreach @makeout;
 690 } else {
 691   print "ok $test\n";
 692 }
 693 $test++;
 694
 695 check_for_bonus_files ('.', @files, '.', '..');
 696
 697 unless ($keep_files) {
 698   foreach (@files) {
 699     unlink $_ or warn "unlink $_: $!";
 700   }
 701 }
 702
 703 check_for_bonus_files ('.', '.', '..');