lib/ExtUtils/Liblist.pm

   1 package ExtUtils::Liblist;
   2 use vars qw($VERSION);
   3 # Broken out of MakeMaker from version 4.11
   4
   5 $VERSION = substr q$Revision: 1.25 $, 10;
   6
   7 use Config;
   8 use Cwd 'cwd';
   9 use File::Basename;
  10
  11 sub ext {
  12   if   ($^O eq 'VMS')     { return &_vms_ext;      }
  13   elsif($^O eq 'MSWin32') { return &_win32_ext;    }
  14   else                    { return &_unix_os2_ext; }
  15 }
  16
  17 sub _unix_os2_ext {
  18     my($self,$potential_libs, $verbose) = @_;
  19     if ($^O =~ 'os2' and $Config{libs}) {
  20         # Dynamic libraries are not transitive, so we may need including
  21         # the libraries linked against perl.dll again.
  22
  23         $potential_libs .= " " if $potential_libs;
  24         $potential_libs .= $Config{libs};
  25     }
  26     return ("", "", "", "") unless $potential_libs;
  27     warn "Potential libraries are '$potential_libs':\n" if $verbose;
  28
  29     my($so)   = $Config{'so'};
  30     my($libs) = $Config{'libs'};
  31     my $Config_libext = $Config{lib_ext} || ".a";
  32
  33
  34     # compute $extralibs, $bsloadlibs and $ldloadlibs from
  35     # $potential_libs
  36     # this is a rewrite of Andy Dougherty's extliblist in perl
  37
  38     my(@searchpath); # from "-L/path" entries in $potential_libs
  39     my(@libpath) = split " ", $Config{'libpth'};
  40     my(@ldloadlibs, @bsloadlibs, @extralibs, @ld_run_path, %ld_run_path_seen);
  41     my($fullname, $thislib, $thispth, @fullname);
  42     my($pwd) = cwd(); # from Cwd.pm
  43     my($found) = 0;
  44
  45     foreach $thislib (split ' ', $potential_libs){
  46
  47         # Handle possible linker path arguments.
  48         if ($thislib =~ s/^(-[LR])//){  # save path flag type
  49             my($ptype) = $1;
  50             unless (-d $thislib){
  51                 warn "$ptype$thislib ignored, directory does not exist\n"
  52                         if $verbose;
  53                 next;
  54             }
  55             unless ($self->file_name_is_absolute($thislib)) {
  56               warn "Warning: $ptype$thislib changed to $ptype$pwd/$thislib\n";
  57               $thislib = $self->catdir($pwd,$thislib);
  58             }
  59             push(@searchpath, $thislib);
  60             push(@extralibs,  "$ptype$thislib");
  61             push(@ldloadlibs, "$ptype$thislib");
  62             next;
  63         }
  64
  65         # Handle possible library arguments.
  66         unless ($thislib =~ s/^-l//){
  67           warn "Unrecognized argument in LIBS ignored: '$thislib'\n";
  68           next;
  69         }
  70
  71         my($found_lib)=0;
  72         foreach $thispth (@searchpath, @libpath){
  73
  74                 # Try to find the full name of the library.  We need this to
  75                 # determine whether it's a dynamically-loadable library or not.
  76                 # This tends to be subject to various os-specific quirks.
  77                 # For gcc-2.6.2 on linux (March 1995), DLD can not load
  78                 # .sa libraries, with the exception of libm.sa, so we
  79                 # deliberately skip them.
  80             if (@fullname =
  81                     $self->lsdir($thispth,"^\Qlib$thislib.$so.\E[0-9]+")){
  82                 # Take care that libfoo.so.10 wins against libfoo.so.9.
  83                 # Compare two libraries to find the most recent version
  84                 # number.  E.g.  if you have libfoo.so.9.0.7 and
  85                 # libfoo.so.10.1, first convert all digits into two
  86                 # decimal places.  Then we'll add ".00" to the shorter
  87                 # strings so that we're comparing strings of equal length
  88                 # Thus we'll compare libfoo.so.09.07.00 with
  89                 # libfoo.so.10.01.00.  Some libraries might have letters
  90                 # in the version.  We don't know what they mean, but will
  91                 # try to skip them gracefully -- we'll set any letter to
  92                 # '0'.  Finally, sort in reverse so we can take the
  93                 # first element.
  94
  95                 #TODO: iterate through the directory instead of sorting
  96
  97                 $fullname = "$thispth/" .
  98                 (sort { my($ma) = $a;
  99                         my($mb) = $b;
 100                         $ma =~ tr/A-Za-z/0/s;
 101                         $ma =~ s/\b(\d)\b/0$1/g;
 102                         $mb =~ tr/A-Za-z/0/s;
 103                         $mb =~ s/\b(\d)\b/0$1/g;
 104                         while (length($ma) < length($mb)) { $ma .= ".00"; }
 105                         while (length($mb) < length($ma)) { $mb .= ".00"; }
 106                         # Comparison deliberately backwards
 107                         $mb cmp $ma;} @fullname)[0];
 108             } elsif (-f ($fullname="$thispth/lib$thislib.$so")
 109                  && (($Config{'dlsrc'} ne "dl_dld.xs") || ($thislib eq "m"))){
 110             } elsif (-f ($fullname="$thispth/lib${thislib}_s$Config_libext")
 111                  && ($thislib .= "_s") ){ # we must explicitly use _s version
 112             } elsif (-f ($fullname="$thispth/lib$thislib$Config_libext")){
 113             } elsif (-f ($fullname="$thispth/$thislib$Config_libext")){
 114             } elsif (-f ($fullname="$thispth/Slib$thislib$Config_libext")){
 115             } elsif ($^O eq 'dgux'
 116                  && -l ($fullname="$thispth/lib$thislib$Config_libext")
 117                  && readlink($fullname) =~ /^elink:/) {
 118                  # Some of DG's libraries look like misconnected symbolic
 119                  # links, but development tools can follow them.  (They
 120                  # look like this:
 121                  #
 122                  #    libm.a -> elink:${SDE_PATH:-/usr}/sde/\
 123                  #    ${TARGET_BINARY_INTERFACE:-m88kdgux}/usr/lib/libm.a
 124                  #
 125                  # , the compilation tools expand the environment variables.)
 126             } else {
 127                 warn "$thislib not found in $thispth\n" if $verbose;
 128                 next;
 129             }
 130             warn "'-l$thislib' found at $fullname\n" if $verbose;
 131             my($fullnamedir) = dirname($fullname);
 132             push @ld_run_path, $fullnamedir unless $ld_run_path_seen{$fullnamedir}++;
 133             $found++;
 134             $found_lib++;
 135
 136             # Now update library lists
 137
 138             # what do we know about this library...
 139             my $is_dyna = ($fullname !~ /\Q$Config_libext\E$/);
 140             my $in_perl = ($libs =~ /\B-l\Q$ {thislib}\E\b/s);
 141
 142             # Do not add it into the list if it is already linked in
 143             # with the main perl executable.
 144             # We have to special-case the NeXT, because math and ndbm
 145             # are both in libsys_s
 146             unless ($in_perl ||
 147                 ($Config{'osname'} eq 'next' &&
 148                     ($thislib eq 'm' || $thislib eq 'ndbm')) ){
 149                 push(@extralibs, "-l$thislib");
 150             }
 151
 152             # We might be able to load this archive file dynamically
 153             if ( ($Config{'dlsrc'} =~ /dl_next/ && $Config{'osvers'} lt '4_0')
 154             ||   ($Config{'dlsrc'} =~ /dl_dld/) )
 155             {
 156                 # We push -l$thislib instead of $fullname because
 157                 # it avoids hardwiring a fixed path into the .bs file.
 158                 # Mkbootstrap will automatically add dl_findfile() to
 159                 # the .bs file if it sees a name in the -l format.
 160                 # USE THIS, when dl_findfile() is fixed:
 161                 # push(@bsloadlibs, "-l$thislib");
 162                 # OLD USE WAS while checking results against old_extliblist
 163                 push(@bsloadlibs, "$fullname");
 164             } else {
 165                 if ($is_dyna){
 166                     # For SunOS4, do not add in this shared library if
 167                     # it is already linked in the main perl executable
 168                     push(@ldloadlibs, "-l$thislib")
 169                         unless ($in_perl and $^O eq 'sunos');
 170                 } else {
 171                     push(@ldloadlibs, "-l$thislib");
 172                 }
 173             }
 174             last;       # found one here so don't bother looking further
 175         }
 176         warn "Note (probably harmless): "
 177                      ."No library found for -l$thislib\n"
 178             unless $found_lib>0;
 179     }
 180     return ('','','','') unless $found;
 181     ("@extralibs", "@bsloadlibs", "@ldloadlibs",join(":",@ld_run_path));
 182 }
 183
 184 sub _win32_ext {
 185     my($self, $potential_libs, $verbose) = @_;
 186
 187     # If user did not supply a list, we punt.
 188     # (caller should probably use the list in $Config{libs})
 189     return ("", "", "", "") unless $potential_libs;
 190
 191     my($so)   = $Config{'so'};
 192     my($libs) = $Config{'libs'};
 193     my($libpth) = $Config{'libpth'};
 194     my($libext) = $Config{'lib_ext'} || ".lib";
 195
 196     if ($libs and $potential_libs !~ /:nodefault/i) {
 197         # If Config.pm defines a set of default libs, we always
 198         # tack them on to the user-supplied list, unless the user
 199         # specified :nodefault
 200
 201         $potential_libs .= " " if $potential_libs;
 202         $potential_libs .= $libs;
 203     }
 204     warn "Potential libraries are '$potential_libs':\n" if $verbose;
 205
 206     # compute $extralibs from $potential_libs
 207
 208     my(@searchpath); # from "-L/path" entries in $potential_libs
 209     my(@libpath) = split " ", $libpth;
 210     my(@extralibs);
 211     my($fullname, $thislib, $thispth);
 212     my($pwd) = cwd(); # from Cwd.pm
 213     my($lib) = '';
 214     my($found) = 0;
 215
 216     foreach $thislib (split ' ', $potential_libs){
 217
 218         # Handle possible linker path arguments.
 219         if ($thislib =~ s/^-L// and not -d $thislib) {
 220             warn "-L$thislib ignored, directory does not exist\n"
 221                 if $verbose;
 222             next;
 223         }
 224         elsif (-d $thislib) {
 225             unless ($self->file_name_is_absolute($thislib)) {
 226               warn "Warning: -L$thislib changed to -L$pwd/$thislib\n";
 227               $thislib = $self->catdir($pwd,$thislib);
 228             }
 229             push(@searchpath, $thislib);
 230             next;
 231         }
 232
 233         # Handle possible library arguments.
 234         if ($thislib =~ s/^-l// and $thislib !~ /^lib/i) {
 235             $thislib = "lib$thislib";
 236         }
 237         $thislib .= $libext if $thislib !~ /\Q$libext\E$/i;
 238
 239         my($found_lib)=0;
 240         foreach $thispth (@searchpath, @libpath){
 241             unless (-f ($fullname="$thispth\\$thislib")) {
 242                 warn "$thislib not found in $thispth\n" if $verbose;
 243                 next;
 244             }
 245             warn "'$thislib' found at $fullname\n" if $verbose;
 246             $found++;
 247             $found_lib++;
 248             push(@extralibs, $fullname);
 249             last;
 250         }
 251         warn "Note (probably harmless): "
 252                      ."No library found for '$thislib'\n"
 253             unless $found_lib>0;
 254     }
 255     return ('','','','') unless $found;
 256     $lib = join(' ',@extralibs);
 257     warn "Result: $lib\n" if $verbose;
 258     wantarray ? ($lib, '', $lib, '') : $lib;
 259 }
 260
 261
 262 sub _vms_ext {
 263   my($self, $potential_libs,$verbose) = @_;
 264   return ('', '', '', '') unless $potential_libs;
 265
 266   my(@dirs,@libs,$dir,$lib,%sh,%olb,%obj);
 267   my $cwd = cwd();
 268   my($so,$lib_ext,$obj_ext) = @Config{'so','lib_ext','obj_ext'};
 269   # List of common Unix library names and there VMS equivalents
 270   # (VMS equivalent of '' indicates that the library is automatially
 271   # searched by the linker, and should be skipped here.)
 272   my %libmap = ( 'm' => '', 'f77' => '', 'F77' => '', 'V77' => '', 'c' => '',
 273                  'malloc' => '', 'crypt' => '', 'resolv' => '', 'c_s' => '',
 274                  'socket' => '', 'X11' => 'DECW$XLIBSHR',
 275                  'Xt' => 'DECW$XTSHR', 'Xm' => 'DECW$XMLIBSHR',
 276                  'Xmu' => 'DECW$XMULIBSHR');
 277   if ($Config{'vms_cc_type'} ne 'decc') { $libmap{'curses'} = 'VAXCCURSE'; }
 278
 279   warn "Potential libraries are '$potential_libs'\n" if $verbose;
 280
 281   # First, sort out directories and library names in the input
 282   foreach $lib (split ' ',$potential_libs) {
 283     push(@dirs,$1),   next if $lib =~ /^-L(.*)/;
 284     push(@dirs,$lib), next if $lib =~ /[:>\]]$/;
 285     push(@dirs,$lib), next if -d $lib;
 286     push(@libs,$1),   next if $lib =~ /^-l(.*)/;
 287     push(@libs,$lib);
 288   }
 289   push(@dirs,split(' ',$Config{'libpth'}));
 290
 291   # Now make sure we've got VMS-syntax absolute directory specs
 292   # (We don't, however, check whether someone's hidden a relative
 293   # path in a logical name.)
 294   foreach $dir (@dirs) {
 295     unless (-d $dir) {
 296       warn "Skipping nonexistent Directory $dir\n" if $verbose > 1;
 297       $dir = '';
 298       next;
 299     }
 300     warn "Resolving directory $dir\n" if $verbose;
 301     if ($self->file_name_is_absolute($dir)) { $dir = $self->fixpath($dir,1); }
 302     else                                    { $dir = $self->catdir($cwd,$dir); }
 303   }
 304   @dirs = grep { length($_) } @dirs;
 305   unshift(@dirs,''); # Check each $lib without additions first
 306
 307   LIB: foreach $lib (@libs) {
 308     if (exists $libmap{$lib}) {
 309       next unless length $libmap{$lib};
 310       $lib = $libmap{$lib};
 311     }
 312
 313     my(@variants,$variant,$name,$test,$cand);
 314     my($ctype) = '';
 315
 316     # If we don't have a file type, consider it a possibly abbreviated name and
 317     # check for common variants.  We try these first to grab libraries before
 318     # a like-named executable image (e.g. -lperl resolves to perlshr.exe
 319     # before perl.exe).
 320     if ($lib !~ /\.[^:>\]]*$/) {
 321       push(@variants,"${lib}shr","${lib}rtl","${lib}lib");
 322       push(@variants,"lib$lib") if $lib !~ /[:>\]]/;
 323     }
 324     push(@variants,$lib);
 325     warn "Looking for $lib\n" if $verbose;
 326     foreach $variant (@variants) {
 327       foreach $dir (@dirs) {
 328         my($type);
 329
 330         $name = "$dir$variant";
 331         warn "\tChecking $name\n" if $verbose > 2;
 332         if (-f ($test = VMS::Filespec::rmsexpand($name))) {
 333           # It's got its own suffix, so we'll have to figure out the type
 334           if    ($test =~ /(?:$so|exe)$/i)      { $type = 'sh'; }
 335           elsif ($test =~ /(?:$lib_ext|olb)$/i) { $type = 'olb'; }
 336           elsif ($test =~ /(?:$obj_ext|obj)$/i) {
 337             warn "Note (probably harmless): "
 338                          ."Plain object file $test found in library list\n";
 339             $type = 'obj';
 340           }
 341           else {
 342             warn "Note (probably harmless): "
 343                          ."Unknown library type for $test; assuming shared\n";
 344             $type = 'sh';
 345           }
 346         }
 347         elsif (-f ($test = VMS::Filespec::rmsexpand($name,$so))      or
 348                -f ($test = VMS::Filespec::rmsexpand($name,'.exe')))     {
 349           $type = 'sh';
 350           $name = $test unless $test =~ /exe;?\d*$/i;
 351         }
 352         elsif (not length($ctype) and  # If we've got a lib already, don't bother
 353                ( -f ($test = VMS::Filespec::rmsexpand($name,$lib_ext)) or
 354                  -f ($test = VMS::Filespec::rmsexpand($name,'.olb'))))  {
 355           $type = 'olb';
 356           $name = $test unless $test =~ /olb;?\d*$/i;
 357         }
 358         elsif (not length($ctype) and  # If we've got a lib already, don't bother
 359                ( -f ($test = VMS::Filespec::rmsexpand($name,$obj_ext)) or
 360                  -f ($test = VMS::Filespec::rmsexpand($name,'.obj'))))  {
 361           warn "Note (probably harmless): "
 362                        ."Plain object file $test found in library list\n";
 363           $type = 'obj';
 364           $name = $test unless $test =~ /obj;?\d*$/i;
 365         }
 366         if (defined $type) {
 367           $ctype = $type; $cand = $name;
 368           last if $ctype eq 'sh';
 369         }
 370       }
 371       if ($ctype) {
 372         eval '$' . $ctype . "{'$cand'}++";
 373         die "Error recording library: $@" if $@;
 374         warn "\tFound as $cand (really $test), type $ctype\n" if $verbose > 1;
 375         next LIB;
 376       }
 377     }
 378     warn "Note (probably harmless): "
 379                  ."No library found for $lib\n";
 380   }
 381
 382   @libs = sort keys %obj;
 383   # This has to precede any other CRTLs, so just make it first
 384   if ($olb{VAXCCURSE}) {
 385     push(@libs,"$olb{VAXCCURSE}/Library");
 386     delete $olb{VAXCCURSE};
 387   }
 388   push(@libs, map { "$_/Library" } sort keys %olb);
 389   push(@libs, map { "$_/Share"   } sort keys %sh);
 390   $lib = join(' ',@libs);
 391   warn "Result: $lib\n" if $verbose;
 392   wantarray ? ($lib, '', $lib, '') : $lib;
 393 }
 394
 395 1;
 396
 397 __END__
 398
 399 =head1 NAME
 400
 401 ExtUtils::Liblist - determine libraries to use and how to use them
 402
 403 =head1 SYNOPSIS
 404
 405 C<require ExtUtils::Liblist;>
 406
 407 C<ExtUtils::Liblist::ext($self, $potential_libs, $verbose);>
 408
 409 =head1 DESCRIPTION
 410
 411 This utility takes a list of libraries in the form C<-llib1 -llib2
 412 -llib3> and prints out lines suitable for inclusion in an extension
 413 Makefile.  Extra library paths may be included with the form
 414 C<-L/another/path> this will affect the searches for all subsequent
 415 libraries.
 416
 417 It returns an array of four scalar values: EXTRALIBS, BSLOADLIBS,
 418 LDLOADLIBS, and LD_RUN_PATH.  Some of these don't mean anything
 419 on VMS and Win32.  See the details about those platform specifics
 420 below.
 421
 422 Dependent libraries can be linked in one of three ways:
 423
 424 =over 2
 425
 426 =item * For static extensions
 427
 428 by the ld command when the perl binary is linked with the extension
 429 library. See EXTRALIBS below.
 430
 431 =item * For dynamic extensions
 432
 433 by the ld command when the shared object is built/linked. See
 434 LDLOADLIBS below.
 435
 436 =item * For dynamic extensions
 437
 438 by the DynaLoader when the shared object is loaded. See BSLOADLIBS
 439 below.
 440
 441 =back
 442
 443 =head2 EXTRALIBS
 444
 445 List of libraries that need to be linked with when linking a perl
 446 binary which includes this extension Only those libraries that
 447 actually exist are included.  These are written to a file and used
 448 when linking perl.
 449
 450 =head2 LDLOADLIBS and LD_RUN_PATH
 451
 452 List of those libraries which can or must be linked into the shared
 453 library when created using ld. These may be static or dynamic
 454 libraries.  LD_RUN_PATH is a colon separated list of the directories
 455 in LDLOADLIBS. It is passed as an environment variable to the process
 456 that links the shared library.
 457
 458 =head2 BSLOADLIBS
 459
 460 List of those libraries that are needed but can be linked in
 461 dynamically at run time on this platform.  SunOS/Solaris does not need
 462 this because ld records the information (from LDLOADLIBS) into the
 463 object file.  This list is used to create a .bs (bootstrap) file.
 464
 465 =head1 PORTABILITY
 466
 467 This module deals with a lot of system dependencies and has quite a
 468 few architecture specific B<if>s in the code.
 469
 470 =head2 VMS implementation
 471
 472 The version of ext() which is executed under VMS differs from the
 473 Unix-OS/2 version in several respects:
 474
 475 =over 2
 476
 477 =item *
 478
 479 Input library and path specifications are accepted with or without the
 480 C<-l> and C<-L> prefices used by Unix linkers.  If neither prefix is
 481 present, a token is considered a directory to search if it is in fact
 482 a directory, and a library to search for otherwise.  Authors who wish
 483 their extensions to be portable to Unix or OS/2 should use the Unix
 484 prefixes, since the Unix-OS/2 version of ext() requires them.
 485
 486 =item *
 487
 488 Wherever possible, shareable images are preferred to object libraries,
 489 and object libraries to plain object files.  In accordance with VMS
 490 naming conventions, ext() looks for files named I<lib>shr and I<lib>rtl;
 491 it also looks for I<lib>lib and libI<lib> to accomodate Unix conventions
 492 used in some ported software.
 493
 494 =item *
 495
 496 For each library that is found, an appropriate directive for a linker options
 497 file is generated.  The return values are space-separated strings of
 498 these directives, rather than elements used on the linker command line.
 499
 500 =item *
 501
 502 LDLOADLIBS and EXTRALIBS are always identical under VMS, and BSLOADLIBS
 503 and LD_RIN_PATH are always empty.
 504
 505 =back
 506
 507 In addition, an attempt is made to recognize several common Unix library
 508 names, and filter them out or convert them to their VMS equivalents, as
 509 appropriate.
 510
 511 In general, the VMS version of ext() should properly handle input from
 512 extensions originally designed for a Unix or VMS environment.  If you
 513 encounter problems, or discover cases where the search could be improved,
 514 please let us know.
 515
 516 =head2 Win32 implementation
 517
 518 The version of ext() which is executed under Win32 differs from the
 519 Unix-OS/2 version in several respects:
 520
 521 =over 2
 522
 523 =item *
 524
 525 Input library and path specifications are accepted with or without the
 526 C<-l> and C<-L> prefices used by Unix linkers.  C<-lfoo> specifies the
 527 library C<libfoo.lib> (unless C<foo> already starts with C<lib>), and
 528 C<-Ls:ome\dir> specifies a directory to look for the libraries that follow.
 529 If neither prefix is present, a token is considered a directory to search
 530 if it is in fact a directory, and a library to search for otherwise.  The
 531 C<$Config{lib_ext}> suffix will be appended to any entries that are not
 532 directories and don't already have the suffix.  Authors who wish their
 533 extensions to be portable to Unix or OS/2 should use the Unix prefixes,
 534 since the Unix-OS/2 version of ext() requires them.
 535
 536 =item *
 537
 538 Entries cannot be plain object files, as many Win32 compilers will
 539 not handle object files in the place of libraries.
 540
 541 =item *
 542
 543 If C<$potential_libs> is empty, the return value will be empty.
 544 Otherwise, the libraries specified by C<$Config{libs}> (see Config.pm)
 545 will be appended to the list of C<$potential_libs>.  The libraries
 546 will be searched for in the directories specified in C<$potential_libs>
 547 as well as in C<$Config{libpth}>. For each library that is found,  a
 548 space-separated list of fully qualified library pathnames is generated.
 549 You may specify an entry that matches C</:nodefault/i> in
 550 C<$potential_libs> to disable the appending of default libraries
 551 found in C<$Config{libs}> (this should be only needed very rarely).
 552
 553 =item *
 554
 555 The libraries specified may be a mixture of static libraries and
 556 import libraries (to link with DLLs).  Since both kinds are used
 557 pretty transparently on the win32 platform, we do not attempt to
 558 distinguish between them.
 559
 560 =item *
 561
 562 LDLOADLIBS and EXTRALIBS are always identical under Win32, and BSLOADLIBS
 563 and LD_RUN_PATH are always empty (this may change in future).
 564
 565 =back
 566
 567
 568 =head1 SEE ALSO
 569
 570 L<ExtUtils::MakeMaker>
 571
 572 =cut
 573