lib/ExtUtils/Mksymlists.pm

   1 package ExtUtils::Mksymlists;
   2 use strict qw[ subs refs ];
   3 # no strict 'vars';  # until filehandles are exempted
   4
   5 use Carp;
   6 use Exporter;
   7 use vars qw( @ISA @EXPORT $VERSION );
   8 @ISA = 'Exporter';
   9 @EXPORT = '&Mksymlists';
  10 $VERSION = substr q$Revision: 1.17 $, 10;
  11
  12 sub Mksymlists {
  13     my(%spec) = @_;
  14     my($osname) = $^O;
  15
  16     croak("Insufficient information specified to Mksymlists")
  17         unless ( $spec{NAME} or
  18                  ($spec{FILE} and ($spec{DL_FUNCS} or $spec{FUNCLIST})) );
  19
  20     $spec{DL_VARS} = [] unless $spec{DL_VARS};
  21     ($spec{FILE} = $spec{NAME}) =~ s/.*::// unless $spec{FILE};
  22     $spec{DL_FUNCS} = { $spec{NAME} => [] }
  23         unless ( ($spec{DL_FUNCS} and keys %{$spec{DL_FUNCS}}) or
  24                  $spec{FUNCLIST});
  25     $spec{FUNCLIST} = [] unless $spec{FUNCLIST};
  26     if (defined $spec{DL_FUNCS}) {
  27         my($package);
  28         foreach $package (keys %{$spec{DL_FUNCS}}) {
  29             my($packprefix,$sym,$bootseen);
  30             ($packprefix = $package) =~ s/\W/_/g;
  31             foreach $sym (@{$spec{DL_FUNCS}->{$package}}) {
  32                 if ($sym =~ /^boot_/) {
  33                     push(@{$spec{FUNCLIST}},$sym);
  34                     $bootseen++;
  35                 }
  36                 else { push(@{$spec{FUNCLIST}},"XS_${packprefix}_$sym"); }
  37             }
  38             push(@{$spec{FUNCLIST}},"boot_$packprefix") unless $bootseen;
  39         }
  40     }
  41
  42 #    We'll need this if we ever add any OS which uses mod2fname
  43 #    not as pseudo-builtin.
  44 #    require DynaLoader;
  45     if (defined &DynaLoader::mod2fname and not $spec{DLBASE}) {
  46         $spec{DLBASE} = DynaLoader::mod2fname([ split(/::/,$spec{NAME}) ]);
  47     }
  48
  49     if    ($osname eq 'aix') { _write_aix(\%spec); }
  50     elsif ($osname eq 'VMS') { _write_vms(\%spec) }
  51     elsif ($osname eq 'os2') { _write_os2(\%spec) }
  52     elsif ($osname eq 'MSWin32') { _write_win32(\%spec) }
  53     else { croak("Don't know how to create linker option file for $osname\n"); }
  54 }
  55
  56
  57 sub _write_aix {
  58     my($data) = @_;
  59
  60     rename "$data->{FILE}.exp", "$data->{FILE}.exp_old";
  61
  62     open(EXP,">$data->{FILE}.exp")
  63         or croak("Can't create $data->{FILE}.exp: $!\n");
  64     print EXP join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  65     print EXP join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  66     close EXP;
  67 }
  68
  69
  70 sub _write_os2 {
  71     my($data) = @_;
  72     require Config;
  73     my $threaded = ($Config::Config{archname} =~ /-thread/ ? " threaded" : "");
  74
  75     if (not $data->{DLBASE}) {
  76         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
  77         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
  78     }
  79     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
  80
  81     open(DEF,">$data->{FILE}.def")
  82         or croak("Can't create $data->{FILE}.def: $!\n");
  83     print DEF "LIBRARY '$data->{DLBASE}' INITINSTANCE TERMINSTANCE\n";
  84     print DEF "DESCRIPTION 'Perl (v$]$threaded) module $data->{NAME} v$data->{VERSION}'\n";
  85     print DEF "CODE LOADONCALL\n";
  86     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
  87     print DEF "EXPORTS\n  ";
  88     print DEF join("\n  ",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  89     print DEF join("\n  ",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  90     if (%{$data->{IMPORTS}}) {
  91         print DEF "IMPORTS\n";
  92 my ($name, $exp);
  93 while (($name, $exp)= each %{$data->{IMPORTS}}) {
  94   print DEF "  $name=$exp\n";
  95 }
  96     }
  97     close DEF;
  98 }
  99
 100 sub _write_win32 {
 101     my($data) = @_;
 102
 103     require Config;
 104     if (not $data->{DLBASE}) {
 105         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
 106         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
 107     }
 108     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
 109
 110     open(DEF,">$data->{FILE}.def")
 111         or croak("Can't create $data->{FILE}.def: $!\n");
 112     # put library name in quotes (it could be a keyword, like 'Alias')
 113     if ($Config::Config{'cc'} !~ /^gcc/i) {
 114       print DEF "LIBRARY \"$data->{DLBASE}\"\n";
 115     }
 116     print DEF "EXPORTS\n  ";
 117     my @syms;
 118     # Export public symbols both with and without underscores to
 119     # ensure compatibility between DLLs from different compilers
 120     # NOTE: DynaLoader itself only uses the names without underscores,
 121     # so this is only to cover the case when the extension DLL may be
 122     # linked to directly from C. GSAR 97-07-10
 123     if ($Config::Config{'cc'} =~ /^bcc/i) {
 124         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 125             push @syms, "_$_", "$_ = _$_";
 126         }
 127     }
 128     else {
 129         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 130             push @syms, "$_", "_$_ = $_";
 131         }
 132     }
 133     print DEF join("\n  ",@syms, "\n") if @syms;
 134     if (%{$data->{IMPORTS}}) {
 135         print DEF "IMPORTS\n";
 136         my ($name, $exp);
 137         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 138             print DEF "  $name=$exp\n";
 139         }
 140     }
 141     close DEF;
 142 }
 143
 144
 145 sub _write_vms {
 146     my($data) = @_;
 147
 148     require Config; # a reminder for once we do $^O
 149     require ExtUtils::XSSymSet;
 150
 151     my($isvax) = $Config::Config{'arch'} =~ /VAX/i;
 152     my($set) = new ExtUtils::XSSymSet;
 153     my($sym);
 154
 155     rename "$data->{FILE}.opt", "$data->{FILE}.opt_old";
 156
 157     open(OPT,">$data->{FILE}.opt")
 158         or croak("Can't create $data->{FILE}.opt: $!\n");
 159
 160     # Options file declaring universal symbols
 161     # Used when linking shareable image for dynamic extension,
 162     # or when linking PerlShr into which we've added this package
 163     # as a static extension
 164     # We don't do anything to preserve order, so we won't relax
 165     # the GSMATCH criteria for a dynamic extension
 166
 167     foreach $sym (@{$data->{FUNCLIST}}) {
 168         my $safe = $set->addsym($sym);
 169         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 170         else        { print OPT "SYMBOL_VECTOR=($safe=PROCEDURE)\n"; }
 171     }
 172     foreach $sym (@{$data->{DL_VARS}}) {
 173         my $safe = $set->addsym($sym);
 174         print OPT "PSECT_ATTR=${sym},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 175         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 176         else        { print OPT "SYMBOL_VECTOR=($safe=DATA)\n"; }
 177     }
 178     close OPT;
 179
 180 }
 181
 182 1;
 183
 184 __END__
 185
 186 =head1 NAME
 187
 188 ExtUtils::Mksymlists - write linker options files for dynamic extension
 189
 190 =head1 SYNOPSIS
 191
 192     use ExtUtils::Mksymlists;
 193     Mksymlists({ NAME     => $name ,
 194                  DL_VARS  => [ $var1, $var2, $var3 ],
 195                  DL_FUNCS => { $pkg1 => [ $func1, $func2 ],
 196                                $pkg2 => [ $func3 ] });
 197
 198 =head1 DESCRIPTION
 199
 200 C<ExtUtils::Mksymlists> produces files used by the linker under some OSs
 201 during the creation of shared libraries for dynamic extensions.  It is
 202 normally called from a MakeMaker-generated Makefile when the extension
 203 is built.  The linker option file is generated by calling the function
 204 C<Mksymlists>, which is exported by default from C<ExtUtils::Mksymlists>.
 205 It takes one argument, a list of key-value pairs, in which the following
 206 keys are recognized:
 207
 208 =over
 209
 210 =item NAME
 211
 212 This gives the name of the extension (I<e.g.> Tk::Canvas) for which
 213 the linker option file will be produced.
 214
 215 =item DL_FUNCS
 216
 217 This is identical to the DL_FUNCS attribute available via MakeMaker,
 218 from which it is usually taken.  Its value is a reference to an
 219 associative array, in which each key is the name of a package, and
 220 each value is an a reference to an array of function names which
 221 should be exported by the extension.  For instance, one might say
 222 C<DL_FUNCS =E<gt> { Homer::Iliad   =E<gt> [ qw(trojans greeks) ],
 223 Homer::Odyssey =E<gt> [ qw(travellers family suitors) ] }>.  The
 224 function names should be identical to those in the XSUB code;
 225 C<Mksymlists> will alter the names written to the linker option
 226 file to match the changes made by F<xsubpp>.  In addition, if
 227 none of the functions in a list begin with the string B<boot_>,
 228 C<Mksymlists> will add a bootstrap function for that package,
 229 just as xsubpp does.  (If a B<boot_E<lt>pkgE<gt>> function is
 230 present in the list, it is passed through unchanged.)  If
 231 DL_FUNCS is not specified, it defaults to the bootstrap
 232 function for the extension specified in NAME.
 233
 234 =item DL_VARS
 235
 236 This is identical to the DL_VARS attribute available via MakeMaker,
 237 and, like DL_FUNCS, it is usually specified via MakeMaker.  Its
 238 value is a reference to an array of variable names which should
 239 be exported by the extension.
 240
 241 =item FILE
 242
 243 This key can be used to specify the name of the linker option file
 244 (minus the OS-specific extension), if for some reason you do not
 245 want to use the default value, which is the last word of the NAME
 246 attribute (I<e.g.> for Tk::Canvas, FILE defaults to 'Canvas').
 247
 248 =item FUNCLIST
 249
 250 This provides an alternate means to specify function names to be
 251 exported from the extension.  Its value is a reference to an
 252 array of function names to be exported by the extension.  These
 253 names are passed through unaltered to the linker options file.
 254
 255 =item DLBASE
 256
 257 This item specifies the name by which the linker knows the
 258 extension, which may be different from the name of the
 259 extension itself (for instance, some linkers add an '_' to the
 260 name of the extension).  If it is not specified, it is derived
 261 from the NAME attribute.  It is presently used only by OS2.
 262
 263 =back
 264
 265 When calling C<Mksymlists>, one should always specify the NAME
 266 attribute.  In most cases, this is all that's necessary.  In
 267 the case of unusual extensions, however, the other attributes
 268 can be used to provide additional information to the linker.
 269
 270 =head1 AUTHOR
 271
 272 Charles Bailey I<E<lt>bailey@genetics.upenn.eduE<gt>>
 273
 274 =head1 REVISION
 275
 276 Last revised 14-Feb-1996, for Perl 5.002.