lib/ExtUtils/MM.pm

   1 package ExtUtils::MM;
   2
   3 use strict;
   4 use ExtUtils::MakeMaker::Config;
   5 use vars qw(@ISA $VERSION);
   6 $VERSION = '0.06';
   7
   8 require ExtUtils::Liblist;
   9 require ExtUtils::MakeMaker;
  10
  11 @ISA = qw(ExtUtils::Liblist ExtUtils::MakeMaker);
  12
  13 =head1 NAME
  14
  15 ExtUtils::MM - OS adjusted ExtUtils::MakeMaker subclass
  16
  17 =head1 SYNOPSIS
  18
  19   require ExtUtils::MM;
  20   my $mm = MM->new(...);
  21
  22 =head1 DESCRIPTION
  23
  24 B<FOR INTERNAL USE ONLY>
  25
  26 ExtUtils::MM is a subclass of ExtUtils::MakeMaker which automatically
  27 chooses the appropriate OS specific subclass for you
  28 (ie. ExtUils::MM_Unix, etc...).
  29
  30 It also provides a convenient alias via the MM class (I didn't want
  31 MakeMaker modules outside of ExtUtils/).
  32
  33 This class might turn out to be a temporary solution, but MM won't go
  34 away.
  35
  36 =cut
  37
  38 {
  39     # Convenient alias.
  40     package MM;
  41     use vars qw(@ISA);
  42     @ISA = qw(ExtUtils::MM);
  43     sub DESTROY {}
  44 }
  45
  46 my %Is = ();
  47 $Is{VMS}    = $^O eq 'VMS';
  48 $Is{OS2}    = $^O eq 'os2';
  49 $Is{MacOS}  = $^O eq 'MacOS';
  50 if( $^O eq 'MSWin32' ) {
  51     if (defined &DynaLoader::boot_DynaLoader) {
  52         Win32::IsWin95() ? $Is{Win95} = 1 : $Is{Win32} = 1;
  53     }
  54     else {
  55         # Can't use Win32::* with miniperl
  56         !(defined $ENV{SYSTEMROOT}) ? $Is{Win95} = 1 : $Is{Win32} = 1;
  57     }
  58 }
  59 $Is{UWIN}   = $^O =~ /^uwin(-nt)?$/;
  60 $Is{Cygwin} = $^O eq 'cygwin';
  61 $Is{NW5}    = $Config{osname} eq 'NetWare';  # intentional
  62 $Is{BeOS}   = $^O =~ /beos/i;    # XXX should this be that loose?
  63 $Is{DOS}    = $^O eq 'dos';
  64 if( $Is{NW5} ) {
  65     $^O = 'NetWare';
  66     delete $Is{Win32};
  67 }
  68 $Is{VOS}    = $^O eq 'vos';
  69 $Is{QNX}    = $^O eq 'qnx';
  70 $Is{AIX}    = $^O eq 'aix';
  71
  72 $Is{Unix}   = !grep { $_ } values %Is;
  73
  74 map { delete $Is{$_} unless $Is{$_} } keys %Is;
  75 _assert( keys %Is == 1 );
  76 my($OS) = keys %Is;
  77
  78
  79 my $class = "ExtUtils::MM_$OS";
  80 eval "require $class" unless $INC{"ExtUtils/MM_$OS.pm"};
  81 die $@ if $@;
  82 unshift @ISA, $class;
  83
  84
  85 sub _assert {
  86     my $sanity = shift;
  87     die sprintf "Assert failed at %s line %d\n", (caller)[1,2] unless $sanity;
  88     return;
  89 }