lib/ExtUtils/Mksymlists.pm

   1 package ExtUtils::Mksymlists;
   2 use strict qw[ subs refs ];
   3 # no strict 'vars';  # until filehandles are exempted
   4
   5 use Carp;
   6 use Exporter;
   7 use vars qw( @ISA @EXPORT $VERSION );
   8 @ISA = 'Exporter';
   9 @EXPORT = '&Mksymlists';
  10 $VERSION = substr q$Revision: 1.17 $, 10;
  11
  12 sub Mksymlists {
  13     my(%spec) = @_;
  14     my($osname) = $^O;
  15
  16     croak("Insufficient information specified to Mksymlists")
  17         unless ( $spec{NAME} or
  18                  ($spec{FILE} and ($spec{DL_FUNCS} or $spec{FUNCLIST})) );
  19
  20     $spec{DL_VARS} = [] unless $spec{DL_VARS};
  21     ($spec{FILE} = $spec{NAME}) =~ s/.*::// unless $spec{FILE};
  22     $spec{DL_FUNCS} = { $spec{NAME} => [] }
  23         unless ( ($spec{DL_FUNCS} and keys %{$spec{DL_FUNCS}}) or
  24                  $spec{FUNCLIST});
  25     $spec{FUNCLIST} = [] unless $spec{FUNCLIST};
  26     if (defined $spec{DL_FUNCS}) {
  27         my($package);
  28         foreach $package (keys %{$spec{DL_FUNCS}}) {
  29             my($packprefix,$sym,$bootseen);
  30             ($packprefix = $package) =~ s/\W/_/g;
  31             foreach $sym (@{$spec{DL_FUNCS}->{$package}}) {
  32                 if ($sym =~ /^boot_/) {
  33                     push(@{$spec{FUNCLIST}},$sym);
  34                     $bootseen++;
  35                 }
  36                 else { push(@{$spec{FUNCLIST}},"XS_${packprefix}_$sym"); }
  37             }
  38             push(@{$spec{FUNCLIST}},"boot_$packprefix") unless $bootseen;
  39         }
  40     }
  41
  42 #    We'll need this if we ever add any OS which uses mod2fname
  43 #    not as pseudo-builtin.
  44 #    require DynaLoader;
  45     if (defined &DynaLoader::mod2fname and not $spec{DLBASE}) {
  46         $spec{DLBASE} = DynaLoader::mod2fname([ split(/::/,$spec{NAME}) ]);
  47     }
  48
  49     if    ($osname eq 'aix') { _write_aix(\%spec); }
  50     elsif ($osname eq 'VMS') { _write_vms(\%spec) }
  51     elsif ($osname eq 'os2') { _write_os2(\%spec) }
  52     elsif ($osname eq 'MSWin32') { _write_win32(\%spec) }
  53     else { croak("Don't know how to create linker option file for $osname\n"); }
  54 }
  55
  56
  57 sub _write_aix {
  58     my($data) = @_;
  59
  60     rename "$data->{FILE}.exp", "$data->{FILE}.exp_old";
  61
  62     open(EXP,">$data->{FILE}.exp")
  63         or croak("Can't create $data->{FILE}.exp: $!\n");
  64     print EXP join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  65     print EXP join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  66     close EXP;
  67 }
  68
  69
  70 sub _write_os2 {
  71     my($data) = @_;
  72     require Config;
  73     my $threaded = ($Config::Config{archname} =~ /-thread/ ? " threaded" : "");
  74
  75     if (not $data->{DLBASE}) {
  76         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
  77         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
  78     }
  79     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
  80
  81     open(DEF,">$data->{FILE}.def")
  82         or croak("Can't create $data->{FILE}.def: $!\n");
  83     print DEF "LIBRARY '$data->{DLBASE}' INITINSTANCE TERMINSTANCE\n";
  84     print DEF "DESCRIPTION 'Perl (v$]$threaded) module $data->{NAME} v$data->{VERSION}'\n";
  85     print DEF "CODE LOADONCALL\n";
  86     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
  87     print DEF "EXPORTS\n  ";
  88     print DEF join("\n  ",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  89     print DEF join("\n  ",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  90     if (%{$data->{IMPORTS}}) {
  91         print DEF "IMPORTS\n";
  92 my ($name, $exp);
  93 while (($name, $exp)= each %{$data->{IMPORTS}}) {
  94   print DEF "  $name=$exp\n";
  95 }
  96     }
  97     close DEF;
  98 }
  99
 100 sub _write_win32 {
 101     my($data) = @_;
 102
 103     require Config;
 104     if (not $data->{DLBASE}) {
 105         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
 106         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
 107     }
 108     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
 109
 110     open(DEF,">$data->{FILE}.def")
 111         or croak("Can't create $data->{FILE}.def: $!\n");
 112     # put library name in quotes (it could be a keyword, like 'Alias')
 113     if ($Config::Config{'cc'} !~ /^gcc/i) {
 114       print DEF "LIBRARY \"$data->{DLBASE}\"\n";
 115       print DEF "CODE LOADONCALL\n";
 116       print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
 117     }
 118     print DEF "EXPORTS\n  ";
 119     my @syms;
 120     # Export public symbols both with and without underscores to
 121     # ensure compatibility between DLLs from different compilers
 122     # NOTE: DynaLoader itself only uses the names without underscores,
 123     # so this is only to cover the case when the extension DLL may be
 124     # linked to directly from C. GSAR 97-07-10
 125     if ($Config::Config{'cc'} =~ /^bcc/i) {
 126         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 127             push @syms, "_$_", "$_ = _$_";
 128         }
 129     }
 130     else {
 131         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 132             push @syms, "$_", "_$_ = $_";
 133         }
 134     }
 135     print DEF join("\n  ",@syms, "\n") if @syms;
 136     if (%{$data->{IMPORTS}}) {
 137         print DEF "IMPORTS\n";
 138         my ($name, $exp);
 139         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 140             print DEF "  $name=$exp\n";
 141         }
 142     }
 143     close DEF;
 144 }
 145
 146
 147 sub _write_vms {
 148     my($data) = @_;
 149
 150     require Config; # a reminder for once we do $^O
 151     require ExtUtils::XSSymSet;
 152
 153     my($isvax) = $Config::Config{'arch'} =~ /VAX/i;
 154     my($set) = new ExtUtils::XSSymSet;
 155     my($sym);
 156
 157     rename "$data->{FILE}.opt", "$data->{FILE}.opt_old";
 158
 159     open(OPT,">$data->{FILE}.opt")
 160         or croak("Can't create $data->{FILE}.opt: $!\n");
 161
 162     # Options file declaring universal symbols
 163     # Used when linking shareable image for dynamic extension,
 164     # or when linking PerlShr into which we've added this package
 165     # as a static extension
 166     # We don't do anything to preserve order, so we won't relax
 167     # the GSMATCH criteria for a dynamic extension
 168
 169     foreach $sym (@{$data->{FUNCLIST}}) {
 170         my $safe = $set->addsym($sym);
 171         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 172         else        { print OPT "SYMBOL_VECTOR=($safe=PROCEDURE)\n"; }
 173     }
 174     foreach $sym (@{$data->{DL_VARS}}) {
 175         my $safe = $set->addsym($sym);
 176         print OPT "PSECT_ATTR=${sym},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 177         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 178         else        { print OPT "SYMBOL_VECTOR=($safe=DATA)\n"; }
 179     }
 180     close OPT;
 181
 182 }
 183
 184 1;
 185
 186 __END__
 187
 188 =head1 NAME
 189
 190 ExtUtils::Mksymlists - write linker options files for dynamic extension
 191
 192 =head1 SYNOPSIS
 193
 194     use ExtUtils::Mksymlists;
 195     Mksymlists({ NAME     => $name ,
 196                  DL_VARS  => [ $var1, $var2, $var3 ],
 197                  DL_FUNCS => { $pkg1 => [ $func1, $func2 ],
 198                                $pkg2 => [ $func3 ] });
 199
 200 =head1 DESCRIPTION
 201
 202 C<ExtUtils::Mksymlists> produces files used by the linker under some OSs
 203 during the creation of shared libraries for dynamic extensions.  It is
 204 normally called from a MakeMaker-generated Makefile when the extension
 205 is built.  The linker option file is generated by calling the function
 206 C<Mksymlists>, which is exported by default from C<ExtUtils::Mksymlists>.
 207 It takes one argument, a list of key-value pairs, in which the following
 208 keys are recognized:
 209
 210 =over
 211
 212 =item NAME
 213
 214 This gives the name of the extension (I<e.g.> Tk::Canvas) for which
 215 the linker option file will be produced.
 216
 217 =item DL_FUNCS
 218
 219 This is identical to the DL_FUNCS attribute available via MakeMaker,
 220 from which it is usually taken.  Its value is a reference to an
 221 associative array, in which each key is the name of a package, and
 222 each value is an a reference to an array of function names which
 223 should be exported by the extension.  For instance, one might say
 224 C<DL_FUNCS =E<gt> { Homer::Iliad   =E<gt> [ qw(trojans greeks) ],
 225 Homer::Odyssey =E<gt> [ qw(travellers family suitors) ] }>.  The
 226 function names should be identical to those in the XSUB code;
 227 C<Mksymlists> will alter the names written to the linker option
 228 file to match the changes made by F<xsubpp>.  In addition, if
 229 none of the functions in a list begin with the string B<boot_>,
 230 C<Mksymlists> will add a bootstrap function for that package,
 231 just as xsubpp does.  (If a B<boot_E<lt>pkgE<gt>> function is
 232 present in the list, it is passed through unchanged.)  If
 233 DL_FUNCS is not specified, it defaults to the bootstrap
 234 function for the extension specified in NAME.
 235
 236 =item DL_VARS
 237
 238 This is identical to the DL_VARS attribute available via MakeMaker,
 239 and, like DL_FUNCS, it is usually specified via MakeMaker.  Its
 240 value is a reference to an array of variable names which should
 241 be exported by the extension.
 242
 243 =item FILE
 244
 245 This key can be used to specify the name of the linker option file
 246 (minus the OS-specific extension), if for some reason you do not
 247 want to use the default value, which is the last word of the NAME
 248 attribute (I<e.g.> for Tk::Canvas, FILE defaults to 'Canvas').
 249
 250 =item FUNCLIST
 251
 252 This provides an alternate means to specify function names to be
 253 exported from the extension.  Its value is a reference to an
 254 array of function names to be exported by the extension.  These
 255 names are passed through unaltered to the linker options file.
 256
 257 =item DLBASE
 258
 259 This item specifies the name by which the linker knows the
 260 extension, which may be different from the name of the
 261 extension itself (for instance, some linkers add an '_' to the
 262 name of the extension).  If it is not specified, it is derived
 263 from the NAME attribute.  It is presently used only by OS2.
 264
 265 =back
 266
 267 When calling C<Mksymlists>, one should always specify the NAME
 268 attribute.  In most cases, this is all that's necessary.  In
 269 the case of unusual extensions, however, the other attributes
 270 can be used to provide additional information to the linker.
 271
 272 =head1 AUTHOR
 273
 274 Charles Bailey I<E<lt>bailey@genetics.upenn.eduE<gt>>
 275
 276 =head1 REVISION
 277
 278 Last revised 14-Feb-1996, for Perl 5.002.