lib/ExtUtils/Mksymlists.pm

   1 package ExtUtils::Mksymlists;
   2
   3 use 5.006_001;
   4 use strict qw[ subs refs ];
   5 # no strict 'vars';  # until filehandles are exempted
   6
   7 use Carp;
   8 use Exporter;
   9 use Config;
  10 our(@ISA, @EXPORT, $VERSION);
  11 @ISA = 'Exporter';
  12 @EXPORT = '&Mksymlists';
  13 $VERSION = 1.18_00;
  14
  15 sub Mksymlists {
  16     my(%spec) = @_;
  17     my($osname) = $^O;
  18
  19     croak("Insufficient information specified to Mksymlists")
  20         unless ( $spec{NAME} or
  21                  ($spec{FILE} and ($spec{DL_FUNCS} or $spec{FUNCLIST})) );
  22
  23     $spec{DL_VARS} = [] unless $spec{DL_VARS};
  24     ($spec{FILE} = $spec{NAME}) =~ s/.*::// unless $spec{FILE};
  25     $spec{FUNCLIST} = [] unless $spec{FUNCLIST};
  26     $spec{DL_FUNCS} = { $spec{NAME} => [] }
  27         unless ( ($spec{DL_FUNCS} and keys %{$spec{DL_FUNCS}}) or
  28                  @{$spec{FUNCLIST}});
  29     if (defined $spec{DL_FUNCS}) {
  30         my($package);
  31         foreach $package (keys %{$spec{DL_FUNCS}}) {
  32             my($packprefix,$sym,$bootseen);
  33             ($packprefix = $package) =~ s/\W/_/g;
  34             foreach $sym (@{$spec{DL_FUNCS}->{$package}}) {
  35                 if ($sym =~ /^boot_/) {
  36                     push(@{$spec{FUNCLIST}},$sym);
  37                     $bootseen++;
  38                 }
  39                 else { push(@{$spec{FUNCLIST}},"XS_${packprefix}_$sym"); }
  40             }
  41             push(@{$spec{FUNCLIST}},"boot_$packprefix") unless $bootseen;
  42         }
  43     }
  44
  45 #    We'll need this if we ever add any OS which uses mod2fname
  46 #    not as pseudo-builtin.
  47 #    require DynaLoader;
  48     if (defined &DynaLoader::mod2fname and not $spec{DLBASE}) {
  49         $spec{DLBASE} = DynaLoader::mod2fname([ split(/::/,$spec{NAME}) ]);
  50     }
  51
  52     if    ($osname eq 'aix') { _write_aix(\%spec); }
  53     elsif ($osname eq 'MacOS'){ _write_aix(\%spec) }
  54     elsif ($osname eq 'VMS') { _write_vms(\%spec) }
  55     elsif ($osname eq 'os2') { _write_os2(\%spec) }
  56     elsif ($osname eq 'MSWin32') { _write_win32(\%spec) }
  57     else { croak("Don't know how to create linker option file for $osname\n"); }
  58 }
  59
  60
  61 sub _write_aix {
  62     my($data) = @_;
  63
  64     rename "$data->{FILE}.exp", "$data->{FILE}.exp_old";
  65
  66     open(EXP,">$data->{FILE}.exp")
  67         or croak("Can't create $data->{FILE}.exp: $!\n");
  68     print EXP join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  69     print EXP join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  70     close EXP;
  71 }
  72
  73
  74 sub _write_os2 {
  75     my($data) = @_;
  76     require Config;
  77     my $threaded = ($Config::Config{archname} =~ /-thread/ ? " threaded" : "");
  78
  79     if (not $data->{DLBASE}) {
  80         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
  81         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
  82     }
  83     my $distname = $data->{DISTNAME} || $data->{NAME};
  84     $distname = "Distribution $distname";
  85     my $patchlevel = $Config{perl_patchlevel} || '';
  86     $patchlevel = " pl$patchlevel" if $patchlevel;
  87     my $comment = <<EOC;
  88 Perl (v$Config::Config{version}$threaded$patchlevel) module $data->{NAME}
  89 EOC
  90     chomp $comment;
  91     if ($data->{INSTALLDIRS} and $data->{INSTALLDIRS} eq 'perl') {
  92         $distname = 'perl5-porters@perl.org';
  93         $comment = "Core $comment";
  94     }
  95     $comment = "$comment (Perl-config: $Config{config_args})";
  96     $comment = substr($comment, 0, 200) . "...)" if length $comment > 203;
  97     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
  98
  99     open(DEF,">$data->{FILE}.def")
 100         or croak("Can't create $data->{FILE}.def: $!\n");
 101     print DEF "LIBRARY '$data->{DLBASE}' INITINSTANCE TERMINSTANCE\n";
 102     print DEF "DESCRIPTION '\@#$distname:$data->{VERSION}#\@ $comment'\n";
 103     print DEF "CODE LOADONCALL\n";
 104     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
 105     print DEF "EXPORTS\n  ";
 106     print DEF join("\n  ",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
 107     print DEF join("\n  ",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
 108     if (%{$data->{IMPORTS}}) {
 109         print DEF "IMPORTS\n";
 110         my ($name, $exp);
 111         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 112             print DEF "  $name=$exp\n";
 113         }
 114     }
 115     close DEF;
 116 }
 117
 118 sub _write_win32 {
 119     my($data) = @_;
 120
 121     require Config;
 122     if (not $data->{DLBASE}) {
 123         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
 124         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
 125     }
 126     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
 127
 128     open(DEF,">$data->{FILE}.def")
 129         or croak("Can't create $data->{FILE}.def: $!\n");
 130     # put library name in quotes (it could be a keyword, like 'Alias')
 131     if ($Config::Config{'cc'} !~ /^gcc/i) {
 132       print DEF "LIBRARY \"$data->{DLBASE}\"\n";
 133     }
 134     print DEF "EXPORTS\n  ";
 135     my @syms;
 136     # Export public symbols both with and without underscores to
 137     # ensure compatibility between DLLs from different compilers
 138     # NOTE: DynaLoader itself only uses the names without underscores,
 139     # so this is only to cover the case when the extension DLL may be
 140     # linked to directly from C. GSAR 97-07-10
 141     if ($Config::Config{'cc'} =~ /^bcc/i) {
 142         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 143             push @syms, "_$_", "$_ = _$_";
 144         }
 145     }
 146     else {
 147         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 148             push @syms, "$_", "_$_ = $_";
 149         }
 150     }
 151     print DEF join("\n  ",@syms, "\n") if @syms;
 152     if (%{$data->{IMPORTS}}) {
 153         print DEF "IMPORTS\n";
 154         my ($name, $exp);
 155         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 156             print DEF "  $name=$exp\n";
 157         }
 158     }
 159     close DEF;
 160 }
 161
 162
 163 sub _write_vms {
 164     my($data) = @_;
 165
 166     require Config; # a reminder for once we do $^O
 167     require ExtUtils::XSSymSet;
 168
 169     my($isvax) = $Config::Config{'archname'} =~ /VAX/i;
 170     my($set) = new ExtUtils::XSSymSet;
 171     my($sym);
 172
 173     rename "$data->{FILE}.opt", "$data->{FILE}.opt_old";
 174
 175     open(OPT,">$data->{FILE}.opt")
 176         or croak("Can't create $data->{FILE}.opt: $!\n");
 177
 178     # Options file declaring universal symbols
 179     # Used when linking shareable image for dynamic extension,
 180     # or when linking PerlShr into which we've added this package
 181     # as a static extension
 182     # We don't do anything to preserve order, so we won't relax
 183     # the GSMATCH criteria for a dynamic extension
 184
 185     print OPT "case_sensitive=yes\n"
 186         if $Config::Config{d_vms_case_sensitive_symbols};
 187     foreach $sym (@{$data->{FUNCLIST}}) {
 188         my $safe = $set->addsym($sym);
 189         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 190         else        { print OPT "SYMBOL_VECTOR=($safe=PROCEDURE)\n"; }
 191     }
 192     foreach $sym (@{$data->{DL_VARS}}) {
 193         my $safe = $set->addsym($sym);
 194         print OPT "PSECT_ATTR=${sym},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 195         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 196         else        { print OPT "SYMBOL_VECTOR=($safe=DATA)\n"; }
 197     }
 198     close OPT;
 199
 200 }
 201
 202 1;
 203
 204 __END__
 205
 206 =head1 NAME
 207
 208 ExtUtils::Mksymlists - write linker options files for dynamic extension
 209
 210 =head1 SYNOPSIS
 211
 212     use ExtUtils::Mksymlists;
 213     Mksymlists({ NAME     => $name ,
 214                  DL_VARS  => [ $var1, $var2, $var3 ],
 215                  DL_FUNCS => { $pkg1 => [ $func1, $func2 ],
 216                                $pkg2 => [ $func3 ] });
 217
 218 =head1 DESCRIPTION
 219
 220 C<ExtUtils::Mksymlists> produces files used by the linker under some OSs
 221 during the creation of shared libraries for dynamic extensions.  It is
 222 normally called from a MakeMaker-generated Makefile when the extension
 223 is built.  The linker option file is generated by calling the function
 224 C<Mksymlists>, which is exported by default from C<ExtUtils::Mksymlists>.
 225 It takes one argument, a list of key-value pairs, in which the following
 226 keys are recognized:
 227
 228 =over 4
 229
 230 =item DLBASE
 231
 232 This item specifies the name by which the linker knows the
 233 extension, which may be different from the name of the
 234 extension itself (for instance, some linkers add an '_' to the
 235 name of the extension).  If it is not specified, it is derived
 236 from the NAME attribute.  It is presently used only by OS2 and Win32.
 237
 238 =item DL_FUNCS
 239
 240 This is identical to the DL_FUNCS attribute available via MakeMaker,
 241 from which it is usually taken.  Its value is a reference to an
 242 associative array, in which each key is the name of a package, and
 243 each value is an a reference to an array of function names which
 244 should be exported by the extension.  For instance, one might say
 245 C<DL_FUNCS =E<gt> { Homer::Iliad =E<gt> [ qw(trojans greeks) ],
 246 Homer::Odyssey =E<gt> [ qw(travellers family suitors) ] }>.  The
 247 function names should be identical to those in the XSUB code;
 248 C<Mksymlists> will alter the names written to the linker option
 249 file to match the changes made by F<xsubpp>.  In addition, if
 250 none of the functions in a list begin with the string B<boot_>,
 251 C<Mksymlists> will add a bootstrap function for that package,
 252 just as xsubpp does.  (If a B<boot_E<lt>pkgE<gt>> function is
 253 present in the list, it is passed through unchanged.)  If
 254 DL_FUNCS is not specified, it defaults to the bootstrap
 255 function for the extension specified in NAME.
 256
 257 =item DL_VARS
 258
 259 This is identical to the DL_VARS attribute available via MakeMaker,
 260 and, like DL_FUNCS, it is usually specified via MakeMaker.  Its
 261 value is a reference to an array of variable names which should
 262 be exported by the extension.
 263
 264 =item FILE
 265
 266 This key can be used to specify the name of the linker option file
 267 (minus the OS-specific extension), if for some reason you do not
 268 want to use the default value, which is the last word of the NAME
 269 attribute (I<e.g.> for C<Tk::Canvas>, FILE defaults to C<Canvas>).
 270
 271 =item FUNCLIST
 272
 273 This provides an alternate means to specify function names to be
 274 exported from the extension.  Its value is a reference to an
 275 array of function names to be exported by the extension.  These
 276 names are passed through unaltered to the linker options file.
 277 Specifying a value for the FUNCLIST attribute suppresses automatic
 278 generation of the bootstrap function for the package. To still create
 279 the bootstrap name you have to specify the package name in the
 280 DL_FUNCS hash:
 281
 282     Mksymlists({ NAME     => $name ,
 283                  FUNCLIST => [ $func1, $func2 ],
 284                  DL_FUNCS => { $pkg => [] } });
 285
 286
 287 =item IMPORTS
 288
 289 This attribute is used to specify names to be imported into the
 290 extension. It is currently only used by OS/2 and Win32.
 291
 292 =item NAME
 293
 294 This gives the name of the extension (I<e.g.> C<Tk::Canvas>) for which
 295 the linker option file will be produced.
 296
 297 =back
 298
 299 When calling C<Mksymlists>, one should always specify the NAME
 300 attribute.  In most cases, this is all that's necessary.  In
 301 the case of unusual extensions, however, the other attributes
 302 can be used to provide additional information to the linker.
 303
 304 =head1 AUTHOR
 305
 306 Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>>
 307
 308 =head1 REVISION
 309
 310 Last revised 14-Feb-1996, for Perl 5.002.