lib/ExtUtils/ParseXS.pm

   1 package ExtUtils::ParseXS;
   2
   3 use 5.006;  # We use /??{}/ in regexes
   4 use Cwd;
   5 use Config;
   6 use File::Basename;
   7 use File::Spec;
   8
   9 require Exporter;
  10
  11 @ISA = qw(Exporter);
  12 @EXPORT_OK = qw(process_file);
  13
  14 # use strict;  # One of these days...
  15
  16 my(@XSStack);   # Stack of conditionals and INCLUDEs
  17 my($XSS_work_idx, $cpp_next_tmp);
  18
  19 use vars qw($VERSION);
  20 $VERSION = '2.09_02';
  21 $VERSION = eval $VERSION;
  22
  23 use vars qw(%input_expr %output_expr $ProtoUsed @InitFileCode $FH $proto_re $Overload $errors $Fallback
  24             $cplusplus $hiertype $WantPrototypes $WantVersionChk $except $WantLineNumbers
  25             $WantOptimize $process_inout $process_argtypes @tm
  26             $dir $filename $filepathname %IncludedFiles
  27             %type_kind %proto_letter
  28             %targetable $BLOCK_re $lastline $lastline_no
  29             $Package $Prefix @line @BootCode %args_match %defaults %var_types %arg_list @proto_arg
  30             $processing_arg_with_types %argtype_seen @outlist %in_out %lengthof
  31             $proto_in_this_xsub $scope_in_this_xsub $interface $prepush_done $interface_macro $interface_macro_set
  32             $ProtoThisXSUB $ScopeThisXSUB $xsreturn
  33             @line_no $ret_type $func_header $orig_args
  34            ); # Add these just to get compilation to happen.
  35
  36
  37 sub process_file {
  38
  39   # Allow for $package->process_file(%hash) in the future
  40   my ($pkg, %args) = @_ % 2 ? @_ : (__PACKAGE__, @_);
  41
  42   $ProtoUsed = exists $args{prototypes};
  43
  44   # Set defaults.
  45   %args = (
  46            # 'C++' => 0, # Doesn't seem to *do* anything...
  47            hiertype => 0,
  48            except => 0,
  49            prototypes => 0,
  50            versioncheck => 1,
  51            linenumbers => 1,
  52            optimize => 1,
  53            prototypes => 0,
  54            inout => 1,
  55            argtypes => 1,
  56            typemap => [],
  57            output => \*STDOUT,
  58            csuffix => '.c',
  59            %args,
  60           );
  61
  62   # Global Constants
  63
  64   my ($Is_VMS, $SymSet);
  65   if ($^O eq 'VMS') {
  66     $Is_VMS = 1;
  67     # Establish set of global symbols with max length 28, since xsubpp
  68     # will later add the 'XS_' prefix.
  69     require ExtUtils::XSSymSet;
  70     $SymSet = new ExtUtils::XSSymSet 28;
  71   }
  72   @XSStack = ({type => 'none'});
  73   ($XSS_work_idx, $cpp_next_tmp) = (0, "XSubPPtmpAAAA");
  74   @InitFileCode = ();
  75   $FH = 'File0000' ;
  76   $proto_re = "[" . quotemeta('\$%&*@;[]') . "]" ;
  77   $Overload = 0;
  78   $errors = 0;
  79   $Fallback = 'PL_sv_undef';
  80
  81   # Most of the 1500 lines below uses these globals.  We'll have to
  82   # clean this up sometime, probably.  For now, we just pull them out
  83   # of %args.  -Ken
  84
  85   $cplusplus = $args{'C++'};
  86   $hiertype = $args{hiertype};
  87   $WantPrototypes = $args{prototypes};
  88   $WantVersionChk = $args{versioncheck};
  89   $except = $args{except} ? ' TRY' : '';
  90   $WantLineNumbers = $args{linenumbers};
  91   $WantOptimize = $args{optimize};
  92   $process_inout = $args{inout};
  93   $process_argtypes = $args{argtypes};
  94   @tm = ref $args{typemap} ? @{$args{typemap}} : ($args{typemap});
  95
  96   for ($args{filename}) {
  97     die "Missing required parameter 'filename'" unless $_;
  98     $filepathname = $_;
  99     ($dir, $filename) = (dirname($_), basename($_));
 100     $filepathname =~ s/\\/\\\\/g;
 101     $IncludedFiles{$_}++;
 102   }
 103
 104   # Open the input file
 105   open($FH, $args{filename}) or die "cannot open $args{filename}: $!\n";
 106
 107   # Open the output file if given as a string.  If they provide some
 108   # other kind of reference, trust them that we can print to it.
 109   if (not ref $args{output}) {
 110     open my($fh), "> $args{output}" or die "Can't create $args{output}: $!";
 111     $args{outfile} = $args{output};
 112     $args{output} = $fh;
 113   }
 114
 115   # Really, we shouldn't have to chdir() or select() in the first
 116   # place.  For now, just save & restore.
 117   my $orig_cwd = cwd();
 118   my $orig_fh = select();
 119
 120   chdir($dir);
 121   my $pwd = cwd();
 122   my $csuffix = $args{csuffix};
 123
 124   if ($WantLineNumbers) {
 125     my $cfile;
 126     if ( $args{outfile} ) {
 127       $cfile = $args{outfile};
 128     } else {
 129       $cfile = $args{filename};
 130       $cfile =~ s/\.xs$/$csuffix/i or $cfile .= $csuffix;
 131     }
 132     tie(*PSEUDO_STDOUT, 'ExtUtils::ParseXS::CountLines', $cfile, $args{output});
 133     select PSEUDO_STDOUT;
 134   } else {
 135     select $args{output};
 136   }
 137
 138   foreach my $typemap (@tm) {
 139     die "Can't find $typemap in $pwd\n" unless -r $typemap;
 140   }
 141
 142   push @tm, standard_typemap_locations();
 143
 144   foreach my $typemap (@tm) {
 145     next unless -f $typemap ;
 146     # skip directories, binary files etc.
 147     warn("Warning: ignoring non-text typemap file '$typemap'\n"), next
 148       unless -T $typemap ;
 149     open(TYPEMAP, $typemap)
 150       or warn ("Warning: could not open typemap file '$typemap': $!\n"), next;
 151     my $mode = 'Typemap';
 152     my $junk = "" ;
 153     my $current = \$junk;
 154     while (<TYPEMAP>) {
 155       next if /^\s*             #/;
 156         my $line_no = $. + 1;
 157       if (/^INPUT\s*$/) {
 158         $mode = 'Input';   $current = \$junk;  next;
 159       }
 160       if (/^OUTPUT\s*$/) {
 161         $mode = 'Output';  $current = \$junk;  next;
 162       }
 163       if (/^TYPEMAP\s*$/) {
 164         $mode = 'Typemap'; $current = \$junk;  next;
 165       }
 166       if ($mode eq 'Typemap') {
 167         chomp;
 168         my $line = $_ ;
 169         TrimWhitespace($_) ;
 170         # skip blank lines and comment lines
 171         next if /^$/ or /^#/ ;
 172         my($type,$kind, $proto) = /^\s*(.*?\S)\s+(\S+)\s*($proto_re*)\s*$/ or
 173           warn("Warning: File '$typemap' Line $. '$line' TYPEMAP entry needs 2 or 3 columns\n"), next;
 174         $type = TidyType($type) ;
 175         $type_kind{$type} = $kind ;
 176         # prototype defaults to '$'
 177         $proto = "\$" unless $proto ;
 178         warn("Warning: File '$typemap' Line $. '$line' Invalid prototype '$proto'\n")
 179           unless ValidProtoString($proto) ;
 180         $proto_letter{$type} = C_string($proto) ;
 181       } elsif (/^\s/) {
 182         $$current .= $_;
 183       } elsif ($mode eq 'Input') {
 184         s/\s+$//;
 185         $input_expr{$_} = '';
 186         $current = \$input_expr{$_};
 187       } else {
 188         s/\s+$//;
 189         $output_expr{$_} = '';
 190         $current = \$output_expr{$_};
 191       }
 192     }
 193     close(TYPEMAP);
 194   }
 195
 196   foreach my $key (keys %input_expr) {
 197     $input_expr{$key} =~ s/;*\s+\z//;
 198   }
 199
 200   my ($bal, $cast, $size);
 201   $bal = qr[(?:(?>[^()]+)|\((??{ $bal })\))*]; # ()-balanced
 202   $cast = qr[(?:\(\s*SV\s*\*\s*\)\s*)?]; # Optional (SV*) cast
 203   $size = qr[,\s* (??{ $bal }) ]x; # Third arg (to setpvn)
 204
 205   foreach my $key (keys %output_expr) {
 206     use re 'eval';
 207
 208     my ($t, $with_size, $arg, $sarg) =
 209       ($output_expr{$key} =~
 210        m[^ \s+ sv_set ( [iunp] ) v (n)? # Type, is_setpvn
 211          \s* \( \s* $cast \$arg \s* ,
 212          \s* ( (??{ $bal }) )   # Set from
 213          ( (??{ $size }) )?     # Possible sizeof set-from
 214          \) \s* ; \s* $
 215         ]x);
 216     $targetable{$key} = [$t, $with_size, $arg, $sarg] if $t;
 217   }
 218
 219   my $END = "!End!\n\n";                # "impossible" keyword (multiple newline)
 220
 221   # Match an XS keyword
 222   $BLOCK_re= '\s*(' . join('|', qw(
 223                                    REQUIRE BOOT CASE PREINIT INPUT INIT CODE PPCODE OUTPUT
 224                                    CLEANUP ALIAS ATTRS PROTOTYPES PROTOTYPE VERSIONCHECK INCLUDE
 225                                    SCOPE INTERFACE INTERFACE_MACRO C_ARGS POSTCALL OVERLOAD FALLBACK
 226                                   )) . "|$END)\\s*:";
 227
 228
 229   my ($C_group_rex, $C_arg);
 230   # Group in C (no support for comments or literals)
 231   $C_group_rex = qr/ [({\[]
 232                        (?: (?> [^()\[\]{}]+ ) | (??{ $C_group_rex }) )*
 233                        [)}\]] /x ;
 234   # Chunk in C without comma at toplevel (no comments):
 235   $C_arg = qr/ (?: (?> [^()\[\]{},"']+ )
 236              |   (??{ $C_group_rex })
 237              |   " (?: (?> [^\\"]+ )
 238                    |   \\.
 239                    )* "         # String literal
 240                             |   ' (?: (?> [^\\']+ ) | \\. )* ' # Char literal
 241              )* /xs;
 242
 243   # Identify the version of xsubpp used
 244   print <<EOM ;
 245 /*
 246  * This file was generated automatically by ExtUtils::ParseXS version $VERSION from the
 247  * contents of $filename. Do not edit this file, edit $filename instead.
 248  *
 249  *      ANY CHANGES MADE HERE WILL BE LOST!
 250  *
 251  */
 252
 253 EOM
 254
 255
 256   print("#line 1 \"$filepathname\"\n")
 257     if $WantLineNumbers;
 258
 259   firstmodule:
 260   while (<$FH>) {
 261     if (/^=/) {
 262       my $podstartline = $.;
 263       do {
 264         if (/^=cut\s*$/) {
 265           # We can't just write out a /* */ comment, as our embedded
 266           # POD might itself be in a comment. We can't put a /**/
 267           # comment inside #if 0, as the C standard says that the source
 268           # file is decomposed into preprocessing characters in the stage
 269           # before preprocessing commands are executed.
 270           # I don't want to leave the text as barewords, because the spec
 271           # isn't clear whether macros are expanded before or after
 272           # preprocessing commands are executed, and someone pathological
 273           # may just have defined one of the 3 words as a macro that does
 274           # something strange. Multiline strings are illegal in C, so
 275           # the "" we write must be a string literal. And they aren't
 276           # concatenated until 2 steps later, so we are safe.
 277           #     - Nicholas Clark
 278           print("#if 0\n  \"Skipped embedded POD.\"\n#endif\n");
 279           printf("#line %d \"$filepathname\"\n", $. + 1)
 280             if $WantLineNumbers;
 281           next firstmodule
 282         }
 283
 284       } while (<$FH>);
 285       # At this point $. is at end of file so die won't state the start
 286       # of the problem, and as we haven't yet read any lines &death won't
 287       # show the correct line in the message either.
 288       die ("Error: Unterminated pod in $filename, line $podstartline\n")
 289         unless $lastline;
 290     }
 291     last if ($Package, $Prefix) =
 292       /^MODULE\s*=\s*[\w:]+(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/;
 293
 294     print $_;
 295   }
 296   unless (defined $_) {
 297     warn "Didn't find a 'MODULE ... PACKAGE ... PREFIX' line\n";
 298     exit 0; # Not a fatal error for the caller process
 299   }
 300
 301     print <<"EOF";
 302 #ifndef PERL_UNUSED_VAR
 303 #  define PERL_UNUSED_VAR(var) if (0) var = var
 304 #endif
 305
 306 EOF
 307
 308   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $WantLineNumbers;
 309
 310   $lastline    = $_;
 311   $lastline_no = $.;
 312
 313  PARAGRAPH:
 314   while (fetch_para()) {
 315     # Print initial preprocessor statements and blank lines
 316     while (@line && $line[0] !~ /^[^\#]/) {
 317       my $line = shift(@line);
 318       print $line, "\n";
 319       next unless $line =~ /^\#\s*((if)(?:n?def)?|elsif|else|endif)\b/;
 320       my $statement = $+;
 321       if ($statement eq 'if') {
 322         $XSS_work_idx = @XSStack;
 323         push(@XSStack, {type => 'if'});
 324       } else {
 325         death ("Error: `$statement' with no matching `if'")
 326           if $XSStack[-1]{type} ne 'if';
 327         if ($XSStack[-1]{varname}) {
 328           push(@InitFileCode, "#endif\n");
 329           push(@BootCode,     "#endif");
 330         }
 331
 332         my(@fns) = keys %{$XSStack[-1]{functions}};
 333         if ($statement ne 'endif') {
 334           # Hide the functions defined in other #if branches, and reset.
 335           @{$XSStack[-1]{other_functions}}{@fns} = (1) x @fns;
 336           @{$XSStack[-1]}{qw(varname functions)} = ('', {});
 337         } else {
 338           my($tmp) = pop(@XSStack);
 339           0 while (--$XSS_work_idx
 340                    && $XSStack[$XSS_work_idx]{type} ne 'if');
 341           # Keep all new defined functions
 342           push(@fns, keys %{$tmp->{other_functions}});
 343           @{$XSStack[$XSS_work_idx]{functions}}{@fns} = (1) x @fns;
 344         }
 345       }
 346     }
 347
 348     next PARAGRAPH unless @line;
 349
 350     if ($XSS_work_idx && !$XSStack[$XSS_work_idx]{varname}) {
 351       # We are inside an #if, but have not yet #defined its xsubpp variable.
 352       print "#define $cpp_next_tmp 1\n\n";
 353       push(@InitFileCode, "#if $cpp_next_tmp\n");
 354       push(@BootCode,     "#if $cpp_next_tmp");
 355       $XSStack[$XSS_work_idx]{varname} = $cpp_next_tmp++;
 356     }
 357
 358     death ("Code is not inside a function"
 359            ." (maybe last function was ended by a blank line "
 360            ." followed by a statement on column one?)")
 361       if $line[0] =~ /^\s/;
 362
 363     my ($class, $externC, $static, $elipsis, $wantRETVAL, $RETVAL_no_return);
 364     my (@fake_INPUT_pre);       # For length(s) generated variables
 365     my (@fake_INPUT);
 366
 367     # initialize info arrays
 368     undef(%args_match);
 369     undef(%var_types);
 370     undef(%defaults);
 371     undef(%arg_list) ;
 372     undef(@proto_arg) ;
 373     undef($processing_arg_with_types) ;
 374     undef(%argtype_seen) ;
 375     undef(@outlist) ;
 376     undef(%in_out) ;
 377     undef(%lengthof) ;
 378     undef($proto_in_this_xsub) ;
 379     undef($scope_in_this_xsub) ;
 380     undef($interface);
 381     undef($prepush_done);
 382     $interface_macro = 'XSINTERFACE_FUNC' ;
 383     $interface_macro_set = 'XSINTERFACE_FUNC_SET' ;
 384     $ProtoThisXSUB = $WantPrototypes ;
 385     $ScopeThisXSUB = 0;
 386     $xsreturn = 0;
 387
 388     $_ = shift(@line);
 389     while (my $kwd = check_keyword("REQUIRE|PROTOTYPES|FALLBACK|VERSIONCHECK|INCLUDE")) {
 390       &{"${kwd}_handler"}() ;
 391       next PARAGRAPH unless @line ;
 392       $_ = shift(@line);
 393     }
 394
 395     if (check_keyword("BOOT")) {
 396       &check_cpp;
 397       push (@BootCode, "#line $line_no[@line_no - @line] \"$filepathname\"")
 398         if $WantLineNumbers && $line[0] !~ /^\s*#\s*line\b/;
 399       push (@BootCode, @line, "") ;
 400       next PARAGRAPH ;
 401     }
 402
 403
 404     # extract return type, function name and arguments
 405     ($ret_type) = TidyType($_);
 406     $RETVAL_no_return = 1 if $ret_type =~ s/^NO_OUTPUT\s+//;
 407
 408     # Allow one-line ANSI-like declaration
 409     unshift @line, $2
 410       if $process_argtypes
 411         and $ret_type =~ s/^(.*?\w.*?)\s*\b(\w+\s*\(.*)/$1/s;
 412
 413     # a function definition needs at least 2 lines
 414     blurt ("Error: Function definition too short '$ret_type'"), next PARAGRAPH
 415       unless @line ;
 416
 417     $externC = 1 if $ret_type =~ s/^extern "C"\s+//;
 418     $static  = 1 if $ret_type =~ s/^static\s+//;
 419
 420     $func_header = shift(@line);
 421     blurt ("Error: Cannot parse function definition from '$func_header'"), next PARAGRAPH
 422       unless $func_header =~ /^(?:([\w:]*)::)?(\w+)\s*\(\s*(.*?)\s*\)\s*(const)?\s*(;\s*)?$/s;
 423
 424     ($class, $func_name, $orig_args) =  ($1, $2, $3) ;
 425     $class = "$4 $class" if $4;
 426     ($pname = $func_name) =~ s/^($Prefix)?/$Packprefix/;
 427     ($clean_func_name = $func_name) =~ s/^$Prefix//;
 428     $Full_func_name = "${Packid}_$clean_func_name";
 429     if ($Is_VMS) {
 430       $Full_func_name = $SymSet->addsym($Full_func_name);
 431     }
 432
 433     # Check for duplicate function definition
 434     for my $tmp (@XSStack) {
 435       next unless defined $tmp->{functions}{$Full_func_name};
 436       Warn("Warning: duplicate function definition '$clean_func_name' detected");
 437       last;
 438     }
 439     $XSStack[$XSS_work_idx]{functions}{$Full_func_name} ++ ;
 440     %XsubAliases = %XsubAliasValues = %Interfaces = @Attributes = ();
 441     $DoSetMagic = 1;
 442
 443     $orig_args =~ s/\\\s*/ /g;  # process line continuations
 444     my @args;
 445
 446     my %only_C_inlist;          # Not in the signature of Perl function
 447     if ($process_argtypes and $orig_args =~ /\S/) {
 448       my $args = "$orig_args ,";
 449       if ($args =~ /^( (??{ $C_arg }) , )* $ /x) {
 450         @args = ($args =~ /\G ( (??{ $C_arg }) ) , /xg);
 451         for ( @args ) {
 452           s/^\s+//;
 453           s/\s+$//;
 454           my ($arg, $default) = / ( [^=]* ) ( (?: = .* )? ) /x;
 455           my ($pre, $name) = ($arg =~ /(.*?) \s*
 456                                              \b ( \w+ | length\( \s*\w+\s* \) )
 457                                              \s* $ /x);
 458           next unless defined($pre) && length($pre);
 459           my $out_type;
 460           my $inout_var;
 461           if ($process_inout and s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\s+//) {
 462             my $type = $1;
 463             $out_type = $type if $type ne 'IN';
 464             $arg =~ s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\s+//;
 465             $pre =~ s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\s+//;
 466           }
 467           my $islength;
 468           if ($name =~ /^length\( \s* (\w+) \s* \)\z/x) {
 469             $name = "XSauto_length_of_$1";
 470             $islength = 1;
 471             die "Default value on length() argument: `$_'"
 472               if length $default;
 473           }
 474           if (length $pre or $islength) { # Has a type
 475             if ($islength) {
 476               push @fake_INPUT_pre, $arg;
 477             } else {
 478               push @fake_INPUT, $arg;
 479             }
 480             # warn "pushing '$arg'\n";
 481             $argtype_seen{$name}++;
 482             $_ = "$name$default"; # Assigns to @args
 483           }
 484           $only_C_inlist{$_} = 1 if $out_type eq "OUTLIST" or $islength;
 485           push @outlist, $name if $out_type =~ /OUTLIST$/;
 486           $in_out{$name} = $out_type if $out_type;
 487         }
 488       } else {
 489         @args = split(/\s*,\s*/, $orig_args);
 490         Warn("Warning: cannot parse argument list '$orig_args', fallback to split");
 491       }
 492     } else {
 493       @args = split(/\s*,\s*/, $orig_args);
 494       for (@args) {
 495         if ($process_inout and s/^(IN|IN_OUTLIST|OUTLIST|IN_OUT|OUT)\s+//) {
 496           my $out_type = $1;
 497           next if $out_type eq 'IN';
 498           $only_C_inlist{$_} = 1 if $out_type eq "OUTLIST";
 499           push @outlist, $name if $out_type =~ /OUTLIST$/;
 500           $in_out{$_} = $out_type;
 501         }
 502       }
 503     }
 504     if (defined($class)) {
 505       my $arg0 = ((defined($static) or $func_name eq 'new')
 506                   ? "CLASS" : "THIS");
 507       unshift(@args, $arg0);
 508       ($report_args = "$arg0, $report_args") =~ s/^\w+, $/$arg0/;
 509     }
 510     my $extra_args = 0;
 511     @args_num = ();
 512     $num_args = 0;
 513     my $report_args = '';
 514     foreach my $i (0 .. $#args) {
 515       if ($args[$i] =~ s/\.\.\.//) {
 516         $elipsis = 1;
 517         if ($args[$i] eq '' && $i == $#args) {
 518           $report_args .= ", ...";
 519           pop(@args);
 520           last;
 521         }
 522       }
 523       if ($only_C_inlist{$args[$i]}) {
 524         push @args_num, undef;
 525       } else {
 526         push @args_num, ++$num_args;
 527         $report_args .= ", $args[$i]";
 528       }
 529       if ($args[$i] =~ /^([^=]*[^\s=])\s*=\s*(.*)/s) {
 530         $extra_args++;
 531         $args[$i] = $1;
 532         $defaults{$args[$i]} = $2;
 533         $defaults{$args[$i]} =~ s/"/\\"/g;
 534       }
 535       $proto_arg[$i+1] = '$' ;
 536     }
 537     $min_args = $num_args - $extra_args;
 538     $report_args =~ s/"/\\"/g;
 539     $report_args =~ s/^,\s+//;
 540     my @func_args = @args;
 541     shift @func_args if defined($class);
 542
 543     for (@func_args) {
 544       s/^/&/ if $in_out{$_};
 545     }
 546     $func_args = join(", ", @func_args);
 547     @args_match{@args} = @args_num;
 548
 549     $PPCODE = grep(/^\s*PPCODE\s*:/, @line);
 550     $CODE = grep(/^\s*CODE\s*:/, @line);
 551     # Detect CODE: blocks which use ST(n)= or XST_m*(n,v)
 552     #   to set explicit return values.
 553     $EXPLICIT_RETURN = ($CODE &&
 554                         ("@line" =~ /(\bST\s*\([^;]*=) | (\bXST_m\w+\s*\()/x ));
 555     $ALIAS  = grep(/^\s*ALIAS\s*:/,  @line);
 556     $INTERFACE  = grep(/^\s*INTERFACE\s*:/,  @line);
 557
 558     $xsreturn = 1 if $EXPLICIT_RETURN;
 559
 560     $externC = $externC ? qq[extern "C"] : "";
 561
 562     # print function header
 563     print Q(<<"EOF");
 564 #$externC
 565 #XS(XS_${Full_func_name}); /* prototype to pass -Wmissing-prototypes */
 566 #XS(XS_${Full_func_name})
 567 #[[
 568 #    dXSARGS;
 569 EOF
 570     print Q(<<"EOF") if $ALIAS ;
 571 #    dXSI32;
 572 EOF
 573     print Q(<<"EOF") if $INTERFACE ;
 574 #    dXSFUNCTION($ret_type);
 575 EOF
 576     if ($elipsis) {
 577       $cond = ($min_args ? qq(items < $min_args) : 0);
 578     } elsif ($min_args == $num_args) {
 579       $cond = qq(items != $min_args);
 580     } else {
 581       $cond = qq(items < $min_args || items > $num_args);
 582     }
 583
 584     print Q(<<"EOF") if $except;
 585 #    char errbuf[1024];
 586 #    *errbuf = '\0';
 587 EOF
 588
 589     if ($ALIAS)
 590       { print Q(<<"EOF") if $cond }
 591 #    if ($cond)
 592 #       Perl_croak(aTHX_ "Usage: %s($report_args)", GvNAME(CvGV(cv)));
 593 EOF
 594     else
 595       { print Q(<<"EOF") if $cond }
 596 #    if ($cond)
 597 #       Perl_croak(aTHX_ "Usage: $pname($report_args)");
 598 EOF
 599
 600      # cv doesn't seem to be used, in most cases unless we go in
 601      # the if of this else
 602      print Q(<<"EOF");
 603 #    PERL_UNUSED_VAR(cv); /* -W */
 604 EOF
 605
 606     #gcc -Wall: if an xsub has PPCODE is used
 607     #it is possible none of ST, XSRETURN or XSprePUSH macros are used
 608     #hence `ax' (setup by dXSARGS) is unused
 609     #XXX: could breakup the dXSARGS; into dSP;dMARK;dITEMS
 610     #but such a move could break third-party extensions
 611     print Q(<<"EOF") if $PPCODE;
 612 #    PERL_UNUSED_VAR(ax); /* -Wall */
 613 EOF
 614
 615     print Q(<<"EOF") if $PPCODE;
 616 #    SP -= items;
 617 EOF
 618
 619     # Now do a block of some sort.
 620
 621     $condnum = 0;
 622     $cond = '';                 # last CASE: condidional
 623     push(@line, "$END:");
 624     push(@line_no, $line_no[-1]);
 625     $_ = '';
 626     &check_cpp;
 627     while (@line) {
 628       &CASE_handler if check_keyword("CASE");
 629       print Q(<<"EOF");
 630 #   $except [[
 631 EOF
 632
 633       # do initialization of input variables
 634       $thisdone = 0;
 635       $retvaldone = 0;
 636       $deferred = "";
 637       %arg_list = () ;
 638       $gotRETVAL = 0;
 639
 640       INPUT_handler() ;
 641       process_keyword("INPUT|PREINIT|INTERFACE_MACRO|C_ARGS|ALIAS|ATTRS|PROTOTYPE|SCOPE|OVERLOAD") ;
 642
 643       print Q(<<"EOF") if $ScopeThisXSUB;
 644 #   ENTER;
 645 #   [[
 646 EOF
 647
 648       if (!$thisdone && defined($class)) {
 649         if (defined($static) or $func_name eq 'new') {
 650           print "\tchar *";
 651           $var_types{"CLASS"} = "char *";
 652           &generate_init("char *", 1, "CLASS");
 653         }
 654         else {
 655           print "\t$class *";
 656           $var_types{"THIS"} = "$class *";
 657           &generate_init("$class *", 1, "THIS");
 658         }
 659       }
 660
 661       # do code
 662       if (/^\s*NOT_IMPLEMENTED_YET/) {
 663         print "\n\tPerl_croak(aTHX_ \"$pname: not implemented yet\");\n";
 664         $_ = '' ;
 665       } else {
 666         if ($ret_type ne "void") {
 667           print "\t" . &map_type($ret_type, 'RETVAL') . ";\n"
 668             if !$retvaldone;
 669           $args_match{"RETVAL"} = 0;
 670           $var_types{"RETVAL"} = $ret_type;
 671           print "\tdXSTARG;\n"
 672             if $WantOptimize and $targetable{$type_kind{$ret_type}};
 673         }
 674
 675         if (@fake_INPUT or @fake_INPUT_pre) {
 676           unshift @line, @fake_INPUT_pre, @fake_INPUT, $_;
 677           $_ = "";
 678           $processing_arg_with_types = 1;
 679           INPUT_handler() ;
 680         }
 681         print $deferred;
 682
 683         process_keyword("INIT|ALIAS|ATTRS|PROTOTYPE|INTERFACE_MACRO|INTERFACE|C_ARGS|OVERLOAD") ;
 684
 685         if (check_keyword("PPCODE")) {
 686           print_section();
 687           death ("PPCODE must be last thing") if @line;
 688           print "\tLEAVE;\n" if $ScopeThisXSUB;
 689           print "\tPUTBACK;\n\treturn;\n";
 690         } elsif (check_keyword("CODE")) {
 691           print_section() ;
 692         } elsif (defined($class) and $func_name eq "DESTROY") {
 693           print "\n\t";
 694           print "delete THIS;\n";
 695         } else {
 696           print "\n\t";
 697           if ($ret_type ne "void") {
 698             print "RETVAL = ";
 699             $wantRETVAL = 1;
 700           }
 701           if (defined($static)) {
 702             if ($func_name eq 'new') {
 703               $func_name = "$class";
 704             } else {
 705               print "${class}::";
 706             }
 707           } elsif (defined($class)) {
 708             if ($func_name eq 'new') {
 709               $func_name .= " $class";
 710             } else {
 711               print "THIS->";
 712             }
 713           }
 714           $func_name =~ s/^\Q$args{'s'}//
 715             if exists $args{'s'};
 716           $func_name = 'XSFUNCTION' if $interface;
 717           print "$func_name($func_args);\n";
 718         }
 719       }
 720
 721       # do output variables
 722       $gotRETVAL = 0;           # 1 if RETVAL seen in OUTPUT section;
 723       undef $RETVAL_code ;      # code to set RETVAL (from OUTPUT section);
 724       # $wantRETVAL set if 'RETVAL =' autogenerated
 725       ($wantRETVAL, $ret_type) = (0, 'void') if $RETVAL_no_return;
 726       undef %outargs ;
 727       process_keyword("POSTCALL|OUTPUT|ALIAS|ATTRS|PROTOTYPE|OVERLOAD");
 728
 729       &generate_output($var_types{$_}, $args_match{$_}, $_, $DoSetMagic)
 730         for grep $in_out{$_} =~ /OUT$/, keys %in_out;
 731
 732       # all OUTPUT done, so now push the return value on the stack
 733       if ($gotRETVAL && $RETVAL_code) {
 734         print "\t$RETVAL_code\n";
 735       } elsif ($gotRETVAL || $wantRETVAL) {
 736         my $t = $WantOptimize && $targetable{$type_kind{$ret_type}};
 737         my $var = 'RETVAL';
 738         my $type = $ret_type;
 739
 740         # 0: type, 1: with_size, 2: how, 3: how_size
 741         if ($t and not $t->[1] and $t->[0] eq 'p') {
 742           # PUSHp corresponds to setpvn.  Treate setpv directly
 743           my $what = eval qq("$t->[2]");
 744           warn $@ if $@;
 745
 746           print "\tsv_setpv(TARG, $what); XSprePUSH; PUSHTARG;\n";
 747           $prepush_done = 1;
 748         }
 749         elsif ($t) {
 750           my $what = eval qq("$t->[2]");
 751           warn $@ if $@;
 752
 753           my $size = $t->[3];
 754           $size = '' unless defined $size;
 755           $size = eval qq("$size");
 756           warn $@ if $@;
 757           print "\tXSprePUSH; PUSH$t->[0]($what$size);\n";
 758           $prepush_done = 1;
 759         }
 760         else {
 761           # RETVAL almost never needs SvSETMAGIC()
 762           &generate_output($ret_type, 0, 'RETVAL', 0);
 763         }
 764       }
 765
 766       $xsreturn = 1 if $ret_type ne "void";
 767       my $num = $xsreturn;
 768       my $c = @outlist;
 769       print "\tXSprePUSH;" if $c and not $prepush_done;
 770       print "\tEXTEND(SP,$c);\n" if $c;
 771       $xsreturn += $c;
 772       generate_output($var_types{$_}, $num++, $_, 0, 1) for @outlist;
 773
 774       # do cleanup
 775       process_keyword("CLEANUP|ALIAS|ATTRS|PROTOTYPE|OVERLOAD") ;
 776
 777       print Q(<<"EOF") if $ScopeThisXSUB;
 778 #   ]]
 779 EOF
 780       print Q(<<"EOF") if $ScopeThisXSUB and not $PPCODE;
 781 #   LEAVE;
 782 EOF
 783
 784       # print function trailer
 785       print Q(<<"EOF");
 786 #    ]]
 787 EOF
 788       print Q(<<"EOF") if $except;
 789 #    BEGHANDLERS
 790 #    CATCHALL
 791 #       sprintf(errbuf, "%s: %s\\tpropagated", Xname, Xreason);
 792 #    ENDHANDLERS
 793 EOF
 794       if (check_keyword("CASE")) {
 795         blurt ("Error: No `CASE:' at top of function")
 796           unless $condnum;
 797         $_ = "CASE: $_";        # Restore CASE: label
 798         next;
 799       }
 800       last if $_ eq "$END:";
 801       death(/^$BLOCK_re/o ? "Misplaced `$1:'" : "Junk at end of function");
 802     }
 803
 804     print Q(<<"EOF") if $except;
 805 #    if (errbuf[0])
 806 #       Perl_croak(aTHX_ errbuf);
 807 EOF
 808
 809     if ($xsreturn) {
 810       print Q(<<"EOF") unless $PPCODE;
 811 #    XSRETURN($xsreturn);
 812 EOF
 813     } else {
 814       print Q(<<"EOF") unless $PPCODE;
 815 #    XSRETURN_EMPTY;
 816 EOF
 817     }
 818
 819     print Q(<<"EOF");
 820 #]]
 821 #
 822 EOF
 823
 824     my $newXS = "newXS" ;
 825     my $proto = "" ;
 826
 827     # Build the prototype string for the xsub
 828     if ($ProtoThisXSUB) {
 829       $newXS = "newXSproto";
 830
 831       if ($ProtoThisXSUB eq 2) {
 832         # User has specified empty prototype
 833       }
 834       elsif ($ProtoThisXSUB eq 1) {
 835         my $s = ';';
 836         if ($min_args < $num_args)  {
 837           $s = '';
 838           $proto_arg[$min_args] .= ";" ;
 839         }
 840         push @proto_arg, "$s\@"
 841           if $elipsis ;
 842
 843         $proto = join ("", grep defined, @proto_arg);
 844       }
 845       else {
 846         # User has specified a prototype
 847         $proto = $ProtoThisXSUB;
 848       }
 849       $proto = qq{, "$proto"};
 850     }
 851
 852     if (%XsubAliases) {
 853       $XsubAliases{$pname} = 0
 854         unless defined $XsubAliases{$pname} ;
 855       while ( ($name, $value) = each %XsubAliases) {
 856         push(@InitFileCode, Q(<<"EOF"));
 857 #        cv = newXS(\"$name\", XS_$Full_func_name, file);
 858 #        XSANY.any_i32 = $value ;
 859 EOF
 860         push(@InitFileCode, Q(<<"EOF")) if $proto;
 861 #        sv_setpv((SV*)cv$proto) ;
 862 EOF
 863       }
 864     }
 865     elsif (@Attributes) {
 866       push(@InitFileCode, Q(<<"EOF"));
 867 #        cv = newXS(\"$pname\", XS_$Full_func_name, file);
 868 #        apply_attrs_string("$Package", cv, "@Attributes", 0);
 869 EOF
 870     }
 871     elsif ($interface) {
 872       while ( ($name, $value) = each %Interfaces) {
 873         $name = "$Package\::$name" unless $name =~ /::/;
 874         push(@InitFileCode, Q(<<"EOF"));
 875 #        cv = newXS(\"$name\", XS_$Full_func_name, file);
 876 #        $interface_macro_set(cv,$value) ;
 877 EOF
 878         push(@InitFileCode, Q(<<"EOF")) if $proto;
 879 #        sv_setpv((SV*)cv$proto) ;
 880 EOF
 881       }
 882     }
 883     else {
 884       push(@InitFileCode,
 885            "        ${newXS}(\"$pname\", XS_$Full_func_name, file$proto);\n");
 886     }
 887   }
 888
 889   if ($Overload) # make it findable with fetchmethod
 890   {
 891     print Q(<<"EOF");
 892 #XS(XS_${Packid}_nil); /* prototype to pass -Wmissing-prototypes */
 893 #XS(XS_${Packid}_nil)
 894 #{
 895 #   XSRETURN_EMPTY;
 896 #}
 897 #
 898 EOF
 899     unshift(@InitFileCode, <<"MAKE_FETCHMETHOD_WORK");
 900     /* Making a sub named "${Package}::()" allows the package */
 901     /* to be findable via fetchmethod(), and causes */
 902     /* overload::Overloaded("${Package}") to return true. */
 903     newXS("${Package}::()", XS_${Packid}_nil, file$proto);
 904 MAKE_FETCHMETHOD_WORK
 905   }
 906
 907   # print initialization routine
 908
 909   print Q(<<"EOF");
 910 ##ifdef __cplusplus
 911 #extern "C"
 912 ##endif
 913 EOF
 914
 915   print Q(<<"EOF");
 916 #XS(boot_$Module_cname); /* prototype to pass -Wmissing-prototypes */
 917 #XS(boot_$Module_cname)
 918 EOF
 919
 920   print Q(<<"EOF");
 921 #[[
 922 #    dXSARGS;
 923 EOF
 924
 925   #-Wall: if there is no $Full_func_name there are no xsubs in this .xs
 926   #so `file' is unused
 927   print Q(<<"EOF") if $Full_func_name;
 928 #    char* file = __FILE__;
 929 EOF
 930
 931   print Q("#\n");
 932
 933   print Q(<<"EOF");
 934 #    PERL_UNUSED_VAR(cv); /* -W */
 935 #    PERL_UNUSED_VAR(items); /* -W */
 936 EOF
 937
 938   print Q(<<"EOF") if $WantVersionChk ;
 939 #    XS_VERSION_BOOTCHECK ;
 940 #
 941 EOF
 942
 943   print Q(<<"EOF") if defined $XsubAliases or defined $Interfaces ;
 944 #    {
 945 #        CV * cv ;
 946 #
 947 EOF
 948
 949   print Q(<<"EOF") if ($Overload);
 950 #    /* register the overloading (type 'A') magic */
 951 #    PL_amagic_generation++;
 952 #    /* The magic for overload gets a GV* via gv_fetchmeth as */
 953 #    /* mentioned above, and looks in the SV* slot of it for */
 954 #    /* the "fallback" status. */
 955 #    sv_setsv(
 956 #        get_sv( "${Package}::()", TRUE ),
 957 #        $Fallback
 958 #    );
 959 EOF
 960
 961   print @InitFileCode;
 962
 963   print Q(<<"EOF") if defined $XsubAliases or defined $Interfaces ;
 964 #    }
 965 EOF
 966
 967   if (@BootCode)
 968   {
 969     print "\n    /* Initialisation Section */\n\n" ;
 970     @line = @BootCode;
 971     print_section();
 972     print "\n    /* End of Initialisation Section */\n\n" ;
 973   }
 974
 975   print Q(<<"EOF");
 976 #    XSRETURN_YES;
 977 #]]
 978 #
 979 EOF
 980
 981   warn("Please specify prototyping behavior for $filename (see perlxs manual)\n")
 982     unless $ProtoUsed ;
 983
 984   chdir($orig_cwd);
 985   select($orig_fh);
 986   untie *PSEUDO_STDOUT if tied *PSEUDO_STDOUT;
 987
 988   return 1;
 989 }
 990
 991 sub errors { $errors }
 992
 993 sub standard_typemap_locations {
 994   # Add all the default typemap locations to the search path
 995   my @tm = qw(typemap);
 996
 997   my $updir = File::Spec->updir;
 998   foreach my $dir (File::Spec->catdir(($updir) x 1), File::Spec->catdir(($updir) x 2),
 999                    File::Spec->catdir(($updir) x 3), File::Spec->catdir(($updir) x 4)) {
1000
1001     unshift @tm, File::Spec->catfile($dir, 'typemap');
1002     unshift @tm, File::Spec->catfile($dir, lib => ExtUtils => 'typemap');
1003   }
1004   foreach my $dir (@INC) {
1005     my $file = File::Spec->catfile($dir, ExtUtils => 'typemap');
1006     unshift @tm, $file if -e $file;
1007   }
1008   return @tm;
1009 }
1010
1011 sub TrimWhitespace
1012 {
1013   $_[0] =~ s/^\s+|\s+$//go ;
1014 }
1015
1016 sub TidyType
1017   {
1018     local ($_) = @_ ;
1019
1020     # rationalise any '*' by joining them into bunches and removing whitespace
1021     s#\s*(\*+)\s*#$1#g;
1022     s#(\*+)# $1 #g ;
1023
1024     # change multiple whitespace into a single space
1025     s/\s+/ /g ;
1026
1027     # trim leading & trailing whitespace
1028     TrimWhitespace($_) ;
1029
1030     $_ ;
1031 }
1032
1033 # Input:  ($_, @line) == unparsed input.
1034 # Output: ($_, @line) == (rest of line, following lines).
1035 # Return: the matched keyword if found, otherwise 0
1036 sub check_keyword {
1037         $_ = shift(@line) while !/\S/ && @line;
1038         s/^(\s*)($_[0])\s*:\s*(?:#.*)?/$1/s && $2;
1039 }
1040
1041 sub print_section {
1042     # the "do" is required for right semantics
1043     do { $_ = shift(@line) } while !/\S/ && @line;
1044
1045     print("#line ", $line_no[@line_no - @line -1], " \"$filepathname\"\n")
1046         if $WantLineNumbers && !/^\s*#\s*line\b/ && !/^#if XSubPPtmp/;
1047     for (;  defined($_) && !/^$BLOCK_re/o;  $_ = shift(@line)) {
1048         print "$_\n";
1049     }
1050     print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $WantLineNumbers;
1051 }
1052
1053 sub merge_section {
1054     my $in = '';
1055
1056     while (!/\S/ && @line) {
1057       $_ = shift(@line);
1058     }
1059
1060     for (;  defined($_) && !/^$BLOCK_re/o;  $_ = shift(@line)) {
1061       $in .= "$_\n";
1062     }
1063     chomp $in;
1064     return $in;
1065   }
1066
1067 sub process_keyword($)
1068   {
1069     my($pattern) = @_ ;
1070     my $kwd ;
1071
1072     &{"${kwd}_handler"}()
1073       while $kwd = check_keyword($pattern) ;
1074   }
1075
1076 sub CASE_handler {
1077   blurt ("Error: `CASE:' after unconditional `CASE:'")
1078     if $condnum && $cond eq '';
1079   $cond = $_;
1080   TrimWhitespace($cond);
1081   print "   ", ($condnum++ ? " else" : ""), ($cond ? " if ($cond)\n" : "\n");
1082   $_ = '' ;
1083 }
1084
1085 sub INPUT_handler {
1086   for (;  !/^$BLOCK_re/o;  $_ = shift(@line)) {
1087     last if /^\s*NOT_IMPLEMENTED_YET/;
1088     next unless /\S/;           # skip blank lines
1089
1090     TrimWhitespace($_) ;
1091     my $line = $_ ;
1092
1093     # remove trailing semicolon if no initialisation
1094     s/\s*;$//g unless /[=;+].*\S/ ;
1095
1096     # Process the length(foo) declarations
1097     if (s/^([^=]*)\blength\(\s*(\w+)\s*\)\s*$/$1 XSauto_length_of_$2=NO_INIT/x) {
1098       print "\tSTRLEN\tSTRLEN_length_of_$2;\n";
1099       $lengthof{$2} = $name;
1100       # $islengthof{$name} = $1;
1101       $deferred .= "\n\tXSauto_length_of_$2 = STRLEN_length_of_$2;";
1102     }
1103
1104     # check for optional initialisation code
1105     my $var_init = '' ;
1106     $var_init = $1 if s/\s*([=;+].*)$//s ;
1107     $var_init =~ s/"/\\"/g;
1108
1109     s/\s+/ /g;
1110     my ($var_type, $var_addr, $var_name) = /^(.*?[^&\s])\s*(\&?)\s*\b(\w+)$/s
1111       or blurt("Error: invalid argument declaration '$line'"), next;
1112
1113     # Check for duplicate definitions
1114     blurt ("Error: duplicate definition of argument '$var_name' ignored"), next
1115       if $arg_list{$var_name}++
1116         or defined $argtype_seen{$var_name} and not $processing_arg_with_types;
1117
1118     $thisdone |= $var_name eq "THIS";
1119     $retvaldone |= $var_name eq "RETVAL";
1120     $var_types{$var_name} = $var_type;
1121     # XXXX This check is a safeguard against the unfinished conversion of
1122     # generate_init().  When generate_init() is fixed,
1123     # one can use 2-args map_type() unconditionally.
1124     if ($var_type =~ / \( \s* \* \s* \) /x) {
1125       # Function pointers are not yet supported with &output_init!
1126       print "\t" . &map_type($var_type, $var_name);
1127       $name_printed = 1;
1128     } else {
1129       print "\t" . &map_type($var_type);
1130       $name_printed = 0;
1131     }
1132     $var_num = $args_match{$var_name};
1133
1134     $proto_arg[$var_num] = ProtoString($var_type)
1135       if $var_num ;
1136     $func_args =~ s/\b($var_name)\b/&$1/ if $var_addr;
1137     if ($var_init =~ /^[=;]\s*NO_INIT\s*;?\s*$/
1138         or $in_out{$var_name} and $in_out{$var_name} =~ /^OUT/
1139         and $var_init !~ /\S/) {
1140       if ($name_printed) {
1141         print ";\n";
1142       } else {
1143         print "\t$var_name;\n";
1144       }
1145     } elsif ($var_init =~ /\S/) {
1146       &output_init($var_type, $var_num, $var_name, $var_init, $name_printed);
1147     } elsif ($var_num) {
1148       # generate initialization code
1149       &generate_init($var_type, $var_num, $var_name, $name_printed);
1150     } else {
1151       print ";\n";
1152     }
1153   }
1154 }
1155
1156 sub OUTPUT_handler {
1157   for (;  !/^$BLOCK_re/o;  $_ = shift(@line)) {
1158     next unless /\S/;
1159     if (/^\s*SETMAGIC\s*:\s*(ENABLE|DISABLE)\s*/) {
1160       $DoSetMagic = ($1 eq "ENABLE" ? 1 : 0);
1161       next;
1162     }
1163     my ($outarg, $outcode) = /^\s*(\S+)\s*(.*?)\s*$/s ;
1164     blurt ("Error: duplicate OUTPUT argument '$outarg' ignored"), next
1165       if $outargs{$outarg} ++ ;
1166     if (!$gotRETVAL and $outarg eq 'RETVAL') {
1167       # deal with RETVAL last
1168       $RETVAL_code = $outcode ;
1169       $gotRETVAL = 1 ;
1170       next ;
1171     }
1172     blurt ("Error: OUTPUT $outarg not an argument"), next
1173       unless defined($args_match{$outarg});
1174     blurt("Error: No input definition for OUTPUT argument '$outarg' - ignored"), next
1175       unless defined $var_types{$outarg} ;
1176     $var_num = $args_match{$outarg};
1177     if ($outcode) {
1178       print "\t$outcode\n";
1179       print "\tSvSETMAGIC(ST(" , $var_num-1 , "));\n" if $DoSetMagic;
1180     } else {
1181       &generate_output($var_types{$outarg}, $var_num, $outarg, $DoSetMagic);
1182     }
1183     delete $in_out{$outarg}     # No need to auto-OUTPUT
1184       if exists $in_out{$outarg} and $in_out{$outarg} =~ /OUT$/;
1185   }
1186 }
1187
1188 sub C_ARGS_handler() {
1189   my $in = merge_section();
1190
1191   TrimWhitespace($in);
1192   $func_args = $in;
1193 }
1194
1195 sub INTERFACE_MACRO_handler() {
1196   my $in = merge_section();
1197
1198   TrimWhitespace($in);
1199   if ($in =~ /\s/) {            # two
1200     ($interface_macro, $interface_macro_set) = split ' ', $in;
1201   } else {
1202     $interface_macro = $in;
1203     $interface_macro_set = 'UNKNOWN_CVT'; # catch later
1204   }
1205   $interface = 1;               # local
1206   $Interfaces = 1;              # global
1207 }
1208
1209 sub INTERFACE_handler() {
1210   my $in = merge_section();
1211
1212   TrimWhitespace($in);
1213
1214   foreach (split /[\s,]+/, $in) {
1215     $Interfaces{$_} = $_;
1216   }
1217   print Q(<<"EOF");
1218 #       XSFUNCTION = $interface_macro($ret_type,cv,XSANY.any_dptr);
1219 EOF
1220   $interface = 1;               # local
1221   $Interfaces = 1;              # global
1222 }
1223
1224 sub CLEANUP_handler() { print_section() }
1225 sub PREINIT_handler() { print_section() }
1226 sub POSTCALL_handler() { print_section() }
1227 sub INIT_handler()    { print_section() }
1228
1229 sub GetAliases
1230   {
1231     my ($line) = @_ ;
1232     my ($orig) = $line ;
1233     my ($alias) ;
1234     my ($value) ;
1235
1236     # Parse alias definitions
1237     # format is
1238     #    alias = value alias = value ...
1239
1240     while ($line =~ s/^\s*([\w:]+)\s*=\s*(\w+)\s*//) {
1241       $alias = $1 ;
1242       $orig_alias = $alias ;
1243       $value = $2 ;
1244
1245       # check for optional package definition in the alias
1246       $alias = $Packprefix . $alias if $alias !~ /::/ ;
1247
1248       # check for duplicate alias name & duplicate value
1249       Warn("Warning: Ignoring duplicate alias '$orig_alias'")
1250         if defined $XsubAliases{$alias} ;
1251
1252       Warn("Warning: Aliases '$orig_alias' and '$XsubAliasValues{$value}' have identical values")
1253         if $XsubAliasValues{$value} ;
1254
1255       $XsubAliases = 1;
1256       $XsubAliases{$alias} = $value ;
1257       $XsubAliasValues{$value} = $orig_alias ;
1258     }
1259
1260     blurt("Error: Cannot parse ALIAS definitions from '$orig'")
1261       if $line ;
1262   }
1263
1264 sub ATTRS_handler ()
1265   {
1266     for (;  !/^$BLOCK_re/o;  $_ = shift(@line)) {
1267       next unless /\S/;
1268       TrimWhitespace($_) ;
1269       push @Attributes, $_;
1270     }
1271   }
1272
1273 sub ALIAS_handler ()
1274   {
1275     for (;  !/^$BLOCK_re/o;  $_ = shift(@line)) {
1276       next unless /\S/;
1277       TrimWhitespace($_) ;
1278       GetAliases($_) if $_ ;
1279     }
1280   }
1281
1282 sub OVERLOAD_handler()
1283 {
1284   for (;  !/^$BLOCK_re/o;  $_ = shift(@line)) {
1285     next unless /\S/;
1286     TrimWhitespace($_) ;
1287     while ( s/^\s*([\w:"\\)\+\-\*\/\%\<\>\.\&\|\^\!\~\{\}\=]+)\s*//) {
1288       $Overload = 1 unless $Overload;
1289       my $overload = "$Package\::(".$1 ;
1290       push(@InitFileCode,
1291            "        newXS(\"$overload\", XS_$Full_func_name, file$proto);\n");
1292     }
1293   }
1294 }
1295
1296 sub FALLBACK_handler()
1297 {
1298   # the rest of the current line should contain either TRUE,
1299   # FALSE or UNDEF
1300
1301   TrimWhitespace($_) ;
1302   my %map = (
1303              TRUE => "PL_sv_yes", 1 => "PL_sv_yes",
1304              FALSE => "PL_sv_no", 0 => "PL_sv_no",
1305              UNDEF => "PL_sv_undef",
1306             ) ;
1307
1308   # check for valid FALLBACK value
1309   death ("Error: FALLBACK: TRUE/FALSE/UNDEF") unless exists $map{uc $_} ;
1310
1311   $Fallback = $map{uc $_} ;
1312 }
1313
1314
1315 sub REQUIRE_handler ()
1316   {
1317     # the rest of the current line should contain a version number
1318     my ($Ver) = $_ ;
1319
1320     TrimWhitespace($Ver) ;
1321
1322     death ("Error: REQUIRE expects a version number")
1323       unless $Ver ;
1324
1325     # check that the version number is of the form n.n
1326     death ("Error: REQUIRE: expected a number, got '$Ver'")
1327       unless $Ver =~ /^\d+(\.\d*)?/ ;
1328
1329     death ("Error: xsubpp $Ver (or better) required--this is only $VERSION.")
1330       unless $VERSION >= $Ver ;
1331   }
1332
1333 sub VERSIONCHECK_handler ()
1334   {
1335     # the rest of the current line should contain either ENABLE or
1336     # DISABLE
1337
1338     TrimWhitespace($_) ;
1339
1340     # check for ENABLE/DISABLE
1341     death ("Error: VERSIONCHECK: ENABLE/DISABLE")
1342       unless /^(ENABLE|DISABLE)/i ;
1343
1344     $WantVersionChk = 1 if $1 eq 'ENABLE' ;
1345     $WantVersionChk = 0 if $1 eq 'DISABLE' ;
1346
1347   }
1348
1349 sub PROTOTYPE_handler ()
1350   {
1351     my $specified ;
1352
1353     death("Error: Only 1 PROTOTYPE definition allowed per xsub")
1354       if $proto_in_this_xsub ++ ;
1355
1356     for (;  !/^$BLOCK_re/o;  $_ = shift(@line)) {
1357       next unless /\S/;
1358       $specified = 1 ;
1359       TrimWhitespace($_) ;
1360       if ($_ eq 'DISABLE') {
1361         $ProtoThisXSUB = 0
1362       } elsif ($_ eq 'ENABLE') {
1363         $ProtoThisXSUB = 1
1364       } else {
1365         # remove any whitespace
1366         s/\s+//g ;
1367         death("Error: Invalid prototype '$_'")
1368           unless ValidProtoString($_) ;
1369         $ProtoThisXSUB = C_string($_) ;
1370       }
1371     }
1372
1373     # If no prototype specified, then assume empty prototype ""
1374     $ProtoThisXSUB = 2 unless $specified ;
1375
1376     $ProtoUsed = 1 ;
1377
1378   }
1379
1380 sub SCOPE_handler ()
1381   {
1382     death("Error: Only 1 SCOPE declaration allowed per xsub")
1383       if $scope_in_this_xsub ++ ;
1384
1385     for (;  !/^$BLOCK_re/o;  $_ = shift(@line)) {
1386       next unless /\S/;
1387       TrimWhitespace($_) ;
1388       if ($_ =~ /^DISABLE/i) {
1389         $ScopeThisXSUB = 0
1390       } elsif ($_ =~ /^ENABLE/i) {
1391         $ScopeThisXSUB = 1
1392       }
1393     }
1394
1395   }
1396
1397 sub PROTOTYPES_handler ()
1398   {
1399     # the rest of the current line should contain either ENABLE or
1400     # DISABLE
1401
1402     TrimWhitespace($_) ;
1403
1404     # check for ENABLE/DISABLE
1405     death ("Error: PROTOTYPES: ENABLE/DISABLE")
1406       unless /^(ENABLE|DISABLE)/i ;
1407
1408     $WantPrototypes = 1 if $1 eq 'ENABLE' ;
1409     $WantPrototypes = 0 if $1 eq 'DISABLE' ;
1410     $ProtoUsed = 1 ;
1411
1412   }
1413
1414 sub INCLUDE_handler ()
1415   {
1416     # the rest of the current line should contain a valid filename
1417
1418     TrimWhitespace($_) ;
1419
1420     death("INCLUDE: filename missing")
1421       unless $_ ;
1422
1423     death("INCLUDE: output pipe is illegal")
1424       if /^\s*\|/ ;
1425
1426     # simple minded recursion detector
1427     death("INCLUDE loop detected")
1428       if $IncludedFiles{$_} ;
1429
1430     ++ $IncludedFiles{$_} unless /\|\s*$/ ;
1431
1432     # Save the current file context.
1433     push(@XSStack, {
1434                     type                => 'file',
1435                     LastLine        => $lastline,
1436                     LastLineNo      => $lastline_no,
1437                     Line            => \@line,
1438                     LineNo          => \@line_no,
1439                     Filename        => $filename,
1440                     Handle          => $FH,
1441                    }) ;
1442
1443     ++ $FH ;
1444
1445     # open the new file
1446     open ($FH, "$_") or death("Cannot open '$_': $!") ;
1447
1448     print Q(<<"EOF");
1449 #
1450 #/* INCLUDE:  Including '$_' from '$filename' */
1451 #
1452 EOF
1453
1454     $filename = $_ ;
1455
1456     # Prime the pump by reading the first
1457     # non-blank line
1458
1459     # skip leading blank lines
1460     while (<$FH>) {
1461       last unless /^\s*$/ ;
1462     }
1463
1464     $lastline = $_ ;
1465     $lastline_no = $. ;
1466
1467   }
1468
1469 sub PopFile()
1470   {
1471     return 0 unless $XSStack[-1]{type} eq 'file' ;
1472
1473     my $data     = pop @XSStack ;
1474     my $ThisFile = $filename ;
1475     my $isPipe   = ($filename =~ /\|\s*$/) ;
1476
1477     -- $IncludedFiles{$filename}
1478       unless $isPipe ;
1479
1480     close $FH ;
1481
1482     $FH         = $data->{Handle} ;
1483     $filename   = $data->{Filename} ;
1484     $lastline   = $data->{LastLine} ;
1485     $lastline_no = $data->{LastLineNo} ;
1486     @line       = @{ $data->{Line} } ;
1487     @line_no    = @{ $data->{LineNo} } ;
1488
1489     if ($isPipe and $? ) {
1490       -- $lastline_no ;
1491       print STDERR "Error reading from pipe '$ThisFile': $! in $filename, line $lastline_no\n"  ;
1492       exit 1 ;
1493     }
1494
1495     print Q(<<"EOF");
1496 #
1497 #/* INCLUDE: Returning to '$filename' from '$ThisFile' */
1498 #
1499 EOF
1500
1501     return 1 ;
1502   }
1503
1504 sub ValidProtoString ($)
1505   {
1506     my($string) = @_ ;
1507
1508     if ( $string =~ /^$proto_re+$/ ) {
1509       return $string ;
1510     }
1511
1512     return 0 ;
1513   }
1514
1515 sub C_string ($)
1516   {
1517     my($string) = @_ ;
1518
1519     $string =~ s[\\][\\\\]g ;
1520     $string ;
1521   }
1522
1523 sub ProtoString ($)
1524   {
1525     my ($type) = @_ ;
1526
1527     $proto_letter{$type} or "\$" ;
1528   }
1529
1530 sub check_cpp {
1531   my @cpp = grep(/^\#\s*(?:if|e\w+)/, @line);
1532   if (@cpp) {
1533     my ($cpp, $cpplevel);
1534     for $cpp (@cpp) {
1535       if ($cpp =~ /^\#\s*if/) {
1536         $cpplevel++;
1537       } elsif (!$cpplevel) {
1538         Warn("Warning: #else/elif/endif without #if in this function");
1539         print STDERR "    (precede it with a blank line if the matching #if is outside the function)\n"
1540           if $XSStack[-1]{type} eq 'if';
1541         return;
1542       } elsif ($cpp =~ /^\#\s*endif/) {
1543         $cpplevel--;
1544       }
1545     }
1546     Warn("Warning: #if without #endif in this function") if $cpplevel;
1547   }
1548 }
1549
1550
1551 sub Q {
1552   my($text) = @_;
1553   $text =~ s/^#//gm;
1554   $text =~ s/\[\[/{/g;
1555   $text =~ s/\]\]/}/g;
1556   $text;
1557 }
1558
1559 # Read next xsub into @line from ($lastline, <$FH>).
1560 sub fetch_para {
1561   # parse paragraph
1562   death ("Error: Unterminated `#if/#ifdef/#ifndef'")
1563     if !defined $lastline && $XSStack[-1]{type} eq 'if';
1564   @line = ();
1565   @line_no = () ;
1566   return PopFile() if !defined $lastline;
1567
1568   if ($lastline =~
1569       /^MODULE\s*=\s*([\w:]+)(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/) {
1570     $Module = $1;
1571     $Package = defined($2) ? $2 : ''; # keep -w happy
1572     $Prefix  = defined($3) ? $3 : ''; # keep -w happy
1573     $Prefix = quotemeta $Prefix ;
1574     ($Module_cname = $Module) =~ s/\W/_/g;
1575     ($Packid = $Package) =~ tr/:/_/;
1576     $Packprefix = $Package;
1577     $Packprefix .= "::" if $Packprefix ne "";
1578     $lastline = "";
1579   }
1580
1581   for (;;) {
1582     # Skip embedded PODs
1583     while ($lastline =~ /^=/) {
1584       while ($lastline = <$FH>) {
1585         last if ($lastline =~ /^=cut\s*$/);
1586       }
1587       death ("Error: Unterminated pod") unless $lastline;
1588       $lastline = <$FH>;
1589       chomp $lastline;
1590       $lastline =~ s/^\s+$//;
1591     }
1592     if ($lastline !~ /^\s*#/ ||
1593         # CPP directives:
1594         #       ANSI:   if ifdef ifndef elif else endif define undef
1595         #               line error pragma
1596         #       gcc:    warning include_next
1597         #   obj-c:      import
1598         #   others:     ident (gcc notes that some cpps have this one)
1599         $lastline =~ /^#[ \t]*(?:(?:if|ifn?def|elif|else|endif|define|undef|pragma|error|warning|line\s+\d+|ident)\b|(?:include(?:_next)?|import)\s*["<].*[>"])/) {
1600       last if $lastline =~ /^\S/ && @line && $line[-1] eq "";
1601       push(@line, $lastline);
1602       push(@line_no, $lastline_no) ;
1603     }
1604
1605     # Read next line and continuation lines
1606     last unless defined($lastline = <$FH>);
1607     $lastline_no = $.;
1608     my $tmp_line;
1609     $lastline .= $tmp_line
1610       while ($lastline =~ /\\$/ && defined($tmp_line = <$FH>));
1611
1612     chomp $lastline;
1613     $lastline =~ s/^\s+$//;
1614   }
1615   pop(@line), pop(@line_no) while @line && $line[-1] eq "";
1616   1;
1617 }
1618
1619 sub output_init {
1620   local($type, $num, $var, $init, $name_printed) = @_;
1621   local($arg) = "ST(" . ($num - 1) . ")";
1622
1623   if (  $init =~ /^=/  ) {
1624     if ($name_printed) {
1625       eval qq/print " $init\\n"/;
1626     } else {
1627       eval qq/print "\\t$var $init\\n"/;
1628     }
1629     warn $@   if  $@;
1630   } else {
1631     if (  $init =~ s/^\+//  &&  $num  ) {
1632       &generate_init($type, $num, $var, $name_printed);
1633     } elsif ($name_printed) {
1634       print ";\n";
1635       $init =~ s/^;//;
1636     } else {
1637       eval qq/print "\\t$var;\\n"/;
1638       warn $@   if  $@;
1639       $init =~ s/^;//;
1640     }
1641     $deferred .= eval qq/"\\n\\t$init\\n"/;
1642     warn $@   if  $@;
1643   }
1644 }
1645
1646 sub Warn
1647   {
1648     # work out the line number
1649     my $line_no = $line_no[@line_no - @line -1] ;
1650
1651     print STDERR "@_ in $filename, line $line_no\n" ;
1652   }
1653
1654 sub blurt
1655   {
1656     Warn @_ ;
1657     $errors ++
1658   }
1659
1660 sub death
1661   {
1662     Warn @_ ;
1663     exit 1 ;
1664   }
1665
1666 sub generate_init {
1667   local($type, $num, $var) = @_;
1668   local($arg) = "ST(" . ($num - 1) . ")";
1669   local($argoff) = $num - 1;
1670   local($ntype);
1671   local($tk);
1672
1673   $type = TidyType($type) ;
1674   blurt("Error: '$type' not in typemap"), return
1675     unless defined($type_kind{$type});
1676
1677   ($ntype = $type) =~ s/\s*\*/Ptr/g;
1678   ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1679   $tk = $type_kind{$type};
1680   $tk =~ s/OBJ$/REF/ if $func_name =~ /DESTROY$/;
1681   if ($tk eq 'T_PV' and exists $lengthof{$var}) {
1682     print "\t$var" unless $name_printed;
1683     print " = ($type)SvPV($arg, STRLEN_length_of_$var);\n";
1684     die "default value not supported with length(NAME) supplied"
1685       if defined $defaults{$var};
1686     return;
1687   }
1688   $type =~ tr/:/_/ unless $hiertype;
1689   blurt("Error: No INPUT definition for type '$type', typekind '$type_kind{$type}' found"), return
1690     unless defined $input_expr{$tk} ;
1691   $expr = $input_expr{$tk};
1692   if ($expr =~ /DO_ARRAY_ELEM/) {
1693     blurt("Error: '$subtype' not in typemap"), return
1694       unless defined($type_kind{$subtype});
1695     blurt("Error: No INPUT definition for type '$subtype', typekind '$type_kind{$subtype}' found"), return
1696       unless defined $input_expr{$type_kind{$subtype}} ;
1697     $subexpr = $input_expr{$type_kind{$subtype}};
1698     $subexpr =~ s/\$type/\$subtype/g;
1699     $subexpr =~ s/ntype/subtype/g;
1700     $subexpr =~ s/\$arg/ST(ix_$var)/g;
1701     $subexpr =~ s/\n\t/\n\t\t/g;
1702     $subexpr =~ s/is not of (.*\")/[arg %d] is not of $1, ix_$var + 1/g;
1703     $subexpr =~ s/\$var/${var}[ix_$var - $argoff]/;
1704     $expr =~ s/DO_ARRAY_ELEM/$subexpr/;
1705   }
1706   if ($expr =~ m#/\*.*scope.*\*/#i) {  # "scope" in C comments
1707     $ScopeThisXSUB = 1;
1708   }
1709   if (defined($defaults{$var})) {
1710     $expr =~ s/(\t+)/$1    /g;
1711     $expr =~ s/        /\t/g;
1712     if ($name_printed) {
1713       print ";\n";
1714     } else {
1715       eval qq/print "\\t$var;\\n"/;
1716       warn $@   if  $@;
1717     }
1718     if ($defaults{$var} eq 'NO_INIT') {
1719       $deferred .= eval qq/"\\n\\tif (items >= $num) {\\n$expr;\\n\\t}\\n"/;
1720     } else {
1721       $deferred .= eval qq/"\\n\\tif (items < $num)\\n\\t    $var = $defaults{$var};\\n\\telse {\\n$expr;\\n\\t}\\n"/;
1722     }
1723     warn $@   if  $@;
1724   } elsif ($ScopeThisXSUB or $expr !~ /^\s*\$var =/) {
1725     if ($name_printed) {
1726       print ";\n";
1727     } else {
1728       eval qq/print "\\t$var;\\n"/;
1729       warn $@   if  $@;
1730     }
1731     $deferred .= eval qq/"\\n$expr;\\n"/;
1732     warn $@   if  $@;
1733   } else {
1734     die "panic: do not know how to handle this branch for function pointers"
1735       if $name_printed;
1736     eval qq/print "$expr;\\n"/;
1737     warn $@   if  $@;
1738   }
1739 }
1740
1741 sub generate_output {
1742   local($type, $num, $var, $do_setmagic, $do_push) = @_;
1743   local($arg) = "ST(" . ($num - ($num != 0)) . ")";
1744   local($argoff) = $num - 1;
1745   local($ntype);
1746
1747   $type = TidyType($type) ;
1748   if ($type =~ /^array\(([^,]*),(.*)\)/) {
1749     print "\t$arg = sv_newmortal();\n";
1750     print "\tsv_setpvn($arg, (char *)$var, $2 * sizeof($1));\n";
1751     print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1752   } else {
1753     blurt("Error: '$type' not in typemap"), return
1754       unless defined($type_kind{$type});
1755     blurt("Error: No OUTPUT definition for type '$type', typekind '$type_kind{$type}' found"), return
1756       unless defined $output_expr{$type_kind{$type}} ;
1757     ($ntype = $type) =~ s/\s*\*/Ptr/g;
1758     $ntype =~ s/\(\)//g;
1759     ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1760     $expr = $output_expr{$type_kind{$type}};
1761     if ($expr =~ /DO_ARRAY_ELEM/) {
1762       blurt("Error: '$subtype' not in typemap"), return
1763         unless defined($type_kind{$subtype});
1764       blurt("Error: No OUTPUT definition for type '$subtype', typekind '$type_kind{$subtype}' found"), return
1765         unless defined $output_expr{$type_kind{$subtype}} ;
1766       $subexpr = $output_expr{$type_kind{$subtype}};
1767       $subexpr =~ s/ntype/subtype/g;
1768       $subexpr =~ s/\$arg/ST(ix_$var)/g;
1769       $subexpr =~ s/\$var/${var}[ix_$var]/g;
1770       $subexpr =~ s/\n\t/\n\t\t/g;
1771       $expr =~ s/DO_ARRAY_ELEM\n/$subexpr/;
1772       eval "print qq\a$expr\a";
1773       warn $@   if  $@;
1774       print "\t\tSvSETMAGIC(ST(ix_$var));\n" if $do_setmagic;
1775     } elsif ($var eq 'RETVAL') {
1776       if ($expr =~ /^\t\$arg = new/) {
1777         # We expect that $arg has refcnt 1, so we need to
1778         # mortalize it.
1779         eval "print qq\a$expr\a";
1780         warn $@   if  $@;
1781         print "\tsv_2mortal(ST($num));\n";
1782         print "\tSvSETMAGIC(ST($num));\n" if $do_setmagic;
1783       } elsif ($expr =~ /^\s*\$arg\s*=/) {
1784         # We expect that $arg has refcnt >=1, so we need
1785         # to mortalize it!
1786         eval "print qq\a$expr\a";
1787         warn $@   if  $@;
1788         print "\tsv_2mortal(ST(0));\n";
1789         print "\tSvSETMAGIC(ST(0));\n" if $do_setmagic;
1790       } else {
1791         # Just hope that the entry would safely write it
1792         # over an already mortalized value. By
1793         # coincidence, something like $arg = &sv_undef
1794         # works too.
1795         print "\tST(0) = sv_newmortal();\n";
1796         eval "print qq\a$expr\a";
1797         warn $@   if  $@;
1798         # new mortals don't have set magic
1799       }
1800     } elsif ($do_push) {
1801       print "\tPUSHs(sv_newmortal());\n";
1802       $arg = "ST($num)";
1803       eval "print qq\a$expr\a";
1804       warn $@   if  $@;
1805       print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1806     } elsif ($arg =~ /^ST\(\d+\)$/) {
1807       eval "print qq\a$expr\a";
1808       warn $@   if  $@;
1809       print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1810     }
1811   }
1812 }
1813
1814 sub map_type {
1815   my($type, $varname) = @_;
1816
1817   # C++ has :: in types too so skip this
1818   $type =~ tr/:/_/ unless $hiertype;
1819   $type =~ s/^array\(([^,]*),(.*)\).*/$1 */s;
1820   if ($varname) {
1821     if ($varname && $type =~ / \( \s* \* (?= \s* \) ) /xg) {
1822       (substr $type, pos $type, 0) = " $varname ";
1823     } else {
1824       $type .= "\t$varname";
1825     }
1826   }
1827   $type;
1828 }
1829
1830
1831 #########################################################
1832 package
1833   ExtUtils::ParseXS::CountLines;
1834 use strict;
1835 use vars qw($SECTION_END_MARKER);
1836
1837 sub TIEHANDLE {
1838   my ($class, $cfile, $fh) = @_;
1839   $cfile =~ s/\\/\\\\/g;
1840   $SECTION_END_MARKER = qq{#line --- "$cfile"};
1841
1842   return bless {buffer => '',
1843                 fh => $fh,
1844                 line_no => 1,
1845                }, $class;
1846 }
1847
1848 sub PRINT {
1849   my $self = shift;
1850   for (@_) {
1851     $self->{buffer} .= $_;
1852     while ($self->{buffer} =~ s/^([^\n]*\n)//) {
1853       my $line = $1;
1854       ++ $self->{line_no};
1855       $line =~ s|^\#line\s+---(?=\s)|#line $self->{line_no}|;
1856       print {$self->{fh}} $line;
1857     }
1858   }
1859 }
1860
1861 sub PRINTF {
1862   my $self = shift;
1863   my $fmt = shift;
1864   $self->PRINT(sprintf($fmt, @_));
1865 }
1866
1867 sub DESTROY {
1868   # Not necessary if we're careful to end with a "\n"
1869   my $self = shift;
1870   print {$self->{fh}} $self->{buffer};
1871 }
1872
1873 sub UNTIE {
1874   # This sub does nothing, but is neccessary for references to be released.
1875 }
1876
1877 sub end_marker {
1878   return $SECTION_END_MARKER;
1879 }
1880
1881
1882 1;
1883 __END__
1884
1885 =head1 NAME
1886
1887 ExtUtils::ParseXS - converts Perl XS code into C code
1888
1889 =head1 SYNOPSIS
1890
1891   use ExtUtils::ParseXS qw(process_file);
1892
1893   process_file( filename => 'foo.xs' );
1894
1895   process_file( filename => 'foo.xs',
1896                 output => 'bar.c',
1897                 'C++' => 1,
1898                 typemap => 'path/to/typemap',
1899                 hiertype => 1,
1900                 except => 1,
1901                 prototypes => 1,
1902                 versioncheck => 1,
1903                 linenumbers => 1,
1904                 optimize => 1,
1905                 prototypes => 1,
1906               );
1907 =head1 DESCRIPTION
1908
1909 C<ExtUtils::ParseXS> will compile XS code into C code by embedding the constructs
1910 necessary to let C functions manipulate Perl values and creates the glue
1911 necessary to let Perl access those functions.  The compiler uses typemaps to
1912 determine how to map C function parameters and variables to Perl values.
1913
1914 The compiler will search for typemap files called I<typemap>.  It will use
1915 the following search path to find default typemaps, with the rightmost
1916 typemap taking precedence.
1917
1918         ../../../typemap:../../typemap:../typemap:typemap
1919
1920 =head1 EXPORT
1921
1922 None by default.  C<process_file()> may be exported upon request.
1923
1924
1925 =head1 FUNCTIONS
1926
1927 =over 4
1928
1929 =item process_xs()
1930
1931 This function processes an XS file and sends output to a C file.
1932 Named parameters control how the processing is done.  The following
1933 parameters are accepted:
1934
1935 =over 4
1936
1937 =item B<C++>
1938
1939 Adds C<extern "C"> to the C code.  Default is false.
1940
1941 =item B<hiertype>
1942
1943 Retains C<::> in type names so that C++ hierachical types can be
1944 mapped.  Default is false.
1945
1946 =item B<except>
1947
1948 Adds exception handling stubs to the C code.  Default is false.
1949
1950 =item B<typemap>
1951
1952 Indicates that a user-supplied typemap should take precedence over the
1953 default typemaps.  A single typemap may be specified as a string, or
1954 multiple typemaps can be specified in an array reference, with the
1955 last typemap having the highest precedence.
1956
1957 =item B<prototypes>
1958
1959 Generates prototype code for all xsubs.  Default is false.
1960
1961 =item B<versioncheck>
1962
1963 Makes sure at run time that the object file (derived from the C<.xs>
1964 file) and the C<.pm> files have the same version number.  Default is
1965 true.
1966
1967 =item B<linenumbers>
1968
1969 Adds C<#line> directives to the C output so error messages will look
1970 like they came from the original XS file.  Default is true.
1971
1972 =item B<optimize>
1973
1974 Enables certain optimizations.  The only optimization that is currently
1975 affected is the use of I<target>s by the output C code (see L<perlguts>).
1976 Not optimizing may significantly slow down the generated code, but this is the way
1977 B<xsubpp> of 5.005 and earlier operated.  Default is to optimize.
1978
1979 =item B<inout>
1980
1981 Enable recognition of C<IN>, C<OUT_LIST> and C<INOUT_LIST>
1982 declarations.  Default is true.
1983
1984 =item B<argtypes>
1985
1986 Enable recognition of ANSI-like descriptions of function signature.
1987 Default is true.
1988
1989 =item B<s>
1990
1991 I have no clue what this does.  Strips function prefixes?
1992
1993 =back
1994
1995 =item errors()
1996
1997 This function returns the number of [a certain kind of] errors
1998 encountered during processing of the XS file.
1999
2000 =back
2001
2002 =head1 AUTHOR
2003
2004 Based on xsubpp code, written by Larry Wall.
2005
2006 Maintained by Ken Williams, <ken@mathforum.org>
2007
2008 =head1 COPYRIGHT
2009
2010 Copyright 2002-2003 Ken Williams.  All rights reserved.
2011
2012 This library is free software; you can redistribute it and/or
2013 modify it under the same terms as Perl itself.
2014
2015 Based on the ExtUtils::xsubpp code by Larry Wall and the Perl 5
2016 Porters, which was released under the same license terms.
2017
2018 =head1 SEE ALSO
2019
2020 L<perl>, ExtUtils::xsubpp, ExtUtils::MakeMaker, L<perlxs>, L<perlxstut>.
2021
2022 =cut