lib/ExtUtils/Liblist.pm

   1 package ExtUtils::Liblist;
   2 use vars qw($VERSION);
   3 # Broken out of MakeMaker from version 4.11
   4
   5 $VERSION = substr q$Revision: 1.25 $, 10;
   6
   7 use Config;
   8 use Cwd 'cwd';
   9 use File::Basename;
  10
  11 sub ext {
  12   if   ($^O eq 'VMS')     { return &_vms_ext;      }
  13   elsif($^O eq 'MSWin32') { return &_win32_ext;    }
  14   else                    { return &_unix_os2_ext; }
  15 }
  16
  17 sub _unix_os2_ext {
  18     my($self,$potential_libs, $verbose) = @_;
  19     if ($^O =~ 'os2' and $Config{libs}) {
  20         # Dynamic libraries are not transitive, so we may need including
  21         # the libraries linked against perl.dll again.
  22
  23         $potential_libs .= " " if $potential_libs;
  24         $potential_libs .= $Config{libs};
  25     }
  26     return ("", "", "", "") unless $potential_libs;
  27     warn "Potential libraries are '$potential_libs':\n" if $verbose;
  28
  29     my($so)   = $Config{'so'};
  30     my($libs) = $Config{'libs'};
  31     my $Config_libext = $Config{lib_ext} || ".a";
  32
  33
  34     # compute $extralibs, $bsloadlibs and $ldloadlibs from
  35     # $potential_libs
  36     # this is a rewrite of Andy Dougherty's extliblist in perl
  37
  38     my(@searchpath); # from "-L/path" entries in $potential_libs
  39     my(@libpath) = split " ", $Config{'libpth'};
  40     my(@ldloadlibs, @bsloadlibs, @extralibs, @ld_run_path, %ld_run_path_seen);
  41     my($fullname, $thislib, $thispth, @fullname);
  42     my($pwd) = cwd(); # from Cwd.pm
  43     my($found) = 0;
  44
  45     foreach $thislib (split ' ', $potential_libs){
  46
  47         # Handle possible linker path arguments.
  48         if ($thislib =~ s/^(-[LR])//){  # save path flag type
  49             my($ptype) = $1;
  50             unless (-d $thislib){
  51                 warn "$ptype$thislib ignored, directory does not exist\n"
  52                         if $verbose;
  53                 next;
  54             }
  55             unless ($self->file_name_is_absolute($thislib)) {
  56               warn "Warning: $ptype$thislib changed to $ptype$pwd/$thislib\n";
  57               $thislib = $self->catdir($pwd,$thislib);
  58             }
  59             push(@searchpath, $thislib);
  60             push(@extralibs,  "$ptype$thislib");
  61             push(@ldloadlibs, "$ptype$thislib");
  62             next;
  63         }
  64
  65         # Handle possible library arguments.
  66         unless ($thislib =~ s/^-l//){
  67           warn "Unrecognized argument in LIBS ignored: '$thislib'\n";
  68           next;
  69         }
  70
  71         my($found_lib)=0;
  72         foreach $thispth (@searchpath, @libpath){
  73
  74                 # Try to find the full name of the library.  We need this to
  75                 # determine whether it's a dynamically-loadable library or not.
  76                 # This tends to be subject to various os-specific quirks.
  77                 # For gcc-2.6.2 on linux (March 1995), DLD can not load
  78                 # .sa libraries, with the exception of libm.sa, so we
  79                 # deliberately skip them.
  80             if (@fullname =
  81                     $self->lsdir($thispth,"^\Qlib$thislib.$so.\E[0-9]+")){
  82                 # Take care that libfoo.so.10 wins against libfoo.so.9.
  83                 # Compare two libraries to find the most recent version
  84                 # number.  E.g.  if you have libfoo.so.9.0.7 and
  85                 # libfoo.so.10.1, first convert all digits into two
  86                 # decimal places.  Then we'll add ".00" to the shorter
  87                 # strings so that we're comparing strings of equal length
  88                 # Thus we'll compare libfoo.so.09.07.00 with
  89                 # libfoo.so.10.01.00.  Some libraries might have letters
  90                 # in the version.  We don't know what they mean, but will
  91                 # try to skip them gracefully -- we'll set any letter to
  92                 # '0'.  Finally, sort in reverse so we can take the
  93                 # first element.
  94
  95                 #TODO: iterate through the directory instead of sorting
  96
  97                 $fullname = "$thispth/" .
  98                 (sort { my($ma) = $a;
  99                         my($mb) = $b;
 100                         $ma =~ tr/A-Za-z/0/s;
 101                         $ma =~ s/\b(\d)\b/0$1/g;
 102                         $mb =~ tr/A-Za-z/0/s;
 103                         $mb =~ s/\b(\d)\b/0$1/g;
 104                         while (length($ma) < length($mb)) { $ma .= ".00"; }
 105                         while (length($mb) < length($ma)) { $mb .= ".00"; }
 106                         # Comparison deliberately backwards
 107                         $mb cmp $ma;} @fullname)[0];
 108             } elsif (-f ($fullname="$thispth/lib$thislib.$so")
 109                  && (($Config{'dlsrc'} ne "dl_dld.xs") || ($thislib eq "m"))){
 110             } elsif (-f ($fullname="$thispth/lib${thislib}_s$Config_libext")
 111                  && ($thislib .= "_s") ){ # we must explicitly use _s version
 112             } elsif (-f ($fullname="$thispth/lib$thislib$Config_libext")){
 113             } elsif (-f ($fullname="$thispth/$thislib$Config_libext")){
 114             } elsif (-f ($fullname="$thispth/Slib$thislib$Config_libext")){
 115             } elsif ($^O eq 'dgux'
 116                  && -l ($fullname="$thispth/lib$thislib$Config_libext")
 117                  && readlink($fullname) =~ /^elink:/) {
 118                  # Some of DG's libraries look like misconnected symbolic
 119                  # links, but development tools can follow them.  (They
 120                  # look like this:
 121                  #
 122                  #    libm.a -> elink:${SDE_PATH:-/usr}/sde/\
 123                  #    ${TARGET_BINARY_INTERFACE:-m88kdgux}/usr/lib/libm.a
 124                  #
 125                  # , the compilation tools expand the environment variables.)
 126             } else {
 127                 warn "$thislib not found in $thispth\n" if $verbose;
 128                 next;
 129             }
 130             warn "'-l$thislib' found at $fullname\n" if $verbose;
 131             my($fullnamedir) = dirname($fullname);
 132             push @ld_run_path, $fullnamedir unless $ld_run_path_seen{$fullnamedir}++;
 133             $found++;
 134             $found_lib++;
 135
 136             # Now update library lists
 137
 138             # what do we know about this library...
 139             my $is_dyna = ($fullname !~ /\Q$Config_libext\E$/);
 140             my $in_perl = ($libs =~ /\B-l\Q$ {thislib}\E\b/s);
 141
 142             # Do not add it into the list if it is already linked in
 143             # with the main perl executable.
 144             # We have to special-case the NeXT, because math and ndbm
 145             # are both in libsys_s
 146             unless ($in_perl ||
 147                 ($Config{'osname'} eq 'next' &&
 148                     ($thislib eq 'm' || $thislib eq 'ndbm')) ){
 149                 push(@extralibs, "-l$thislib");
 150             }
 151
 152             # We might be able to load this archive file dynamically
 153             if ( ($Config{'dlsrc'} =~ /dl_next/ && $Config{'osvers'} lt '4_0')
 154             ||   ($Config{'dlsrc'} =~ /dl_dld/) )
 155             {
 156                 # We push -l$thislib instead of $fullname because
 157                 # it avoids hardwiring a fixed path into the .bs file.
 158                 # Mkbootstrap will automatically add dl_findfile() to
 159                 # the .bs file if it sees a name in the -l format.
 160                 # USE THIS, when dl_findfile() is fixed:
 161                 # push(@bsloadlibs, "-l$thislib");
 162                 # OLD USE WAS while checking results against old_extliblist
 163                 push(@bsloadlibs, "$fullname");
 164             } else {
 165                 if ($is_dyna){
 166                     # For SunOS4, do not add in this shared library if
 167                     # it is already linked in the main perl executable
 168                     push(@ldloadlibs, "-l$thislib")
 169                         unless ($in_perl and $^O eq 'sunos');
 170                 } else {
 171                     push(@ldloadlibs, "-l$thislib");
 172                 }
 173             }
 174             last;       # found one here so don't bother looking further
 175         }
 176         warn "Note (probably harmless): "
 177                      ."No library found for -l$thislib\n"
 178             unless $found_lib>0;
 179     }
 180     return ('','','','') unless $found;
 181     ("@extralibs", "@bsloadlibs", "@ldloadlibs",join(":",@ld_run_path));
 182 }
 183
 184 sub _win32_ext {
 185
 186     require Text::ParseWords;
 187
 188     my($self, $potential_libs, $verbose) = @_;
 189
 190     # If user did not supply a list, we punt.
 191     # (caller should probably use the list in $Config{libs})
 192     return ("", "", "", "") unless $potential_libs;
 193
 194     my($so)   = $Config{'so'};
 195     my($libs) = $Config{'libs'};
 196     my($libpth) = $Config{'libpth'};
 197     my($libext) = $Config{'lib_ext'} || ".lib";
 198
 199     if ($libs and $potential_libs !~ /:nodefault/i) {
 200         # If Config.pm defines a set of default libs, we always
 201         # tack them on to the user-supplied list, unless the user
 202         # specified :nodefault
 203
 204         $potential_libs .= " " if $potential_libs;
 205         $potential_libs .= $libs;
 206     }
 207     warn "Potential libraries are '$potential_libs':\n" if $verbose;
 208
 209     # compute $extralibs from $potential_libs
 210
 211     my(@searchpath); # from "-L/path" entries in $potential_libs
 212     my(@libpath) = Text::ParseWords::quotewords('\s+', 0, $libpth);
 213     my(@extralibs);
 214     my($fullname, $thislib, $thispth);
 215     my($pwd) = cwd(); # from Cwd.pm
 216     my($lib) = '';
 217     my($found) = 0;
 218
 219     foreach $thislib (Text::ParseWords::quotewords('\s+', 0, $potential_libs)){
 220
 221         # Handle possible linker path arguments.
 222         if ($thislib =~ s/^-L// and not -d $thislib) {
 223             warn "-L$thislib ignored, directory does not exist\n"
 224                 if $verbose;
 225             next;
 226         }
 227         elsif (-d $thislib) {
 228             unless ($self->file_name_is_absolute($thislib)) {
 229               warn "Warning: '-L$thislib' changed to '-L$pwd/$thislib'\n";
 230               $thislib = $self->catdir($pwd,$thislib);
 231             }
 232             push(@searchpath, $thislib);
 233             next;
 234         }
 235
 236         # Handle possible library arguments.
 237         if ($thislib =~ s/^-l// and $thislib !~ /^lib/i) {
 238             $thislib = "lib$thislib";
 239         }
 240         $thislib .= $libext if $thislib !~ /\Q$libext\E$/i;
 241
 242         my($found_lib)=0;
 243         foreach $thispth (@searchpath, @libpath){
 244             unless (-f ($fullname="$thispth\\$thislib")) {
 245                 warn "$thislib not found in $thispth\n" if $verbose;
 246                 next;
 247             }
 248             warn "'$thislib' found at $fullname\n" if $verbose;
 249             $found++;
 250             $found_lib++;
 251             push(@extralibs, $fullname);
 252             last;
 253         }
 254         warn "Note (probably harmless): "
 255                      ."No library found for '$thislib'\n"
 256             unless $found_lib>0;
 257     }
 258     return ('','','','') unless $found;
 259
 260     # make sure paths with spaces are properly quoted
 261     @extralibs = map { (/\s/ && !/^".*"$/) ? qq["$_"] : $_ } @extralibs;
 262     $lib = join(' ',@extralibs);
 263     warn "Result: $lib\n" if $verbose;
 264     wantarray ? ($lib, '', $lib, '') : $lib;
 265 }
 266
 267
 268 sub _vms_ext {
 269   my($self, $potential_libs,$verbose) = @_;
 270   my(@crtls,$crtlstr);
 271   my($dbgqual) = $self->{OPTIMIZE} || $Config{'optimize'} ||
 272                  $self->{CCFLAS}   || $Config{'ccflags'};
 273   @crtls = ( ($dbgqual =~ m-/Debug-i ? $Config{'dbgprefix'} : '')
 274               . 'PerlShr/Share' );
 275   push(@crtls, grep { not /\(/ } split /\s+/, $Config{'libs'});
 276   push(@crtls, grep { not /\(/ } split /\s+/, $Config{'libc'});
 277   # In general, we pass through the basic libraries from %Config unchanged.
 278   # The one exception is that if we're building in the Perl source tree, and
 279   # a library spec could be resolved via a logical name, we go to some trouble
 280   # to insure that the copy in the local tree is used, rather than one to
 281   # which a system-wide logical may point.
 282   if ($self->{PERL_SRC}) {
 283     my($lib,$locspec,$type);
 284     foreach $lib (@crtls) {
 285       if (($locspec,$type) = $lib =~ m-^([\w$\-]+)(/\w+)?- and $locspec =~ /perl/i) {
 286         if    (lc $type eq '/share')   { $locspec .= $Config{'exe_ext'}; }
 287         elsif (lc $type eq '/library') { $locspec .= $Config{'lib_ext'}; }
 288         else                           { $locspec .= $Config{'obj_ext'}; }
 289         $locspec = $self->catfile($self->{PERL_SRC},$locspec);
 290         $lib = "$locspec$type" if -e $locspec;
 291       }
 292     }
 293   }
 294   $crtlstr = @crtls ? join(' ',@crtls) : '';
 295
 296   unless ($potential_libs) {
 297     warn "Result:\n\tEXTRALIBS: \n\tLDLOADLIBS: $crtlstr\n" if $verbose;
 298     return ('', '', $crtlstr, '');
 299   }
 300
 301   my(@dirs,@libs,$dir,$lib,%sh,%olb,%obj,$ldlib);
 302   my $cwd = cwd();
 303   my($so,$lib_ext,$obj_ext) = @Config{'so','lib_ext','obj_ext'};
 304   # List of common Unix library names and there VMS equivalents
 305   # (VMS equivalent of '' indicates that the library is automatially
 306   # searched by the linker, and should be skipped here.)
 307   my %libmap = ( 'm' => '', 'f77' => '', 'F77' => '', 'V77' => '', 'c' => '',
 308                  'malloc' => '', 'crypt' => '', 'resolv' => '', 'c_s' => '',
 309                  'socket' => '', 'X11' => 'DECW$XLIBSHR',
 310                  'Xt' => 'DECW$XTSHR', 'Xm' => 'DECW$XMLIBSHR',
 311                  'Xmu' => 'DECW$XMULIBSHR');
 312   if ($Config{'vms_cc_type'} ne 'decc') { $libmap{'curses'} = 'VAXCCURSE'; }
 313
 314   warn "Potential libraries are '$potential_libs'\n" if $verbose;
 315
 316   # First, sort out directories and library names in the input
 317   foreach $lib (split ' ',$potential_libs) {
 318     push(@dirs,$1),   next if $lib =~ /^-L(.*)/;
 319     push(@dirs,$lib), next if $lib =~ /[:>\]]$/;
 320     push(@dirs,$lib), next if -d $lib;
 321     push(@libs,$1),   next if $lib =~ /^-l(.*)/;
 322     push(@libs,$lib);
 323   }
 324   push(@dirs,split(' ',$Config{'libpth'}));
 325
 326   # Now make sure we've got VMS-syntax absolute directory specs
 327   # (We don't, however, check whether someone's hidden a relative
 328   # path in a logical name.)
 329   foreach $dir (@dirs) {
 330     unless (-d $dir) {
 331       warn "Skipping nonexistent Directory $dir\n" if $verbose > 1;
 332       $dir = '';
 333       next;
 334     }
 335     warn "Resolving directory $dir\n" if $verbose;
 336     if ($self->file_name_is_absolute($dir)) { $dir = $self->fixpath($dir,1); }
 337     else                                    { $dir = $self->catdir($cwd,$dir); }
 338   }
 339   @dirs = grep { length($_) } @dirs;
 340   unshift(@dirs,''); # Check each $lib without additions first
 341
 342   LIB: foreach $lib (@libs) {
 343     if (exists $libmap{$lib}) {
 344       next unless length $libmap{$lib};
 345       $lib = $libmap{$lib};
 346     }
 347
 348     my(@variants,$variant,$name,$test,$cand);
 349     my($ctype) = '';
 350
 351     # If we don't have a file type, consider it a possibly abbreviated name and
 352     # check for common variants.  We try these first to grab libraries before
 353     # a like-named executable image (e.g. -lperl resolves to perlshr.exe
 354     # before perl.exe).
 355     if ($lib !~ /\.[^:>\]]*$/) {
 356       push(@variants,"${lib}shr","${lib}rtl","${lib}lib");
 357       push(@variants,"lib$lib") if $lib !~ /[:>\]]/;
 358     }
 359     push(@variants,$lib);
 360     warn "Looking for $lib\n" if $verbose;
 361     foreach $variant (@variants) {
 362       foreach $dir (@dirs) {
 363         my($type);
 364
 365         $name = "$dir$variant";
 366         warn "\tChecking $name\n" if $verbose > 2;
 367         if (-f ($test = VMS::Filespec::rmsexpand($name))) {
 368           # It's got its own suffix, so we'll have to figure out the type
 369           if    ($test =~ /(?:$so|exe)$/i)      { $type = 'sh'; }
 370           elsif ($test =~ /(?:$lib_ext|olb)$/i) { $type = 'olb'; }
 371           elsif ($test =~ /(?:$obj_ext|obj)$/i) {
 372             warn "Note (probably harmless): "
 373                          ."Plain object file $test found in library list\n";
 374             $type = 'obj';
 375           }
 376           else {
 377             warn "Note (probably harmless): "
 378                          ."Unknown library type for $test; assuming shared\n";
 379             $type = 'sh';
 380           }
 381         }
 382         elsif (-f ($test = VMS::Filespec::rmsexpand($name,$so))      or
 383                -f ($test = VMS::Filespec::rmsexpand($name,'.exe')))     {
 384           $type = 'sh';
 385           $name = $test unless $test =~ /exe;?\d*$/i;
 386         }
 387         elsif (not length($ctype) and  # If we've got a lib already, don't bother
 388                ( -f ($test = VMS::Filespec::rmsexpand($name,$lib_ext)) or
 389                  -f ($test = VMS::Filespec::rmsexpand($name,'.olb'))))  {
 390           $type = 'olb';
 391           $name = $test unless $test =~ /olb;?\d*$/i;
 392         }
 393         elsif (not length($ctype) and  # If we've got a lib already, don't bother
 394                ( -f ($test = VMS::Filespec::rmsexpand($name,$obj_ext)) or
 395                  -f ($test = VMS::Filespec::rmsexpand($name,'.obj'))))  {
 396           warn "Note (probably harmless): "
 397                        ."Plain object file $test found in library list\n";
 398           $type = 'obj';
 399           $name = $test unless $test =~ /obj;?\d*$/i;
 400         }
 401         if (defined $type) {
 402           $ctype = $type; $cand = $name;
 403           last if $ctype eq 'sh';
 404         }
 405       }
 406       if ($ctype) {
 407         eval '$' . $ctype . "{'$cand'}++";
 408         die "Error recording library: $@" if $@;
 409         warn "\tFound as $cand (really $test), type $ctype\n" if $verbose > 1;
 410         next LIB;
 411       }
 412     }
 413     warn "Note (probably harmless): "
 414                  ."No library found for $lib\n";
 415   }
 416
 417   @libs = sort keys %obj;
 418   # This has to precede any other CRTLs, so just make it first
 419   if ($olb{VAXCCURSE}) {
 420     push(@libs,"$olb{VAXCCURSE}/Library");
 421     delete $olb{VAXCCURSE};
 422   }
 423   push(@libs, map { "$_/Library" } sort keys %olb);
 424   push(@libs, map { "$_/Share"   } sort keys %sh);
 425   $lib = join(' ',@libs);
 426
 427   $ldlib = $crtlstr ? "$lib $crtlstr" : $lib;
 428   warn "Result:\n\tEXTRALIBS: $lib\n\tLDLOADLIBS: $ldlib\n" if $verbose;
 429   wantarray ? ($lib, '', $ldlib, '') : $lib;
 430 }
 431
 432 1;
 433
 434 __END__
 435
 436 =head1 NAME
 437
 438 ExtUtils::Liblist - determine libraries to use and how to use them
 439
 440 =head1 SYNOPSIS
 441
 442 C<require ExtUtils::Liblist;>
 443
 444 C<ExtUtils::Liblist::ext($self, $potential_libs, $verbose);>
 445
 446 =head1 DESCRIPTION
 447
 448 This utility takes a list of libraries in the form C<-llib1 -llib2
 449 -llib3> and prints out lines suitable for inclusion in an extension
 450 Makefile.  Extra library paths may be included with the form
 451 C<-L/another/path> this will affect the searches for all subsequent
 452 libraries.
 453
 454 It returns an array of four scalar values: EXTRALIBS, BSLOADLIBS,
 455 LDLOADLIBS, and LD_RUN_PATH.  Some of these don't mean anything
 456 on VMS and Win32.  See the details about those platform specifics
 457 below.
 458
 459 Dependent libraries can be linked in one of three ways:
 460
 461 =over 2
 462
 463 =item * For static extensions
 464
 465 by the ld command when the perl binary is linked with the extension
 466 library. See EXTRALIBS below.
 467
 468 =item * For dynamic extensions
 469
 470 by the ld command when the shared object is built/linked. See
 471 LDLOADLIBS below.
 472
 473 =item * For dynamic extensions
 474
 475 by the DynaLoader when the shared object is loaded. See BSLOADLIBS
 476 below.
 477
 478 =back
 479
 480 =head2 EXTRALIBS
 481
 482 List of libraries that need to be linked with when linking a perl
 483 binary which includes this extension Only those libraries that
 484 actually exist are included.  These are written to a file and used
 485 when linking perl.
 486
 487 =head2 LDLOADLIBS and LD_RUN_PATH
 488
 489 List of those libraries which can or must be linked into the shared
 490 library when created using ld. These may be static or dynamic
 491 libraries.  LD_RUN_PATH is a colon separated list of the directories
 492 in LDLOADLIBS. It is passed as an environment variable to the process
 493 that links the shared library.
 494
 495 =head2 BSLOADLIBS
 496
 497 List of those libraries that are needed but can be linked in
 498 dynamically at run time on this platform.  SunOS/Solaris does not need
 499 this because ld records the information (from LDLOADLIBS) into the
 500 object file.  This list is used to create a .bs (bootstrap) file.
 501
 502 =head1 PORTABILITY
 503
 504 This module deals with a lot of system dependencies and has quite a
 505 few architecture specific B<if>s in the code.
 506
 507 =head2 VMS implementation
 508
 509 The version of ext() which is executed under VMS differs from the
 510 Unix-OS/2 version in several respects:
 511
 512 =over 2
 513
 514 =item *
 515
 516 Input library and path specifications are accepted with or without the
 517 C<-l> and C<-L> prefices used by Unix linkers.  If neither prefix is
 518 present, a token is considered a directory to search if it is in fact
 519 a directory, and a library to search for otherwise.  Authors who wish
 520 their extensions to be portable to Unix or OS/2 should use the Unix
 521 prefixes, since the Unix-OS/2 version of ext() requires them.
 522
 523 =item *
 524
 525 Wherever possible, shareable images are preferred to object libraries,
 526 and object libraries to plain object files.  In accordance with VMS
 527 naming conventions, ext() looks for files named I<lib>shr and I<lib>rtl;
 528 it also looks for I<lib>lib and libI<lib> to accomodate Unix conventions
 529 used in some ported software.
 530
 531 =item *
 532
 533 For each library that is found, an appropriate directive for a linker options
 534 file is generated.  The return values are space-separated strings of
 535 these directives, rather than elements used on the linker command line.
 536
 537 =item *
 538
 539 LDLOADLIBS contains both the libraries found based on C<$potential_libs> and
 540 the CRTLs, if any, specified in Config.pm.  EXTRALIBS contains just those
 541 libraries found based on C<$potential_libs>.  BSLOADLIBS and LD_RUN_PATH
 542 are always empty.
 543
 544 =back
 545
 546 In addition, an attempt is made to recognize several common Unix library
 547 names, and filter them out or convert them to their VMS equivalents, as
 548 appropriate.
 549
 550 In general, the VMS version of ext() should properly handle input from
 551 extensions originally designed for a Unix or VMS environment.  If you
 552 encounter problems, or discover cases where the search could be improved,
 553 please let us know.
 554
 555 =head2 Win32 implementation
 556
 557 The version of ext() which is executed under Win32 differs from the
 558 Unix-OS/2 version in several respects:
 559
 560 =over 2
 561
 562 =item *
 563
 564 Input library and path specifications are accepted with or without the
 565 C<-l> and C<-L> prefices used by Unix linkers.  C<-lfoo> specifies the
 566 library C<libfoo.lib> (unless C<foo> already starts with C<lib>), and
 567 C<-Ls:ome\dir> specifies a directory to look for the libraries that follow.
 568 If neither prefix is present, a token is considered a directory to search
 569 if it is in fact a directory, and a library to search for otherwise.  The
 570 C<$Config{lib_ext}> suffix will be appended to any entries that are not
 571 directories and don't already have the suffix.  Authors who wish their
 572 extensions to be portable to Unix or OS/2 should use the Unix prefixes,
 573 since the Unix-OS/2 version of ext() requires them.
 574
 575 =item *
 576
 577 Entries cannot be plain object files, as many Win32 compilers will
 578 not handle object files in the place of libraries.
 579
 580 =item *
 581
 582 If C<$potential_libs> is empty, the return value will be empty.
 583 Otherwise, the libraries specified by C<$Config{libs}> (see Config.pm)
 584 will be appended to the list of C<$potential_libs>.  The libraries
 585 will be searched for in the directories specified in C<$potential_libs>
 586 as well as in C<$Config{libpth}>. For each library that is found,  a
 587 space-separated list of fully qualified library pathnames is generated.
 588 You may specify an entry that matches C</:nodefault/i> in
 589 C<$potential_libs> to disable the appending of default libraries
 590 found in C<$Config{libs}> (this should be only needed very rarely).
 591
 592 =item *
 593
 594 The libraries specified may be a mixture of static libraries and
 595 import libraries (to link with DLLs).  Since both kinds are used
 596 pretty transparently on the win32 platform, we do not attempt to
 597 distinguish between them.
 598
 599 =item *
 600
 601 LDLOADLIBS and EXTRALIBS are always identical under Win32, and BSLOADLIBS
 602 and LD_RUN_PATH are always empty (this may change in future).
 603
 604 =item *
 605
 606 You must make sure that any paths and path components are properly
 607 surrounded with double-quotes if they contain spaces. For example,
 608 C<$potential_libs> could be (literally):
 609
 610         "-Lc:\Program Files\vc\lib" msvcrt.lib "la test\foo bar.lib"
 611
 612 Note how the first and last entries are protected by quotes in order
 613 to protect the spaces.
 614
 615 =back
 616
 617
 618 =head1 SEE ALSO
 619
 620 L<ExtUtils::MakeMaker>
 621
 622 =cut
 623