lib/ExtUtils/Liblist.pm

   1 package ExtUtils::Liblist;
   2
   3 # Broken out of MakeMaker from version 4.11
   4
   5 use Config;
   6 use Cwd;
   7 use File::Basename;
   8
   9 my $Config_libext = $Config{lib_ext} || ".a";
  10
  11 sub ext {
  12     my($potential_libs, $Verbose) = @_;
  13     if ($Config{'osname'} eq 'os2' and $Config{libs}) {
  14         # Dynamic libraries are not transitive, so we may need including
  15         # the libraries linked against perl.dll again.
  16
  17         $potential_libs .= " " if $potential_libs;
  18         $potential_libs .= $Config{libs};
  19     }
  20     return ("", "", "", "") unless $potential_libs;
  21     print STDOUT "Potential libraries are '$potential_libs':\n" if $Verbose;
  22
  23     my($so)   = $Config{'so'};
  24     my($libs) = $Config{'libs'};
  25
  26     # compute $extralibs, $bsloadlibs and $ldloadlibs from
  27     # $potential_libs
  28     # this is a rewrite of Andy Dougherty's extliblist in perl
  29     # its home is in <distribution>/ext/util
  30
  31     my(@searchpath); # from "-L/path" entries in $potential_libs
  32     my(@libpath) = split " ", $Config{'libpth'};
  33     my(@ldloadlibs, @bsloadlibs, @extralibs, @ld_run_path, %ld_run_path_seen);
  34     my($fullname, $thislib, $thispth, @fullname);
  35     my($pwd) = fastcwd(); # from Cwd.pm
  36     my($found) = 0;
  37
  38     foreach $thislib (split ' ', $potential_libs){
  39
  40         # Handle possible linker path arguments.
  41         if ($thislib =~ s/^(-[LR])//){  # save path flag type
  42             my($ptype) = $1;
  43             unless (-d $thislib){
  44                 print STDOUT "$ptype$thislib ignored, directory does not exist\n"
  45                         if $Verbose;
  46                 next;
  47             }
  48             if ($thislib !~ m|^/|) {
  49               print STDOUT "Warning: $ptype$thislib changed to $ptype$pwd/$thislib\n";
  50               $thislib = "$pwd/$thislib";
  51             }
  52             push(@searchpath, $thislib);
  53             push(@extralibs,  "$ptype$thislib");
  54             push(@ldloadlibs, "$ptype$thislib");
  55             next;
  56         }
  57
  58         # Handle possible library arguments.
  59         unless ($thislib =~ s/^-l//){
  60           print STDOUT "Unrecognized argument in LIBS ignored: '$thislib'\n";
  61           next;
  62         }
  63
  64         my($found_lib)=0;
  65         foreach $thispth (@searchpath, @libpath){
  66
  67                 # Try to find the full name of the library.  We need this to
  68                 # determine whether it's a dynamically-loadable library or not.
  69                 # This tends to be subject to various os-specific quirks.
  70                 # For gcc-2.6.2 on linux (March 1995), DLD can not load
  71                 # .sa libraries, with the exception of libm.sa, so we
  72                 # deliberately skip them.
  73             if (@fullname = lsdir($thispth,"^lib$thislib\.$so\.[0-9]+")){
  74                 # Take care that libfoo.so.10 wins against libfoo.so.9.
  75                 # Compare two libraries to find the most recent version
  76                 # number.  E.g.  if you have libfoo.so.9.0.7 and
  77                 # libfoo.so.10.1, first convert all digits into two
  78                 # decimal places.  Then we'll add ".00" to the shorter
  79                 # strings so that we're comparing strings of equal length
  80                 # Thus we'll compare libfoo.so.09.07.00 with
  81                 # libfoo.so.10.01.00.  Some libraries might have letters
  82                 # in the version.  We don't know what they mean, but will
  83                 # try to skip them gracefully -- we'll set any letter to
  84                 # '0'.  Finally, sort in reverse so we can take the
  85                 # first element.
  86
  87                 #TODO: iterate through the directory instead of sorting
  88
  89                 $fullname = "$thispth/" .
  90                 (sort { my($ma) = $a;
  91                         my($mb) = $b;
  92                         $ma =~ tr/A-Za-z/0/s;
  93                         $ma =~ s/\b(\d)\b/0$1/g;
  94                         $mb =~ tr/A-Za-z/0/s;
  95                         $mb =~ s/\b(\d)\b/0$1/g;
  96                         while (length($ma) < length($mb)) { $ma .= ".00"; }
  97                         while (length($mb) < length($ma)) { $mb .= ".00"; }
  98                         # Comparison deliberately backwards
  99                         $mb cmp $ma;} @fullname)[0];
 100             } elsif (-f ($fullname="$thispth/lib$thislib.$so")
 101                  && (($Config{'dlsrc'} ne "dl_dld.xs") || ($thislib eq "m"))){
 102             } elsif (-f ($fullname="$thispth/lib${thislib}_s$Config_libext")
 103                  && ($thislib .= "_s") ){ # we must explicitly use _s version
 104             } elsif (-f ($fullname="$thispth/lib$thislib$Config_libext")){
 105             } elsif (-f ($fullname="$thispth/$thislib$Config_libext")){
 106             } elsif (-f ($fullname="$thispth/Slib$thislib$Config_libext")){
 107             } else {
 108                 print STDOUT "$thislib not found in $thispth\n" if $Verbose;
 109                 next;
 110             }
 111             print STDOUT "'-l$thislib' found at $fullname\n" if $Verbose;
 112             my($fullnamedir) = dirname($fullname);
 113             push @ld_run_path, $fullnamedir unless $ld_run_path_seen{$fullnamedir}++;
 114             $found++;
 115             $found_lib++;
 116
 117             # Now update library lists
 118
 119             # what do we know about this library...
 120             my $is_dyna = ($fullname !~ /\Q$Config_libext\E$/);
 121             my $in_perl = ($libs =~ /\B-l\Q$ {thislib}\E\b/s);
 122
 123             # Do not add it into the list if it is already linked in
 124             # with the main perl executable.
 125             # We have to special-case the NeXT, because all the math
 126             # is also in libsys_s
 127             unless ($in_perl ||
 128                     ($Config{'osname'} eq 'next' && $thislib eq 'm') ){
 129                 push(@extralibs, "-l$thislib");
 130             }
 131
 132             # We might be able to load this archive file dynamically
 133             if ( $Config{'dlsrc'} =~ /dl_next|dl_dld/){
 134                 # We push -l$thislib instead of $fullname because
 135                 # it avoids hardwiring a fixed path into the .bs file.
 136                 # Mkbootstrap will automatically add dl_findfile() to
 137                 # the .bs file if it sees a name in the -l format.
 138                 # USE THIS, when dl_findfile() is fixed:
 139                 # push(@bsloadlibs, "-l$thislib");
 140                 # OLD USE WAS while checking results against old_extliblist
 141                 push(@bsloadlibs, "$fullname");
 142             } else {
 143                 if ($is_dyna){
 144                     # For SunOS4, do not add in this shared library if
 145                     # it is already linked in the main perl executable
 146                     push(@ldloadlibs, "-l$thislib")
 147                         unless ($in_perl and $Config{'osname'} eq 'sunos');
 148                 } else {
 149                     push(@ldloadlibs, "-l$thislib");
 150                 }
 151             }
 152             last;       # found one here so don't bother looking further
 153         }
 154         print STDOUT "Warning (will try anyway): No library found for -l$thislib\n"
 155             unless $found_lib>0;
 156     }
 157     return ('','','','') unless $found;
 158     ("@extralibs", "@bsloadlibs", "@ldloadlibs",join(":",@ld_run_path));
 159 }
 160
 161 sub lsdir { #yes, duplicate code seems less hassle than having an
 162             #extra file with only lsdir
 163     my($dir, $regex) = @_;
 164     local(*DIR, @ls);
 165     opendir(DIR, $dir || ".") or return ();
 166     @ls = readdir(DIR);
 167     closedir(DIR);
 168     @ls = grep(/$regex/, @ls) if $regex;
 169     @ls;
 170 }
 171
 172 1;
 173 __END__
 174 =head1 NAME
 175
 176 ExtUtils::Liblist - determine libraries to use and how to use them
 177
 178 =head1 SYNOPSIS
 179
 180 C<require ExtUtils::Liblist;>
 181
 182 C<ExtUtils::Liblist::ext($potential_libs, $Verbose);>
 183
 184 =head1 DESCRIPTION
 185
 186 This utility takes a list of libraries in the form C<-llib1 -llib2
 187 -llib3> and prints out lines suitable for inclusion in an extension
 188 Makefile.  Extra library paths may be included with the form
 189 C<-L/another/path> this will affect the searches for all subsequent
 190 libraries.
 191
 192 It returns an array of four scalar values: EXTRALIBS, BSLOADLIBS,
 193 LDLOADLIBS, and LD_RUN_PATH.
 194
 195 Dependent libraries can be linked in one of three ways:
 196
 197 =over 2
 198
 199 =item * For static extensions
 200
 201 by the ld command when the perl binary is linked with the extension
 202 library. See EXTRALIBS below.
 203
 204 =item * For dynamic extensions
 205
 206 by the ld command when the shared object is built/linked. See
 207 LDLOADLIBS below.
 208
 209 =item * For dynamic extensions
 210
 211 by the DynaLoader when the shared object is loaded. See BSLOADLIBS
 212 below.
 213
 214 =back
 215
 216 =head2 EXTRALIBS
 217
 218 List of libraries that need to be linked with when linking a perl
 219 binary which includes this extension Only those libraries that
 220 actually exist are included.  These are written to a file and used
 221 when linking perl.
 222
 223 =head2 LDLOADLIBS and LD_RUN_PATH
 224
 225 List of those libraries which can or must be linked into the shared
 226 library when created using ld. These may be static or dynamic
 227 libraries.  LD_RUN_PATH is a colon separated list of the directories
 228 in LDLOADLIBS. It is passed as an environment variable to the process
 229 that links the shared library.
 230
 231 =head2 BSLOADLIBS
 232
 233 List of those libraries that are needed but can be linked in
 234 dynamically at run time on this platform.  SunOS/Solaris does not need
 235 this because ld records the information (from LDLOADLIBS) into the
 236 object file.  This list is used to create a .bs (bootstrap) file.
 237
 238 =head1 PORTABILITY
 239
 240 This module deals with a lot of system dependencies and has quite a
 241 few architecture specific B<if>s in the code.
 242
 243 =head1 SEE ALSO
 244
 245 L<ExtUtils::MakeMaker>
 246
 247 =cut
 248
 249
 250