lib/ExtUtils/MM_NW5.pm

   1 package ExtUtils::MM_NW5;
   2
   3 =head1 NAME
   4
   5 ExtUtils::MM_NW5 - methods to override UN*X behaviour in ExtUtils::MakeMaker
   6
   7 =head1 SYNOPSIS
   8
   9  use ExtUtils::MM_NW5; # Done internally by ExtUtils::MakeMaker if needed
  10
  11 =head1 DESCRIPTION
  12
  13 See ExtUtils::MM_Unix for a documentation of the methods provided
  14 there. This package overrides the implementation of these methods, not
  15 the semantics.
  16
  17 =over
  18
  19 =cut
  20
  21 use Config;
  22 use File::Basename;
  23
  24 use vars qw(@ISA $VERSION);
  25 $VERSION = '2.02_01';
  26
  27 require ExtUtils::MM_Win32;
  28 @ISA = qw(ExtUtils::MM_Win32);
  29
  30 use ExtUtils::MakeMaker qw( &neatvalue );
  31
  32 $ENV{EMXSHELL} = 'sh'; # to run `commands`
  33
  34 my $BORLAND  = 1 if $Config{'cc'} =~ /^bcc/i;
  35 my $GCC      = 1 if $Config{'cc'} =~ /^gcc/i;
  36 my $DMAKE    = 1 if $Config{'make'} =~ /^dmake/i;
  37
  38
  39 sub init_others {
  40     my ($self) = @_;
  41     $self->SUPER::init_others(@_);
  42
  43     # incpath is copied to makefile var INCLUDE in constants sub, here just
  44     # make it empty
  45     my $libpth = $Config{'libpth'};
  46     $libpth =~ s( )(;);
  47     $self->{'LIBPTH'} = $libpth;
  48     $self->{'BASE_IMPORT'} = $Config{'base_import'};
  49
  50     # Additional import file specified from Makefile.pl
  51     if($self->{'base_import'}) {
  52         $self->{'BASE_IMPORT'} .= ', ' . $self->{'base_import'};
  53     }
  54
  55     $self->{'NLM_VERSION'} = $Config{'nlm_version'};
  56     $self->{'MPKTOOL'}  = $Config{'mpktool'};
  57     $self->{'TOOLPATH'} = $Config{'toolpath'};
  58 }
  59
  60
  61 =item constants (o)
  62
  63 Initializes lots of constants and .SUFFIXES and .PHONY
  64
  65 =cut
  66
  67 sub const_cccmd {
  68     my($self,$libperl)=@_;
  69     return $self->{CONST_CCCMD} if $self->{CONST_CCCMD};
  70     return '' unless $self->needs_linking();
  71     return $self->{CONST_CCCMD} = <<'MAKE_FRAG';
  72 CCCMD = $(CC) $(CCFLAGS) $(INC) $(OPTIMIZE) \
  73         $(PERLTYPE) $(MPOLLUTE) -o $@ \
  74         -DVERSION=\"$(VERSION)\" -DXS_VERSION=\"$(XS_VERSION)\"
  75 MAKE_FRAG
  76
  77 }
  78
  79 sub constants {
  80     my($self) = @_;
  81     my(@m,$tmp);
  82
  83 # Added LIBPTH, BASE_IMPORT, ABSTRACT, NLM_VERSION BOOT_SYMBOL, NLM_SHORT_NAME
  84 # for NETWARE
  85
  86     for $tmp (qw/
  87
  88               AR_STATIC_ARGS NAME DISTNAME NAME_SYM VERSION
  89               VERSION_SYM XS_VERSION INST_BIN INST_LIB
  90               INST_ARCHLIB INST_SCRIPT PREFIX  INSTALLDIRS
  91               INSTALLPRIVLIB INSTALLARCHLIB INSTALLSITELIB
  92               INSTALLSITEARCH INSTALLBIN INSTALLSCRIPT PERL_LIB
  93               PERL_ARCHLIB SITELIBEXP SITEARCHEXP LIBPERL_A MYEXTLIB
  94               FIRST_MAKEFILE MAKE_APERL_FILE PERLMAINCC PERL_SRC
  95               PERL_INC PERL FULLPERL LIBPTH BASE_IMPORT PERLRUN
  96               FULLPERLRUN PERLRUNINST FULLPERLRUNINST
  97               FULL_AR PERL_CORE NLM_VERSION MPKTOOL TOOLPATH
  98
  99               / ) {
 100         next unless defined $self->{$tmp};
 101         push @m, "$tmp = $self->{$tmp}\n";
 102     }
 103
 104     (my $boot = $self->{'NAME'}) =~ s/:/_/g;
 105     $self->{'BOOT_SYMBOL'}=$boot;
 106     push @m, "BOOT_SYMBOL = $self->{'BOOT_SYMBOL'}\n";
 107
 108     # If the final binary name is greater than 8 chars,
 109     # truncate it here and rename it after creation
 110     # otherwise, Watcom Linker fails
 111     if(length($self->{'BASEEXT'}) > 8) {
 112         $self->{'NLM_SHORT_NAME'} = substr($self->{'BASEEXT'},0,8);
 113         push @m, "NLM_SHORT_NAME = $self->{'NLM_SHORT_NAME'}\n";
 114     }
 115
 116     push @m, qq{
 117 VERSION_MACRO = VERSION
 118 DEFINE_VERSION = -D\$(VERSION_MACRO)=\\\"\$(VERSION)\\\"
 119 XS_VERSION_MACRO = XS_VERSION
 120 XS_DEFINE_VERSION = -D\$(XS_VERSION_MACRO)=\\\"\$(XS_VERSION)\\\"
 121 };
 122
 123     # Get the include path and replace the spaces with ;
 124     # Copy this to makefile as INCLUDE = d:\...;d:\;
 125     (my $inc = $Config{'incpath'}) =~ s/([ ]*)-I/;/g;
 126
 127     # Get the additional include path and append to INCLUDE, keeping it
 128     # in INC will give problems during compilation, hence reset it
 129     # after getting the value
 130     $self->{INC} = '';
 131
 132     push @m, qq{
 133 INCLUDE = $inc;
 134 };
 135
 136     # Set the path to CodeWarrior binaries which might not have been set in
 137     # any other place
 138     push @m, qq{
 139 PATH = \$(PATH);\$(TOOLPATH)
 140 };
 141
 142     push @m, qq{
 143 MAKEMAKER = $INC{'ExtUtils/MakeMaker.pm'}
 144 MM_VERSION = $ExtUtils::MakeMaker::VERSION
 145 };
 146
 147     push @m, q{
 148 # FULLEXT = Pathname for extension directory (eg Foo/Bar/Oracle).
 149 # BASEEXT = Basename part of FULLEXT. May be just equal FULLEXT. (eg Oracle)
 150 # PARENT_NAME = NAME without BASEEXT and no trailing :: (eg Foo::Bar)
 151 # DLBASE  = Basename part of dynamic library. May be just equal BASEEXT.
 152 };
 153
 154     for $tmp (qw/
 155               FULLEXT BASEEXT PARENT_NAME DLBASE VERSION_FROM INC DEFINE OBJECT
 156               LDFROM LINKTYPE
 157               / ) {
 158         next unless defined $self->{$tmp};
 159         push @m, "$tmp = $self->{$tmp}\n";
 160     }
 161
 162     push @m, "
 163 # Handy lists of source code files:
 164 XS_FILES= ".join(" \\\n\t", sort keys %{$self->{XS}})."
 165 C_FILES = ".join(" \\\n\t", @{$self->{C}})."
 166 O_FILES = ".join(" \\\n\t", @{$self->{O_FILES}})."
 167 H_FILES = ".join(" \\\n\t", @{$self->{H}})."
 168 MAN1PODS = ".join(" \\\n\t", sort keys %{$self->{MAN1PODS}})."
 169 MAN3PODS = ".join(" \\\n\t", sort keys %{$self->{MAN3PODS}})."
 170 ";
 171
 172     for $tmp (qw/
 173               INST_MAN1DIR        INSTALLMAN1DIR MAN1EXT
 174               INST_MAN3DIR        INSTALLMAN3DIR MAN3EXT
 175               /) {
 176         next unless defined $self->{$tmp};
 177         push @m, "$tmp = $self->{$tmp}\n";
 178     }
 179
 180     push @m, qq{
 181 .USESHELL :
 182 } if $DMAKE;
 183
 184     push @m, q{
 185 .NO_CONFIG_REC: Makefile
 186 } if $ENV{CLEARCASE_ROOT};
 187
 188     # why not q{} ? -- emacs
 189     push @m, qq{
 190 # work around a famous dec-osf make(1) feature(?):
 191 makemakerdflt: all
 192
 193 .SUFFIXES: .xs .c .C .cpp .cxx .cc \$(OBJ_EXT)
 194
 195 .PHONY: all config static dynamic test linkext manifest
 196
 197 # Where is the Config information that we are using/depend on
 198 CONFIGDEP = \$(PERL_ARCHLIB)\\Config.pm \$(PERL_INC)\\config.h
 199 };
 200
 201     my @parentdir = split(/::/, $self->{PARENT_NAME});
 202     push @m, q{
 203 # Where to put things:
 204 INST_LIBDIR      = }. File::Spec->catdir('$(INST_LIB)',@parentdir)        .q{
 205 INST_ARCHLIBDIR  = }. File::Spec->catdir('$(INST_ARCHLIB)',@parentdir)    .q{
 206
 207 INST_AUTODIR     = }. File::Spec->catdir('$(INST_LIB)','auto','$(FULLEXT)')       .q{
 208 INST_ARCHAUTODIR = }. File::Spec->catdir('$(INST_ARCHLIB)','auto','$(FULLEXT)')   .q{
 209 };
 210
 211     if ($self->has_link_code()) {
 212         push @m, '
 213 INST_STATIC  = $(INST_ARCHAUTODIR)\$(BASEEXT)$(LIB_EXT)
 214 INST_DYNAMIC = $(INST_ARCHAUTODIR)\$(DLBASE).$(DLEXT)
 215 INST_BOOT    = $(INST_ARCHAUTODIR)\$(BASEEXT).bs
 216 ';
 217     } else {
 218         push @m, '
 219 INST_STATIC  =
 220 INST_DYNAMIC =
 221 INST_BOOT    =
 222 ';
 223     }
 224
 225     $tmp = $self->export_list;
 226     push @m, "
 227 EXPORT_LIST = $tmp
 228 ";
 229     $tmp = $self->perl_archive;
 230     push @m, "
 231 PERL_ARCHIVE = $tmp
 232 ";
 233
 234     push @m, q{
 235 TO_INST_PM = }.join(" \\\n\t", sort keys %{$self->{PM}}).q{
 236
 237 PM_TO_BLIB = }.join(" \\\n\t", %{$self->{PM}}).q{
 238 };
 239
 240     join('',@m);
 241 }
 242
 243
 244 =item static_lib (o)
 245
 246 =cut
 247
 248 sub static_lib {
 249     my($self) = @_;
 250 # Come to think of it, if there are subdirs with linkcode, we still have no INST_STATIC
 251 #    return '' unless $self->needs_linking(); #might be because of a subdir
 252
 253     return '' unless $self->has_link_code;
 254
 255     my(@m);
 256     push(@m, <<'END');
 257 $(INST_STATIC): $(OBJECT) $(MYEXTLIB) $(INST_ARCHAUTODIR)\.exists
 258         $(RM_RF) $@
 259 END
 260
 261     # If this extension has it's own library (eg SDBM_File)
 262     # then copy that to $(INST_STATIC) and add $(OBJECT) into it.
 263     push(@m, "\t$self->{CP} \$(MYEXTLIB) \$\@\n") if $self->{MYEXTLIB};
 264
 265     push @m,
 266 q{      $(AR) }.($BORLAND ? '$@ $(OBJECT:^"+")'
 267                           : ($GCC ? '-ru $@ $(OBJECT)'
 268                                   : '-type library -o $@ $(OBJECT)')).q{
 269         }.$self->{NOECHO}.q{echo "$(EXTRALIBS)" > $(INST_ARCHAUTODIR)\extralibs.ld
 270         $(CHMOD) 755 $@
 271 };
 272 # CW change ( -type library ... )
 273 # Old mechanism - still available:
 274
 275     push @m, "\t$self->{NOECHO}".q{echo "$(EXTRALIBS)" >> $(PERL_SRC)\ext.libs}."\n\n"
 276         if $self->{PERL_SRC};
 277
 278     push @m, $self->dir_target('$(INST_ARCHAUTODIR)');
 279     join('', "\n",@m);
 280 }
 281
 282
 283 =item dynamic_lib (o)
 284
 285 Defines how to produce the *.so (or equivalent) files.
 286
 287 =cut
 288
 289 sub dynamic_lib {
 290     my($self, %attribs) = @_;
 291     return '' unless $self->needs_linking(); #might be because of a subdir
 292
 293     return '' unless $self->has_link_code;
 294
 295     my($otherldflags) = $attribs{OTHERLDFLAGS} || ($BORLAND ? 'c0d32.obj': '');
 296     my($inst_dynamic_dep) = $attribs{INST_DYNAMIC_DEP} || "";
 297     my($ldfrom) = '$(LDFROM)';
 298
 299     (my $boot = $self->{NAME}) =~ s/:/_/g;
 300
 301     my $m = <<'MAKE_FRAG';
 302 # This section creates the dynamically loadable $(INST_DYNAMIC)
 303 # from $(OBJECT) and possibly $(MYEXTLIB).
 304 OTHERLDFLAGS = '.$otherldflags.'
 305 INST_DYNAMIC_DEP = '.$inst_dynamic_dep.'
 306
 307 # Create xdc data for an MT safe NLM in case of mpk build
 308 $(INST_DYNAMIC): $(OBJECT) $(MYEXTLIB) $(BOOTSTRAP)
 309         @echo Export boot_$(BOOT_SYMBOL) > $(BASEEXT).def
 310         @echo $(BASE_IMPORT) >> $(BASEEXT).def
 311         @echo Import @$(PERL_INC)\perl.imp >> $(BASEEXT).def
 312 MAKE_FRAG
 313
 314
 315     if ( $self->{CCFLAGS} =~ m/ -DMPK_ON /) {
 316         $m .= <<'MAKE_FRAG';
 317         $(MPKTOOL) $(XDCFLAGS) $(BASEEXT).xdc
 318         @echo xdcdata $(BASEEXT).xdc >> $(BASEEXT).def
 319 MAKE_FRAG
 320     }
 321
 322     $m .= '     $(LD) $(LDFLAGS) $(OBJECT:.obj=.obj) -desc "Perl 5.7.3 Extension ($(BASEEXT))  XS_VERSION: $(XS_VERSION)" -nlmversion $(NLM_VERSION)';
 323
 324     # Taking care of long names like FileHandle, ByteLoader, SDBM_File etc
 325     if($self->{NLM_SHORT_NAME}) {
 326         # In case of nlms with names exceeding 8 chars, build nlm in the
 327         # current dir, rename and move to auto\lib.  If we create in auto\lib
 328         # in the first place, we can't rename afterwards.
 329         $m .= q{ -o $(NLM_SHORT_NAME).$(DLEXT)}
 330     } else {
 331         $m .= q{ -o $(INST_AUTODIR)\\$(BASEEXT).$(DLEXT)}
 332     }
 333
 334     # Add additional lib files if any (SDBM_File)
 335     $m .= q{ $(MYEXTLIB) } if $self->{MYEXTLIB};
 336
 337     $m .= q{ $(PERL_INC)\Main.lib -commandfile $(BASEEXT).def}."\n";
 338
 339     # If it is having a short name, rename it
 340     if($self->{NLM_SHORT_NAME}) {
 341         $m .= <<'MAKE_FRAG';
 342         if exist $(INST_AUTODIR)\$(BASEEXT).$(DLEXT) del $(INST_AUTODIR)\$(BASEEXT).$(DLEXT)
 343         rename $(NLM_SHORT_NAME).$(DLEXT) $(BASEEXT).$(DLEXT)
 344         move $(BASEEXT).$(DLEXT) $(INST_AUTODIR)
 345 MAKE_FRAG
 346     }
 347
 348     $m .= <<'MAKE_FRAG';
 349
 350         $(CHMOD) 755 $@
 351 MAKE_FRAG
 352
 353     $m .= $self->dir_target('$(INST_ARCHAUTODIR)');
 354
 355     return $m;
 356 }
 357
 358
 359 1;
 360 __END__
 361
 362 =back
 363
 364 =cut
 365
 366