lib/ExtUtils/Mksymlists.pm

   1 package ExtUtils::Mksymlists;
   2 use strict qw[ subs refs ];
   3 # no strict 'vars';  # until filehandles are exempted
   4
   5 use Carp;
   6 use Exporter;
   7 use vars qw( @ISA @EXPORT $VERSION );
   8 @ISA = 'Exporter';
   9 @EXPORT = '&Mksymlists';
  10 $VERSION = substr q$Revision: 1.16 $, 10;
  11
  12 sub Mksymlists {
  13     my(%spec) = @_;
  14     my($osname) = $^O;
  15
  16     croak("Insufficient information specified to Mksymlists")
  17         unless ( $spec{NAME} or
  18                  ($spec{FILE} and ($spec{DL_FUNCS} or $spec{FUNCLIST})) );
  19
  20     $spec{DL_VARS} = [] unless $spec{DL_VARS};
  21     ($spec{FILE} = $spec{NAME}) =~ s/.*::// unless $spec{FILE};
  22     $spec{DL_FUNCS} = { $spec{NAME} => [] }
  23         unless ( ($spec{DL_FUNCS} and keys %{$spec{DL_FUNCS}}) or
  24                  $spec{FUNCLIST});
  25     $spec{FUNCLIST} = [] unless $spec{FUNCLIST};
  26     if (defined $spec{DL_FUNCS}) {
  27         my($package);
  28         foreach $package (keys %{$spec{DL_FUNCS}}) {
  29             my($packprefix,$sym,$bootseen);
  30             ($packprefix = $package) =~ s/\W/_/g;
  31             foreach $sym (@{$spec{DL_FUNCS}->{$package}}) {
  32                 if ($sym =~ /^boot_/) {
  33                     push(@{$spec{FUNCLIST}},$sym);
  34                     $bootseen++;
  35                 }
  36                 else { push(@{$spec{FUNCLIST}},"XS_${packprefix}_$sym"); }
  37             }
  38             push(@{$spec{FUNCLIST}},"boot_$packprefix") unless $bootseen;
  39         }
  40     }
  41
  42 #    We'll need this if we ever add any OS which uses mod2fname
  43 #    not as pseudo-builtin.
  44 #    require DynaLoader;
  45     if (defined &DynaLoader::mod2fname and not $spec{DLBASE}) {
  46         $spec{DLBASE} = DynaLoader::mod2fname([ split(/::/,$spec{NAME}) ]);
  47     }
  48
  49     if    ($osname eq 'aix') { _write_aix(\%spec); }
  50     elsif ($osname eq 'VMS') { _write_vms(\%spec) }
  51     elsif ($osname eq 'os2') { _write_os2(\%spec) }
  52     elsif ($osname eq 'MSWin32') { _write_win32(\%spec) }
  53     else { croak("Don't know how to create linker option file for $osname\n"); }
  54 }
  55
  56
  57 sub _write_aix {
  58     my($data) = @_;
  59
  60     rename "$data->{FILE}.exp", "$data->{FILE}.exp_old";
  61
  62     open(EXP,">$data->{FILE}.exp")
  63         or croak("Can't create $data->{FILE}.exp: $!\n");
  64     print EXP join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  65     print EXP join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  66     close EXP;
  67 }
  68
  69
  70 sub _write_os2 {
  71     my($data) = @_;
  72
  73     if (not $data->{DLBASE}) {
  74         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
  75         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
  76     }
  77     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
  78
  79     open(DEF,">$data->{FILE}.def")
  80         or croak("Can't create $data->{FILE}.def: $!\n");
  81     print DEF "LIBRARY '$data->{DLBASE}' INITINSTANCE TERMINSTANCE\n";
  82     print DEF "CODE LOADONCALL\n";
  83     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
  84     print DEF "EXPORTS\n  ";
  85     print DEF join("\n  ",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  86     print DEF join("\n  ",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  87     if (%{$data->{IMPORTS}}) {
  88         print DEF "IMPORTS\n";
  89 my ($name, $exp);
  90 while (($name, $exp)= each %{$data->{IMPORTS}}) {
  91   print DEF "  $name=$exp\n";
  92 }
  93     }
  94     close DEF;
  95 }
  96
  97 sub _write_win32 {
  98     my($data) = @_;
  99
 100     require Config;
 101     if (not $data->{DLBASE}) {
 102         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
 103         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
 104     }
 105     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
 106
 107     open(DEF,">$data->{FILE}.def")
 108         or croak("Can't create $data->{FILE}.def: $!\n");
 109     # put library name in quotes (it could be a keyword, like 'Alias')
 110     if ($Config::Config{'cc'} !~ /^gcc/i) {
 111       print DEF "LIBRARY \"$data->{DLBASE}\"\n";
 112       print DEF "CODE LOADONCALL\n";
 113       print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
 114     }
 115     print DEF "EXPORTS\n  ";
 116     my @syms;
 117     # Export public symbols both with and without underscores to
 118     # ensure compatibility between DLLs from different compilers
 119     # NOTE: DynaLoader itself only uses the names without underscores,
 120     # so this is only to cover the case when the extension DLL may be
 121     # linked to directly from C. GSAR 97-07-10
 122     if ($Config::Config{'cc'} =~ /^bcc/i) {
 123         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 124             push @syms, "_$_", "$_ = _$_";
 125         }
 126     }
 127     else {
 128         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 129             push @syms, "$_", "_$_ = $_";
 130         }
 131     }
 132     print DEF join("\n  ",@syms, "\n") if @syms;
 133     if (%{$data->{IMPORTS}}) {
 134         print DEF "IMPORTS\n";
 135         my ($name, $exp);
 136         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 137             print DEF "  $name=$exp\n";
 138         }
 139     }
 140     close DEF;
 141 }
 142
 143
 144 sub _write_vms {
 145     my($data) = @_;
 146
 147     require Config; # a reminder for once we do $^O
 148     require ExtUtils::XSSymSet;
 149
 150     my($isvax) = $Config::Config{'arch'} =~ /VAX/i;
 151     my($set) = new ExtUtils::XSSymSet;
 152     my($sym);
 153
 154     rename "$data->{FILE}.opt", "$data->{FILE}.opt_old";
 155
 156     open(OPT,">$data->{FILE}.opt")
 157         or croak("Can't create $data->{FILE}.opt: $!\n");
 158
 159     # Options file declaring universal symbols
 160     # Used when linking shareable image for dynamic extension,
 161     # or when linking PerlShr into which we've added this package
 162     # as a static extension
 163     # We don't do anything to preserve order, so we won't relax
 164     # the GSMATCH criteria for a dynamic extension
 165
 166     foreach $sym (@{$data->{FUNCLIST}}) {
 167         my $safe = $set->addsym($sym);
 168         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 169         else        { print OPT "SYMBOL_VECTOR=($safe=PROCEDURE)\n"; }
 170     }
 171     foreach $sym (@{$data->{DL_VARS}}) {
 172         my $safe = $set->addsym($sym);
 173         print OPT "PSECT_ATTR=${sym},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 174         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 175         else        { print OPT "SYMBOL_VECTOR=($safe=DATA)\n"; }
 176     }
 177     close OPT;
 178
 179     # Options file specifying RTLs to which this extension must be linked.
 180     # Eventually, the list of libraries will be supplied by a working
 181     # extliblist routine.
 182     open OPT,'>rtls.opt';
 183     print OPT "PerlShr/Share\n";
 184     foreach $rtl (split(/\s+/,$Config::Config{'libs'})) { print OPT "$rtl\n"; }
 185     close OPT;
 186 }
 187
 188 1;
 189
 190 __END__
 191
 192 =head1 NAME
 193
 194 ExtUtils::Mksymlists - write linker options files for dynamic extension
 195
 196 =head1 SYNOPSIS
 197
 198     use ExtUtils::Mksymlists;
 199     Mksymlists({ NAME     => $name ,
 200                  DL_VARS  => [ $var1, $var2, $var3 ],
 201                  DL_FUNCS => { $pkg1 => [ $func1, $func2 ],
 202                                $pkg2 => [ $func3 ] });
 203
 204 =head1 DESCRIPTION
 205
 206 C<ExtUtils::Mksymlists> produces files used by the linker under some OSs
 207 during the creation of shared libraries for dynamic extensions.  It is
 208 normally called from a MakeMaker-generated Makefile when the extension
 209 is built.  The linker option file is generated by calling the function
 210 C<Mksymlists>, which is exported by default from C<ExtUtils::Mksymlists>.
 211 It takes one argument, a list of key-value pairs, in which the following
 212 keys are recognized:
 213
 214 =over
 215
 216 =item NAME
 217
 218 This gives the name of the extension (I<e.g.> Tk::Canvas) for which
 219 the linker option file will be produced.
 220
 221 =item DL_FUNCS
 222
 223 This is identical to the DL_FUNCS attribute available via MakeMaker,
 224 from which it is usually taken.  Its value is a reference to an
 225 associative array, in which each key is the name of a package, and
 226 each value is an a reference to an array of function names which
 227 should be exported by the extension.  For instance, one might say
 228 C<DL_FUNCS =E<gt> { Homer::Iliad   =E<gt> [ qw(trojans greeks) ],
 229 Homer::Odyssey =E<gt> [ qw(travellers family suitors) ] }>.  The
 230 function names should be identical to those in the XSUB code;
 231 C<Mksymlists> will alter the names written to the linker option
 232 file to match the changes made by F<xsubpp>.  In addition, if
 233 none of the functions in a list begin with the string B<boot_>,
 234 C<Mksymlists> will add a bootstrap function for that package,
 235 just as xsubpp does.  (If a B<boot_E<lt>pkgE<gt>> function is
 236 present in the list, it is passed through unchanged.)  If
 237 DL_FUNCS is not specified, it defaults to the bootstrap
 238 function for the extension specified in NAME.
 239
 240 =item DL_VARS
 241
 242 This is identical to the DL_VARS attribute available via MakeMaker,
 243 and, like DL_FUNCS, it is usually specified via MakeMaker.  Its
 244 value is a reference to an array of variable names which should
 245 be exported by the extension.
 246
 247 =item FILE
 248
 249 This key can be used to specify the name of the linker option file
 250 (minus the OS-specific extension), if for some reason you do not
 251 want to use the default value, which is the last word of the NAME
 252 attribute (I<e.g.> for Tk::Canvas, FILE defaults to 'Canvas').
 253
 254 =item FUNCLIST
 255
 256 This provides an alternate means to specify function names to be
 257 exported from the extension.  Its value is a reference to an
 258 array of function names to be exported by the extension.  These
 259 names are passed through unaltered to the linker options file.
 260
 261 =item DLBASE
 262
 263 This item specifies the name by which the linker knows the
 264 extension, which may be different from the name of the
 265 extension itself (for instance, some linkers add an '_' to the
 266 name of the extension).  If it is not specified, it is derived
 267 from the NAME attribute.  It is presently used only by OS2.
 268
 269 =back
 270
 271 When calling C<Mksymlists>, one should always specify the NAME
 272 attribute.  In most cases, this is all that's necessary.  In
 273 the case of unusual extensions, however, the other attributes
 274 can be used to provide additional information to the linker.
 275
 276 =head1 AUTHOR
 277
 278 Charles Bailey I<E<lt>bailey@genetics.upenn.eduE<gt>>
 279
 280 =head1 REVISION
 281
 282 Last revised 14-Feb-1996, for Perl 5.002.