lib/ExtUtils/Mksymlists.pm

   1 package ExtUtils::Mksymlists;
   2
   3 use 5.005_64;
   4 use strict qw[ subs refs ];
   5 # no strict 'vars';  # until filehandles are exempted
   6
   7 use Carp;
   8 use Exporter;
   9 our(@ISA, @EXPORT, $VERSION);
  10 @ISA = 'Exporter';
  11 @EXPORT = '&Mksymlists';
  12 $VERSION = substr q$Revision: 1.17 $, 10;
  13
  14 sub Mksymlists {
  15     my(%spec) = @_;
  16     my($osname) = $^O;
  17
  18     croak("Insufficient information specified to Mksymlists")
  19         unless ( $spec{NAME} or
  20                  ($spec{FILE} and ($spec{DL_FUNCS} or $spec{FUNCLIST})) );
  21
  22     $spec{DL_VARS} = [] unless $spec{DL_VARS};
  23     ($spec{FILE} = $spec{NAME}) =~ s/.*::// unless $spec{FILE};
  24     $spec{FUNCLIST} = [] unless $spec{FUNCLIST};
  25     $spec{DL_FUNCS} = { $spec{NAME} => [] }
  26         unless ( ($spec{DL_FUNCS} and keys %{$spec{DL_FUNCS}}) or
  27                  @{$spec{FUNCLIST}});
  28     if (defined $spec{DL_FUNCS}) {
  29         my($package);
  30         foreach $package (keys %{$spec{DL_FUNCS}}) {
  31             my($packprefix,$sym,$bootseen);
  32             ($packprefix = $package) =~ s/\W/_/g;
  33             foreach $sym (@{$spec{DL_FUNCS}->{$package}}) {
  34                 if ($sym =~ /^boot_/) {
  35                     push(@{$spec{FUNCLIST}},$sym);
  36                     $bootseen++;
  37                 }
  38                 else { push(@{$spec{FUNCLIST}},"XS_${packprefix}_$sym"); }
  39             }
  40             push(@{$spec{FUNCLIST}},"boot_$packprefix") unless $bootseen;
  41         }
  42     }
  43
  44 #    We'll need this if we ever add any OS which uses mod2fname
  45 #    not as pseudo-builtin.
  46 #    require DynaLoader;
  47     if (defined &DynaLoader::mod2fname and not $spec{DLBASE}) {
  48         $spec{DLBASE} = DynaLoader::mod2fname([ split(/::/,$spec{NAME}) ]);
  49     }
  50
  51     if    ($osname eq 'aix') { _write_aix(\%spec); }
  52     elsif ($osname eq 'VMS') { _write_vms(\%spec) }
  53     elsif ($osname eq 'os2') { _write_os2(\%spec) }
  54     elsif ($osname eq 'MSWin32') { _write_win32(\%spec) }
  55     else { croak("Don't know how to create linker option file for $osname\n"); }
  56 }
  57
  58
  59 sub _write_aix {
  60     my($data) = @_;
  61
  62     rename "$data->{FILE}.exp", "$data->{FILE}.exp_old";
  63
  64     open(EXP,">$data->{FILE}.exp")
  65         or croak("Can't create $data->{FILE}.exp: $!\n");
  66     print EXP join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  67     print EXP join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  68     close EXP;
  69 }
  70
  71
  72 sub _write_os2 {
  73     my($data) = @_;
  74     require Config;
  75     my $threaded = ($Config::Config{archname} =~ /-thread/ ? " threaded" : "");
  76
  77     if (not $data->{DLBASE}) {
  78         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
  79         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
  80     }
  81     my $distname = $data->{DISTNAME} || $data->{NAME};
  82     $distname = "Distribution $distname";
  83     my $comment = "Perl (v$Config::Config{version}$threaded) module $data->{NAME}";
  84     if ($data->{INSTALLDIRS} and $data->{INSTALLDIRS} eq 'perl') {
  85         $distname = 'perl5-porters@perl.org';
  86         $comment = "Core $comment";
  87     }
  88     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
  89
  90     open(DEF,">$data->{FILE}.def")
  91         or croak("Can't create $data->{FILE}.def: $!\n");
  92     print DEF "LIBRARY '$data->{DLBASE}' INITINSTANCE TERMINSTANCE\n";
  93     print DEF "DESCRIPTION '\@#$distname:$data->{VERSION}#\@ $comment'\n";
  94     print DEF "CODE LOADONCALL\n";
  95     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
  96     print DEF "EXPORTS\n  ";
  97     print DEF join("\n  ",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  98     print DEF join("\n  ",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  99     if (%{$data->{IMPORTS}}) {
 100         print DEF "IMPORTS\n";
 101         my ($name, $exp);
 102         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 103             print DEF "  $name=$exp\n";
 104         }
 105     }
 106     close DEF;
 107 }
 108
 109 sub _write_win32 {
 110     my($data) = @_;
 111
 112     require Config;
 113     if (not $data->{DLBASE}) {
 114         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
 115         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
 116     }
 117     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
 118
 119     open(DEF,">$data->{FILE}.def")
 120         or croak("Can't create $data->{FILE}.def: $!\n");
 121     # put library name in quotes (it could be a keyword, like 'Alias')
 122     if ($Config::Config{'cc'} !~ /^gcc/i) {
 123       print DEF "LIBRARY \"$data->{DLBASE}\"\n";
 124     }
 125     print DEF "EXPORTS\n  ";
 126     my @syms;
 127     # Export public symbols both with and without underscores to
 128     # ensure compatibility between DLLs from different compilers
 129     # NOTE: DynaLoader itself only uses the names without underscores,
 130     # so this is only to cover the case when the extension DLL may be
 131     # linked to directly from C. GSAR 97-07-10
 132     if ($Config::Config{'cc'} =~ /^bcc/i) {
 133         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 134             push @syms, "_$_", "$_ = _$_";
 135         }
 136     }
 137     else {
 138         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 139             push @syms, "$_", "_$_ = $_";
 140         }
 141     }
 142     print DEF join("\n  ",@syms, "\n") if @syms;
 143     if (%{$data->{IMPORTS}}) {
 144         print DEF "IMPORTS\n";
 145         my ($name, $exp);
 146         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 147             print DEF "  $name=$exp\n";
 148         }
 149     }
 150     close DEF;
 151 }
 152
 153
 154 sub _write_vms {
 155     my($data) = @_;
 156
 157     require Config; # a reminder for once we do $^O
 158     require ExtUtils::XSSymSet;
 159
 160     my($isvax) = $Config::Config{'arch'} =~ /VAX/i;
 161     my($set) = new ExtUtils::XSSymSet;
 162     my($sym);
 163
 164     rename "$data->{FILE}.opt", "$data->{FILE}.opt_old";
 165
 166     open(OPT,">$data->{FILE}.opt")
 167         or croak("Can't create $data->{FILE}.opt: $!\n");
 168
 169     # Options file declaring universal symbols
 170     # Used when linking shareable image for dynamic extension,
 171     # or when linking PerlShr into which we've added this package
 172     # as a static extension
 173     # We don't do anything to preserve order, so we won't relax
 174     # the GSMATCH criteria for a dynamic extension
 175
 176     foreach $sym (@{$data->{FUNCLIST}}) {
 177         my $safe = $set->addsym($sym);
 178         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 179         else        { print OPT "SYMBOL_VECTOR=($safe=PROCEDURE)\n"; }
 180     }
 181     foreach $sym (@{$data->{DL_VARS}}) {
 182         my $safe = $set->addsym($sym);
 183         print OPT "PSECT_ATTR=${sym},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 184         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 185         else        { print OPT "SYMBOL_VECTOR=($safe=DATA)\n"; }
 186     }
 187     close OPT;
 188
 189 }
 190
 191 1;
 192
 193 __END__
 194
 195 =head1 NAME
 196
 197 ExtUtils::Mksymlists - write linker options files for dynamic extension
 198
 199 =head1 SYNOPSIS
 200
 201     use ExtUtils::Mksymlists;
 202     Mksymlists({ NAME     => $name ,
 203                  DL_VARS  => [ $var1, $var2, $var3 ],
 204                  DL_FUNCS => { $pkg1 => [ $func1, $func2 ],
 205                                $pkg2 => [ $func3 ] });
 206
 207 =head1 DESCRIPTION
 208
 209 C<ExtUtils::Mksymlists> produces files used by the linker under some OSs
 210 during the creation of shared libraries for dynamic extensions.  It is
 211 normally called from a MakeMaker-generated Makefile when the extension
 212 is built.  The linker option file is generated by calling the function
 213 C<Mksymlists>, which is exported by default from C<ExtUtils::Mksymlists>.
 214 It takes one argument, a list of key-value pairs, in which the following
 215 keys are recognized:
 216
 217 =over
 218
 219 =item DLBASE
 220
 221 This item specifies the name by which the linker knows the
 222 extension, which may be different from the name of the
 223 extension itself (for instance, some linkers add an '_' to the
 224 name of the extension).  If it is not specified, it is derived
 225 from the NAME attribute.  It is presently used only by OS2 and Win32.
 226
 227 =item DL_FUNCS
 228
 229 This is identical to the DL_FUNCS attribute available via MakeMaker,
 230 from which it is usually taken.  Its value is a reference to an
 231 associative array, in which each key is the name of a package, and
 232 each value is an a reference to an array of function names which
 233 should be exported by the extension.  For instance, one might say
 234 C<DL_FUNCS =E<gt> { Homer::Iliad =E<gt> [ qw(trojans greeks) ],
 235 Homer::Odyssey =E<gt> [ qw(travellers family suitors) ] }>.  The
 236 function names should be identical to those in the XSUB code;
 237 C<Mksymlists> will alter the names written to the linker option
 238 file to match the changes made by F<xsubpp>.  In addition, if
 239 none of the functions in a list begin with the string B<boot_>,
 240 C<Mksymlists> will add a bootstrap function for that package,
 241 just as xsubpp does.  (If a B<boot_E<lt>pkgE<gt>> function is
 242 present in the list, it is passed through unchanged.)  If
 243 DL_FUNCS is not specified, it defaults to the bootstrap
 244 function for the extension specified in NAME.
 245
 246 =item DL_VARS
 247
 248 This is identical to the DL_VARS attribute available via MakeMaker,
 249 and, like DL_FUNCS, it is usually specified via MakeMaker.  Its
 250 value is a reference to an array of variable names which should
 251 be exported by the extension.
 252
 253 =item FILE
 254
 255 This key can be used to specify the name of the linker option file
 256 (minus the OS-specific extension), if for some reason you do not
 257 want to use the default value, which is the last word of the NAME
 258 attribute (I<e.g.> for C<Tk::Canvas>, FILE defaults to C<Canvas>).
 259
 260 =item FUNCLIST
 261
 262 This provides an alternate means to specify function names to be
 263 exported from the extension.  Its value is a reference to an
 264 array of function names to be exported by the extension.  These
 265 names are passed through unaltered to the linker options file.
 266 Specifying a value for the FUNCLIST attribute suppresses automatic
 267 generation of the bootstrap function for the package. To still create
 268 the bootstrap name you have to specify the package name in the
 269 DL_FUNCS hash:
 270
 271     Mksymlists({ NAME     => $name ,
 272                  FUNCLIST => [ $func1, $func2 ],
 273                  DL_FUNCS => { $pkg => [] } });
 274
 275
 276 =item IMPORTS
 277
 278 This attribute is used to specify names to be imported into the
 279 extension. It is currently only used by OS/2 and Win32.
 280
 281 =item NAME
 282
 283 This gives the name of the extension (I<e.g.> C<Tk::Canvas>) for which
 284 the linker option file will be produced.
 285
 286 =back
 287
 288 When calling C<Mksymlists>, one should always specify the NAME
 289 attribute.  In most cases, this is all that's necessary.  In
 290 the case of unusual extensions, however, the other attributes
 291 can be used to provide additional information to the linker.
 292
 293 =head1 AUTHOR
 294
 295 Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>>
 296
 297 =head1 REVISION
 298
 299 Last revised 14-Feb-1996, for Perl 5.002.