lib/ExtUtils/Mksymlists.pm

   1 package ExtUtils::Mksymlists;
   2 use strict qw[ subs refs ];
   3 # no strict 'vars';  # until filehandles are exempted
   4
   5 use Carp;
   6 use Exporter;
   7 use vars qw( @ISA @EXPORT $VERSION );
   8 @ISA = 'Exporter';
   9 @EXPORT = '&Mksymlists';
  10 $VERSION = '1.03';
  11
  12 sub Mksymlists {
  13     my(%spec) = @_;
  14     my($osname) = $^O;
  15
  16     croak("Insufficient information specified to Mksymlists")
  17         unless ( $spec{NAME} or
  18                  ($spec{FILE} and ($spec{DL_FUNCS} or $spec{FUNCLIST})) );
  19
  20     $spec{DL_VARS} = [] unless $spec{DL_VARS};
  21     ($spec{FILE} = $spec{NAME}) =~ s/.*::// unless $spec{FILE};
  22     $spec{DL_FUNCS} = { $spec{NAME} => [] }
  23         unless ( ($spec{DL_FUNCS} and keys %{$spec{DL_FUNCS}}) or
  24                  $spec{FUNCLIST});
  25     $spec{FUNCLIST} = [] unless $spec{FUNCLIST};
  26     if (defined $spec{DL_FUNCS}) {
  27         my($package);
  28         foreach $package (keys %{$spec{DL_FUNCS}}) {
  29             my($packprefix,$sym,$bootseen);
  30             ($packprefix = $package) =~ s/\W/_/g;
  31             foreach $sym (@{$spec{DL_FUNCS}->{$package}}) {
  32                 if ($sym =~ /^boot_/) {
  33                     push(@{$spec{FUNCLIST}},$sym);
  34                     $bootseen++;
  35                 }
  36                 else { push(@{$spec{FUNCLIST}},"XS_${packprefix}_$sym"); }
  37             }
  38             push(@{$spec{FUNCLIST}},"boot_$packprefix") unless $bootseen;
  39         }
  40     }
  41
  42 #    We'll need this if we ever add any OS which uses mod2fname
  43 #    require DynaLoader;
  44     if (defined &DynaLoader::mod2fname and not $spec{DLBASE}) {
  45         $spec{DLBASE} = DynaLoader::mod2fname([ split(/::/,$spec{NAME}) ]);
  46     }
  47
  48     if    ($osname eq 'aix') { _write_aix(\%spec); }
  49     elsif ($osname eq 'VMS') { _write_vms(\%spec) }
  50     elsif ($osname =~ m|^os/?2$|i) { _write_os2(\%spec) }
  51     else { croak("Don't know how to create linker option file for $osname\n"); }
  52 }
  53
  54
  55 sub _write_aix {
  56     my($data) = @_;
  57
  58     rename "$data->{FILE}.exp", "$data->{FILE}.exp_old";
  59
  60     open(EXP,">$data->{FILE}.exp")
  61         or croak("Can't create $data->{FILE}.exp: $!\n");
  62     print EXP join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  63     print EXP join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  64     close EXP;
  65 }
  66
  67
  68 sub _write_os2 {
  69     my($data) = @_;
  70
  71     if (not $data->{DLBASE}) {
  72         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
  73         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
  74     }
  75     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
  76
  77     open(DEF,">$data->{FILE}.def")
  78         or croak("Can't create $data->{FILE}.def: $!\n");
  79     print DEF "LIBRARY '$data->{DLBASE}' INITINSTANCE TERMINSTANCE\n";
  80     print DEF "CODE LOADONCALL\n";
  81     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
  82     print DEF "EXPORTS\n  ";
  83     print DEF join("\n  ",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  84     print DEF join("\n  ",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  85     if (%{$data->{IMPORTS}}) {
  86         print DEF "IMPORTS\n";
  87 my ($name, $exp);
  88 while (($name, $exp)= each %{$data->{IMPORTS}}) {
  89   print DEF "  $name=$exp\n";
  90 }
  91     }
  92     close DEF;
  93 }
  94
  95
  96 sub _write_vms {
  97     my($data) = @_;
  98
  99     require Config; # a reminder for once we do $^O
 100
 101     my($isvax) = $Config::Config{'arch'} =~ /VAX/i;
 102     my($sym);
 103
 104     rename "$data->{FILE}.opt", "$data->{FILE}.opt_old";
 105
 106     open(OPT,">$data->{FILE}.opt")
 107         or croak("Can't create $data->{FILE}.opt: $!\n");
 108
 109     # Options file declaring universal symbols
 110     # Used when linking shareable image for dynamic extension,
 111     # or when linking PerlShr into which we've added this package
 112     # as a static extension
 113     # We don't do anything to preserve order, so we won't relax
 114     # the GSMATCH criteria for a dynamic extension
 115
 116     foreach $sym (@{$data->{FUNCLIST}}) {
 117         if ($isvax) { print OPT "UNIVERSAL=$sym\n" }
 118         else        { print OPT "SYMBOL_VECTOR=($sym=PROCEDURE)\n"; }
 119     }
 120     foreach $sym (@{$data->{DL_VARS}}) {
 121         print OPT "PSECT_ATTR=${sym},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 122         if ($isvax) { print OPT "UNIVERSAL=$sym\n" }
 123         else        { print OPT "SYMBOL_VECTOR=($sym=DATA)\n"; }
 124     }
 125     close OPT;
 126
 127     # Options file specifying RTLs to which this extension must be linked.
 128     # Eventually, the list of libraries will be supplied by a working
 129     # extliblist routine.
 130     open OPT,'>rtls.opt';
 131     print OPT "PerlShr/Share\n";
 132     foreach $rtl (split(/\s+/,$Config::Config{'libs'})) { print OPT "$rtl\n"; }
 133     close OPT;
 134 }
 135
 136 1;
 137
 138 __END__
 139
 140 =head1 NAME
 141
 142 ExtUtils::Mksymlists - write linker options files for dynamic extension
 143
 144 =head1 SYNOPSIS
 145
 146     use ExtUtils::Mksymlists;
 147     Mksymlists({ NAME     => $name ,
 148                  DL_VARS  => [ $var1, $var2, $var3 ],
 149                  DL_FUNCS => { $pkg1 => [ $func1, $func2 ],
 150                                $pkg2 => [ $func3 ] });
 151
 152 =head1 DESCRIPTION
 153
 154 C<ExtUtils::Mksymlists> produces files used by the linker under some OSs
 155 during the creation of shared libraries for synamic extensions.  It is
 156 normally called from a MakeMaker-generated Makefile when the extension
 157 is built.  The linker option file is generated by calling the function
 158 C<Mksymlists>, which is exported by default from C<ExtUtils::Mksymlists>.
 159 It takes one argument, a list of key-value pairs, in which the following
 160 keys are recognized:
 161
 162 =item NAME
 163
 164 This gives the name of the extension (I<e.g.> Tk::Canvas) for which
 165 the linker option file will be produced.
 166
 167 =item DL_FUNCS
 168
 169 This is identical to the DL_FUNCS attribute available via MakeMaker,
 170 from which it is usually taken.  Its value is a reference to an
 171 associative array, in which each key is the name of a package, and
 172 each value is an a reference to an array of function names which
 173 should be exported by the extension.  For instance, one might say
 174 C<DL_FUNCS =E<gt> { Homer::Iliad   =E<gt> [ qw(trojans greeks) ],
 175 Homer::Odyssey =E<gt> [ qw(travellers family suitors) ] }>.  The
 176 function names should be identical to those in the XSUB code;
 177 C<Mksymlists> will alter the names written to the linker option
 178 file to match the changes made by F<xsubpp>.  In addition, if
 179 none of the functions in a list begin with the string B<boot_>,
 180 C<Mksymlists> will add a bootstrap function for that package,
 181 just as xsubpp does.  (If a B<boot_E<lt>pkgE<gt>> function is
 182 present in the list, it is passed through unchanged.)  If
 183 DL_FUNCS is not specified, it defaults to the bootstrap
 184 function for the extension specified in NAME.
 185
 186 =item DL_VARS
 187
 188 This is identical to the DL_VARS attribute available via MakeMaker,
 189 and, like DL_FUNCS, it is usually specified via MakeMaker.  Its
 190 value is a reference to an array of variable names which should
 191 be exported by the extension.
 192
 193 =item FILE
 194
 195 This key can be used to specify the name of the linker option file
 196 (minus the OS-specific extension), if for some reason you do not
 197 want to use the default value, which is the last word of the NAME
 198 attribute (I<e.g.> for Tk::Canvas, FILE defaults to 'Canvas').
 199
 200 =item FUNCLIST
 201
 202 This provides an alternate means to specify function names to be
 203 exported from the extension.  Its value is a reference to an
 204 array of function names to be exported by the extension.  These
 205 names are passed through unaltered to the linker options file.
 206
 207 =item DLBASE
 208
 209 This item specifies the name by which the linker knows the
 210 extension, which may be different from the name of the
 211 extension itself (for instance, some linkers add an '_' to the
 212 name of the extension).  If it is not specified, it is derived
 213 from the NAME attribute.  It is presently used only by OS2.
 214
 215 When calling C<Mksymlists>, one should always specify the NAME
 216 attribute.  In most cases, this is all that's necessary.  In
 217 the case of unusual extensions, however, the other attributes
 218 can be used to provide additional information to the linker.
 219
 220 =head1 AUTHOR
 221
 222 Charles Bailey I<E<lt>bailey@genetics.upenn.eduE<gt>>
 223
 224 =head1 REVISION
 225
 226 Last revised 14-Feb-1996, for Perl 5.002.