lib/ExtUtils/Mksymlists.pm

   1 package ExtUtils::Mksymlists;
   2 use strict qw[ subs refs ];
   3 # no strict 'vars';  # until filehandles are exempted
   4
   5 use Carp;
   6 use Exporter;
   7 use vars qw( @ISA @EXPORT $VERSION );
   8 @ISA = 'Exporter';
   9 @EXPORT = '&Mksymlists';
  10 $VERSION = substr q$Revision: 1.13 $, 10;
  11
  12 sub Mksymlists {
  13     my(%spec) = @_;
  14     my($osname) = $^O;
  15
  16     croak("Insufficient information specified to Mksymlists")
  17         unless ( $spec{NAME} or
  18                  ($spec{FILE} and ($spec{DL_FUNCS} or $spec{FUNCLIST})) );
  19
  20     $spec{DL_VARS} = [] unless $spec{DL_VARS};
  21     ($spec{FILE} = $spec{NAME}) =~ s/.*::// unless $spec{FILE};
  22     $spec{DL_FUNCS} = { $spec{NAME} => [] }
  23         unless ( ($spec{DL_FUNCS} and keys %{$spec{DL_FUNCS}}) or
  24                  $spec{FUNCLIST});
  25     $spec{FUNCLIST} = [] unless $spec{FUNCLIST};
  26     if (defined $spec{DL_FUNCS}) {
  27         my($package);
  28         foreach $package (keys %{$spec{DL_FUNCS}}) {
  29             my($packprefix,$sym,$bootseen);
  30             ($packprefix = $package) =~ s/\W/_/g;
  31             foreach $sym (@{$spec{DL_FUNCS}->{$package}}) {
  32                 if ($sym =~ /^boot_/) {
  33                     push(@{$spec{FUNCLIST}},$sym);
  34                     $bootseen++;
  35                 }
  36                 else { push(@{$spec{FUNCLIST}},"XS_${packprefix}_$sym"); }
  37             }
  38             push(@{$spec{FUNCLIST}},"boot_$packprefix") unless $bootseen;
  39         }
  40     }
  41
  42 #    We'll need this if we ever add any OS which uses mod2fname
  43 #    not as pseudo-builtin.
  44 #    require DynaLoader;
  45     if (defined &DynaLoader::mod2fname and not $spec{DLBASE}) {
  46         $spec{DLBASE} = DynaLoader::mod2fname([ split(/::/,$spec{NAME}) ]);
  47     }
  48
  49     if    ($osname eq 'aix') { _write_aix(\%spec); }
  50     elsif ($osname eq 'VMS') { _write_vms(\%spec) }
  51     elsif ($osname eq 'os2') { _write_os2(\%spec) }
  52     elsif ($osname eq 'MSWin32') { _write_win32(\%spec) }
  53     else { croak("Don't know how to create linker option file for $osname\n"); }
  54 }
  55
  56
  57 sub _write_aix {
  58     my($data) = @_;
  59
  60     rename "$data->{FILE}.exp", "$data->{FILE}.exp_old";
  61
  62     open(EXP,">$data->{FILE}.exp")
  63         or croak("Can't create $data->{FILE}.exp: $!\n");
  64     print EXP join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  65     print EXP join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  66     close EXP;
  67 }
  68
  69
  70 sub _write_os2 {
  71     my($data) = @_;
  72
  73     if (not $data->{DLBASE}) {
  74         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
  75         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
  76     }
  77     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
  78
  79     open(DEF,">$data->{FILE}.def")
  80         or croak("Can't create $data->{FILE}.def: $!\n");
  81     print DEF "LIBRARY '$data->{DLBASE}' INITINSTANCE TERMINSTANCE\n";
  82     print DEF "CODE LOADONCALL\n";
  83     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
  84     print DEF "EXPORTS\n  ";
  85     print DEF join("\n  ",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  86     print DEF join("\n  ",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  87     if (%{$data->{IMPORTS}}) {
  88         print DEF "IMPORTS\n";
  89 my ($name, $exp);
  90 while (($name, $exp)= each %{$data->{IMPORTS}}) {
  91   print DEF "  $name=$exp\n";
  92 }
  93     }
  94     close DEF;
  95 }
  96
  97 sub _write_win32 {
  98     my($data) = @_;
  99
 100     require Config;
 101     if (not $data->{DLBASE}) {
 102         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
 103         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
 104     }
 105     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
 106
 107     open(DEF,">$data->{FILE}.def")
 108         or croak("Can't create $data->{FILE}.def: $!\n");
 109     print DEF "LIBRARY $data->{DLBASE}\n";
 110     print DEF "CODE LOADONCALL\n";
 111     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
 112     print DEF "EXPORTS\n  ";
 113     if ($Config::Config{'cc'} =~ /^bcc/i) {
 114         for (@{$data->{DL_VARS}}) { $_ = "$_ = _$_" }
 115         for (@{$data->{FUNCLIST}}) { $_ = "$_ = _$_" }
 116     }
 117     print DEF join("\n  ",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
 118     print DEF join("\n  ",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
 119     if (%{$data->{IMPORTS}}) {
 120         print DEF "IMPORTS\n";
 121         my ($name, $exp);
 122         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 123             print DEF "  $name=$exp\n";
 124         }
 125     }
 126     close DEF;
 127 }
 128
 129
 130 sub _write_vms {
 131     my($data) = @_;
 132
 133     require Config; # a reminder for once we do $^O
 134     require ExtUtils::XSSymSet;
 135
 136     my($isvax) = $Config::Config{'arch'} =~ /VAX/i;
 137     my($set) = new ExtUtils::XSSymSet;
 138     my($sym);
 139
 140     rename "$data->{FILE}.opt", "$data->{FILE}.opt_old";
 141
 142     open(OPT,">$data->{FILE}.opt")
 143         or croak("Can't create $data->{FILE}.opt: $!\n");
 144
 145     # Options file declaring universal symbols
 146     # Used when linking shareable image for dynamic extension,
 147     # or when linking PerlShr into which we've added this package
 148     # as a static extension
 149     # We don't do anything to preserve order, so we won't relax
 150     # the GSMATCH criteria for a dynamic extension
 151
 152     foreach $sym (@{$data->{FUNCLIST}}) {
 153         my $safe = $set->addsym($sym);
 154         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 155         else        { print OPT "SYMBOL_VECTOR=($safe=PROCEDURE)\n"; }
 156     }
 157     foreach $sym (@{$data->{DL_VARS}}) {
 158         my $safe = $set->addsym($sym);
 159         print OPT "PSECT_ATTR=${sym},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 160         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 161         else        { print OPT "SYMBOL_VECTOR=($safe=DATA)\n"; }
 162     }
 163     close OPT;
 164
 165     # Options file specifying RTLs to which this extension must be linked.
 166     # Eventually, the list of libraries will be supplied by a working
 167     # extliblist routine.
 168     open OPT,'>rtls.opt';
 169     print OPT "PerlShr/Share\n";
 170     foreach $rtl (split(/\s+/,$Config::Config{'libs'})) { print OPT "$rtl\n"; }
 171     close OPT;
 172 }
 173
 174 1;
 175
 176 __END__
 177
 178 =head1 NAME
 179
 180 ExtUtils::Mksymlists - write linker options files for dynamic extension
 181
 182 =head1 SYNOPSIS
 183
 184     use ExtUtils::Mksymlists;
 185     Mksymlists({ NAME     => $name ,
 186                  DL_VARS  => [ $var1, $var2, $var3 ],
 187                  DL_FUNCS => { $pkg1 => [ $func1, $func2 ],
 188                                $pkg2 => [ $func3 ] });
 189
 190 =head1 DESCRIPTION
 191
 192 C<ExtUtils::Mksymlists> produces files used by the linker under some OSs
 193 during the creation of shared libraries for dynamic extensions.  It is
 194 normally called from a MakeMaker-generated Makefile when the extension
 195 is built.  The linker option file is generated by calling the function
 196 C<Mksymlists>, which is exported by default from C<ExtUtils::Mksymlists>.
 197 It takes one argument, a list of key-value pairs, in which the following
 198 keys are recognized:
 199
 200 =over
 201
 202 =item NAME
 203
 204 This gives the name of the extension (I<e.g.> Tk::Canvas) for which
 205 the linker option file will be produced.
 206
 207 =item DL_FUNCS
 208
 209 This is identical to the DL_FUNCS attribute available via MakeMaker,
 210 from which it is usually taken.  Its value is a reference to an
 211 associative array, in which each key is the name of a package, and
 212 each value is an a reference to an array of function names which
 213 should be exported by the extension.  For instance, one might say
 214 C<DL_FUNCS =E<gt> { Homer::Iliad   =E<gt> [ qw(trojans greeks) ],
 215 Homer::Odyssey =E<gt> [ qw(travellers family suitors) ] }>.  The
 216 function names should be identical to those in the XSUB code;
 217 C<Mksymlists> will alter the names written to the linker option
 218 file to match the changes made by F<xsubpp>.  In addition, if
 219 none of the functions in a list begin with the string B<boot_>,
 220 C<Mksymlists> will add a bootstrap function for that package,
 221 just as xsubpp does.  (If a B<boot_E<lt>pkgE<gt>> function is
 222 present in the list, it is passed through unchanged.)  If
 223 DL_FUNCS is not specified, it defaults to the bootstrap
 224 function for the extension specified in NAME.
 225
 226 =item DL_VARS
 227
 228 This is identical to the DL_VARS attribute available via MakeMaker,
 229 and, like DL_FUNCS, it is usually specified via MakeMaker.  Its
 230 value is a reference to an array of variable names which should
 231 be exported by the extension.
 232
 233 =item FILE
 234
 235 This key can be used to specify the name of the linker option file
 236 (minus the OS-specific extension), if for some reason you do not
 237 want to use the default value, which is the last word of the NAME
 238 attribute (I<e.g.> for Tk::Canvas, FILE defaults to 'Canvas').
 239
 240 =item FUNCLIST
 241
 242 This provides an alternate means to specify function names to be
 243 exported from the extension.  Its value is a reference to an
 244 array of function names to be exported by the extension.  These
 245 names are passed through unaltered to the linker options file.
 246
 247 =item DLBASE
 248
 249 This item specifies the name by which the linker knows the
 250 extension, which may be different from the name of the
 251 extension itself (for instance, some linkers add an '_' to the
 252 name of the extension).  If it is not specified, it is derived
 253 from the NAME attribute.  It is presently used only by OS2.
 254
 255 =back
 256
 257 When calling C<Mksymlists>, one should always specify the NAME
 258 attribute.  In most cases, this is all that's necessary.  In
 259 the case of unusual extensions, however, the other attributes
 260 can be used to provide additional information to the linker.
 261
 262 =head1 AUTHOR
 263
 264 Charles Bailey I<E<lt>bailey@genetics.upenn.eduE<gt>>
 265
 266 =head1 REVISION
 267
 268 Last revised 14-Feb-1996, for Perl 5.002.