lib/ExtUtils/MM_Unix.pm

   1 package ExtUtils::MM_Unix;
   2
   3 use Exporter ();
   4 use Config;
   5 use File::Basename qw(basename dirname fileparse);
   6 use DirHandle;
   7 use strict;
   8 use vars qw($VERSION $Is_Mac $Is_OS2 $Is_VMS
   9             $Verbose %pm %static $Xsubpp_Version);
  10
  11 $VERSION = substr q$Revision: 1.107 $, 10;
  12 # $Id: MM_Unix.pm,v 1.107 1996/09/03 20:53:39 k Exp $
  13
  14 Exporter::import('ExtUtils::MakeMaker',
  15         qw( $Verbose &neatvalue));
  16
  17 $Is_OS2 = $^O =~ m|^os/?2$|i;
  18 $Is_Mac = $^O eq "MacOS";
  19
  20 if ($Is_VMS = $^O eq 'VMS') {
  21     require VMS::Filespec;
  22     import VMS::Filespec qw( &vmsify );
  23 }
  24
  25 =head1 NAME
  26
  27 ExtUtils::MM_Unix - methods used by ExtUtils::MakeMaker
  28
  29 =head1 SYNOPSIS
  30
  31 C<require ExtUtils::MM_Unix;>
  32
  33 =head1 DESCRIPTION
  34
  35 The methods provided by this package are designed to be used in
  36 conjunction with ExtUtils::MakeMaker. When MakeMaker writes a
  37 Makefile, it creates one or more objects that inherit their methods
  38 from a package C<MM>. MM itself doesn't provide any methods, but it
  39 ISA ExtUtils::MM_Unix class. The inheritance tree of MM lets operating
  40 specific packages take the responsibility for all the methods provided
  41 by MM_Unix. We are trying to reduce the number of the necessary
  42 overrides by defining rather primitive operations within
  43 ExtUtils::MM_Unix.
  44
  45 If you are going to write a platform specific MM package, please try
  46 to limit the necessary overrides to primitive methods, and if it is not
  47 possible to do so, let's work out how to achieve that gain.
  48
  49 If you are overriding any of these methods in your Makefile.PL (in the
  50 MY class), please report that to the makemaker mailing list. We are
  51 trying to minimize the necessary method overrides and switch to data
  52 driven Makefile.PLs wherever possible. In the long run less methods
  53 will be overridable via the MY class.
  54
  55 =head1 METHODS
  56
  57 The following description of methods is still under
  58 development. Please refer to the code for not suitably documented
  59 sections and complain loudly to the makemaker mailing list.
  60
  61 Not all of the methods below are overridable in a
  62 Makefile.PL. Overridable methods are marked as (o). All methods are
  63 overridable by a platform specific MM_*.pm file (See
  64 L<ExtUtils::MM_VMS> and L<ExtUtils::MM_OS2>).
  65
  66 =head2 Preloaded methods
  67
  68 =over 2
  69
  70 =item canonpath
  71
  72 No physical check on the filesystem, but a logical cleanup of a
  73 path. On UNIX eliminated successive slashes and successive "/.".
  74
  75 =cut
  76
  77 sub canonpath {
  78     my($self,$path) = @_;
  79     $path =~ s|/+|/|g ;                            # xx////xx  -> xx/xx
  80     $path =~ s|(/\.)+/|/|g ;                       # xx/././xx -> xx/xx
  81     $path =~ s|^(\./)+|| unless $path eq "./";     # ./xx      -> xx
  82     $path =~ s|/$|| unless $path eq "/";           # xx/       -> xx
  83     $path;
  84 }
  85
  86 =item catdir
  87
  88 Concatenate two or more directory names to form a complete path ending
  89 with a directory. But remove the trailing slash from the resulting
  90 string, because it doesn't look good, isn't necessary and confuses
  91 OS2. Of course, if this is the root directory, don't cut off the
  92 trailing slash :-)
  93
  94 =cut
  95
  96 # ';
  97
  98 sub catdir {
  99     shift;
 100     my @args = @_;
 101     for (@args) {
 102         # append a slash to each argument unless it has one there
 103         $_ .= "/" if $_ eq '' or substr($_,-1) ne "/";
 104     }
 105     my $result = join('', @args);
 106     # remove a trailing slash unless we are root
 107     substr($result,-1) = ""
 108         if length($result) > 1 && substr($result,-1) eq "/";
 109     $result;
 110 }
 111
 112 =item catfile
 113
 114 Concatenate one or more directory names and a filename to form a
 115 complete path ending with a filename
 116
 117 =cut
 118
 119 sub catfile {
 120     my $self = shift @_;
 121     my $file = pop @_;
 122     return $file unless @_;
 123     my $dir = $self->catdir(@_);
 124     for ($dir) {
 125         $_ .= "/" unless substr($_,length($_)-1,1) eq "/";
 126     }
 127     return $dir.$file;
 128 }
 129
 130 =item curdir
 131
 132 Returns a string representing of the current directory.  "." on UNIX.
 133
 134 =cut
 135
 136 sub curdir {
 137     return "." ;
 138 }
 139
 140 =item rootdir
 141
 142 Returns a string representing of the root directory.  "/" on UNIX.
 143
 144 =cut
 145
 146 sub rootdir {
 147     return "/";
 148 }
 149
 150 =item updir
 151
 152 Returns a string representing of the parent directory.  ".." on UNIX.
 153
 154 =cut
 155
 156 sub updir {
 157     return "..";
 158 }
 159
 160 sub ExtUtils::MM_Unix::c_o ;
 161 sub ExtUtils::MM_Unix::clean ;
 162 sub ExtUtils::MM_Unix::const_cccmd ;
 163 sub ExtUtils::MM_Unix::const_config ;
 164 sub ExtUtils::MM_Unix::const_loadlibs ;
 165 sub ExtUtils::MM_Unix::constants ;
 166 sub ExtUtils::MM_Unix::depend ;
 167 sub ExtUtils::MM_Unix::dir_target ;
 168 sub ExtUtils::MM_Unix::dist ;
 169 sub ExtUtils::MM_Unix::dist_basics ;
 170 sub ExtUtils::MM_Unix::dist_ci ;
 171 sub ExtUtils::MM_Unix::dist_core ;
 172 sub ExtUtils::MM_Unix::dist_dir ;
 173 sub ExtUtils::MM_Unix::dist_test ;
 174 sub ExtUtils::MM_Unix::dlsyms ;
 175 sub ExtUtils::MM_Unix::dynamic ;
 176 sub ExtUtils::MM_Unix::dynamic_bs ;
 177 sub ExtUtils::MM_Unix::dynamic_lib ;
 178 sub ExtUtils::MM_Unix::exescan ;
 179 sub ExtUtils::MM_Unix::extliblist ;
 180 sub ExtUtils::MM_Unix::file_name_is_absolute ;
 181 sub ExtUtils::MM_Unix::find_perl ;
 182 sub ExtUtils::MM_Unix::force ;
 183 sub ExtUtils::MM_Unix::guess_name ;
 184 sub ExtUtils::MM_Unix::has_link_code ;
 185 sub ExtUtils::MM_Unix::init_dirscan ;
 186 sub ExtUtils::MM_Unix::init_main ;
 187 sub ExtUtils::MM_Unix::init_others ;
 188 sub ExtUtils::MM_Unix::install ;
 189 sub ExtUtils::MM_Unix::installbin ;
 190 sub ExtUtils::MM_Unix::libscan ;
 191 sub ExtUtils::MM_Unix::linkext ;
 192 sub ExtUtils::MM_Unix::lsdir ;
 193 sub ExtUtils::MM_Unix::macro ;
 194 sub ExtUtils::MM_Unix::makeaperl ;
 195 sub ExtUtils::MM_Unix::makefile ;
 196 sub ExtUtils::MM_Unix::manifypods ;
 197 sub ExtUtils::MM_Unix::maybe_command ;
 198 sub ExtUtils::MM_Unix::maybe_command_in_dirs ;
 199 sub ExtUtils::MM_Unix::needs_linking ;
 200 sub ExtUtils::MM_Unix::nicetext ;
 201 sub ExtUtils::MM_Unix::parse_version ;
 202 sub ExtUtils::MM_Unix::pasthru ;
 203 sub ExtUtils::MM_Unix::path ;
 204 sub ExtUtils::MM_Unix::perl_script ;
 205 sub ExtUtils::MM_Unix::perldepend ;
 206 sub ExtUtils::MM_Unix::pm_to_blib ;
 207 sub ExtUtils::MM_Unix::post_constants ;
 208 sub ExtUtils::MM_Unix::post_initialize ;
 209 sub ExtUtils::MM_Unix::postamble ;
 210 sub ExtUtils::MM_Unix::prefixify ;
 211 sub ExtUtils::MM_Unix::processPL ;
 212 sub ExtUtils::MM_Unix::realclean ;
 213 sub ExtUtils::MM_Unix::replace_manpage_separator ;
 214 sub ExtUtils::MM_Unix::static ;
 215 sub ExtUtils::MM_Unix::static_lib ;
 216 sub ExtUtils::MM_Unix::staticmake ;
 217 sub ExtUtils::MM_Unix::subdir_x ;
 218 sub ExtUtils::MM_Unix::subdirs ;
 219 sub ExtUtils::MM_Unix::test ;
 220 sub ExtUtils::MM_Unix::test_via_harness ;
 221 sub ExtUtils::MM_Unix::test_via_script ;
 222 sub ExtUtils::MM_Unix::tool_autosplit ;
 223 sub ExtUtils::MM_Unix::tool_xsubpp ;
 224 sub ExtUtils::MM_Unix::tools_other ;
 225 sub ExtUtils::MM_Unix::top_targets ;
 226 sub ExtUtils::MM_Unix::writedoc ;
 227 sub ExtUtils::MM_Unix::xs_c ;
 228 sub ExtUtils::MM_Unix::xs_o ;
 229 sub ExtUtils::MM_Unix::xsubpp_version ;
 230
 231 package ExtUtils::MM_Unix;
 232
 233 use SelfLoader;
 234
 235 1;
 236
 237 __DATA__
 238
 239 =head2 SelfLoaded methods
 240
 241 =item c_o (o)
 242
 243 Defines the suffix rules to compile different flavors of C files to
 244 object files.
 245
 246 =cut
 247
 248 sub c_o {
 249 # --- Translation Sections ---
 250
 251     my($self) = shift;
 252     return '' unless $self->needs_linking();
 253     my(@m);
 254     push @m, '
 255 .c$(OBJ_EXT):
 256         $(CCCMD) $(CCCDLFLAGS) -I$(PERL_INC) $(DEFINE) $*.c
 257 ';
 258     push @m, '
 259 .C$(OBJ_EXT):
 260         $(CCCMD) $(CCCDLFLAGS) -I$(PERL_INC) $(DEFINE) $*.C
 261 ' if $^O ne 'os2';                      # Case-specific
 262     push @m, '
 263 .cpp$(OBJ_EXT):
 264         $(CCCMD) $(CCCDLFLAGS) -I$(PERL_INC) $(DEFINE) $*.cpp
 265
 266 .cxx$(OBJ_EXT):
 267         $(CCCMD) $(CCCDLFLAGS) -I$(PERL_INC) $(DEFINE) $*.cxx
 268
 269 .cc$(OBJ_EXT):
 270         $(CCCMD) $(CCCDLFLAGS) -I$(PERL_INC) $(DEFINE) $*.cc
 271 ';
 272     join "", @m;
 273 }
 274
 275 =item cflags (o)
 276
 277 Does very much the same as the cflags script in the perl
 278 distribution. It doesn't return the whole compiler command line, but
 279 initializes all of its parts. The const_cccmd method then actually
 280 returns the definition of the CCCMD macro which uses these parts.
 281
 282 =cut
 283
 284 #'
 285
 286 sub cflags {
 287     my($self,$libperl)=@_;
 288     return $self->{CFLAGS} if $self->{CFLAGS};
 289     return '' unless $self->needs_linking();
 290
 291     my($prog, $uc, $perltype, %cflags);
 292     $libperl ||= $self->{LIBPERL_A} || "libperl$self->{LIB_EXT}" ;
 293     $libperl =~ s/\.\$\(A\)$/$self->{LIB_EXT}/;
 294
 295     @cflags{qw(cc ccflags optimize large split shellflags)}
 296         = @Config{qw(cc ccflags optimize large split shellflags)};
 297     my($optdebug) = "";
 298
 299     $cflags{shellflags} ||= '';
 300
 301     my(%map) =  (
 302                 D =>   '-DDEBUGGING',
 303                 E =>   '-DEMBED',
 304                 DE =>  '-DDEBUGGING -DEMBED',
 305                 M =>   '-DEMBED -DMULTIPLICITY',
 306                 DM =>  '-DDEBUGGING -DEMBED -DMULTIPLICITY',
 307                 );
 308
 309     if ($libperl =~ /libperl(\w*)\Q$self->{LIB_EXT}/){
 310         $uc = uc($1);
 311     } else {
 312         $uc = ""; # avoid warning
 313     }
 314     $perltype = $map{$uc} ? $map{$uc} : "";
 315
 316     if ($uc =~ /^D/) {
 317         $optdebug = "-g";
 318     }
 319
 320
 321     my($name);
 322     ( $name = $self->{NAME} . "_cflags" ) =~ s/:/_/g ;
 323     if ($prog = $Config::Config{$name}) {
 324         # Expand hints for this extension via the shell
 325         print STDOUT "Processing $name hint:\n" if $Verbose;
 326         my(@o)=`cc=\"$cflags{cc}\"
 327           ccflags=\"$cflags{ccflags}\"
 328           optimize=\"$cflags{optimize}\"
 329           perltype=\"$cflags{perltype}\"
 330           optdebug=\"$cflags{optdebug}\"
 331           large=\"$cflags{large}\"
 332           split=\"$cflags{'split'}\"
 333           eval '$prog'
 334           echo cc=\$cc
 335           echo ccflags=\$ccflags
 336           echo optimize=\$optimize
 337           echo perltype=\$perltype
 338           echo optdebug=\$optdebug
 339           echo large=\$large
 340           echo split=\$split
 341           `;
 342         my($line);
 343         foreach $line (@o){
 344             chomp $line;
 345             if ($line =~ /(.*?)=\s*(.*)\s*$/){
 346                 $cflags{$1} = $2;
 347                 print STDOUT "  $1 = $2\n" if $Verbose;
 348             } else {
 349                 print STDOUT "Unrecognised result from hint: '$line'\n";
 350             }
 351         }
 352     }
 353
 354     if ($optdebug) {
 355         $cflags{optimize} = $optdebug;
 356     }
 357
 358     for (qw(ccflags optimize perltype large split)) {
 359         $cflags{$_} =~ s/^\s+//;
 360         $cflags{$_} =~ s/\s+/ /g;
 361         $cflags{$_} =~ s/\s+$//;
 362         $self->{uc $_} ||= $cflags{$_}
 363     }
 364
 365     return $self->{CFLAGS} = qq{
 366 CCFLAGS = $self->{CCFLAGS}
 367 OPTIMIZE = $self->{OPTIMIZE}
 368 PERLTYPE = $self->{PERLTYPE}
 369 LARGE = $self->{LARGE}
 370 SPLIT = $self->{SPLIT}
 371 };
 372
 373 }
 374
 375 =item clean (o)
 376
 377 Defines the clean target.
 378
 379 =cut
 380
 381 sub clean {
 382 # --- Cleanup and Distribution Sections ---
 383
 384     my($self, %attribs) = @_;
 385     my(@m,$dir);
 386     push(@m, '
 387 # Delete temporary files but do not touch installed files. We don\'t delete
 388 # the Makefile here so a later make realclean still has a makefile to use.
 389
 390 clean ::
 391 ');
 392     # clean subdirectories first
 393     for $dir (@{$self->{DIR}}) {
 394         push @m, "\t-cd $dir && test -f $self->{MAKEFILE} && \$(MAKE) clean\n";
 395     }
 396
 397     my(@otherfiles) = values %{$self->{XS}}; # .c files from *.xs files
 398     push(@otherfiles, $attribs{FILES}) if $attribs{FILES};
 399     push(@otherfiles, qw[./blib $(MAKE_APERL_FILE) $(INST_ARCHAUTODIR)/extralibs.all
 400                          perlmain.c mon.out core so_locations pm_to_blib
 401                          *~ */*~ */*/*~ *$(OBJ_EXT) *$(LIB_EXT) perl.exe
 402                          $(BOOTSTRAP) $(BASEEXT).bso $(BASEEXT).def
 403                          $(BASEEXT).exp
 404                         ]);
 405     push @m, "\t-$self->{RM_RF} @otherfiles\n";
 406     # See realclean and ext/utils/make_ext for usage of Makefile.old
 407     push(@m,
 408          "\t-$self->{MV} $self->{MAKEFILE} $self->{MAKEFILE}.old 2>/dev/null\n");
 409     push(@m,
 410          "\t$attribs{POSTOP}\n")   if $attribs{POSTOP};
 411     join("", @m);
 412 }
 413
 414 =item const_cccmd (o)
 415
 416 Returns the full compiler call for C programs and stores the
 417 definition in CONST_CCCMD.
 418
 419 =cut
 420
 421 sub const_cccmd {
 422     my($self,$libperl)=@_;
 423     return $self->{CONST_CCCMD} if $self->{CONST_CCCMD};
 424     return '' unless $self->needs_linking();
 425     return $self->{CONST_CCCMD} =
 426         q{CCCMD = $(CC) -c $(INC) $(CCFLAGS) $(OPTIMIZE) \\
 427         $(PERLTYPE) $(LARGE) $(SPLIT) $(DEFINE_VERSION) \\
 428         $(XS_DEFINE_VERSION)};
 429 }
 430
 431 =item const_config (o)
 432
 433 Defines a couple of constants in the Makefile that are imported from
 434 %Config.
 435
 436 =cut
 437
 438 sub const_config {
 439 # --- Constants Sections ---
 440
 441     my($self) = shift;
 442     my(@m,$m);
 443     push(@m,"\n# These definitions are from config.sh (via $INC{'Config.pm'})\n");
 444     push(@m,"\n# They may have been overridden via Makefile.PL or on the command line\n");
 445     my(%once_only);
 446     foreach $m (@{$self->{CONFIG}}){
 447         # SITE*EXP macros are defined in &constants; avoid duplicates here
 448         next if $once_only{$m} or $m eq 'sitelibexp' or $m eq 'sitearchexp';
 449         push @m, "\U$m\E = ".$self->{uc $m}."\n";
 450         $once_only{$m} = 1;
 451     }
 452     join('', @m);
 453 }
 454
 455 =item const_loadlibs (o)
 456
 457 Defines EXTRALIBS, LDLOADLIBS, BSLOADLIBS, LD_RUN_PATH. See
 458 L<ExtUtils::Liblist> for details.
 459
 460 =cut
 461
 462 sub const_loadlibs {
 463     my($self) = shift;
 464     return "" unless $self->needs_linking;
 465     my @m;
 466     push @m, qq{
 467 # $self->{NAME} might depend on some other libraries:
 468 # See ExtUtils::Liblist for details
 469 #
 470 };
 471     my($tmp);
 472     for $tmp (qw/
 473          EXTRALIBS LDLOADLIBS BSLOADLIBS LD_RUN_PATH
 474          /) {
 475         next unless defined $self->{$tmp};
 476         push @m, "$tmp = $self->{$tmp}\n";
 477     }
 478     return join "", @m;
 479 }
 480
 481 =item constants (o)
 482
 483 Initializes lots of constants and .SUFFIXES and .PHONY
 484
 485 =cut
 486
 487 sub constants {
 488     my($self) = @_;
 489     my(@m,$tmp);
 490
 491     for $tmp (qw/
 492
 493               AR_STATIC_ARGS NAME DISTNAME NAME_SYM VERSION
 494               VERSION_SYM XS_VERSION INST_BIN INST_EXE INST_LIB
 495               INST_ARCHLIB INST_SCRIPT PREFIX INSTALLDIRS
 496               INSTALLPRIVLIB INSTALLARCHLIB INSTALLSITELIB
 497               INSTALLSITEARCH INSTALLBIN INSTALLSCRIPT PERL_LIB
 498               PERL_ARCHLIB SITELIBEXP SITEARCHEXP LIBPERL_A MYEXTLIB
 499               FIRST_MAKEFILE MAKE_APERL_FILE PERLMAINCC PERL_SRC
 500               PERL_INC PERL FULLPERL
 501
 502               / ) {
 503         next unless defined $self->{$tmp};
 504         push @m, "$tmp = $self->{$tmp}\n";
 505     }
 506
 507     push @m, qq{
 508 VERSION_MACRO = VERSION
 509 DEFINE_VERSION = -D\$(VERSION_MACRO)=\\\"\$(VERSION)\\\"
 510 XS_VERSION_MACRO = XS_VERSION
 511 XS_DEFINE_VERSION = -D\$(XS_VERSION_MACRO)=\\\"\$(XS_VERSION)\\\"
 512 };
 513
 514     push @m, qq{
 515 MAKEMAKER = $INC{'ExtUtils/MakeMaker.pm'}
 516 MM_VERSION = $ExtUtils::MakeMaker::VERSION
 517 };
 518
 519     push @m, q{
 520 # FULLEXT = Pathname for extension directory (eg Foo/Bar/Oracle).
 521 # BASEEXT = Basename part of FULLEXT. May be just equal FULLEXT. (eg Oracle)
 522 # ROOTEXT = Directory part of FULLEXT with leading slash (eg /DBD)  !!! Deprecated from MM 5.32  !!!
 523 # PARENT_NAME = NAME without BASEEXT and no trailing :: (eg Foo::Bar)
 524 # DLBASE  = Basename part of dynamic library. May be just equal BASEEXT.
 525 };
 526
 527     for $tmp (qw/
 528               FULLEXT BASEEXT PARENT_NAME DLBASE VERSION_FROM INC DEFINE OBJECT
 529               LDFROM LINKTYPE
 530               / ) {
 531         next unless defined $self->{$tmp};
 532         push @m, "$tmp = $self->{$tmp}\n";
 533     }
 534
 535     push @m, "
 536 # Handy lists of source code files:
 537 XS_FILES= ".join(" \\\n\t", sort keys %{$self->{XS}})."
 538 C_FILES = ".join(" \\\n\t", @{$self->{C}})."
 539 O_FILES = ".join(" \\\n\t", @{$self->{O_FILES}})."
 540 H_FILES = ".join(" \\\n\t", @{$self->{H}})."
 541 MAN1PODS = ".join(" \\\n\t", sort keys %{$self->{MAN1PODS}})."
 542 MAN3PODS = ".join(" \\\n\t", sort keys %{$self->{MAN3PODS}})."
 543 ";
 544
 545     for $tmp (qw/
 546               INST_MAN1DIR INSTALLMAN1DIR MAN1EXT INST_MAN3DIR INSTALLMAN3DIR MAN3EXT
 547               /) {
 548         next unless defined $self->{$tmp};
 549         push @m, "$tmp = $self->{$tmp}\n";
 550     }
 551
 552     push @m, q{
 553 .NO_CONFIG_REC: Makefile
 554 } if $ENV{CLEARCASE_ROOT};
 555
 556     # why not q{} ? -- emacs
 557     push @m, qq{
 558 # work around a famous dec-osf make(1) feature(?):
 559 makemakerdflt: all
 560
 561 .SUFFIXES: .xs .c .C .cpp .cxx .cc \$(OBJ_EXT)
 562
 563 # Nick wanted to get rid of .PRECIOUS. I don't remember why. I seem to recall, that
 564 # some make implementations will delete the Makefile when we rebuild it. Because
 565 # we call false(1) when we rebuild it. So make(1) is not completely wrong when it
 566 # does so. Our milage may vary.
 567 # .PRECIOUS: Makefile    # seems to be not necessary anymore
 568
 569 .PHONY: all config static dynamic test linkext manifest
 570
 571 # Where is the Config information that we are using/depend on
 572 CONFIGDEP = \$(PERL_ARCHLIB)/Config.pm \$(PERL_INC)/config.h
 573 };
 574
 575     my @parentdir = split(/::/, $self->{PARENT_NAME});
 576     push @m, q{
 577 # Where to put things:
 578 INST_LIBDIR      = }. $self->catdir('$(INST_LIB)',@parentdir)        .q{
 579 INST_ARCHLIBDIR  = }. $self->catdir('$(INST_ARCHLIB)',@parentdir)    .q{
 580
 581 INST_AUTODIR     = }. $self->catdir('$(INST_LIB)','auto','$(FULLEXT)')       .q{
 582 INST_ARCHAUTODIR = }. $self->catdir('$(INST_ARCHLIB)','auto','$(FULLEXT)')   .q{
 583 };
 584
 585     if ($self->has_link_code()) {
 586         push @m, '
 587 INST_STATIC  = $(INST_ARCHAUTODIR)/$(BASEEXT)$(LIB_EXT)
 588 INST_DYNAMIC = $(INST_ARCHAUTODIR)/$(DLBASE).$(DLEXT)
 589 INST_BOOT    = $(INST_ARCHAUTODIR)/$(BASEEXT).bs
 590 ';
 591     } else {
 592         push @m, '
 593 INST_STATIC  =
 594 INST_DYNAMIC =
 595 INST_BOOT    =
 596 ';
 597     }
 598
 599     if ($Is_OS2) {
 600         $tmp = "$self->{BASEEXT}.def";
 601     } else {
 602         $tmp = "";
 603     }
 604     push @m, "
 605 EXPORT_LIST = $tmp
 606 ";
 607
 608     if ($Is_OS2) {
 609         $tmp = "\$(PERL_INC)/libperl\$(LIB_EXT)";
 610     } else {
 611         $tmp = "";
 612     }
 613     push @m, "
 614 PERL_ARCHIVE = $tmp
 615 ";
 616
 617 #    push @m, q{
 618 #INST_PM = }.join(" \\\n\t", sort values %{$self->{PM}}).q{
 619 #
 620 #PM_TO_BLIB = }.join(" \\\n\t", %{$self->{PM}}).q{
 621 #};
 622
 623     push @m, q{
 624 TO_INST_PM = }.join(" \\\n\t", sort keys %{$self->{PM}}).q{
 625
 626 PM_TO_BLIB = }.join(" \\\n\t", %{$self->{PM}}).q{
 627 };
 628
 629     join('',@m);
 630 }
 631
 632 =item depend (o)
 633
 634 Same as macro for the depend attribute.
 635
 636 =cut
 637
 638 sub depend {
 639     my($self,%attribs) = @_;
 640     my(@m,$key,$val);
 641     while (($key,$val) = each %attribs){
 642         last unless defined $key;
 643         push @m, "$key: $val\n";
 644     }
 645     join "", @m;
 646 }
 647
 648 =item dir_target (o)
 649
 650 Takes an array of directories that need to exist and returns a
 651 Makefile entry for a .exists file in these directories. Returns
 652 nothing, if the entry has already been processed. We're helpless
 653 though, if the same directory comes as $(FOO) _and_ as "bar". Both of
 654 them get an entry, that's why we use "::".
 655
 656 =cut
 657
 658 sub dir_target {
 659 # --- Make-Directories section (internal method) ---
 660 # dir_target(@array) returns a Makefile entry for the file .exists in each
 661 # named directory. Returns nothing, if the entry has already been processed.
 662 # We're helpless though, if the same directory comes as $(FOO) _and_ as "bar".
 663 # Both of them get an entry, that's why we use "::". I chose '$(PERL)' as the
 664 # prerequisite, because there has to be one, something that doesn't change
 665 # too often :)
 666
 667     my($self,@dirs) = @_;
 668     my(@m,$dir);
 669     foreach $dir (@dirs) {
 670         my($src) = $self->catfile($self->{PERL_INC},'perl.h');
 671         my($targ) = $self->catfile($dir,'.exists');
 672         my($targdir) = $targ;       # Necessary because catfile may have
 673         $targdir =~ s:/?.exists$::; # adapted syntax of $dir to target OS
 674         next if $self->{DIR_TARGET}{$self}{$targdir}++;
 675         push @m, qq{
 676 $targ :: $src
 677         $self->{NOECHO}\$(MKPATH) $targdir
 678         $self->{NOECHO}\$(EQUALIZE_TIMESTAMP) $src $targ
 679 };
 680         push(@m,qq{
 681         -$self->{NOECHO}\$(CHMOD) 755 $targdir
 682 }) unless $Is_VMS;
 683     }
 684     join "", @m;
 685 }
 686
 687 =item dist (o)
 688
 689 Defines a lot of macros for distribution support.
 690
 691 =cut
 692
 693 sub dist {
 694     my($self, %attribs) = @_;
 695
 696     my(@m);
 697     # VERSION should be sanitised before use as a file name
 698     my($version)  = $attribs{VERSION}  || '$(VERSION)';
 699     my($name)     = $attribs{NAME}     || '$(DISTNAME)';
 700     my($tar)      = $attribs{TAR}      || 'tar';        # eg /usr/bin/gnutar
 701     my($tarflags) = $attribs{TARFLAGS} || 'cvf';
 702     my($zip)      = $attribs{ZIP}      || 'zip';        # eg pkzip Yuck!
 703     my($zipflags) = $attribs{ZIPFLAGS} || '-r';
 704     my($compress) = $attribs{COMPRESS} || 'compress';   # eg gzip
 705     my($suffix)   = $attribs{SUFFIX}   || '.Z';          # eg .gz
 706     my($shar)     = $attribs{SHAR}     || 'shar';       # eg "shar --gzip"
 707     my($preop)    = $attribs{PREOP}    || "$self->{NOECHO}\$(NOOP)"; # eg update MANIFEST
 708     my($postop)   = $attribs{POSTOP}   || "$self->{NOECHO}\$(NOOP)"; # eg remove the distdir
 709
 710     my($to_unix)  = $attribs{TO_UNIX} || ($Is_OS2
 711                                           ? "$self->{NOECHO}"
 712                                           . 'test -f tmp.zip && $(RM) tmp.zip;'
 713                                           . ' $(ZIP) -ll -mr tmp.zip $(DISTVNAME) && unzip -o tmp.zip && $(RM) tmp.zip'
 714                                           : "$self->{NOECHO}\$(NOOP)");
 715
 716     my($ci)       = $attribs{CI}       || 'ci -u';
 717     my($rcs_label)= $attribs{RCS_LABEL}|| 'rcs -Nv$(VERSION_SYM): -q';
 718     my($dist_cp)  = $attribs{DIST_CP}  || 'best';
 719     my($dist_default) = $attribs{DIST_DEFAULT} || 'tardist';
 720
 721     push @m, "
 722 DISTVNAME = ${name}-$version
 723 TAR  = $tar
 724 TARFLAGS = $tarflags
 725 ZIP  = $zip
 726 ZIPFLAGS = $zipflags
 727 COMPRESS = $compress
 728 SUFFIX = $suffix
 729 SHAR = $shar
 730 PREOP = $preop
 731 POSTOP = $postop
 732 TO_UNIX = $to_unix
 733 CI = $ci
 734 RCS_LABEL = $rcs_label
 735 DIST_CP = $dist_cp
 736 DIST_DEFAULT = $dist_default
 737 ";
 738     join "", @m;
 739 }
 740
 741 =item dist_basics (o)
 742
 743 Defines the targets distclean, distcheck, skipcheck, manifest.
 744
 745 =cut
 746
 747 sub dist_basics {
 748     my($self) = shift;
 749     my @m;
 750     push @m, q{
 751 distclean :: realclean distcheck
 752 };
 753
 754     push @m, q{
 755 distcheck :
 756         $(PERL) -I$(PERL_ARCHLIB) -I$(PERL_LIB) -e 'use ExtUtils::Manifest "&fullcheck";' \\
 757                 -e 'fullcheck();'
 758 };
 759
 760     push @m, q{
 761 skipcheck :
 762         $(PERL) -I$(PERL_ARCHLIB) -I$(PERL_LIB) -e 'use ExtUtils::Manifest "&skipcheck";' \\
 763                 -e 'skipcheck();'
 764 };
 765
 766     push @m, q{
 767 manifest :
 768         $(PERL) -I$(PERL_ARCHLIB) -I$(PERL_LIB) -e 'use ExtUtils::Manifest "&mkmanifest";' \\
 769                 -e 'mkmanifest();'
 770 };
 771     join "", @m;
 772 }
 773
 774 =item dist_ci (o)
 775
 776 Defines a check in target for RCS.
 777
 778 =cut
 779
 780 sub dist_ci {
 781     my($self) = shift;
 782     my @m;
 783     push @m, q{
 784 ci :
 785         $(PERL) -I$(PERL_ARCHLIB) -I$(PERL_LIB) -e 'use ExtUtils::Manifest "&maniread";' \\
 786                 -e '@all = keys %{ maniread() };' \\
 787                 -e 'print("Executing $(CI) @all\n"); system("$(CI) @all");' \\
 788                 -e 'print("Executing $(RCS_LABEL) ...\n"); system("$(RCS_LABEL) @all");'
 789 };
 790     join "", @m;
 791 }
 792
 793 =item dist_core (o)
 794
 795 Defeines the targets dist, tardist, zipdist, uutardist, shdist
 796
 797 =cut
 798
 799 sub dist_core {
 800     my($self) = shift;
 801     my @m;
 802     push @m, q{
 803 dist : $(DIST_DEFAULT)
 804         }.$self->{NOECHO}.q{$(PERL) -le 'print "Warning: Makefile possibly out of date with $$vf" if ' \
 805             -e '-e ($$vf="$(VERSION_FROM)") and -M $$vf < -M "}.$self->{MAKEFILE}.q{";'
 806
 807 tardist : $(DISTVNAME).tar$(SUFFIX)
 808
 809 zipdist : $(DISTVNAME).zip
 810
 811 $(DISTVNAME).tar$(SUFFIX) : distdir
 812         $(PREOP)
 813         $(TO_UNIX)
 814         $(TAR) $(TARFLAGS) $(DISTVNAME).tar $(DISTVNAME)
 815         $(RM_RF) $(DISTVNAME)
 816         $(COMPRESS) $(DISTVNAME).tar
 817         $(POSTOP)
 818
 819 $(DISTVNAME).zip : distdir
 820         $(PREOP)
 821         $(ZIP) $(ZIPFLAGS) $(DISTVNAME).zip $(DISTVNAME)
 822         $(RM_RF) $(DISTVNAME)
 823         $(POSTOP)
 824
 825 uutardist : $(DISTVNAME).tar$(SUFFIX)
 826         uuencode $(DISTVNAME).tar$(SUFFIX) \\
 827                 $(DISTVNAME).tar$(SUFFIX) > \\
 828                 $(DISTVNAME).tar$(SUFFIX)_uu
 829
 830 shdist : distdir
 831         $(PREOP)
 832         $(SHAR) $(DISTVNAME) > $(DISTVNAME).shar
 833         $(RM_RF) $(DISTVNAME)
 834         $(POSTOP)
 835 };
 836     join "", @m;
 837 }
 838
 839 =item dist_dir (o)
 840
 841 Defines the scratch directory target that will hold the distribution
 842 before tar-ing (or shar-ing).
 843
 844 =cut
 845
 846 sub dist_dir {
 847     my($self) = shift;
 848     my @m;
 849     push @m, q{
 850 distdir :
 851         $(RM_RF) $(DISTVNAME)
 852         $(PERL) -I$(PERL_ARCHLIB) -I$(PERL_LIB) -MExtUtils::Manifest=manicopy,maniread \\
 853                 -e 'manicopy(maniread(),"$(DISTVNAME)", "$(DIST_CP)");'
 854 };
 855     join "", @m;
 856 }
 857
 858 =item dist_test (o)
 859
 860 Defines a target that produces the distribution in the
 861 scratchdirectory, and runs 'perl Makefile.PL; make ;make test' in that
 862 subdirectory.
 863
 864 =cut
 865
 866 sub dist_test {
 867     my($self) = shift;
 868     my @m;
 869     push @m, q{
 870 disttest : distdir
 871         cd $(DISTVNAME) && $(PERL) -I$(PERL_ARCHLIB) -I$(PERL_LIB) Makefile.PL
 872         cd $(DISTVNAME) && $(MAKE)
 873         cd $(DISTVNAME) && $(MAKE) test
 874 };
 875     join "", @m;
 876 }
 877
 878 =item dlsyms (o)
 879
 880 Used by AIX and VMS to define DL_FUNCS and DL_VARS and write the *.exp
 881 files.
 882
 883 =cut
 884
 885 sub dlsyms {
 886     my($self,%attribs) = @_;
 887
 888     return '' unless ($^O eq 'aix' && $self->needs_linking() );
 889
 890     my($funcs) = $attribs{DL_FUNCS} || $self->{DL_FUNCS} || {};
 891     my($vars)  = $attribs{DL_VARS} || $self->{DL_VARS} || [];
 892     my(@m);
 893
 894     push(@m,"
 895 dynamic :: $self->{BASEEXT}.exp
 896
 897 ") unless $self->{SKIPHASH}{'dynamic'}; # dynamic and static are subs, so...
 898
 899     push(@m,"
 900 static :: $self->{BASEEXT}.exp
 901
 902 ") unless $self->{SKIPHASH}{'static'};  # we avoid a warning if we tick them
 903
 904     push(@m,"
 905 $self->{BASEEXT}.exp: Makefile.PL
 906 ",'     $(PERL) "-I$(PERL_ARCHLIB)" "-I$(PERL_LIB)" -e \'use ExtUtils::Mksymlists; \\
 907         Mksymlists("NAME" => "',$self->{NAME},'", "DL_FUNCS" => ',
 908         neatvalue($funcs),', "DL_VARS" => ', neatvalue($vars), ');\'
 909 ');
 910
 911     join('',@m);
 912 }
 913
 914 =item dynamic (o)
 915
 916 Defines the dynamic target.
 917
 918 =cut
 919
 920 sub dynamic {
 921 # --- Dynamic Loading Sections ---
 922
 923     my($self) = shift;
 924     '
 925 ## $(INST_PM) has been moved to the all: target.
 926 ## It remains here for awhile to allow for old usage: "make dynamic"
 927 #dynamic :: '.$self->{MAKEFILE}.' $(INST_DYNAMIC) $(INST_BOOT) $(INST_PM)
 928 dynamic :: '.$self->{MAKEFILE}.' $(INST_DYNAMIC) $(INST_BOOT)
 929         '.$self->{NOECHO}.'$(NOOP)
 930 ';
 931 }
 932
 933 =item dynamic_bs (o)
 934
 935 Defines targets for bootstrap files.
 936
 937 =cut
 938
 939 sub dynamic_bs {
 940     my($self, %attribs) = @_;
 941     return '
 942 BOOTSTRAP =
 943 ' unless $self->has_link_code();
 944
 945     return '
 946 BOOTSTRAP = '."$self->{BASEEXT}.bs".'
 947
 948 # As Mkbootstrap might not write a file (if none is required)
 949 # we use touch to prevent make continually trying to remake it.
 950 # The DynaLoader only reads a non-empty file.
 951 $(BOOTSTRAP): '."$self->{MAKEFILE} $self->{BOOTDEP}".' $(INST_ARCHAUTODIR)/.exists
 952         '.$self->{NOECHO}.'echo "Running Mkbootstrap for $(NAME) ($(BSLOADLIBS))"
 953         '.$self->{NOECHO}.'$(PERL) "-I$(PERL_ARCHLIB)" "-I$(PERL_LIB)" \
 954                 -e \'use ExtUtils::Mkbootstrap;\' \
 955                 -e \'Mkbootstrap("$(BASEEXT)","$(BSLOADLIBS)");\'
 956         '.$self->{NOECHO}.'$(TOUCH) $(BOOTSTRAP)
 957         $(CHMOD) 644 $@
 958
 959 $(INST_BOOT): $(BOOTSTRAP) $(INST_ARCHAUTODIR)/.exists
 960         '."$self->{NOECHO}$self->{RM_RF}".' $(INST_BOOT)
 961         -'.$self->{CP}.' $(BOOTSTRAP) $(INST_BOOT)
 962         $(CHMOD) 644 $@
 963 ';
 964 }
 965
 966 =item dynamic_lib (o)
 967
 968 Defines how to produce the *.so (or equivalent) files.
 969
 970 =cut
 971
 972 sub dynamic_lib {
 973     my($self, %attribs) = @_;
 974     return '' unless $self->needs_linking(); #might be because of a subdir
 975
 976     return '' unless $self->has_link_code;
 977
 978     my($otherldflags) = $attribs{OTHERLDFLAGS} || "";
 979     my($inst_dynamic_dep) = $attribs{INST_DYNAMIC_DEP} || "";
 980     my($armaybe) = $attribs{ARMAYBE} || $self->{ARMAYBE} || ":";
 981     my($ldfrom) = '$(LDFROM)';
 982     $armaybe = 'ar' if ($^O eq 'dec_osf' and $armaybe eq ':');
 983     my(@m);
 984     push(@m,'
 985 # This section creates the dynamically loadable $(INST_DYNAMIC)
 986 # from $(OBJECT) and possibly $(MYEXTLIB).
 987 ARMAYBE = '.$armaybe.'
 988 OTHERLDFLAGS = '.$otherldflags.'
 989 INST_DYNAMIC_DEP = '.$inst_dynamic_dep.'
 990
 991 $(INST_DYNAMIC): $(OBJECT) $(MYEXTLIB) $(BOOTSTRAP) $(INST_ARCHAUTODIR)/.exists $(EXPORT_LIST) $(PERL_ARCHIVE) $(INST_DYNAMIC_DEP)
 992 ');
 993     if ($armaybe ne ':'){
 994         $ldfrom = 'tmp$(LIB_EXT)';
 995         push(@m,'       $(ARMAYBE) cr '.$ldfrom.' $(OBJECT)'."\n");
 996         push(@m,'       $(RANLIB) '."$ldfrom\n");
 997     }
 998     $ldfrom = "-all $ldfrom -none" if ($^O eq 'dec_osf');
 999     push(@m,'   LD_RUN_PATH="$(LD_RUN_PATH)" $(LD) -o $@ $(LDDLFLAGS) '.$ldfrom.
1000                 ' $(OTHERLDFLAGS) $(MYEXTLIB) $(PERL_ARCHIVE) $(LDLOADLIBS) $(EXPORT_LIST)');
1001     push @m, '
1002         $(CHMOD) 755 $@
1003 ';
1004
1005     push @m, $self->dir_target('$(INST_ARCHAUTODIR)');
1006     join('',@m);
1007 }
1008
1009 =item exescan
1010
1011 Deprecated method. Use libscan instead.
1012
1013 =cut
1014
1015 sub exescan {
1016     my($self,$path) = @_;
1017     $path;
1018 }
1019
1020 =item extliblist
1021
1022 Called by init_others, and calls ext ExtUtils::Liblist. See
1023 L<ExtUtils::Liblist> for details.
1024
1025 =cut
1026
1027 sub extliblist {
1028     my($self,$libs) = @_;
1029     require ExtUtils::Liblist;
1030     $self->ext($libs, $Verbose);
1031 }
1032
1033 =item file_name_is_absolute
1034
1035 Takes as argument a path and returns true, if it is an absolute path.
1036
1037 =cut
1038
1039 sub file_name_is_absolute {
1040     my($self,$file) = @_;
1041     $file =~ m:^/: ;
1042 }
1043
1044 =item find_perl
1045
1046 Finds the executables PERL and FULLPERL
1047
1048 =cut
1049
1050 sub find_perl {
1051     my($self, $ver, $names, $dirs, $trace) = @_;
1052     my($name, $dir);
1053     if ($trace >= 2){
1054         print "Looking for perl $ver by these names:
1055 @$names
1056 in these dirs:
1057 @$dirs
1058 ";
1059     }
1060     foreach $dir (@$dirs){
1061         next unless defined $dir; # $self->{PERL_SRC} may be undefined
1062         foreach $name (@$names){
1063             my ($abs, $val);
1064             if ($self->file_name_is_absolute($name)) { # /foo/bar
1065                 $abs = $name;
1066             } elsif ($self->canonpath($name) eq $self->canonpath(basename($name))) { # foo
1067                 $abs = $self->catfile($dir, $name);
1068             } else { # foo/bar
1069                 $abs = $self->canonpath($self->catfile($self->curdir, $name));
1070             }
1071             print "Checking $abs\n" if ($trace >= 2);
1072             next unless $self->maybe_command($abs);
1073             print "Executing $abs\n" if ($trace >= 2);
1074             $val = `$abs -e 'require $ver; print "VER_OK\n" ' 2>&1`;
1075             if ($val =~ /VER_OK/) {
1076                 print "Using PERL=$abs\n" if $trace;
1077                 return $abs;
1078             } elsif ($trace >= 2) {
1079                 print "Result: `$val'\n";
1080             }
1081         }
1082     }
1083     print STDOUT "Unable to find a perl $ver (by these names: @$names, in these dirs: @$dirs)\n";
1084     0; # false and not empty
1085 }
1086
1087 =head2 Methods to actually produce chunks of text for the Makefile
1088
1089 The methods here are called in the order specified by
1090 @ExtUtils::MakeMaker::MM_Sections. This manpage reflects the order as
1091 well as possible. Some methods call each other, so in doubt refer to
1092 the code.
1093
1094 =item force (o)
1095
1096 Just writes FORCE:
1097
1098 =cut
1099
1100 sub force {
1101     my($self) = shift;
1102     '# Phony target to force checking subdirectories.
1103 FORCE:
1104 ';
1105 }
1106
1107 =item guess_name
1108
1109 Guess the name of this package by examining the working directory's
1110 name. MakeMaker calls this only if the developer has not supplied a
1111 NAME attribute.
1112
1113 =cut
1114
1115 # ';
1116
1117 sub guess_name {
1118     my($self) = @_;
1119     use Cwd 'cwd';
1120     my $name = basename(cwd());
1121     $name =~ s|[\-_][\d\.\-]+$||;   # this is new with MM 5.00, we
1122                                     # strip minus or underline
1123                                     # followed by a float or some such
1124     print "Warning: Guessing NAME [$name] from current directory name.\n";
1125     $name;
1126 }
1127
1128 =item has_link_code
1129
1130 Returns true if C, XS, MYEXTLIB or similar objects exist within this
1131 object that need a compiler. Does not descend into subdirectories as
1132 needs_linking() does.
1133
1134 =cut
1135
1136 sub has_link_code {
1137     my($self) = shift;
1138     return $self->{HAS_LINK_CODE} if defined $self->{HAS_LINK_CODE};
1139     if ($self->{OBJECT} or @{$self->{C} || []} or $self->{MYEXTLIB}){
1140         $self->{HAS_LINK_CODE} = 1;
1141         return 1;
1142     }
1143     return $self->{HAS_LINK_CODE} = 0;
1144 }
1145
1146 =item init_dirscan
1147
1148 Initializes DIR, XS, PM, C, O_FILES, H, PL_FILES, MAN*PODS, EXE_FILES.
1149
1150 =cut
1151
1152 sub init_dirscan {      # --- File and Directory Lists (.xs .pm .pod etc)
1153     my($self) = @_;
1154     my($name, %dir, %xs, %c, %h, %ignore, %pl_files, %manifypods);
1155     local(%pm); #the sub in find() has to see this hash
1156     $ignore{'test.pl'} = 1;
1157     $ignore{'makefile.pl'} = 1 if $Is_VMS;
1158     foreach $name ($self->lsdir($self->curdir)){
1159         next if $name eq $self->curdir or $name eq $self->updir or $ignore{$name};
1160         next unless $self->libscan($name);
1161         if (-d $name){
1162             next if -l $name; # We do not support symlinks at all
1163             $dir{$name} = $name if (-f $self->catfile($name,"Makefile.PL"));
1164         } elsif ($name =~ /\.xs$/){
1165             my($c); ($c = $name) =~ s/\.xs$/.c/;
1166             $xs{$name} = $c;
1167             $c{$c} = 1;
1168         } elsif ($name =~ /\.c(pp|xx|c)?$/i){  # .c .C .cpp .cxx .cc
1169             $c{$name} = 1
1170                 unless $name =~ m/perlmain\.c/; # See MAP_TARGET
1171         } elsif ($name =~ /\.h$/i){
1172             $h{$name} = 1;
1173         } elsif ($name =~ /\.(p[ml]|pod)$/){
1174             $pm{$name} = $self->catfile('$(INST_LIBDIR)',$name);
1175         } elsif ($name =~ /\.PL$/ && $name ne "Makefile.PL") {
1176             ($pl_files{$name} = $name) =~ s/\.PL$// ;
1177         } elsif ($Is_VMS && $name =~ /\.pl$/ && $name ne 'makefile.pl' &&
1178                  $name ne 'test.pl') {  # case-insensitive filesystem
1179             ($pl_files{$name} = $name) =~ s/\.pl$// ;
1180         }
1181     }
1182
1183     # Some larger extensions often wish to install a number of *.pm/pl
1184     # files into the library in various locations.
1185
1186     # The attribute PMLIBDIRS holds an array reference which lists
1187     # subdirectories which we should search for library files to
1188     # install. PMLIBDIRS defaults to [ 'lib', $self->{BASEEXT} ].  We
1189     # recursively search through the named directories (skipping any
1190     # which don't exist or contain Makefile.PL files).
1191
1192     # For each *.pm or *.pl file found $self->libscan() is called with
1193     # the default installation path in $_[1]. The return value of
1194     # libscan defines the actual installation location.  The default
1195     # libscan function simply returns the path.  The file is skipped
1196     # if libscan returns false.
1197
1198     # The default installation location passed to libscan in $_[1] is:
1199     #
1200     #  ./*.pm           => $(INST_LIBDIR)/*.pm
1201     #  ./xyz/...        => $(INST_LIBDIR)/xyz/...
1202     #  ./lib/...        => $(INST_LIB)/...
1203     #
1204     # In this way the 'lib' directory is seen as the root of the actual
1205     # perl library whereas the others are relative to INST_LIBDIR
1206     # (which includes PARENT_NAME). This is a subtle distinction but one
1207     # that's important for nested modules.
1208
1209     $self->{PMLIBDIRS} = ['lib', $self->{BASEEXT}]
1210         unless $self->{PMLIBDIRS};
1211
1212     #only existing directories that aren't in $dir are allowed
1213
1214     # Avoid $_ wherever possible:
1215     # @{$self->{PMLIBDIRS}} = grep -d && !$dir{$_}, @{$self->{PMLIBDIRS}};
1216     my (@pmlibdirs) = @{$self->{PMLIBDIRS}};
1217     my ($pmlibdir);
1218     @{$self->{PMLIBDIRS}} = ();
1219     foreach $pmlibdir (@pmlibdirs) {
1220         -d $pmlibdir && !$dir{$pmlibdir} && push @{$self->{PMLIBDIRS}}, $pmlibdir;
1221     }
1222
1223     if (@{$self->{PMLIBDIRS}}){
1224         print "Searching PMLIBDIRS: @{$self->{PMLIBDIRS}}\n"
1225             if ($Verbose >= 2);
1226         require File::Find;
1227         File::Find::find(sub {
1228             if (-d $_){
1229                 if ($_ eq "CVS" || $_ eq "RCS"){
1230                     $File::Find::prune = 1;
1231                 }
1232                 return;
1233             }
1234             my($path, $prefix) = ($File::Find::name, '$(INST_LIBDIR)');
1235             my($striplibpath,$striplibname);
1236             $prefix =  '$(INST_LIB)' if (($striplibpath = $path) =~ s:^(\W*)lib\W:$1:i);
1237             ($striplibname,$striplibpath) = fileparse($striplibpath);
1238             my($inst) = $self->catfile($prefix,$striplibpath,$striplibname);
1239             local($_) = $inst; # for backwards compatibility
1240             $inst = $self->libscan($inst);
1241             print "libscan($path) => '$inst'\n" if ($Verbose >= 2);
1242             return unless $inst;
1243             $pm{$path} = $inst;
1244         }, @{$self->{PMLIBDIRS}});
1245     }
1246
1247     $self->{DIR} = [sort keys %dir] unless $self->{DIR};
1248     $self->{XS}  = \%xs             unless $self->{XS};
1249     $self->{PM}  = \%pm             unless $self->{PM};
1250     $self->{C}   = [sort keys %c]   unless $self->{C};
1251     my(@o_files) = @{$self->{C}};
1252     $self->{O_FILES} = [grep s/\.c(pp|xx|c)?$/$self->{OBJ_EXT}/i, @o_files] ;
1253     $self->{H}   = [sort keys %h]   unless $self->{H};
1254     $self->{PL_FILES} = \%pl_files unless $self->{PL_FILES};
1255
1256     # Set up names of manual pages to generate from pods
1257     if ($self->{MAN1PODS}) {
1258     } elsif ( $self->{INST_MAN1DIR} =~ /^(none|\s*)$/ ) {
1259         $self->{MAN1PODS} = {};
1260     } else {
1261         my %manifypods = ();
1262         if ( exists $self->{EXE_FILES} ) {
1263             foreach $name (@{$self->{EXE_FILES}}) {
1264 #               use FileHandle ();
1265 #               my $fh = new FileHandle;
1266                 local *FH;
1267                 my($ispod)=0;
1268                 # one day test, if $/ can be set to '' safely (is the bug fixed that was in 5.001m?)
1269 #               if ($fh->open("<$name")) {
1270                 if (open(FH,"<$name")) {
1271 #                   while (<$fh>) {
1272                     while (<FH>) {
1273                         if (/^=head1\s+\w+/) {
1274                             $ispod=1;
1275                             last;
1276                         }
1277                     }
1278 #                   $fh->close;
1279                     close FH;
1280                 } else {
1281                     # If it doesn't exist yet, we assume, it has pods in it
1282                     $ispod = 1;
1283                 }
1284                 if( $ispod ) {
1285                     $manifypods{$name} = $self->catfile('$(INST_MAN1DIR)',basename($name).'.$(MAN1EXT)');
1286                 }
1287             }
1288         }
1289         $self->{MAN1PODS} = \%manifypods;
1290     }
1291     if ($self->{MAN3PODS}) {
1292     } elsif ( $self->{INST_MAN3DIR} =~ /^(none|\s*)$/ ) {
1293         $self->{MAN3PODS} = {};
1294     } else {
1295         my %manifypods = (); # we collect the keys first, i.e. the files
1296                              # we have to convert to pod
1297         foreach $name (keys %{$self->{PM}}) {
1298             if ($name =~ /\.pod$/ ) {
1299                 $manifypods{$name} = $self->{PM}{$name};
1300             } elsif ($name =~ /\.p[ml]$/ ) {
1301 #               use FileHandle ();
1302 #               my $fh = new FileHandle;
1303                 local *FH;
1304                 my($ispod)=0;
1305 #               $fh->open("<$name");
1306                 if (open(FH,"<$name")) {
1307                     #           while (<$fh>) {
1308                     while (<FH>) {
1309                         if (/^=head1\s+\w+/) {
1310                             $ispod=1;
1311                             last;
1312                         }
1313                     }
1314                     #           $fh->close;
1315                     close FH;
1316                 } else {
1317                     $ispod = 1;
1318                 }
1319                 if( $ispod ) {
1320                     $manifypods{$name} = $self->{PM}{$name};
1321                 }
1322             }
1323         }
1324
1325         # Remove "Configure.pm" and similar, if it's not the only pod listed
1326         # To force inclusion, just name it "Configure.pod", or override MAN3PODS
1327         foreach $name (keys %manifypods) {
1328             if ($name =~ /(config|setup).*\.pm/i) {
1329                 delete $manifypods{$name};
1330                 next;
1331             }
1332             my($manpagename) = $name;
1333             unless ($manpagename =~ s!^\W*lib\W+!!) { # everything below lib is ok
1334                 $manpagename = $self->catfile(split(/::/,$self->{PARENT_NAME}),$manpagename);
1335             }
1336             $manpagename =~ s/\.p(od|m|l)$//;
1337             $manpagename = $self->replace_manpage_separator($manpagename);
1338             $manifypods{$name} = $self->catfile("\$(INST_MAN3DIR)","$manpagename.\$(MAN3EXT)");
1339         }
1340         $self->{MAN3PODS} = \%manifypods;
1341     }
1342 }
1343
1344 =item init_main
1345
1346 Initializes NAME, FULLEXT, BASEEXT, PARENT_NAME, DLBASE, PERL_SRC,
1347 PERL_LIB, PERL_ARCHLIB, PERL_INC, INSTALLDIRS, INST_*, INSTALL*,
1348 PREFIX, CONFIG, AR, AR_STATIC_ARGS, LD, OBJ_EXT, LIB_EXT, MAP_TARGET,
1349 LIBPERL_A, VERSION_FROM, VERSION, DISTNAME, VERSION_SYM.
1350
1351 =cut
1352
1353 sub init_main {
1354     my($self) = @_;
1355
1356     # --- Initialize Module Name and Paths
1357
1358     # NAME    = Foo::Bar::Oracle
1359     # FULLEXT = Foo/Bar/Oracle
1360     # BASEEXT = Oracle
1361     # ROOTEXT = Directory part of FULLEXT with leading /. !!! Deprecated from MM 5.32 !!!
1362     # PARENT_NAME = Foo::Bar
1363 ### Only UNIX:
1364 ###    ($self->{FULLEXT} =
1365 ###     $self->{NAME}) =~ s!::!/!g ; #eg. BSD/Foo/Socket
1366     $self->{FULLEXT} = $self->catdir(split /::/, $self->{NAME});
1367
1368
1369     # Copied from DynaLoader:
1370
1371     my(@modparts) = split(/::/,$self->{NAME});
1372     my($modfname) = $modparts[-1];
1373
1374     # Some systems have restrictions on files names for DLL's etc.
1375     # mod2fname returns appropriate file base name (typically truncated)
1376     # It may also edit @modparts if required.
1377     if (defined &DynaLoader::mod2fname) {
1378         $modfname = &DynaLoader::mod2fname(\@modparts);
1379     }
1380
1381     ($self->{PARENT_NAME}, $self->{BASEEXT}) = $self->{NAME} =~ m!([\w:]+::)?(\w+)$! ;
1382
1383     if (defined &DynaLoader::mod2fname) {
1384         # As of 5.001m, dl_os2 appends '_'
1385         $self->{DLBASE} = $modfname;
1386     } else {
1387         $self->{DLBASE} = '$(BASEEXT)';
1388     }
1389
1390
1391     ### ROOTEXT deprecated from MM 5.32
1392 ###    ($self->{ROOTEXT} =
1393 ###     $self->{FULLEXT}) =~ s#/?\Q$self->{BASEEXT}\E$## ;      #eg. /BSD/Foo
1394 ###    $self->{ROOTEXT} = ($Is_VMS ? '' : '/') . $self->{ROOTEXT} if $self->{ROOTEXT};
1395
1396
1397     # --- Initialize PERL_LIB, INST_LIB, PERL_SRC
1398
1399     # *Real* information: where did we get these two from? ...
1400     my $inc_config_dir = dirname($INC{'Config.pm'});
1401     my $inc_carp_dir   = dirname($INC{'Carp.pm'});
1402
1403     unless ($self->{PERL_SRC}){
1404         my($dir);
1405         foreach $dir ($self->updir(),$self->catdir($self->updir(),$self->updir()),$self->catdir($self->updir(),$self->updir(),$self->updir())){
1406             if (
1407                 -f $self->catfile($dir,"config.sh")
1408                 &&
1409                 -f $self->catfile($dir,"perl.h")
1410                 &&
1411                 -f $self->catfile($dir,"lib","Exporter.pm")
1412                ) {
1413                 $self->{PERL_SRC}=$dir ;
1414                 last;
1415             }
1416         }
1417     }
1418     if ($self->{PERL_SRC}){
1419         $self->{PERL_LIB}     ||= $self->catdir("$self->{PERL_SRC}","lib");
1420         $self->{PERL_ARCHLIB} = $self->{PERL_LIB};
1421         $self->{PERL_INC}     = $self->{PERL_SRC};
1422         # catch a situation that has occurred a few times in the past:
1423
1424         warn <<EOM unless (-s $self->catfile($self->{PERL_SRC},'cflags') or $Is_VMS && -s $self->catfile($self->{PERL_SRC},'perlshr_attr.opt') or $Is_Mac);
1425 You cannot build extensions below the perl source tree after executing
1426 a 'make clean' in the perl source tree.
1427
1428 To rebuild extensions distributed with the perl source you should
1429 simply Configure (to include those extensions) and then build perl as
1430 normal. After installing perl the source tree can be deleted. It is
1431 not needed for building extensions by running 'perl Makefile.PL'
1432 usually without extra arguments.
1433
1434 It is recommended that you unpack and build additional extensions away
1435 from the perl source tree.
1436 EOM
1437     } else {
1438         # we should also consider $ENV{PERL5LIB} here
1439         $self->{PERL_LIB}     ||= $Config::Config{privlibexp};
1440         $self->{PERL_ARCHLIB} ||= $Config::Config{archlibexp};
1441         $self->{PERL_INC}     = $self->catdir("$self->{PERL_ARCHLIB}","CORE"); # wild guess for now
1442         my $perl_h;
1443         die <<EOM unless (-f ($perl_h = $self->catfile($self->{PERL_INC},"perl.h")));
1444 Error: Unable to locate installed Perl libraries or Perl source code.
1445
1446 It is recommended that you install perl in a standard location before
1447 building extensions. You can say:
1448
1449     $^X Makefile.PL PERL_SRC=/path/to/perl/source/directory
1450
1451 if you have not yet installed perl but still want to build this
1452 extension now.
1453 (You get this message, because MakeMaker could not find "$perl_h")
1454 EOM
1455
1456 #        print STDOUT "Using header files found in $self->{PERL_INC}\n"
1457 #            if $Verbose && $self->needs_linking();
1458
1459     }
1460
1461     # We get SITELIBEXP and SITEARCHEXP directly via
1462     # Get_from_Config. When we are running standard modules, these
1463     # won't matter, we will set INSTALLDIRS to "perl". Otherwise we
1464     # set it to "site". I prefer that INSTALLDIRS be set from outside
1465     # MakeMaker.
1466     $self->{INSTALLDIRS} ||= "site";
1467
1468     # INST_LIB typically pre-set if building an extension after
1469     # perl has been built and installed. Setting INST_LIB allows
1470     # you to build directly into, say $Config::Config{privlibexp}.
1471     unless ($self->{INST_LIB}){
1472
1473
1474         ##### XXXXX We have to change this nonsense
1475
1476         if (defined $self->{PERL_SRC} and $self->{INSTALLDIRS} eq "perl") {
1477             $self->{INST_LIB} = $self->{INST_ARCHLIB} = $self->{PERL_LIB};
1478         } else {
1479             $self->{INST_LIB} = $self->catdir($self->curdir,"blib","lib");
1480         }
1481     }
1482     $self->{INST_ARCHLIB} ||= $self->catdir($self->curdir,"blib","arch");
1483     $self->{INST_BIN} ||= $self->catdir($self->curdir,'blib','bin');
1484
1485     # We need to set up INST_LIBDIR before init_libscan() for VMS
1486     my @parentdir = split(/::/, $self->{PARENT_NAME});
1487     $self->{INST_LIBDIR} = $self->catdir('$(INST_LIB)',@parentdir);
1488     $self->{INST_ARCHLIBDIR} = $self->catdir('$(INST_ARCHLIB)',@parentdir);
1489     $self->{INST_AUTODIR} = $self->catdir('$(INST_LIB)','auto','$(FULLEXT)');
1490     $self->{INST_ARCHAUTODIR} = $self->catdir('$(INST_ARCHLIB)','auto','$(FULLEXT)');
1491
1492     # INST_EXE is deprecated, should go away March '97
1493     $self->{INST_EXE} ||= $self->catdir($self->curdir,'blib','script');
1494     $self->{INST_SCRIPT} ||= $self->catdir($self->curdir,'blib','script');
1495
1496     # The user who requests an installation directory explicitly
1497     # should not have to tell us a architecture installation directory
1498     # as well We look if a directory exists that is named after the
1499     # architecture. If not we take it as a sign that it should be the
1500     # same as the requested installation directory. Otherwise we take
1501     # the found one.
1502     # We do the same thing twice: for privlib/archlib and for sitelib/sitearch
1503     my($libpair);
1504     for $libpair ({l=>"privlib", a=>"archlib"}, {l=>"sitelib", a=>"sitearch"}) {
1505         my $lib = "install$libpair->{l}";
1506         my $Lib = uc $lib;
1507         my $Arch = uc "install$libpair->{a}";
1508         if( $self->{$Lib} && ! $self->{$Arch} ){
1509             my($ilib) = $Config{$lib};
1510             $ilib = VMS::Filespec::unixify($ilib) if $Is_VMS;
1511
1512             $self->prefixify($Arch,$ilib,$self->{$Lib});
1513
1514             unless (-d $self->{$Arch}) {
1515                 print STDOUT "Directory $self->{$Arch} not found, thusly\n" if $Verbose;
1516                 $self->{$Arch} = $self->{$Lib};
1517             }
1518             print STDOUT "Defaulting $Arch to $self->{$Arch}\n" if $Verbose;
1519         }
1520     }
1521
1522     # we have to look at the relation between $Config{prefix} and the
1523     # requested values. We're going to set the $Config{prefix} part of
1524     # all the installation path variables to literally $(PREFIX), so
1525     # the user can still say make PREFIX=foo
1526     my($prefix) = $Config{'prefix'};
1527     $prefix = VMS::Filespec::unixify($prefix) if $Is_VMS;
1528     unless ($self->{PREFIX}){
1529         $self->{PREFIX} = $prefix;
1530     }
1531     my($install_variable);
1532     for $install_variable (qw/
1533
1534                            INSTALLPRIVLIB INSTALLARCHLIB INSTALLBIN
1535                            INSTALLMAN1DIR INSTALLMAN3DIR INSTALLSCRIPT
1536                            INSTALLSITELIB INSTALLSITEARCH
1537
1538                            /) {
1539         $self->prefixify($install_variable,$prefix,q[$(PREFIX)]);
1540     }
1541
1542
1543     # Now we head at the manpages. Maybe they DO NOT want manpages
1544     # installed
1545     $self->{INSTALLMAN1DIR} = $Config::Config{installman1dir}
1546         unless defined $self->{INSTALLMAN1DIR};
1547     unless (defined $self->{INST_MAN1DIR}){
1548         if ($self->{INSTALLMAN1DIR} =~ /^(none|\s*)$/){
1549             $self->{INST_MAN1DIR} = $self->{INSTALLMAN1DIR};
1550         } else {
1551             $self->{INST_MAN1DIR} = $self->catdir($self->curdir,'blib','man1');
1552         }
1553     }
1554     $self->{MAN1EXT} ||= $Config::Config{man1ext};
1555
1556     $self->{INSTALLMAN3DIR} = $Config::Config{installman3dir}
1557         unless defined $self->{INSTALLMAN3DIR};
1558     unless (defined $self->{INST_MAN3DIR}){
1559         if ($self->{INSTALLMAN3DIR} =~ /^(none|\s*)$/){
1560             $self->{INST_MAN3DIR} = $self->{INSTALLMAN3DIR};
1561         } else {
1562             $self->{INST_MAN3DIR} = $self->catdir($self->curdir,'blib','man3');
1563         }
1564     }
1565     $self->{MAN3EXT} ||= $Config::Config{man3ext};
1566
1567
1568     # Get some stuff out of %Config if we haven't yet done so
1569     print STDOUT "CONFIG must be an array ref\n"
1570         if ($self->{CONFIG} and ref $self->{CONFIG} ne 'ARRAY');
1571     $self->{CONFIG} = [] unless (ref $self->{CONFIG});
1572     push(@{$self->{CONFIG}}, @ExtUtils::MakeMaker::Get_from_Config);
1573     push(@{$self->{CONFIG}}, 'shellflags') if $Config::Config{shellflags};
1574     my(%once_only,$m);
1575     foreach $m (@{$self->{CONFIG}}){
1576         next if $once_only{$m};
1577         print STDOUT "CONFIG key '$m' does not exist in Config.pm\n"
1578                 unless exists $Config::Config{$m};
1579         $self->{uc $m} ||= $Config::Config{$m};
1580         $once_only{$m} = 1;
1581     }
1582
1583 # This is too dangerous:
1584 #    if ($^O eq "next") {
1585 #       $self->{AR} = "libtool";
1586 #       $self->{AR_STATIC_ARGS} = "-o";
1587 #    }
1588 # But I leave it as a placeholder
1589
1590     $self->{AR_STATIC_ARGS} ||= "cr";
1591
1592     # These should never be needed
1593     $self->{LD} ||= 'ld';
1594     $self->{OBJ_EXT} ||= '.o';
1595     $self->{LIB_EXT} ||= '.a';
1596
1597     $self->{MAP_TARGET} ||= "perl";
1598
1599     $self->{LIBPERL_A} ||= "libperl$self->{LIB_EXT}";
1600
1601     # make a simple check if we find Exporter
1602     warn "Warning: PERL_LIB ($self->{PERL_LIB}) seems not to be a perl library directory
1603         (Exporter.pm not found)"
1604         unless -f $self->catfile("$self->{PERL_LIB}","Exporter.pm") ||
1605         $self->{NAME} eq "ExtUtils::MakeMaker";
1606
1607     # Determine VERSION and VERSION_FROM
1608     ($self->{DISTNAME}=$self->{NAME}) =~ s#(::)#-#g unless $self->{DISTNAME};
1609     if ($self->{VERSION_FROM}){
1610         $self->{VERSION} = $self->parse_version($self->{VERSION_FROM}) or
1611             Carp::carp "WARNING: Setting VERSION via file '$self->{VERSION_FROM}' failed\n"
1612     }
1613
1614     # strip blanks
1615     if ($self->{VERSION}) {
1616         $self->{VERSION} =~ s/^\s+//;
1617         $self->{VERSION} =~ s/\s+$//;
1618     }
1619
1620     $self->{VERSION} ||= "0.10";
1621     ($self->{VERSION_SYM} = $self->{VERSION}) =~ s/\W/_/g;
1622
1623
1624     # Graham Barr and Paul Marquess had some ideas how to ensure
1625     # version compatibility between the *.pm file and the
1626     # corresponding *.xs file. The bottomline was, that we need an
1627     # XS_VERSION macro that defaults to VERSION:
1628     $self->{XS_VERSION} ||= $self->{VERSION};
1629
1630     # --- Initialize Perl Binary Locations
1631
1632     # Find Perl 5. The only contract here is that both 'PERL' and 'FULLPERL'
1633     # will be working versions of perl 5. miniperl has priority over perl
1634     # for PERL to ensure that $(PERL) is usable while building ./ext/*
1635     my ($component,@defpath);
1636     foreach $component ($self->{PERL_SRC}, $self->path(), $Config::Config{binexp}) {
1637         push @defpath, $component if defined $component;
1638     }
1639     $self->{PERL} =
1640         $self->find_perl(5.0, [ $^X, 'miniperl','perl','perl5',"perl$]" ],
1641             \@defpath, $Verbose ) unless ($self->{PERL});
1642     # don't check if perl is executable, maybe they have decided to
1643     # supply switches with perl
1644
1645     # Define 'FULLPERL' to be a non-miniperl (used in test: target)
1646     ($self->{FULLPERL} = $self->{PERL}) =~ s/miniperl/perl/i
1647         unless ($self->{FULLPERL});
1648 }
1649
1650 =item init_others
1651
1652 Initializes EXTRALIBS, BSLOADLIBS, LDLOADLIBS, LIBS, LD_RUN_PATH,
1653 OBJECT, BOOTDEP, PERLMAINCC, LDFROM, LINKTYPE, NOOP, FIRST_MAKEFILE,
1654 MAKEFILE, NOECHO, RM_F, RM_RF, TOUCH, CP, MV, CHMOD, UMASK_NULL
1655
1656 =cut
1657
1658 sub init_others {       # --- Initialize Other Attributes
1659     my($self) = shift;
1660
1661     # Compute EXTRALIBS, BSLOADLIBS and LDLOADLIBS from $self->{LIBS}
1662     # Lets look at $self->{LIBS} carefully: It may be an anon array, a string or
1663     # undefined. In any case we turn it into an anon array:
1664
1665     # May check $Config{libs} too, thus not empty.
1666     $self->{LIBS}=[''] unless $self->{LIBS};
1667
1668     $self->{LIBS}=[$self->{LIBS}] if ref \$self->{LIBS} eq 'SCALAR';
1669     $self->{LD_RUN_PATH} = "";
1670     my($libs);
1671     foreach $libs ( @{$self->{LIBS}} ){
1672         $libs =~ s/^\s*(.*\S)\s*$/$1/; # remove leading and trailing whitespace
1673         my(@libs) = $self->extliblist($libs);
1674         if ($libs[0] or $libs[1] or $libs[2]){
1675             # LD_RUN_PATH now computed by ExtUtils::Liblist
1676             ($self->{EXTRALIBS}, $self->{BSLOADLIBS}, $self->{LDLOADLIBS}, $self->{LD_RUN_PATH}) = @libs;
1677             last;
1678         }
1679     }
1680
1681     if ( $self->{OBJECT} ) {
1682         $self->{OBJECT} =~ s!\.o(bj)?\b!\$(OBJ_EXT)!g;
1683     } else {
1684         # init_dirscan should have found out, if we have C files
1685         $self->{OBJECT} = "";
1686         $self->{OBJECT} = '$(BASEEXT)$(OBJ_EXT)' if @{$self->{C}||[]};
1687     }
1688     $self->{OBJECT} =~ s/\n+/ \\\n\t/g;
1689     $self->{BOOTDEP}  = (-f "$self->{BASEEXT}_BS") ? "$self->{BASEEXT}_BS" : "";
1690     $self->{PERLMAINCC} ||= '$(CC)';
1691     $self->{LDFROM} = '$(OBJECT)' unless $self->{LDFROM};
1692
1693     # Sanity check: don't define LINKTYPE = dynamic if we're skipping
1694     # the 'dynamic' section of MM.  We don't have this problem with
1695     # 'static', since we either must use it (%Config says we can't
1696     # use dynamic loading) or the caller asked for it explicitly.
1697     if (!$self->{LINKTYPE}) {
1698        $self->{LINKTYPE} = $self->{SKIPHASH}{'dynamic'}
1699                         ? 'static'
1700                         : ($Config::Config{usedl} ? 'dynamic' : 'static');
1701     };
1702
1703     # These get overridden for VMS and maybe some other systems
1704     $self->{NOOP}  ||= "sh -c true";
1705     $self->{FIRST_MAKEFILE} ||= "Makefile";
1706     $self->{MAKEFILE} ||= $self->{FIRST_MAKEFILE};
1707     $self->{MAKE_APERL_FILE} ||= "Makefile.aperl";
1708     $self->{NOECHO} = '@' unless defined $self->{NOECHO};
1709     $self->{RM_F}  ||= "rm -f";
1710     $self->{RM_RF} ||= "rm -rf";
1711     $self->{TOUCH} ||= "touch";
1712     $self->{CP} ||= "cp";
1713     $self->{MV} ||= "mv";
1714     $self->{CHMOD} ||= "chmod";
1715     $self->{UMASK_NULL} ||= "umask 0";
1716 }
1717
1718 =item install (o)
1719
1720 Defines the install target.
1721
1722 =cut
1723
1724 sub install {
1725     my($self, %attribs) = @_;
1726     my(@m);
1727
1728     push @m, q{
1729 install :: all pure_install doc_install
1730
1731 install_perl :: all pure_perl_install doc_perl_install
1732
1733 install_site :: all pure_site_install doc_site_install
1734
1735 install_ :: install_site
1736         @echo INSTALLDIRS not defined, defaulting to INSTALLDIRS=site
1737
1738 pure_install :: pure_$(INSTALLDIRS)_install
1739
1740 doc_install :: doc_$(INSTALLDIRS)_install
1741         }.$self->{NOECHO}.q{echo Appending installation info to $(INSTALLARCHLIB)/perllocal.pod
1742
1743 pure__install : pure_site_install
1744         @echo INSTALLDIRS not defined, defaulting to INSTALLDIRS=site
1745
1746 doc__install : doc_site_install
1747         @echo INSTALLDIRS not defined, defaulting to INSTALLDIRS=site
1748
1749 pure_perl_install ::
1750         }.$self->{NOECHO}.q{$(MOD_INSTALL) \
1751                 read }.$self->catfile('$(PERL_ARCHLIB)','auto','$(FULLEXT)','.packlist').q{ \
1752                 write }.$self->catfile('$(INSTALLARCHLIB)','auto','$(FULLEXT)','.packlist').q{ \
1753                 $(INST_LIB) $(INSTALLPRIVLIB) \
1754                 $(INST_ARCHLIB) $(INSTALLARCHLIB) \
1755                 $(INST_BIN) $(INSTALLBIN) \
1756                 $(INST_SCRIPT) $(INSTALLSCRIPT) \
1757                 $(INST_MAN1DIR) $(INSTALLMAN1DIR) \
1758                 $(INST_MAN3DIR) $(INSTALLMAN3DIR)
1759         }.$self->{NOECHO}.q{$(WARN_IF_OLD_PACKLIST) \
1760                 }.$self->catdir('$(SITEARCHEXP)','auto','$(FULLEXT)').q{
1761
1762
1763 pure_site_install ::
1764         }.$self->{NOECHO}.q{$(MOD_INSTALL) \
1765                 read }.$self->catfile('$(SITEARCHEXP)','auto','$(FULLEXT)','.packlist').q{ \
1766                 write }.$self->catfile('$(INSTALLSITEARCH)','auto','$(FULLEXT)','.packlist').q{ \
1767                 $(INST_LIB) $(INSTALLSITELIB) \
1768                 $(INST_ARCHLIB) $(INSTALLSITEARCH) \
1769                 $(INST_BIN) $(INSTALLBIN) \
1770                 $(INST_SCRIPT) $(INSTALLSCRIPT) \
1771                 $(INST_MAN1DIR) $(INSTALLMAN1DIR) \
1772                 $(INST_MAN3DIR) $(INSTALLMAN3DIR)
1773         }.$self->{NOECHO}.q{$(WARN_IF_OLD_PACKLIST) \
1774                 }.$self->catdir('$(PERL_ARCHLIB)','auto','$(FULLEXT)').q{
1775
1776 doc_perl_install ::
1777         }.$self->{NOECHO}.q{$(DOC_INSTALL) \
1778                 "Module" "$(NAME)" \
1779                 "installed into" "$(INSTALLPRIVLIB)" \
1780                 LINKTYPE "$(LINKTYPE)" \
1781                 VERSION "$(VERSION)" \
1782                 EXE_FILES "$(EXE_FILES)" \
1783                 >> }.$self->catfile('$(INSTALLARCHLIB)','perllocal.pod').q{
1784
1785 doc_site_install ::
1786         }.$self->{NOECHO}.q{$(DOC_INSTALL) \
1787                 "Module" "$(NAME)" \
1788                 "installed into" "$(INSTALLSITELIB)" \
1789                 LINKTYPE "$(LINKTYPE)" \
1790                 VERSION "$(VERSION)" \
1791                 EXE_FILES "$(EXE_FILES)" \
1792                 >> }.$self->catfile('$(INSTALLARCHLIB)','perllocal.pod').q{
1793
1794 };
1795
1796     push @m, q{
1797 uninstall :: uninstall_from_$(INSTALLDIRS)dirs
1798
1799 uninstall_from_perldirs ::
1800         }.$self->{NOECHO}.
1801         q{$(UNINSTALL) }.$self->catfile('$(PERL_ARCHLIB)','auto','$(FULLEXT)','.packlist').q{
1802
1803 uninstall_from_sitedirs ::
1804         }.$self->{NOECHO}.
1805         q{$(UNINSTALL) }.$self->catfile('$(SITEARCHEXP)','auto','$(FULLEXT)','.packlist').q{
1806 };
1807
1808     join("",@m);
1809 }
1810
1811 =item installbin (o)
1812
1813 Defines targets to install EXE_FILES.
1814
1815 =cut
1816
1817 sub installbin {
1818     my($self) = shift;
1819     return "" unless $self->{EXE_FILES} && ref $self->{EXE_FILES} eq "ARRAY";
1820     return "" unless @{$self->{EXE_FILES}};
1821     my(@m, $from, $to, %fromto, @to);
1822     push @m, $self->dir_target(qw[$(INST_SCRIPT)]);
1823     for $from (@{$self->{EXE_FILES}}) {
1824         my($path)= $self->catfile('$(INST_SCRIPT)', basename($from));
1825         local($_) = $path; # for backwards compatibility
1826         $to = $self->libscan($path);
1827         print "libscan($from) => '$to'\n" if ($Verbose >=2);
1828         $fromto{$from}=$to;
1829     }
1830     @to   = values %fromto;
1831     push(@m, "
1832 EXE_FILES = @{$self->{EXE_FILES}}
1833
1834 all :: @to
1835
1836 realclean ::
1837         $self->{RM_F} @to
1838 ");
1839
1840     while (($from,$to) = each %fromto) {
1841         last unless defined $from;
1842         my $todir = dirname($to);
1843         push @m, "
1844 $to: $from $self->{MAKEFILE} $todir/.exists
1845         $self->{NOECHO}$self->{RM_F} $to
1846         $self->{CP} $from $to
1847 ";
1848     }
1849     join "", @m;
1850 }
1851
1852 =item libscan (o)
1853
1854 Takes a path to a file that is found by init_dirscan and returns false
1855 if we don't want to include this file in the library. Mainly used to
1856 exclude RCS, CVS, and SCCS directories from installation.
1857
1858 =cut
1859
1860 # ';
1861
1862 sub libscan {
1863     my($self,$path) = @_;
1864     return '' if $path =~ m:\b(RCS|CVS|SCCS)\b: ;
1865     $path;
1866 }
1867
1868 =item linkext (o)
1869
1870 Defines the linkext target which in turn defines the LINKTYPE.
1871
1872 =cut
1873
1874 sub linkext {
1875     my($self, %attribs) = @_;
1876     # LINKTYPE => static or dynamic or ''
1877     my($linktype) = defined $attribs{LINKTYPE} ?
1878       $attribs{LINKTYPE} : '$(LINKTYPE)';
1879     "
1880 linkext :: $linktype
1881         $self->{NOECHO}\$(NOOP)
1882 ";
1883 }
1884
1885 =item lsdir
1886
1887 Takes as arguments a directory name and a regular expression. Returns
1888 all entries in the directory that match the regular expression.
1889
1890 =cut
1891
1892 sub lsdir {
1893     my($self) = shift;
1894     my($dir, $regex) = @_;
1895     my(@ls);
1896     my $dh = new DirHandle;
1897     $dh->open($dir || ".") or return ();
1898     @ls = $dh->read;
1899     $dh->close;
1900     @ls = grep(/$regex/, @ls) if $regex;
1901     @ls;
1902 }
1903
1904 =item macro (o)
1905
1906 Simple subroutine to insert the macros defined by the macro attribute
1907 into the Makefile.
1908
1909 =cut
1910
1911 sub macro {
1912     my($self,%attribs) = @_;
1913     my(@m,$key,$val);
1914     while (($key,$val) = each %attribs){
1915         last unless defined $key;
1916         push @m, "$key = $val\n";
1917     }
1918     join "", @m;
1919 }
1920
1921 =item makeaperl (o)
1922
1923 Called by staticmake. Defines how to write the Makefile to produce a
1924 static new perl.
1925
1926 =cut
1927
1928 sub makeaperl {
1929     my($self, %attribs) = @_;
1930     my($makefilename, $searchdirs, $static, $extra, $perlinc, $target, $tmp, $libperl) =
1931         @attribs{qw(MAKE DIRS STAT EXTRA INCL TARGET TMP LIBPERL)};
1932     my(@m);
1933     push @m, "
1934 # --- MakeMaker makeaperl section ---
1935 MAP_TARGET    = $target
1936 FULLPERL      = $self->{FULLPERL}
1937 ";
1938     return join '', @m if $self->{PARENT};
1939
1940     my($dir) = join ":", @{$self->{DIR}};
1941
1942     unless ($self->{MAKEAPERL}) {
1943         push @m, q{
1944 $(MAP_TARGET) :: static $(MAKE_APERL_FILE)
1945         $(MAKE) -f $(MAKE_APERL_FILE) $@
1946
1947 $(MAKE_APERL_FILE) : $(FIRST_MAKEFILE)
1948         }.$self->{NOECHO}.q{echo Writing \"$(MAKE_APERL_FILE)\" for this $(MAP_TARGET)
1949         }.$self->{NOECHO}.q{$(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) \
1950                 Makefile.PL DIR=}, $dir, q{ \
1951                 MAKEFILE=$(MAKE_APERL_FILE) LINKTYPE=static \
1952                 MAKEAPERL=1 NORECURS=1 CCCDLFLAGS=};
1953
1954         foreach (@ARGV){
1955                 if( /\s/ ){
1956                         s/=(.*)/='$1'/;
1957                 }
1958                 push @m, " \\\n\t\t$_";
1959         }
1960 #       push @m, map( " \\\n\t\t$_", @ARGV );
1961         push @m, "\n";
1962
1963         return join '', @m;
1964     }
1965
1966
1967
1968     my($cccmd, $linkcmd, $lperl);
1969
1970
1971     $cccmd = $self->const_cccmd($libperl);
1972     $cccmd =~ s/^CCCMD\s*=\s*//;
1973     $cccmd =~ s/\$\(INC\)/ -I$self->{PERL_INC} /;
1974     $cccmd .= " $Config::Config{cccdlflags}"
1975         if ($Config::Config{useshrplib} eq 'true');
1976     $cccmd =~ s/\(CC\)/\(PERLMAINCC\)/;
1977
1978     # The front matter of the linkcommand...
1979     $linkcmd = join ' ', "\$(CC)",
1980             grep($_, @Config{qw(large split ldflags ccdlflags)});
1981     $linkcmd =~ s/\s+/ /g;
1982     $linkcmd =~ s,(perl\.exp),\$(PERL_INC)/$1,;
1983
1984     # Which *.a files could we make use of...
1985     local(%static);
1986     require File::Find;
1987     File::Find::find(sub {
1988         return unless m/\Q$self->{LIB_EXT}\E$/;
1989         return if m/^libperl/;
1990
1991         if( exists $self->{INCLUDE_EXT} ){
1992                 my $found = 0;
1993                 my $incl;
1994                 my $xx;
1995
1996                 ($xx = $File::Find::name) =~ s,.*?/auto/,,;
1997                 $xx =~ s,/?$_,,;
1998                 $xx =~ s,/,::,g;
1999
2000                 # Throw away anything not explicitly marked for inclusion.
2001                 # DynaLoader is implied.
2002                 foreach $incl ((@{$self->{INCLUDE_EXT}},'DynaLoader')){
2003                         if( $xx eq $incl ){
2004                                 $found++;
2005                                 last;
2006                         }
2007                 }
2008                 return unless $found;
2009         }
2010         elsif( exists $self->{EXCLUDE_EXT} ){
2011                 my $excl;
2012                 my $xx;
2013
2014                 ($xx = $File::Find::name) =~ s,.*?/auto/,,;
2015                 $xx =~ s,/?$_,,;
2016                 $xx =~ s,/,::,g;
2017
2018                 # Throw away anything explicitly marked for exclusion
2019                 foreach $excl (@{$self->{EXCLUDE_EXT}}){
2020                         return if( $xx eq $excl );
2021                 }
2022         }
2023
2024         # don't include the installed version of this extension. I
2025         # leave this line here, although it is not necessary anymore:
2026         # I patched minimod.PL instead, so that Miniperl.pm won't
2027         # enclude duplicates
2028
2029         # Once the patch to minimod.PL is in the distribution, I can
2030         # drop it
2031         return if $File::Find::name =~ m:auto/$self->{FULLEXT}/$self->{BASEEXT}$self->{LIB_EXT}$:;
2032         use Cwd 'cwd';
2033         $static{cwd() . "/" . $_}++;
2034     }, grep( -d $_, @{$searchdirs || []}) );
2035
2036     # We trust that what has been handed in as argument, will be buildable
2037     $static = [] unless $static;
2038     @static{@{$static}} = (1) x @{$static};
2039
2040     $extra = [] unless $extra && ref $extra eq 'ARRAY';
2041     for (sort keys %static) {
2042         next unless /\Q$self->{LIB_EXT}\E$/;
2043         $_ = dirname($_) . "/extralibs.ld";
2044         push @$extra, $_;
2045     }
2046
2047     grep(s/^/-I/, @{$perlinc || []});
2048
2049     $target = "perl" unless $target;
2050     $tmp = "." unless $tmp;
2051
2052 # MAP_STATIC doesn't look into subdirs yet. Once "all" is made and we
2053 # regenerate the Makefiles, MAP_STATIC and the dependencies for
2054 # extralibs.all are computed correctly
2055     push @m, "
2056 MAP_LINKCMD   = $linkcmd
2057 MAP_PERLINC   = @{$perlinc || []}
2058 MAP_STATIC    = ",
2059 join(" \\\n\t", reverse sort keys %static), "
2060
2061 MAP_PRELIBS   = $Config::Config{libs} $Config::Config{cryptlib}
2062 ";
2063
2064     if (defined $libperl) {
2065         ($lperl = $libperl) =~ s/\$\(A\)/$self->{LIB_EXT}/;
2066     }
2067     unless ($libperl && -f $lperl) { # Ilya's code...
2068         my $dir = $self->{PERL_SRC} || "$self->{PERL_ARCHLIB}/CORE";
2069         $libperl ||= "libperl$self->{LIB_EXT}";
2070         $libperl   = "$dir/$libperl";
2071         $lperl   ||= "libperl$self->{LIB_EXT}";
2072         $lperl     = "$dir/$lperl";
2073         print STDOUT "Warning: $libperl not found
2074     If you're going to build a static perl binary, make sure perl is installed
2075     otherwise ignore this warning\n"
2076                 unless (-f $lperl || defined($self->{PERL_SRC}));
2077     }
2078
2079     push @m, "
2080 MAP_LIBPERL = $libperl
2081 ";
2082
2083     push @m, "
2084 \$(INST_ARCHAUTODIR)/extralibs.all: \$(INST_ARCHAUTODIR)/.exists ".join(" \\\n\t", @$extra)."
2085         $self->{NOECHO}$self->{RM_F} \$\@
2086         $self->{NOECHO}\$(TOUCH) \$\@
2087 ";
2088
2089     my $catfile;
2090     foreach $catfile (@$extra){
2091         push @m, "\tcat $catfile >> \$\@\n";
2092     }
2093
2094     push @m, "
2095 \$(MAP_TARGET) :: $tmp/perlmain\$(OBJ_EXT) \$(MAP_LIBPERL) \$(MAP_STATIC) \$(INST_ARCHAUTODIR)/extralibs.all
2096         \$(MAP_LINKCMD) -o \$\@ \$(OPTIMIZE) $tmp/perlmain\$(OBJ_EXT) \$(MAP_LIBPERL) \$(MAP_STATIC) `cat \$(INST_ARCHAUTODIR)/extralibs.all` \$(MAP_PRELIBS)
2097         $self->{NOECHO}echo 'To install the new \"\$(MAP_TARGET)\" binary, call'
2098         $self->{NOECHO}echo '    make -f $makefilename inst_perl MAP_TARGET=\$(MAP_TARGET)'
2099         $self->{NOECHO}echo 'To remove the intermediate files say'
2100         $self->{NOECHO}echo '    make -f $makefilename map_clean'
2101
2102 $tmp/perlmain\$(OBJ_EXT): $tmp/perlmain.c
2103 ";
2104     push @m, "\tcd $tmp && $cccmd -I\$(PERL_INC) perlmain.c\n";
2105
2106     push @m, qq{
2107 $tmp/perlmain.c: $makefilename}, q{
2108         }.$self->{NOECHO}.q{echo Writing $@
2109         }.$self->{NOECHO}.q{$(PERL) $(MAP_PERLINC) -e 'use ExtUtils::Miniperl; \\
2110                 writemain(grep s#.*/auto/##, qw|$(MAP_STATIC)|)' > $@.tmp && mv $@.tmp $@
2111
2112 };
2113
2114     push @m, q{
2115 doc_inst_perl:
2116         }.$self->{NOECHO}.q{echo Appending installation info to $(INSTALLARCHLIB)/perllocal.pod
2117         }.$self->{NOECHO}.q{$(DOC_INSTALL) \
2118                 "Perl binary" "$(MAP_TARGET)" \
2119                 MAP_STATIC "$(MAP_STATIC)" \
2120                 MAP_EXTRA "`cat $(INST_ARCHAUTODIR)/extralibs.all`" \
2121                 MAP_LIBPERL "$(MAP_LIBPERL)" \
2122                 >> }.$self->catfile('$(INSTALLARCHLIB)','perllocal.pod').q{
2123
2124 };
2125
2126     push @m, q{
2127 inst_perl: pure_inst_perl doc_inst_perl
2128
2129 pure_inst_perl: $(MAP_TARGET)
2130         }.$self->{CP}.q{ $(MAP_TARGET) }.$self->catfile('$(INSTALLBIN)','$(MAP_TARGET)').q{
2131
2132 clean :: map_clean
2133
2134 map_clean :
2135         }.$self->{RM_F}.qq{ $tmp/perlmain\$(OBJ_EXT) $tmp/perlmain.c \$(MAP_TARGET) $makefilename \$(INST_ARCHAUTODIR)/extralibs.all
2136 };
2137
2138     join '', @m;
2139 }
2140
2141 =item makefile (o)
2142
2143 Defines how to rewrite the Makefile.
2144
2145 =cut
2146
2147 sub makefile {
2148     my($self) = shift;
2149     my @m;
2150     # We do not know what target was originally specified so we
2151     # must force a manual rerun to be sure. But as it should only
2152     # happen very rarely it is not a significant problem.
2153     push @m, '
2154 $(OBJECT) : $(FIRST_MAKEFILE)
2155 ' if $self->{OBJECT};
2156
2157     push @m, q{
2158 # We take a very conservative approach here, but it\'s worth it.
2159 # We move Makefile to Makefile.old here to avoid gnu make looping.
2160 }.$self->{MAKEFILE}.q{ : Makefile.PL $(CONFIGDEP)
2161         }.$self->{NOECHO}.q{echo "Makefile out-of-date with respect to $?"
2162         }.$self->{NOECHO}.q{echo "Cleaning current config before rebuilding Makefile..."
2163         -}.$self->{NOECHO}.q{mv }."$self->{MAKEFILE} $self->{MAKEFILE}.old".q{
2164         -$(MAKE) -f }.$self->{MAKEFILE}.q{.old clean >/dev/null 2>&1 || true
2165         $(PERL) "-I$(PERL_ARCHLIB)" "-I$(PERL_LIB)" Makefile.PL }.join(" ",map(qq["$_"],@ARGV)).q{
2166         }.$self->{NOECHO}.q{echo ">>> Your Makefile has been rebuilt. <<<"
2167         }.$self->{NOECHO}.q{echo ">>> Please rerun the make command.  <<<"; false
2168
2169 # To change behavior to :: would be nice, but would break Tk b9.02
2170 # so you find such a warning below the dist target.
2171 #}.$self->{MAKEFILE}.q{ :: $(VERSION_FROM)
2172 #       }.$self->{NOECHO}.q{echo "Warning: Makefile possibly out of date with $(VERSION_FROM)"
2173 };
2174
2175     join "", @m;
2176 }
2177
2178 =item manifypods (o)
2179
2180 Defines targets and routines to translate the pods into manpages and
2181 put them into the INST_* directories.
2182
2183 =cut
2184
2185 sub manifypods {
2186     my($self, %attribs) = @_;
2187     return "\nmanifypods :\n\t$self->{NOECHO}\$(NOOP)\n" unless %{$self->{MAN3PODS}} or %{$self->{MAN1PODS}};
2188     my($dist);
2189     my($pod2man_exe);
2190     if (defined $self->{PERL_SRC}) {
2191         $pod2man_exe = $self->catfile($self->{PERL_SRC},'pod','pod2man');
2192     } else {
2193         $pod2man_exe = $self->catfile($Config{scriptdirexp},'pod2man');
2194     }
2195     unless ($self->perl_script($pod2man_exe)) {
2196         # No pod2man but some MAN3PODS to be installed
2197         print <<END;
2198
2199 Warning: I could not locate your pod2man program. Please make sure,
2200          your pod2man program is in your PATH before you execute 'make'
2201
2202 END
2203         $pod2man_exe = "-S pod2man";
2204     }
2205     my(@m);
2206     push @m,
2207 qq[POD2MAN_EXE = $pod2man_exe\n],
2208 q[POD2MAN = $(PERL) -we '%m=@ARGV;for (keys %m){' \\
2209 -e 'next if -e $$m{$$_} && -M $$m{$$_} < -M $$_ && -M $$m{$$_} < -M "].$self->{MAKEFILE}.q[";' \\
2210 -e 'print "Manifying $$m{$$_}\n";' \\
2211 -e 'system(qq[$$^X ].q["-I$(PERL_ARCHLIB)" "-I$(PERL_LIB)" $(POD2MAN_EXE) ].qq[$$_>$$m{$$_}])==0 or warn "Couldn\\047t install $$m{$$_}\n";' \\
2212 -e 'chmod 0644, $$m{$$_} or warn "chmod 644 $$m{$$_}: $$!\n";}'
2213 ];
2214     push @m, "\nmanifypods : ";
2215     push @m, join " \\\n\t", keys %{$self->{MAN1PODS}}, keys %{$self->{MAN3PODS}};
2216
2217     push(@m,"\n");
2218     if (%{$self->{MAN1PODS}} || %{$self->{MAN3PODS}}) {
2219         push @m, "\t$self->{NOECHO}\$(POD2MAN) \\\n\t";
2220         push @m, join " \\\n\t", %{$self->{MAN1PODS}}, %{$self->{MAN3PODS}};
2221     }
2222     join('', @m);
2223 }
2224
2225 =item maybe_command
2226
2227 Returns true, if the argument is likely to be a command.
2228
2229 =cut
2230
2231 sub maybe_command {
2232     my($self,$file) = @_;
2233     return $file if -x $file && ! -d $file;
2234     return;
2235 }
2236
2237 =item maybe_command_in_dirs
2238
2239 method under development. Not yet used. Ask Ilya :-)
2240
2241 =cut
2242
2243 sub maybe_command_in_dirs {     # $ver is optional argument if looking for perl
2244 # Ilya's suggestion. Not yet used, want to understand it first, but at least the code is here
2245     my($self, $names, $dirs, $trace, $ver) = @_;
2246     my($name, $dir);
2247     foreach $dir (@$dirs){
2248         next unless defined $dir; # $self->{PERL_SRC} may be undefined
2249         foreach $name (@$names){
2250             my($abs,$tryabs);
2251             if ($self->file_name_is_absolute($name)) { # /foo/bar
2252                 $abs = $name;
2253             } elsif ($self->canonpath($name) eq $self->canonpath(basename($name))) { # bar
2254                 $abs = $self->catfile($dir, $name);
2255             } else { # foo/bar
2256                 $abs = $self->catfile($self->curdir, $name);
2257             }
2258             print "Checking $abs for $name\n" if ($trace >= 2);
2259             next unless $tryabs = $self->maybe_command($abs);
2260             print "Substituting $tryabs instead of $abs\n"
2261                 if ($trace >= 2 and $tryabs ne $abs);
2262             $abs = $tryabs;
2263             if (defined $ver) {
2264                 print "Executing $abs\n" if ($trace >= 2);
2265                 if (`$abs -e 'require $ver; print "VER_OK\n" ' 2>&1` =~ /VER_OK/) {
2266                     print "Using PERL=$abs\n" if $trace;
2267                     return $abs;
2268                 }
2269             } else { # Do not look for perl
2270                 return $abs;
2271             }
2272         }
2273     }
2274 }
2275
2276 =item needs_linking (o)
2277
2278 Does this module need linking? Looks into subdirectory objects (see
2279 also has_link_code())
2280
2281 =cut
2282
2283 sub needs_linking {
2284     my($self) = shift;
2285     my($child,$caller);
2286     $caller = (caller(0))[3];
2287     Carp::confess("Needs_linking called too early") if $caller =~ /^ExtUtils::MakeMaker::/;
2288     return $self->{NEEDS_LINKING} if defined $self->{NEEDS_LINKING};
2289     if ($self->has_link_code or $self->{MAKEAPERL}){
2290         $self->{NEEDS_LINKING} = 1;
2291         return 1;
2292     }
2293     foreach $child (keys %{$self->{CHILDREN}}) {
2294         if ($self->{CHILDREN}->{$child}->needs_linking) {
2295             $self->{NEEDS_LINKING} = 1;
2296             return 1;
2297         }
2298     }
2299     return $self->{NEEDS_LINKING} = 0;
2300 }
2301
2302 =item nicetext
2303
2304 misnamed method (will have to be changed). The MM_Unix method just
2305 returns the argument without further processing.
2306
2307 On VMS used to insure that colons marking targets are preceded by
2308 space - most Unix Makes don't need this, but it's necessary under VMS
2309 to distinguish the target delimiter from a colon appearing as part of
2310 a filespec.
2311
2312 =cut
2313
2314 sub nicetext {
2315     my($self,$text) = @_;
2316     $text;
2317 }
2318
2319 =item parse_version
2320
2321 parse a file and return what you think is $VERSION in this file set to
2322
2323 =cut
2324
2325 sub parse_version {
2326     my($self,$parsefile) = @_;
2327     my $result;
2328     local *FH;
2329     local $/ = "\n";
2330     open(FH,$parsefile) or die "Could not open '$parsefile': $!";
2331     my $inpod = 0;
2332     while (<FH>) {
2333         $inpod = /^=(?!cut)/ ? 1 : /^=cut/ ? 0 : $inpod;
2334         next if $inpod;
2335         chop;
2336         next unless /\$(([\w\:\']*)\bVERSION)\b.*\=/;
2337         my $eval = qq{
2338             package ExtUtils::MakeMaker::_version;
2339             no strict;
2340
2341             \$$1=undef; do {
2342                 $_
2343             }; \$$1
2344         };
2345         local($^W) = 0;
2346         $result = eval($eval) || 0;
2347         die "Could not eval '$eval' in $parsefile: $@" if $@;
2348         last;
2349     }
2350     close FH;
2351     return $result;
2352 }
2353
2354
2355 =item pasthru (o)
2356
2357 Defines the string that is passed to recursive make calls in
2358 subdirectories.
2359
2360 =cut
2361
2362 sub pasthru {
2363     my($self) = shift;
2364     my(@m,$key);
2365
2366     my(@pasthru);
2367
2368     foreach $key (qw(LIBPERL_A LINKTYPE PREFIX OPTIMIZE)){
2369         push @pasthru, "$key=\"\$($key)\"";
2370     }
2371
2372     push @m, "\nPASTHRU = ", join ("\\\n\t", @pasthru), "\n";
2373     join "", @m;
2374 }
2375
2376 =item path
2377
2378 Takes no argument, returns the environment variable PATH as an array.
2379
2380 =cut
2381
2382 sub path {
2383     my($self) = @_;
2384     my $path_sep = $Is_OS2 ? ";" : ":";
2385     my $path = $ENV{PATH};
2386     $path =~ s:\\:/:g if $Is_OS2;
2387     my @path = split $path_sep, $path;
2388     foreach(@path) { $_ = '.' if $_ eq '' }
2389     @path;
2390 }
2391
2392 =item perl_script
2393
2394 Takes one argument, a file name, and returns the file name, if the
2395 argument is likely to be a perl script. On MM_Unix this is true for
2396 any ordinary, readable file.
2397
2398 =cut
2399
2400 sub perl_script {
2401     my($self,$file) = @_;
2402     return $file if -r $file && -f _;
2403     return;
2404 }
2405
2406 =item perldepend (o)
2407
2408 Defines the dependency from all *.h files that come with the perl
2409 distribution.
2410
2411 =cut
2412
2413 sub perldepend {
2414     my($self) = shift;
2415     my(@m);
2416     push @m, q{
2417 # Check for unpropogated config.sh changes. Should never happen.
2418 # We do NOT just update config.h because that is not sufficient.
2419 # An out of date config.h is not fatal but complains loudly!
2420 $(PERL_INC)/config.h: $(PERL_SRC)/config.sh
2421         -}.$self->{NOECHO}.q{echo "Warning: $(PERL_INC)/config.h out of date with $(PERL_SRC)/config.sh"; false
2422
2423 $(PERL_ARCHLIB)/Config.pm: $(PERL_SRC)/config.sh
2424         }.$self->{NOECHO}.q{echo "Warning: $(PERL_ARCHLIB)/Config.pm may be out of date with $(PERL_SRC)/config.sh"
2425         cd $(PERL_SRC) && $(MAKE) lib/Config.pm
2426 } if $self->{PERL_SRC};
2427
2428     return join "", @m unless $self->needs_linking;
2429
2430     push @m, q{
2431 PERL_HDRS = \
2432 $(PERL_INC)/EXTERN.h       $(PERL_INC)/gv.h           $(PERL_INC)/pp.h       \
2433 $(PERL_INC)/INTERN.h       $(PERL_INC)/handy.h        $(PERL_INC)/proto.h    \
2434 $(PERL_INC)/XSUB.h         $(PERL_INC)/hv.h           $(PERL_INC)/regcomp.h  \
2435 $(PERL_INC)/av.h           $(PERL_INC)/keywords.h     $(PERL_INC)/regexp.h   \
2436 $(PERL_INC)/config.h       $(PERL_INC)/mg.h           $(PERL_INC)/scope.h    \
2437 $(PERL_INC)/cop.h          $(PERL_INC)/op.h           $(PERL_INC)/sv.h       \
2438 $(PERL_INC)/cv.h           $(PERL_INC)/opcode.h       $(PERL_INC)/unixish.h  \
2439 $(PERL_INC)/dosish.h       $(PERL_INC)/patchlevel.h   $(PERL_INC)/util.h     \
2440 $(PERL_INC)/embed.h        $(PERL_INC)/perl.h                                \
2441 $(PERL_INC)/form.h         $(PERL_INC)/perly.h
2442
2443 $(OBJECT) : $(PERL_HDRS)
2444 } if $self->{OBJECT};
2445
2446     push @m, join(" ", values %{$self->{XS}})." : \$(XSUBPPDEPS)\n"  if %{$self->{XS}};
2447
2448     join "\n", @m;
2449 }
2450
2451 =item pm_to_blib
2452
2453 Defines target that copies all files in the hash PM to their
2454 destination and autosplits them. See L<ExtUtils::Install/pm_to_blib>
2455
2456 =cut
2457
2458 sub pm_to_blib {
2459     my $self = shift;
2460     my($autodir) = $self->catdir('$(INST_LIB)','auto');
2461     return q{
2462 pm_to_blib: $(TO_INST_PM)
2463         }.$self->{NOECHO}.q{$(PERL) "-I$(INST_ARCHLIB)" "-I$(INST_LIB)" \
2464         "-I$(PERL_ARCHLIB)" "-I$(PERL_LIB)" -MExtUtils::Install \
2465         -e 'pm_to_blib({qw{$(PM_TO_BLIB)}},"}.$autodir.q{")'
2466         }.$self->{NOECHO}.q{$(TOUCH) $@
2467 };
2468 }
2469
2470 =item post_constants (o)
2471
2472 Returns an empty string per default. Dedicated to overrides from
2473 within Makefile.PL after all constants have been defined.
2474
2475 =cut
2476
2477 sub post_constants{
2478     my($self) = shift;
2479     "";
2480 }
2481
2482 =item post_initialize (o)
2483
2484 Returns an empty string per default. Used in Makefile.PLs to add some
2485 chunk of text to the Makefile after the object is initialized.
2486
2487 =cut
2488
2489 sub post_initialize {
2490     my($self) = shift;
2491     "";
2492 }
2493
2494 =item postamble (o)
2495
2496 Returns an empty string. Can be used in Makefile.PLs to write some
2497 text to the Makefile at the end.
2498
2499 =cut
2500
2501 sub postamble {
2502     my($self) = shift;
2503     "";
2504 }
2505
2506 =item prefixify
2507
2508 Check a path variable in $self from %Config, if it contains a prefix,
2509 and replace it with another one.
2510
2511 Takes as arguments an attribute name, a search prefix and a
2512 replacement prefix. Changes the attribute in the object.
2513
2514 =cut
2515
2516 sub prefixify {
2517     my($self,$var,$sprefix,$rprefix) = @_;
2518     $self->{uc $var} ||= $Config{lc $var};
2519     $self->{uc $var} = VMS::Filespec::unixpath($self->{uc $var}) if $Is_VMS;
2520     $self->{uc $var} =~ s/\Q$sprefix\E/$rprefix/;
2521 }
2522
2523 =item processPL (o)
2524
2525 Defines targets to run *.PL files.
2526
2527 =cut
2528
2529 sub processPL {
2530     my($self) = shift;
2531     return "" unless $self->{PL_FILES};
2532     my(@m, $plfile);
2533     foreach $plfile (sort keys %{$self->{PL_FILES}}) {
2534         push @m, "
2535 all :: $self->{PL_FILES}->{$plfile}
2536
2537 $self->{PL_FILES}->{$plfile} :: $plfile
2538         \$(PERL) -I\$(INST_ARCHLIB) -I\$(INST_LIB) -I\$(PERL_ARCHLIB) -I\$(PERL_LIB) $plfile
2539 ";
2540     }
2541     join "", @m;
2542 }
2543
2544 =item realclean (o)
2545
2546 Defines the realclean target.
2547
2548 =cut
2549
2550 sub realclean {
2551     my($self, %attribs) = @_;
2552     my(@m);
2553     push(@m,'
2554 # Delete temporary files (via clean) and also delete installed files
2555 realclean purge ::  clean
2556 ');
2557     # realclean subdirectories first (already cleaned)
2558     my $sub = "\t-cd %s && test -f %s && \$(MAKE) %s realclean\n";
2559     foreach(@{$self->{DIR}}){
2560         push(@m, sprintf($sub,$_,"$self->{MAKEFILE}.old","-f $self->{MAKEFILE}.old"));
2561         push(@m, sprintf($sub,$_,"$self->{MAKEFILE}",''));
2562     }
2563     push(@m, "  $self->{RM_RF} \$(INST_AUTODIR) \$(INST_ARCHAUTODIR)\n");
2564     if( $self->has_link_code ){
2565         push(@m, "      $self->{RM_F} \$(INST_DYNAMIC) \$(INST_BOOT)\n");
2566         push(@m, "      $self->{RM_F} \$(INST_STATIC)\n");
2567     }
2568     push(@m, "  $self->{RM_F} " . join(" ", values %{$self->{PM}}) . "\n");
2569     my(@otherfiles) = ($self->{MAKEFILE},
2570                        "$self->{MAKEFILE}.old"); # Makefiles last
2571     push(@otherfiles, $attribs{FILES}) if $attribs{FILES};
2572     push(@m, "  $self->{RM_RF} @otherfiles\n") if @otherfiles;
2573     push(@m, "  $attribs{POSTOP}\n")       if $attribs{POSTOP};
2574     join("", @m);
2575 }
2576
2577 =item replace_manpage_separator
2578
2579 Takes the name of a package, which may be a nested package, in the
2580 form Foo/Bar and replaces the slash with C<::>. Returns the replacement.
2581
2582 =cut
2583
2584 sub replace_manpage_separator {
2585     my($self,$man) = @_;
2586     $man =~ s,/+,::,g;
2587     $man;
2588 }
2589
2590 =item static (o)
2591
2592 Defines the static target.
2593
2594 =cut
2595
2596 sub static {
2597 # --- Static Loading Sections ---
2598
2599     my($self) = shift;
2600     '
2601 ## $(INST_PM) has been moved to the all: target.
2602 ## It remains here for awhile to allow for old usage: "make static"
2603 #static :: '.$self->{MAKEFILE}.' $(INST_STATIC) $(INST_PM)
2604 static :: '.$self->{MAKEFILE}.' $(INST_STATIC)
2605         '.$self->{NOECHO}.'$(NOOP)
2606 ';
2607 }
2608
2609 =item static_lib (o)
2610
2611 Defines how to produce the *.a (or equivalent) files.
2612
2613 =cut
2614
2615 sub static_lib {
2616     my($self) = @_;
2617 # Come to think of it, if there are subdirs with linkcode, we still have no INST_STATIC
2618 #    return '' unless $self->needs_linking(); #might be because of a subdir
2619
2620     return '' unless $self->has_link_code;
2621
2622     my(@m);
2623     push(@m, <<'END');
2624 $(INST_STATIC): $(OBJECT) $(MYEXTLIB) $(INST_ARCHAUTODIR)/.exists
2625         $(RM_RF) $@
2626 END
2627     # If this extension has it's own library (eg SDBM_File)
2628     # then copy that to $(INST_STATIC) and add $(OBJECT) into it.
2629     push(@m, "\t$self->{CP} \$(MYEXTLIB) \$\@\n") if $self->{MYEXTLIB};
2630
2631     push @m,
2632 q{      $(AR) $(AR_STATIC_ARGS) $@ $(OBJECT) && $(RANLIB) $@
2633         }.$self->{NOECHO}.q{echo "$(EXTRALIBS)" > $(INST_ARCHAUTODIR)/extralibs.ld
2634         $(CHMOD) 755 $@
2635 };
2636
2637 # Old mechanism - still available:
2638
2639     push @m, "\t$self->{NOECHO}".q{echo "$(EXTRALIBS)" >> $(PERL_SRC)/ext.libs}."\n\n"
2640         if $self->{PERL_SRC};
2641
2642     push @m, $self->dir_target('$(INST_ARCHAUTODIR)');
2643     join('', "\n",@m);
2644 }
2645
2646 =item staticmake (o)
2647
2648 Calls makeaperl.
2649
2650 =cut
2651
2652 sub staticmake {
2653     my($self, %attribs) = @_;
2654     my(@static);
2655
2656     my(@searchdirs)=($self->{PERL_ARCHLIB}, $self->{SITEARCHEXP},  $self->{INST_ARCHLIB});
2657
2658     # And as it's not yet built, we add the current extension
2659     # but only if it has some C code (or XS code, which implies C code)
2660     if (@{$self->{C}}) {
2661         @static = $self->catfile($self->{INST_ARCHLIB},
2662                                  "auto",
2663                                  $self->{FULLEXT},
2664                                  "$self->{BASEEXT}$self->{LIB_EXT}"
2665                                 );
2666     }
2667
2668     # Either we determine now, which libraries we will produce in the
2669     # subdirectories or we do it at runtime of the make.
2670
2671     # We could ask all subdir objects, but I cannot imagine, why it
2672     # would be necessary.
2673
2674     # Instead we determine all libraries for the new perl at
2675     # runtime.
2676     my(@perlinc) = ($self->{INST_ARCHLIB}, $self->{INST_LIB}, $self->{PERL_ARCHLIB}, $self->{PERL_LIB});
2677
2678     $self->makeaperl(MAKE       => $self->{MAKEFILE},
2679                      DIRS       => \@searchdirs,
2680                      STAT       => \@static,
2681                      INCL       => \@perlinc,
2682                      TARGET     => $self->{MAP_TARGET},
2683                      TMP        => "",
2684                      LIBPERL    => $self->{LIBPERL_A}
2685                     );
2686 }
2687
2688 =item subdir_x (o)
2689
2690 Helper subroutine for subdirs
2691
2692 =cut
2693
2694 sub subdir_x {
2695     my($self, $subdir) = @_;
2696     my(@m);
2697     qq{
2698
2699 subdirs ::
2700         $self->{NOECHO}cd $subdir && \$(MAKE) all \$(PASTHRU)
2701
2702 };
2703 }
2704
2705 =item subdirs (o)
2706
2707 Defines targets to process subdirectories.
2708
2709 =cut
2710
2711 sub subdirs {
2712 # --- Sub-directory Sections ---
2713     my($self) = shift;
2714     my(@m,$dir);
2715     # This method provides a mechanism to automatically deal with
2716     # subdirectories containing further Makefile.PL scripts.
2717     # It calls the subdir_x() method for each subdirectory.
2718     foreach $dir (@{$self->{DIR}}){
2719         push(@m, $self->subdir_x($dir));
2720 ####    print "Including $dir subdirectory\n";
2721     }
2722     if (@m){
2723         unshift(@m, "
2724 # The default clean, realclean and test targets in this Makefile
2725 # have automatically been given entries for each subdir.
2726
2727 ");
2728     } else {
2729         push(@m, "\n# none")
2730     }
2731     join('',@m);
2732 }
2733
2734 =item test (o)
2735
2736 Defines the test targets.
2737
2738 =cut
2739
2740 sub test {
2741 # --- Test and Installation Sections ---
2742
2743     my($self, %attribs) = @_;
2744     my($tests) = $attribs{TESTS} || (-d "t" ? "t/*.t" : "");
2745     my(@m);
2746     push(@m,"
2747 TEST_VERBOSE=0
2748 TEST_TYPE=test_\$(LINKTYPE)
2749 TEST_FILE = test.pl
2750 TESTDB_SW = -d
2751
2752 testdb :: testdb_\$(LINKTYPE)
2753
2754 test :: \$(TEST_TYPE)
2755 ");
2756     push(@m, map("\t$self->{NOECHO}cd $_ && test -f $self->{MAKEFILE} && \$(MAKE) test \$(PASTHRU)\n",
2757                  @{$self->{DIR}}));
2758     push(@m, "\t$self->{NOECHO}echo 'No tests defined for \$(NAME) extension.'\n")
2759         unless $tests or -f "test.pl" or @{$self->{DIR}};
2760     push(@m, "\n");
2761
2762     push(@m, "test_dynamic :: pure_all\n");
2763     push(@m, $self->test_via_harness('$(FULLPERL)', $tests)) if $tests;
2764     push(@m, $self->test_via_script('$(FULLPERL)', 'test.pl')) if -f "test.pl";
2765     push(@m, "\n");
2766
2767     push(@m, "testdb_dynamic :: pure_all\n");
2768     push(@m, $self->test_via_script('$(FULLPERL) $(TESTDB_SW)', '$(TEST_FILE)'));
2769     push(@m, "\n");
2770
2771     # Occasionally we may face this degenerate target:
2772     push @m, "test_ : test_dynamic\n\n";
2773
2774     if ($self->needs_linking()) {
2775         push(@m, "test_static :: pure_all \$(MAP_TARGET)\n");
2776         push(@m, $self->test_via_harness('./$(MAP_TARGET)', $tests)) if $tests;
2777         push(@m, $self->test_via_script('./$(MAP_TARGET)', 'test.pl')) if -f "test.pl";
2778         push(@m, "\n");
2779         push(@m, "testdb_static :: pure_all \$(MAP_TARGET)\n");
2780         push(@m, $self->test_via_script('./$(MAP_TARGET) $(TESTDB_SW)', '$(TEST_FILE)'));
2781         push(@m, "\n");
2782     } else {
2783         push @m, "test_static :: test_dynamic\n";
2784         push @m, "testdb_static :: testdb_dynamic\n";
2785     }
2786     join("", @m);
2787 }
2788
2789 =item test_via_harness (o)
2790
2791 Helper method to write the test targets
2792
2793 =cut
2794
2795 sub test_via_harness {
2796     my($self, $perl, $tests) = @_;
2797     "\tPERL_DL_NONLAZY=1 $perl".q! -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) -e 'use Test::Harness qw(&runtests $$verbose); $$verbose=$(TEST_VERBOSE); runtests @ARGV;' !."$tests\n";
2798 }
2799
2800 =item test_via_script (o)
2801
2802 Other helper method for test.
2803
2804 =cut
2805
2806 sub test_via_script {
2807     my($self, $perl, $script) = @_;
2808     qq{\tPERL_DL_NONLAZY=1 $perl}.q{ -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) }.qq{$script
2809 };
2810 }
2811
2812 =item tool_autosplit (o)
2813
2814 Defines a simple perl call that runs autosplit. May be deprecated by
2815 pm_to_blib soon.
2816
2817 =cut
2818
2819 sub tool_autosplit {
2820 # --- Tool Sections ---
2821
2822     my($self, %attribs) = @_;
2823     my($asl) = "";
2824     $asl = "\$AutoSplit::Maxlen=$attribs{MAXLEN};" if $attribs{MAXLEN};
2825     q{
2826 # Usage: $(AUTOSPLITFILE) FileToSplit AutoDirToSplitInto
2827 AUTOSPLITFILE = $(PERL) "-I$(PERL_ARCHLIB)" "-I$(PERL_LIB)" -e 'use AutoSplit;}.$asl.q{autosplit($$ARGV[0], $$ARGV[1], 0, 1, 1) ;'
2828 };
2829 }
2830
2831 =item tools_other (o)
2832
2833 Defines SHELL, LD, TOUCH, CP, MV, RM_F, RM_RF, CHMOD, UMASK_NULL in
2834 the Makefile. Also defines the perl programs MKPATH,
2835 WARN_IF_OLD_PACKLIST, MOD_INSTALL. DOC_INSTALL, and UNINSTALL.
2836
2837 =cut
2838
2839 sub tools_other {
2840     my($self) = shift;
2841     my @m;
2842     my $bin_sh = $Config{sh} || '/bin/sh';
2843     push @m, qq{
2844 SHELL = $bin_sh
2845 };
2846
2847     for (qw/ CHMOD CP LD MV NOOP RM_F RM_RF TOUCH UMASK_NULL / ) {
2848         push @m, "$_ = $self->{$_}\n";
2849     }
2850
2851
2852     push @m, q{
2853 # The following is a portable way to say mkdir -p
2854 # To see which directories are created, change the if 0 to if 1
2855 MKPATH = $(PERL) -wle '$$"="/"; foreach $$p (@ARGV){' \\
2856 -e 'next if -d $$p; my(@p); foreach(split(/\//,$$p)){' \\
2857 -e 'push(@p,$$_); next if -d "@p/"; print "mkdir @p" if 0;' \\
2858 -e 'mkdir("@p",0777)||die $$! } } exit 0;'
2859
2860 # This helps us to minimize the effect of the .exists files A yet
2861 # better solution would be to have a stable file in the perl
2862 # distribution with a timestamp of zero. But this solution doesn't
2863 # need any changes to the core distribution and works with older perls
2864 EQUALIZE_TIMESTAMP = $(PERL) -we 'open F, ">$$ARGV[1]"; close F;' \\
2865 -e 'utime ((stat("$$ARGV[0]"))[8,9], $$ARGV[1])'
2866 };
2867
2868     return join "", @m if $self->{PARENT};
2869
2870     push @m, q{
2871 # Here we warn users that an old packlist file was found somewhere,
2872 # and that they should call some uninstall routine
2873 WARN_IF_OLD_PACKLIST = $(PERL) -we 'exit unless -f $$ARGV[0];' \\
2874 -e 'print "WARNING: I have found an old package in\n";' \\
2875 -e 'print "\t$$ARGV[0].\n";' \\
2876 -e 'print "Please make sure the two installations are not conflicting\n";'
2877
2878 UNINST=0
2879 VERBINST=1
2880
2881 MOD_INSTALL = $(PERL) -I$(INST_LIB) -I$(PERL_LIB) -MExtUtils::Install \
2882 -e 'install({@ARGV},"$(VERBINST)",0,"$(UNINST)");'
2883
2884 DOC_INSTALL = $(PERL) -e '$$\="\n\n";' \
2885 -e 'print "=head2 ", scalar(localtime), ": C<", shift, ">", " L<", shift, ">";' \
2886 -e 'print "=over 4";' \
2887 -e 'while (defined($$key = shift) and defined($$val = shift)){print "=item *";print "C<$$key: $$val>";}' \
2888 -e 'print "=back";'
2889
2890 UNINSTALL =   $(PERL) -MExtUtils::Install \
2891 -e 'uninstall($$ARGV[0],1);'
2892
2893 };
2894
2895     return join "", @m;
2896 }
2897
2898 =item tool_xsubpp (o)
2899
2900 Determines typemaps, xsubpp version, prototype behaviour.
2901
2902 =cut
2903
2904 sub tool_xsubpp {
2905     my($self) = shift;
2906     return "" unless $self->needs_linking;
2907     my($xsdir)  = $self->catdir($self->{PERL_LIB},"ExtUtils");
2908     my(@tmdeps) = $self->catdir('$(XSUBPPDIR)','typemap');
2909     if( $self->{TYPEMAPS} ){
2910         my $typemap;
2911         foreach $typemap (@{$self->{TYPEMAPS}}){
2912                 if( ! -f  $typemap ){
2913                         warn "Typemap $typemap not found.\n";
2914                 }
2915                 else{
2916                         push(@tmdeps,  $typemap);
2917                 }
2918         }
2919     }
2920     push(@tmdeps, "typemap") if -f "typemap";
2921     my(@tmargs) = map("-typemap $_", @tmdeps);
2922     if( exists $self->{XSOPT} ){
2923         unshift( @tmargs, $self->{XSOPT} );
2924     }
2925
2926
2927     my $xsubpp_version = $self->xsubpp_version($self->catfile($xsdir,"xsubpp"));
2928
2929     # What are the correct thresholds for version 1 && 2 Paul?
2930     if ( $xsubpp_version > 1.923 ){
2931         $self->{XSPROTOARG} = "" unless defined $self->{XSPROTOARG};
2932     } else {
2933         if (defined $self->{XSPROTOARG} && $self->{XSPROTOARG} =~ /\-prototypes/) {
2934             print STDOUT qq{Warning: This extension wants to pass the switch "-prototypes" to xsubpp.
2935         Your version of xsubpp is $xsubpp_version and cannot handle this.
2936         Please upgrade to a more recent version of xsubpp.
2937 };
2938         } else {
2939             $self->{XSPROTOARG} = "";
2940         }
2941     }
2942
2943     return qq{
2944 XSUBPPDIR = $xsdir
2945 XSUBPP = \$(XSUBPPDIR)/xsubpp
2946 XSPROTOARG = $self->{XSPROTOARG}
2947 XSUBPPDEPS = @tmdeps
2948 XSUBPPARGS = @tmargs
2949 };
2950 };
2951
2952 sub xsubpp_version
2953 {
2954     my($self,$xsubpp) = @_;
2955     return $Xsubpp_Version if defined $Xsubpp_Version; # global variable
2956
2957     my ($version) ;
2958
2959     # try to figure out the version number of the xsubpp on the system
2960
2961     # first try the -v flag, introduced in 1.921 & 2.000a2
2962
2963     return "" unless $self->needs_linking;
2964
2965     my $command = "$self->{PERL} -I$self->{PERL_LIB} $xsubpp -v 2>&1";
2966     print "Running $command\n" if $Verbose >= 2;
2967     $version = `$command` ;
2968     warn "Running '$command' exits with status " . ($?>>8) if $?;
2969     chop $version ;
2970
2971     return $Xsubpp_Version = $1 if $version =~ /^xsubpp version (.*)/ ;
2972
2973     # nope, then try something else
2974
2975     my $counter = '000';
2976     my ($file) = 'temp' ;
2977     $counter++ while -e "$file$counter"; # don't overwrite anything
2978     $file .= $counter;
2979
2980     open(F, ">$file") or die "Cannot open file '$file': $!\n" ;
2981     print F <<EOM ;
2982 MODULE = fred PACKAGE = fred
2983
2984 int
2985 fred(a)
2986         int     a;
2987 EOM
2988
2989     close F ;
2990
2991     $command = "$self->{PERL} $xsubpp $file 2>&1";
2992     print "Running $command\n" if $Verbose >= 2;
2993     my $text = `$command` ;
2994     warn "Running '$command' exits with status " . ($?>>8) if $?;
2995     unlink $file ;
2996
2997     # gets 1.2 -> 1.92 and 2.000a1
2998     return $Xsubpp_Version = $1 if $text =~ /automatically by xsubpp version ([\S]+)\s*/  ;
2999
3000     # it is either 1.0 or 1.1
3001     return $Xsubpp_Version = 1.1 if $text =~ /^Warning: ignored semicolon/ ;
3002
3003     # none of the above, so 1.0
3004     return $Xsubpp_Version = "1.0" ;
3005 }
3006
3007 =item top_targets (o)
3008
3009 Defines the targets all, subdirs, config, and O_FILES
3010
3011 =cut
3012
3013 sub top_targets {
3014 # --- Target Sections ---
3015
3016     my($self) = shift;
3017     my(@m);
3018     push @m, '
3019 #all :: config $(INST_PM) subdirs linkext manifypods
3020
3021 all :: pure_all manifypods
3022         '.$self->{NOECHO}.'$(NOOP)
3023
3024 pure_all :: config pm_to_blib subdirs linkext
3025         '.$self->{NOECHO}.'$(NOOP)
3026
3027 subdirs :: $(MYEXTLIB)
3028         '.$self->{NOECHO}.'$(NOOP)
3029
3030 config :: '.$self->{MAKEFILE}.' $(INST_LIBDIR)/.exists
3031         '.$self->{NOECHO}.'$(NOOP)
3032
3033 config :: $(INST_ARCHAUTODIR)/.exists
3034         '.$self->{NOECHO}.'$(NOOP)
3035
3036 config :: $(INST_AUTODIR)/.exists
3037         '.$self->{NOECHO}.'$(NOOP)
3038 ';
3039
3040     push @m, qq{
3041 config :: Version_check
3042         $self->{NOECHO}\$(NOOP)
3043
3044 } unless $self->{PARENT} or ($self->{PERL_SRC} && $self->{INSTALLDIRS} eq "perl") or $self->{NO_VC};
3045
3046     push @m, $self->dir_target(qw[$(INST_AUTODIR) $(INST_LIBDIR) $(INST_ARCHAUTODIR)]);
3047
3048     if (%{$self->{MAN1PODS}}) {
3049         push @m, qq[
3050 config :: \$(INST_MAN1DIR)/.exists
3051         $self->{NOECHO}\$(NOOP)
3052
3053 ];
3054         push @m, $self->dir_target(qw[$(INST_MAN1DIR)]);
3055     }
3056     if (%{$self->{MAN3PODS}}) {
3057         push @m, qq[
3058 config :: \$(INST_MAN3DIR)/.exists
3059         $self->{NOECHO}\$(NOOP)
3060
3061 ];
3062         push @m, $self->dir_target(qw[$(INST_MAN3DIR)]);
3063     }
3064
3065     push @m, '
3066 $(O_FILES): $(H_FILES)
3067 ' if @{$self->{O_FILES} || []} && @{$self->{H} || []};
3068
3069     push @m, q{
3070 help:
3071         perldoc ExtUtils::MakeMaker
3072 };
3073
3074     push @m, q{
3075 Version_check:
3076         }.$self->{NOECHO}.q{$(PERL) -I$(PERL_ARCHLIB) -I$(PERL_LIB) \
3077                 -MExtUtils::MakeMaker=Version_check \
3078                 -e 'Version_check("$(MM_VERSION)")'
3079 };
3080
3081     join('',@m);
3082 }
3083
3084 =item writedoc
3085
3086 Obsolete, depecated method. Not used since Version 5.21.
3087
3088 =cut
3089
3090 sub writedoc {
3091 # --- perllocal.pod section ---
3092     my($self,$what,$name,@attribs)=@_;
3093     my $time = localtime;
3094     print "=head2 $time: $what C<$name>\n\n=over 4\n\n=item *\n\n";
3095     print join "\n\n=item *\n\n", map("C<$_>",@attribs);
3096     print "\n\n=back\n\n";
3097 }
3098
3099 =item xs_c (o)
3100
3101 Defines the suffix rules to compile XS files to C.
3102
3103 =cut
3104
3105 sub xs_c {
3106     my($self) = shift;
3107     return '' unless $self->needs_linking();
3108     '
3109 .xs.c:
3110         $(PERL) -I$(PERL_ARCHLIB) -I$(PERL_LIB) $(XSUBPP) $(XSPROTOARG) $(XSUBPPARGS) $*.xs >$*.tc && mv $*.tc $@
3111 ';
3112 }
3113
3114 =item xs_o (o)
3115
3116 Defines suffix rules to go from XS to object files directly. This is
3117 only intended for broken make implementations.
3118
3119 =cut
3120
3121 sub xs_o {      # many makes are too dumb to use xs_c then c_o
3122     my($self) = shift;
3123     return '' unless $self->needs_linking();
3124     '
3125 .xs$(OBJ_EXT):
3126         $(PERL) -I$(PERL_ARCHLIB) -I$(PERL_LIB) $(XSUBPP) $(XSPROTOARG) $(XSUBPPARGS) $*.xs >xstmp.c && mv xstmp.c $*.c
3127         $(CCCMD) $(CCCDLFLAGS) -I$(PERL_INC) $(DEFINE) $*.c
3128 ';
3129 }
3130
3131 1;
3132
3133
3134 =head1 SEE ALSO
3135
3136 L<ExtUtils::MakeMaker>
3137
3138 =cut
3139
3140 __END__