lib/ExtUtils/Mksymlists.pm

   1 package ExtUtils::Mksymlists;
   2
   3 use 5.005_64;
   4 use strict qw[ subs refs ];
   5 # no strict 'vars';  # until filehandles are exempted
   6
   7 use Carp;
   8 use Exporter;
   9 our(@ISA, @EXPORT, $VERSION);
  10 @ISA = 'Exporter';
  11 @EXPORT = '&Mksymlists';
  12 $VERSION = substr q$Revision: 1.17 $, 10;
  13
  14 sub Mksymlists {
  15     my(%spec) = @_;
  16     my($osname) = $^O;
  17
  18     croak("Insufficient information specified to Mksymlists")
  19         unless ( $spec{NAME} or
  20                  ($spec{FILE} and ($spec{DL_FUNCS} or $spec{FUNCLIST})) );
  21
  22     $spec{DL_VARS} = [] unless $spec{DL_VARS};
  23     ($spec{FILE} = $spec{NAME}) =~ s/.*::// unless $spec{FILE};
  24     $spec{FUNCLIST} = [] unless $spec{FUNCLIST};
  25     $spec{DL_FUNCS} = { $spec{NAME} => [] }
  26         unless ( ($spec{DL_FUNCS} and keys %{$spec{DL_FUNCS}}) or
  27                  @{$spec{FUNCLIST}});
  28     if (defined $spec{DL_FUNCS}) {
  29         my($package);
  30         foreach $package (keys %{$spec{DL_FUNCS}}) {
  31             my($packprefix,$sym,$bootseen);
  32             ($packprefix = $package) =~ s/\W/_/g;
  33             foreach $sym (@{$spec{DL_FUNCS}->{$package}}) {
  34                 if ($sym =~ /^boot_/) {
  35                     push(@{$spec{FUNCLIST}},$sym);
  36                     $bootseen++;
  37                 }
  38                 else { push(@{$spec{FUNCLIST}},"XS_${packprefix}_$sym"); }
  39             }
  40             push(@{$spec{FUNCLIST}},"boot_$packprefix") unless $bootseen;
  41         }
  42     }
  43
  44 #    We'll need this if we ever add any OS which uses mod2fname
  45 #    not as pseudo-builtin.
  46 #    require DynaLoader;
  47     if (defined &DynaLoader::mod2fname and not $spec{DLBASE}) {
  48         $spec{DLBASE} = DynaLoader::mod2fname([ split(/::/,$spec{NAME}) ]);
  49     }
  50
  51     if    ($osname eq 'aix') { _write_aix(\%spec); }
  52     elsif ($osname eq 'VMS') { _write_vms(\%spec) }
  53     elsif ($osname eq 'os2') { _write_os2(\%spec) }
  54     elsif ($osname eq 'MSWin32') { _write_win32(\%spec) }
  55     else { croak("Don't know how to create linker option file for $osname\n"); }
  56 }
  57
  58
  59 sub _write_aix {
  60     my($data) = @_;
  61
  62     rename "$data->{FILE}.exp", "$data->{FILE}.exp_old";
  63
  64     open(EXP,">$data->{FILE}.exp")
  65         or croak("Can't create $data->{FILE}.exp: $!\n");
  66     print EXP join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  67     print EXP join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  68     close EXP;
  69 }
  70
  71
  72 sub _write_os2 {
  73     my($data) = @_;
  74     require Config;
  75     my $threaded = ($Config::Config{archname} =~ /-thread/ ? " threaded" : "");
  76
  77     if (not $data->{DLBASE}) {
  78         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
  79         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
  80     }
  81     my $distname = $data->{DISTNAME} || $data->{NAME};
  82     $distname = "Distribution $distname";
  83     my $comment = "Perl (v$Config::Config{version}$threaded) module $data->{NAME}";
  84     if ($data->{INSTALLDIRS} and $data->{INSTALLDIRS} eq 'perl') {
  85         $distname = 'perl5-porters@perl.org';
  86         $comment = "Core $comment";
  87     }
  88     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
  89
  90     open(DEF,">$data->{FILE}.def")
  91         or croak("Can't create $data->{FILE}.def: $!\n");
  92     print DEF "LIBRARY '$data->{DLBASE}' INITINSTANCE TERMINSTANCE\n";
  93     print DEF "DESCRIPTION '\@#$distname:$data->{VERSION}#\@ $comment'\n";
  94     print DEF "CODE LOADONCALL\n";
  95     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
  96     print DEF "EXPORTS\n  ";
  97     print DEF join("\n  ",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  98     print DEF join("\n  ",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  99     if (%{$data->{IMPORTS}}) {
 100         print DEF "IMPORTS\n";
 101         my ($name, $exp);
 102         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 103             print DEF "  $name=$exp\n";
 104         }
 105     }
 106     close DEF;
 107 }
 108
 109 sub _write_win32 {
 110     my($data) = @_;
 111
 112     require Config;
 113     if (not $data->{DLBASE}) {
 114         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
 115         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
 116     }
 117     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
 118
 119     open(DEF,">$data->{FILE}.def")
 120         or croak("Can't create $data->{FILE}.def: $!\n");
 121     # put library name in quotes (it could be a keyword, like 'Alias')
 122     if ($Config::Config{'cc'} !~ /^gcc/i) {
 123       print DEF "LIBRARY \"$data->{DLBASE}\"\n";
 124     }
 125     print DEF "EXPORTS\n  ";
 126     my @syms;
 127     # Export public symbols both with and without underscores to
 128     # ensure compatibility between DLLs from different compilers
 129     # NOTE: DynaLoader itself only uses the names without underscores,
 130     # so this is only to cover the case when the extension DLL may be
 131     # linked to directly from C. GSAR 97-07-10
 132     if ($Config::Config{'cc'} =~ /^bcc/i) {
 133         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 134             push @syms, "_$_", "$_ = _$_";
 135         }
 136     }
 137     else {
 138         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 139             push @syms, "$_", "_$_ = $_";
 140         }
 141     }
 142     print DEF join("\n  ",@syms, "\n") if @syms;
 143     if (%{$data->{IMPORTS}}) {
 144         print DEF "IMPORTS\n";
 145         my ($name, $exp);
 146         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 147             print DEF "  $name=$exp\n";
 148         }
 149     }
 150     close DEF;
 151 }
 152
 153
 154 sub _write_vms {
 155     my($data) = @_;
 156
 157     require Config; # a reminder for once we do $^O
 158     require ExtUtils::XSSymSet;
 159
 160     my($isvax) = $Config::Config{'archname'} =~ /VAX/i;
 161     my($set) = new ExtUtils::XSSymSet;
 162     my($sym);
 163
 164     rename "$data->{FILE}.opt", "$data->{FILE}.opt_old";
 165
 166     open(OPT,">$data->{FILE}.opt")
 167         or croak("Can't create $data->{FILE}.opt: $!\n");
 168
 169     # Options file declaring universal symbols
 170     # Used when linking shareable image for dynamic extension,
 171     # or when linking PerlShr into which we've added this package
 172     # as a static extension
 173     # We don't do anything to preserve order, so we won't relax
 174     # the GSMATCH criteria for a dynamic extension
 175
 176     print OPT "case_sensitive=yes\n"
 177         if $Config::Config{d_vms_case_sensitive_symbols};
 178     foreach $sym (@{$data->{FUNCLIST}}) {
 179         my $safe = $set->addsym($sym);
 180         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 181         else        { print OPT "SYMBOL_VECTOR=($safe=PROCEDURE)\n"; }
 182     }
 183     foreach $sym (@{$data->{DL_VARS}}) {
 184         my $safe = $set->addsym($sym);
 185         print OPT "PSECT_ATTR=${sym},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 186         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 187         else        { print OPT "SYMBOL_VECTOR=($safe=DATA)\n"; }
 188     }
 189     close OPT;
 190
 191 }
 192
 193 1;
 194
 195 __END__
 196
 197 =head1 NAME
 198
 199 ExtUtils::Mksymlists - write linker options files for dynamic extension
 200
 201 =head1 SYNOPSIS
 202
 203     use ExtUtils::Mksymlists;
 204     Mksymlists({ NAME     => $name ,
 205                  DL_VARS  => [ $var1, $var2, $var3 ],
 206                  DL_FUNCS => { $pkg1 => [ $func1, $func2 ],
 207                                $pkg2 => [ $func3 ] });
 208
 209 =head1 DESCRIPTION
 210
 211 C<ExtUtils::Mksymlists> produces files used by the linker under some OSs
 212 during the creation of shared libraries for dynamic extensions.  It is
 213 normally called from a MakeMaker-generated Makefile when the extension
 214 is built.  The linker option file is generated by calling the function
 215 C<Mksymlists>, which is exported by default from C<ExtUtils::Mksymlists>.
 216 It takes one argument, a list of key-value pairs, in which the following
 217 keys are recognized:
 218
 219 =over
 220
 221 =item DLBASE
 222
 223 This item specifies the name by which the linker knows the
 224 extension, which may be different from the name of the
 225 extension itself (for instance, some linkers add an '_' to the
 226 name of the extension).  If it is not specified, it is derived
 227 from the NAME attribute.  It is presently used only by OS2 and Win32.
 228
 229 =item DL_FUNCS
 230
 231 This is identical to the DL_FUNCS attribute available via MakeMaker,
 232 from which it is usually taken.  Its value is a reference to an
 233 associative array, in which each key is the name of a package, and
 234 each value is an a reference to an array of function names which
 235 should be exported by the extension.  For instance, one might say
 236 C<DL_FUNCS =E<gt> { Homer::Iliad =E<gt> [ qw(trojans greeks) ],
 237 Homer::Odyssey =E<gt> [ qw(travellers family suitors) ] }>.  The
 238 function names should be identical to those in the XSUB code;
 239 C<Mksymlists> will alter the names written to the linker option
 240 file to match the changes made by F<xsubpp>.  In addition, if
 241 none of the functions in a list begin with the string B<boot_>,
 242 C<Mksymlists> will add a bootstrap function for that package,
 243 just as xsubpp does.  (If a B<boot_E<lt>pkgE<gt>> function is
 244 present in the list, it is passed through unchanged.)  If
 245 DL_FUNCS is not specified, it defaults to the bootstrap
 246 function for the extension specified in NAME.
 247
 248 =item DL_VARS
 249
 250 This is identical to the DL_VARS attribute available via MakeMaker,
 251 and, like DL_FUNCS, it is usually specified via MakeMaker.  Its
 252 value is a reference to an array of variable names which should
 253 be exported by the extension.
 254
 255 =item FILE
 256
 257 This key can be used to specify the name of the linker option file
 258 (minus the OS-specific extension), if for some reason you do not
 259 want to use the default value, which is the last word of the NAME
 260 attribute (I<e.g.> for C<Tk::Canvas>, FILE defaults to C<Canvas>).
 261
 262 =item FUNCLIST
 263
 264 This provides an alternate means to specify function names to be
 265 exported from the extension.  Its value is a reference to an
 266 array of function names to be exported by the extension.  These
 267 names are passed through unaltered to the linker options file.
 268 Specifying a value for the FUNCLIST attribute suppresses automatic
 269 generation of the bootstrap function for the package. To still create
 270 the bootstrap name you have to specify the package name in the
 271 DL_FUNCS hash:
 272
 273     Mksymlists({ NAME     => $name ,
 274                  FUNCLIST => [ $func1, $func2 ],
 275                  DL_FUNCS => { $pkg => [] } });
 276
 277
 278 =item IMPORTS
 279
 280 This attribute is used to specify names to be imported into the
 281 extension. It is currently only used by OS/2 and Win32.
 282
 283 =item NAME
 284
 285 This gives the name of the extension (I<e.g.> C<Tk::Canvas>) for which
 286 the linker option file will be produced.
 287
 288 =back
 289
 290 When calling C<Mksymlists>, one should always specify the NAME
 291 attribute.  In most cases, this is all that's necessary.  In
 292 the case of unusual extensions, however, the other attributes
 293 can be used to provide additional information to the linker.
 294
 295 =head1 AUTHOR
 296
 297 Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>>
 298
 299 =head1 REVISION
 300
 301 Last revised 14-Feb-1996, for Perl 5.002.