lib/ExtUtils/Mksymlists.pm

   1 package ExtUtils::Mksymlists;
   2 use strict qw[ subs refs ];
   3 # no strict 'vars';  # until filehandles are exempted
   4
   5 use Carp;
   6 use Exporter;
   7 use vars qw( @ISA @EXPORT $VERSION );
   8 @ISA = 'Exporter';
   9 @EXPORT = '&Mksymlists';
  10 $VERSION = substr q$Revision: 1.17 $, 10;
  11
  12 sub Mksymlists {
  13     my(%spec) = @_;
  14     my($osname) = $^O;
  15
  16     croak("Insufficient information specified to Mksymlists")
  17         unless ( $spec{NAME} or
  18                  ($spec{FILE} and ($spec{DL_FUNCS} or $spec{FUNCLIST})) );
  19
  20     $spec{DL_VARS} = [] unless $spec{DL_VARS};
  21     ($spec{FILE} = $spec{NAME}) =~ s/.*::// unless $spec{FILE};
  22     $spec{DL_FUNCS} = { $spec{NAME} => [] }
  23         unless ( ($spec{DL_FUNCS} and keys %{$spec{DL_FUNCS}}) or
  24                  $spec{FUNCLIST});
  25     $spec{FUNCLIST} = [] unless $spec{FUNCLIST};
  26     if (defined $spec{DL_FUNCS}) {
  27         my($package);
  28         foreach $package (keys %{$spec{DL_FUNCS}}) {
  29             my($packprefix,$sym,$bootseen);
  30             ($packprefix = $package) =~ s/\W/_/g;
  31             foreach $sym (@{$spec{DL_FUNCS}->{$package}}) {
  32                 if ($sym =~ /^boot_/) {
  33                     push(@{$spec{FUNCLIST}},$sym);
  34                     $bootseen++;
  35                 }
  36                 else { push(@{$spec{FUNCLIST}},"XS_${packprefix}_$sym"); }
  37             }
  38             push(@{$spec{FUNCLIST}},"boot_$packprefix") unless $bootseen;
  39         }
  40     }
  41
  42 #    We'll need this if we ever add any OS which uses mod2fname
  43 #    not as pseudo-builtin.
  44 #    require DynaLoader;
  45     if (defined &DynaLoader::mod2fname and not $spec{DLBASE}) {
  46         $spec{DLBASE} = DynaLoader::mod2fname([ split(/::/,$spec{NAME}) ]);
  47     }
  48
  49     if    ($osname eq 'aix') { _write_aix(\%spec); }
  50     elsif ($osname eq 'VMS') { _write_vms(\%spec) }
  51     elsif ($osname eq 'os2') { _write_os2(\%spec) }
  52     elsif ($osname eq 'MSWin32') { _write_win32(\%spec) }
  53     else { croak("Don't know how to create linker option file for $osname\n"); }
  54 }
  55
  56
  57 sub _write_aix {
  58     my($data) = @_;
  59
  60     rename "$data->{FILE}.exp", "$data->{FILE}.exp_old";
  61
  62     open(EXP,">$data->{FILE}.exp")
  63         or croak("Can't create $data->{FILE}.exp: $!\n");
  64     print EXP join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  65     print EXP join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  66     close EXP;
  67 }
  68
  69
  70 sub _write_os2 {
  71     my($data) = @_;
  72     require Config;
  73     my $threaded = ($Config::Config{archname} =~ /-thread/ ? " threaded" : "");
  74
  75     if (not $data->{DLBASE}) {
  76         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
  77         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
  78     }
  79     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
  80
  81     open(DEF,">$data->{FILE}.def")
  82         or croak("Can't create $data->{FILE}.def: $!\n");
  83     print DEF "LIBRARY '$data->{DLBASE}' INITINSTANCE TERMINSTANCE\n";
  84     print DEF "DESCRIPTION 'Perl (v$]$threaded) module $data->{NAME} v$data->{VERSION}'\n";
  85     print DEF "CODE LOADONCALL\n";
  86     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
  87     print DEF "EXPORTS\n  ";
  88     print DEF join("\n  ",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  89     print DEF join("\n  ",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  90     if (%{$data->{IMPORTS}}) {
  91         print DEF "IMPORTS\n";
  92 my ($name, $exp);
  93 while (($name, $exp)= each %{$data->{IMPORTS}}) {
  94   print DEF "  $name=$exp\n";
  95 }
  96     }
  97     close DEF;
  98 }
  99
 100 sub _write_win32 {
 101     my($data) = @_;
 102
 103     require Config;
 104     if (not $data->{DLBASE}) {
 105         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
 106         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
 107     }
 108     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
 109
 110     open(DEF,">$data->{FILE}.def")
 111         or croak("Can't create $data->{FILE}.def: $!\n");
 112     # put library name in quotes (it could be a keyword, like 'Alias')
 113     if ($Config::Config{'cc'} !~ /^gcc/i) {
 114       print DEF "LIBRARY \"$data->{DLBASE}\"\n";
 115       if ($Config{'ccflags'} !~ /PERL_OBJECT/i) {
 116         print DEF "CODE LOADONCALL\n";
 117         print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
 118       }
 119     }
 120     print DEF "EXPORTS\n  ";
 121     my @syms;
 122     # Export public symbols both with and without underscores to
 123     # ensure compatibility between DLLs from different compilers
 124     # NOTE: DynaLoader itself only uses the names without underscores,
 125     # so this is only to cover the case when the extension DLL may be
 126     # linked to directly from C. GSAR 97-07-10
 127     if ($Config::Config{'cc'} =~ /^bcc/i) {
 128         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 129             push @syms, "_$_", "$_ = _$_";
 130         }
 131     }
 132     else {
 133         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 134             push @syms, "$_", "_$_ = $_";
 135         }
 136     }
 137     print DEF join("\n  ",@syms, "\n") if @syms;
 138     if (%{$data->{IMPORTS}}) {
 139         print DEF "IMPORTS\n";
 140         my ($name, $exp);
 141         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 142             print DEF "  $name=$exp\n";
 143         }
 144     }
 145     close DEF;
 146 }
 147
 148
 149 sub _write_vms {
 150     my($data) = @_;
 151
 152     require Config; # a reminder for once we do $^O
 153     require ExtUtils::XSSymSet;
 154
 155     my($isvax) = $Config::Config{'arch'} =~ /VAX/i;
 156     my($set) = new ExtUtils::XSSymSet;
 157     my($sym);
 158
 159     rename "$data->{FILE}.opt", "$data->{FILE}.opt_old";
 160
 161     open(OPT,">$data->{FILE}.opt")
 162         or croak("Can't create $data->{FILE}.opt: $!\n");
 163
 164     # Options file declaring universal symbols
 165     # Used when linking shareable image for dynamic extension,
 166     # or when linking PerlShr into which we've added this package
 167     # as a static extension
 168     # We don't do anything to preserve order, so we won't relax
 169     # the GSMATCH criteria for a dynamic extension
 170
 171     foreach $sym (@{$data->{FUNCLIST}}) {
 172         my $safe = $set->addsym($sym);
 173         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 174         else        { print OPT "SYMBOL_VECTOR=($safe=PROCEDURE)\n"; }
 175     }
 176     foreach $sym (@{$data->{DL_VARS}}) {
 177         my $safe = $set->addsym($sym);
 178         print OPT "PSECT_ATTR=${sym},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 179         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 180         else        { print OPT "SYMBOL_VECTOR=($safe=DATA)\n"; }
 181     }
 182     close OPT;
 183
 184     # Options file specifying RTLs to which this extension must be linked.
 185     # Eventually, the list of libraries will be supplied by a working
 186     # extliblist routine.
 187     open OPT,'>rtls.opt';
 188     print OPT "PerlShr/Share\n";
 189     foreach $rtl (split(/\s+/,$Config::Config{'libs'})) { print OPT "$rtl\n"; }
 190     close OPT;
 191 }
 192
 193 1;
 194
 195 __END__
 196
 197 =head1 NAME
 198
 199 ExtUtils::Mksymlists - write linker options files for dynamic extension
 200
 201 =head1 SYNOPSIS
 202
 203     use ExtUtils::Mksymlists;
 204     Mksymlists({ NAME     => $name ,
 205                  DL_VARS  => [ $var1, $var2, $var3 ],
 206                  DL_FUNCS => { $pkg1 => [ $func1, $func2 ],
 207                                $pkg2 => [ $func3 ] });
 208
 209 =head1 DESCRIPTION
 210
 211 C<ExtUtils::Mksymlists> produces files used by the linker under some OSs
 212 during the creation of shared libraries for dynamic extensions.  It is
 213 normally called from a MakeMaker-generated Makefile when the extension
 214 is built.  The linker option file is generated by calling the function
 215 C<Mksymlists>, which is exported by default from C<ExtUtils::Mksymlists>.
 216 It takes one argument, a list of key-value pairs, in which the following
 217 keys are recognized:
 218
 219 =over
 220
 221 =item NAME
 222
 223 This gives the name of the extension (I<e.g.> Tk::Canvas) for which
 224 the linker option file will be produced.
 225
 226 =item DL_FUNCS
 227
 228 This is identical to the DL_FUNCS attribute available via MakeMaker,
 229 from which it is usually taken.  Its value is a reference to an
 230 associative array, in which each key is the name of a package, and
 231 each value is an a reference to an array of function names which
 232 should be exported by the extension.  For instance, one might say
 233 C<DL_FUNCS =E<gt> { Homer::Iliad   =E<gt> [ qw(trojans greeks) ],
 234 Homer::Odyssey =E<gt> [ qw(travellers family suitors) ] }>.  The
 235 function names should be identical to those in the XSUB code;
 236 C<Mksymlists> will alter the names written to the linker option
 237 file to match the changes made by F<xsubpp>.  In addition, if
 238 none of the functions in a list begin with the string B<boot_>,
 239 C<Mksymlists> will add a bootstrap function for that package,
 240 just as xsubpp does.  (If a B<boot_E<lt>pkgE<gt>> function is
 241 present in the list, it is passed through unchanged.)  If
 242 DL_FUNCS is not specified, it defaults to the bootstrap
 243 function for the extension specified in NAME.
 244
 245 =item DL_VARS
 246
 247 This is identical to the DL_VARS attribute available via MakeMaker,
 248 and, like DL_FUNCS, it is usually specified via MakeMaker.  Its
 249 value is a reference to an array of variable names which should
 250 be exported by the extension.
 251
 252 =item FILE
 253
 254 This key can be used to specify the name of the linker option file
 255 (minus the OS-specific extension), if for some reason you do not
 256 want to use the default value, which is the last word of the NAME
 257 attribute (I<e.g.> for Tk::Canvas, FILE defaults to 'Canvas').
 258
 259 =item FUNCLIST
 260
 261 This provides an alternate means to specify function names to be
 262 exported from the extension.  Its value is a reference to an
 263 array of function names to be exported by the extension.  These
 264 names are passed through unaltered to the linker options file.
 265
 266 =item DLBASE
 267
 268 This item specifies the name by which the linker knows the
 269 extension, which may be different from the name of the
 270 extension itself (for instance, some linkers add an '_' to the
 271 name of the extension).  If it is not specified, it is derived
 272 from the NAME attribute.  It is presently used only by OS2.
 273
 274 =back
 275
 276 When calling C<Mksymlists>, one should always specify the NAME
 277 attribute.  In most cases, this is all that's necessary.  In
 278 the case of unusual extensions, however, the other attributes
 279 can be used to provide additional information to the linker.
 280
 281 =head1 AUTHOR
 282
 283 Charles Bailey I<E<lt>bailey@genetics.upenn.eduE<gt>>
 284
 285 =head1 REVISION
 286
 287 Last revised 14-Feb-1996, for Perl 5.002.