lib/ExtUtils/Liblist.pm

   1 package ExtUtils::Liblist;
   2 use vars qw($VERSION);
   3 # Broken out of MakeMaker from version 4.11
   4
   5 $VERSION = substr q$Revision: 1.25 $, 10;
   6
   7 use Config;
   8 use Cwd 'cwd';
   9 use File::Basename;
  10
  11 sub ext {
  12   if   ($^O eq 'VMS')     { return &_vms_ext;      }
  13   elsif($^O eq 'MSWin32') { return &_win32_ext;    }
  14   else                    { return &_unix_os2_ext; }
  15 }
  16
  17 sub _unix_os2_ext {
  18     my($self,$potential_libs, $verbose) = @_;
  19     if ($^O =~ 'os2' and $Config{libs}) {
  20         # Dynamic libraries are not transitive, so we may need including
  21         # the libraries linked against perl.dll again.
  22
  23         $potential_libs .= " " if $potential_libs;
  24         $potential_libs .= $Config{libs};
  25     }
  26     return ("", "", "", "") unless $potential_libs;
  27     warn "Potential libraries are '$potential_libs':\n" if $verbose;
  28
  29     my($so)   = $Config{'so'};
  30     my($libs) = $Config{'libs'};
  31     my $Config_libext = $Config{lib_ext} || ".a";
  32
  33
  34     # compute $extralibs, $bsloadlibs and $ldloadlibs from
  35     # $potential_libs
  36     # this is a rewrite of Andy Dougherty's extliblist in perl
  37
  38     my(@searchpath); # from "-L/path" entries in $potential_libs
  39     my(@libpath) = split " ", $Config{'libpth'};
  40     my(@ldloadlibs, @bsloadlibs, @extralibs, @ld_run_path, %ld_run_path_seen);
  41     my($fullname, $thislib, $thispth, @fullname);
  42     my($pwd) = cwd(); # from Cwd.pm
  43     my($found) = 0;
  44
  45     foreach $thislib (split ' ', $potential_libs){
  46
  47         # Handle possible linker path arguments.
  48         if ($thislib =~ s/^(-[LR])//){  # save path flag type
  49             my($ptype) = $1;
  50             unless (-d $thislib){
  51                 warn "$ptype$thislib ignored, directory does not exist\n"
  52                         if $verbose;
  53                 next;
  54             }
  55             unless ($self->file_name_is_absolute($thislib)) {
  56               warn "Warning: $ptype$thislib changed to $ptype$pwd/$thislib\n";
  57               $thislib = $self->catdir($pwd,$thislib);
  58             }
  59             push(@searchpath, $thislib);
  60             push(@extralibs,  "$ptype$thislib");
  61             push(@ldloadlibs, "$ptype$thislib");
  62             next;
  63         }
  64
  65         # Handle possible library arguments.
  66         unless ($thislib =~ s/^-l//){
  67           warn "Unrecognized argument in LIBS ignored: '$thislib'\n";
  68           next;
  69         }
  70
  71         my($found_lib)=0;
  72         foreach $thispth (@searchpath, @libpath){
  73
  74                 # Try to find the full name of the library.  We need this to
  75                 # determine whether it's a dynamically-loadable library or not.
  76                 # This tends to be subject to various os-specific quirks.
  77                 # For gcc-2.6.2 on linux (March 1995), DLD can not load
  78                 # .sa libraries, with the exception of libm.sa, so we
  79                 # deliberately skip them.
  80             if (@fullname =
  81                     $self->lsdir($thispth,"^\Qlib$thislib.$so.\E[0-9]+")){
  82                 # Take care that libfoo.so.10 wins against libfoo.so.9.
  83                 # Compare two libraries to find the most recent version
  84                 # number.  E.g.  if you have libfoo.so.9.0.7 and
  85                 # libfoo.so.10.1, first convert all digits into two
  86                 # decimal places.  Then we'll add ".00" to the shorter
  87                 # strings so that we're comparing strings of equal length
  88                 # Thus we'll compare libfoo.so.09.07.00 with
  89                 # libfoo.so.10.01.00.  Some libraries might have letters
  90                 # in the version.  We don't know what they mean, but will
  91                 # try to skip them gracefully -- we'll set any letter to
  92                 # '0'.  Finally, sort in reverse so we can take the
  93                 # first element.
  94
  95                 #TODO: iterate through the directory instead of sorting
  96
  97                 $fullname = "$thispth/" .
  98                 (sort { my($ma) = $a;
  99                         my($mb) = $b;
 100                         $ma =~ tr/A-Za-z/0/s;
 101                         $ma =~ s/\b(\d)\b/0$1/g;
 102                         $mb =~ tr/A-Za-z/0/s;
 103                         $mb =~ s/\b(\d)\b/0$1/g;
 104                         while (length($ma) < length($mb)) { $ma .= ".00"; }
 105                         while (length($mb) < length($ma)) { $mb .= ".00"; }
 106                         # Comparison deliberately backwards
 107                         $mb cmp $ma;} @fullname)[0];
 108             } elsif (-f ($fullname="$thispth/lib$thislib.$so")
 109                  && (($Config{'dlsrc'} ne "dl_dld.xs") || ($thislib eq "m"))){
 110             } elsif (-f ($fullname="$thispth/lib${thislib}_s$Config_libext")
 111                  && ($thislib .= "_s") ){ # we must explicitly use _s version
 112             } elsif (-f ($fullname="$thispth/lib$thislib$Config_libext")){
 113             } elsif (-f ($fullname="$thispth/$thislib$Config_libext")){
 114             } elsif (-f ($fullname="$thispth/Slib$thislib$Config_libext")){
 115             } elsif ($^O eq 'dgux'
 116                  && -l ($fullname="$thispth/lib$thislib$Config_libext")
 117                  && readlink($fullname) =~ /^elink:/) {
 118                  # Some of DG's libraries look like misconnected symbolic
 119                  # links, but development tools can follow them.  (They
 120                  # look like this:
 121                  #
 122                  #    libm.a -> elink:${SDE_PATH:-/usr}/sde/\
 123                  #    ${TARGET_BINARY_INTERFACE:-m88kdgux}/usr/lib/libm.a
 124                  #
 125                  # , the compilation tools expand the environment variables.)
 126             } else {
 127                 warn "$thislib not found in $thispth\n" if $verbose;
 128                 next;
 129             }
 130             warn "'-l$thislib' found at $fullname\n" if $verbose;
 131             my($fullnamedir) = dirname($fullname);
 132             push @ld_run_path, $fullnamedir unless $ld_run_path_seen{$fullnamedir}++;
 133             $found++;
 134             $found_lib++;
 135
 136             # Now update library lists
 137
 138             # what do we know about this library...
 139             my $is_dyna = ($fullname !~ /\Q$Config_libext\E$/);
 140             my $in_perl = ($libs =~ /\B-l\Q$ {thislib}\E\b/s);
 141
 142             # Do not add it into the list if it is already linked in
 143             # with the main perl executable.
 144             # We have to special-case the NeXT, because math and ndbm
 145             # are both in libsys_s
 146             unless ($in_perl ||
 147                 ($Config{'osname'} eq 'next' &&
 148                     ($thislib eq 'm' || $thislib eq 'ndbm')) ){
 149                 push(@extralibs, "-l$thislib");
 150             }
 151
 152             # We might be able to load this archive file dynamically
 153             if ( ($Config{'dlsrc'} =~ /dl_next/ && $Config{'osvers'} lt '4_0')
 154             ||   ($Config{'dlsrc'} =~ /dl_dld/) )
 155             {
 156                 # We push -l$thislib instead of $fullname because
 157                 # it avoids hardwiring a fixed path into the .bs file.
 158                 # Mkbootstrap will automatically add dl_findfile() to
 159                 # the .bs file if it sees a name in the -l format.
 160                 # USE THIS, when dl_findfile() is fixed:
 161                 # push(@bsloadlibs, "-l$thislib");
 162                 # OLD USE WAS while checking results against old_extliblist
 163                 push(@bsloadlibs, "$fullname");
 164             } else {
 165                 if ($is_dyna){
 166                     # For SunOS4, do not add in this shared library if
 167                     # it is already linked in the main perl executable
 168                     push(@ldloadlibs, "-l$thislib")
 169                         unless ($in_perl and $^O eq 'sunos');
 170                 } else {
 171                     push(@ldloadlibs, "-l$thislib");
 172                 }
 173             }
 174             last;       # found one here so don't bother looking further
 175         }
 176         warn "Note (probably harmless): "
 177                      ."No library found for -l$thislib\n"
 178             unless $found_lib>0;
 179     }
 180     return ('','','','') unless $found;
 181     ("@extralibs", "@bsloadlibs", "@ldloadlibs",join(":",@ld_run_path));
 182 }
 183
 184 sub _win32_ext {
 185
 186     require Text::ParseWords;
 187
 188     my($self, $potential_libs, $verbose) = @_;
 189
 190     # If user did not supply a list, we punt.
 191     # (caller should probably use the list in $Config{libs})
 192     return ("", "", "", "") unless $potential_libs;
 193
 194     my($so)   = $Config{'so'};
 195     my($libs) = $Config{'libs'};
 196     my($libpth) = $Config{'libpth'};
 197     my($libext) = $Config{'lib_ext'} || ".lib";
 198
 199     if ($libs and $potential_libs !~ /:nodefault/i) {
 200         # If Config.pm defines a set of default libs, we always
 201         # tack them on to the user-supplied list, unless the user
 202         # specified :nodefault
 203
 204         $potential_libs .= " " if $potential_libs;
 205         $potential_libs .= $libs;
 206     }
 207     warn "Potential libraries are '$potential_libs':\n" if $verbose;
 208
 209     # normalize to forward slashes
 210     $libpth =~ s,\\,/,g;
 211     $potential_libs =~ s,\\,/,g;
 212
 213     # compute $extralibs from $potential_libs
 214
 215     my(@searchpath); # from "-L/path" entries in $potential_libs
 216     my(@libpath) = Text::ParseWords::quotewords('\s+', 0, $libpth);
 217     my(@extralibs);
 218     my($fullname, $thislib, $thispth);
 219     my($pwd) = cwd(); # from Cwd.pm
 220     my($lib) = '';
 221     my($found) = 0;
 222
 223     foreach $thislib (Text::ParseWords::quotewords('\s+', 0, $potential_libs)){
 224
 225         # Handle possible linker path arguments.
 226         if ($thislib =~ s/^-L// and not -d $thislib) {
 227             warn "-L$thislib ignored, directory does not exist\n"
 228                 if $verbose;
 229             next;
 230         }
 231         elsif (-d $thislib) {
 232             unless ($self->file_name_is_absolute($thislib)) {
 233               warn "Warning: '-L$thislib' changed to '-L$pwd/$thislib'\n";
 234               $thislib = $self->catdir($pwd,$thislib);
 235             }
 236             push(@searchpath, $thislib);
 237             next;
 238         }
 239
 240         # Handle possible library arguments.
 241         if ($thislib =~ s/^-l// and $thislib !~ /^lib/i) {
 242             $thislib = "lib$thislib";
 243         }
 244         $thislib .= $libext if $thislib !~ /\Q$libext\E$/i;
 245
 246         my($found_lib)=0;
 247         foreach $thispth (@searchpath, @libpath){
 248             unless (-f ($fullname="$thispth\\$thislib")) {
 249                 warn "$thislib not found in $thispth\n" if $verbose;
 250                 next;
 251             }
 252             warn "'$thislib' found at $fullname\n" if $verbose;
 253             $found++;
 254             $found_lib++;
 255             push(@extralibs, $fullname);
 256             last;
 257         }
 258         warn "Note (probably harmless): "
 259                      ."No library found for '$thislib'\n"
 260             unless $found_lib>0;
 261     }
 262     return ('','','','') unless $found;
 263
 264     # make sure paths with spaces are properly quoted
 265     @extralibs = map { (/\s/ && !/^".*"$/) ? qq["$_"] : $_ } @extralibs;
 266     $lib = join(' ',@extralibs);
 267     warn "Result: $lib\n" if $verbose;
 268     wantarray ? ($lib, '', $lib, '') : $lib;
 269 }
 270
 271
 272 sub _vms_ext {
 273   my($self, $potential_libs,$verbose) = @_;
 274   my(@crtls,$crtlstr);
 275   my($dbgqual) = $self->{OPTIMIZE} || $Config{'optimize'} ||
 276                  $self->{CCFLAS}   || $Config{'ccflags'};
 277   @crtls = ( ($dbgqual =~ m-/Debug-i ? $Config{'dbgprefix'} : '')
 278               . 'PerlShr/Share' );
 279   push(@crtls, grep { not /\(/ } split /\s+/, $Config{'libs'});
 280   push(@crtls, grep { not /\(/ } split /\s+/, $Config{'libc'});
 281   # In general, we pass through the basic libraries from %Config unchanged.
 282   # The one exception is that if we're building in the Perl source tree, and
 283   # a library spec could be resolved via a logical name, we go to some trouble
 284   # to insure that the copy in the local tree is used, rather than one to
 285   # which a system-wide logical may point.
 286   if ($self->{PERL_SRC}) {
 287     my($lib,$locspec,$type);
 288     foreach $lib (@crtls) {
 289       if (($locspec,$type) = $lib =~ m-^([\w$\-]+)(/\w+)?- and $locspec =~ /perl/i) {
 290         if    (lc $type eq '/share')   { $locspec .= $Config{'exe_ext'}; }
 291         elsif (lc $type eq '/library') { $locspec .= $Config{'lib_ext'}; }
 292         else                           { $locspec .= $Config{'obj_ext'}; }
 293         $locspec = $self->catfile($self->{PERL_SRC},$locspec);
 294         $lib = "$locspec$type" if -e $locspec;
 295       }
 296     }
 297   }
 298   $crtlstr = @crtls ? join(' ',@crtls) : '';
 299
 300   unless ($potential_libs) {
 301     warn "Result:\n\tEXTRALIBS: \n\tLDLOADLIBS: $crtlstr\n" if $verbose;
 302     return ('', '', $crtlstr, '');
 303   }
 304
 305   my(@dirs,@libs,$dir,$lib,%sh,%olb,%obj,$ldlib);
 306   my $cwd = cwd();
 307   my($so,$lib_ext,$obj_ext) = @Config{'so','lib_ext','obj_ext'};
 308   # List of common Unix library names and there VMS equivalents
 309   # (VMS equivalent of '' indicates that the library is automatially
 310   # searched by the linker, and should be skipped here.)
 311   my %libmap = ( 'm' => '', 'f77' => '', 'F77' => '', 'V77' => '', 'c' => '',
 312                  'malloc' => '', 'crypt' => '', 'resolv' => '', 'c_s' => '',
 313                  'socket' => '', 'X11' => 'DECW$XLIBSHR',
 314                  'Xt' => 'DECW$XTSHR', 'Xm' => 'DECW$XMLIBSHR',
 315                  'Xmu' => 'DECW$XMULIBSHR');
 316   if ($Config{'vms_cc_type'} ne 'decc') { $libmap{'curses'} = 'VAXCCURSE'; }
 317
 318   warn "Potential libraries are '$potential_libs'\n" if $verbose;
 319
 320   # First, sort out directories and library names in the input
 321   foreach $lib (split ' ',$potential_libs) {
 322     push(@dirs,$1),   next if $lib =~ /^-L(.*)/;
 323     push(@dirs,$lib), next if $lib =~ /[:>\]]$/;
 324     push(@dirs,$lib), next if -d $lib;
 325     push(@libs,$1),   next if $lib =~ /^-l(.*)/;
 326     push(@libs,$lib);
 327   }
 328   push(@dirs,split(' ',$Config{'libpth'}));
 329
 330   # Now make sure we've got VMS-syntax absolute directory specs
 331   # (We don't, however, check whether someone's hidden a relative
 332   # path in a logical name.)
 333   foreach $dir (@dirs) {
 334     unless (-d $dir) {
 335       warn "Skipping nonexistent Directory $dir\n" if $verbose > 1;
 336       $dir = '';
 337       next;
 338     }
 339     warn "Resolving directory $dir\n" if $verbose;
 340     if ($self->file_name_is_absolute($dir)) { $dir = $self->fixpath($dir,1); }
 341     else                                    { $dir = $self->catdir($cwd,$dir); }
 342   }
 343   @dirs = grep { length($_) } @dirs;
 344   unshift(@dirs,''); # Check each $lib without additions first
 345
 346   LIB: foreach $lib (@libs) {
 347     if (exists $libmap{$lib}) {
 348       next unless length $libmap{$lib};
 349       $lib = $libmap{$lib};
 350     }
 351
 352     my(@variants,$variant,$name,$test,$cand);
 353     my($ctype) = '';
 354
 355     # If we don't have a file type, consider it a possibly abbreviated name and
 356     # check for common variants.  We try these first to grab libraries before
 357     # a like-named executable image (e.g. -lperl resolves to perlshr.exe
 358     # before perl.exe).
 359     if ($lib !~ /\.[^:>\]]*$/) {
 360       push(@variants,"${lib}shr","${lib}rtl","${lib}lib");
 361       push(@variants,"lib$lib") if $lib !~ /[:>\]]/;
 362     }
 363     push(@variants,$lib);
 364     warn "Looking for $lib\n" if $verbose;
 365     foreach $variant (@variants) {
 366       foreach $dir (@dirs) {
 367         my($type);
 368
 369         $name = "$dir$variant";
 370         warn "\tChecking $name\n" if $verbose > 2;
 371         if (-f ($test = VMS::Filespec::rmsexpand($name))) {
 372           # It's got its own suffix, so we'll have to figure out the type
 373           if    ($test =~ /(?:$so|exe)$/i)      { $type = 'sh'; }
 374           elsif ($test =~ /(?:$lib_ext|olb)$/i) { $type = 'olb'; }
 375           elsif ($test =~ /(?:$obj_ext|obj)$/i) {
 376             warn "Note (probably harmless): "
 377                          ."Plain object file $test found in library list\n";
 378             $type = 'obj';
 379           }
 380           else {
 381             warn "Note (probably harmless): "
 382                          ."Unknown library type for $test; assuming shared\n";
 383             $type = 'sh';
 384           }
 385         }
 386         elsif (-f ($test = VMS::Filespec::rmsexpand($name,$so))      or
 387                -f ($test = VMS::Filespec::rmsexpand($name,'.exe')))     {
 388           $type = 'sh';
 389           $name = $test unless $test =~ /exe;?\d*$/i;
 390         }
 391         elsif (not length($ctype) and  # If we've got a lib already, don't bother
 392                ( -f ($test = VMS::Filespec::rmsexpand($name,$lib_ext)) or
 393                  -f ($test = VMS::Filespec::rmsexpand($name,'.olb'))))  {
 394           $type = 'olb';
 395           $name = $test unless $test =~ /olb;?\d*$/i;
 396         }
 397         elsif (not length($ctype) and  # If we've got a lib already, don't bother
 398                ( -f ($test = VMS::Filespec::rmsexpand($name,$obj_ext)) or
 399                  -f ($test = VMS::Filespec::rmsexpand($name,'.obj'))))  {
 400           warn "Note (probably harmless): "
 401                        ."Plain object file $test found in library list\n";
 402           $type = 'obj';
 403           $name = $test unless $test =~ /obj;?\d*$/i;
 404         }
 405         if (defined $type) {
 406           $ctype = $type; $cand = $name;
 407           last if $ctype eq 'sh';
 408         }
 409       }
 410       if ($ctype) {
 411         eval '$' . $ctype . "{'$cand'}++";
 412         die "Error recording library: $@" if $@;
 413         warn "\tFound as $cand (really $test), type $ctype\n" if $verbose > 1;
 414         next LIB;
 415       }
 416     }
 417     warn "Note (probably harmless): "
 418                  ."No library found for $lib\n";
 419   }
 420
 421   @libs = sort keys %obj;
 422   # This has to precede any other CRTLs, so just make it first
 423   if ($olb{VAXCCURSE}) {
 424     push(@libs,"$olb{VAXCCURSE}/Library");
 425     delete $olb{VAXCCURSE};
 426   }
 427   push(@libs, map { "$_/Library" } sort keys %olb);
 428   push(@libs, map { "$_/Share"   } sort keys %sh);
 429   $lib = join(' ',@libs);
 430
 431   $ldlib = $crtlstr ? "$lib $crtlstr" : $lib;
 432   warn "Result:\n\tEXTRALIBS: $lib\n\tLDLOADLIBS: $ldlib\n" if $verbose;
 433   wantarray ? ($lib, '', $ldlib, '') : $lib;
 434 }
 435
 436 1;
 437
 438 __END__
 439
 440 =head1 NAME
 441
 442 ExtUtils::Liblist - determine libraries to use and how to use them
 443
 444 =head1 SYNOPSIS
 445
 446 C<require ExtUtils::Liblist;>
 447
 448 C<ExtUtils::Liblist::ext($self, $potential_libs, $verbose);>
 449
 450 =head1 DESCRIPTION
 451
 452 This utility takes a list of libraries in the form C<-llib1 -llib2
 453 -llib3> and prints out lines suitable for inclusion in an extension
 454 Makefile.  Extra library paths may be included with the form
 455 C<-L/another/path> this will affect the searches for all subsequent
 456 libraries.
 457
 458 It returns an array of four scalar values: EXTRALIBS, BSLOADLIBS,
 459 LDLOADLIBS, and LD_RUN_PATH.  Some of these don't mean anything
 460 on VMS and Win32.  See the details about those platform specifics
 461 below.
 462
 463 Dependent libraries can be linked in one of three ways:
 464
 465 =over 2
 466
 467 =item * For static extensions
 468
 469 by the ld command when the perl binary is linked with the extension
 470 library. See EXTRALIBS below.
 471
 472 =item * For dynamic extensions
 473
 474 by the ld command when the shared object is built/linked. See
 475 LDLOADLIBS below.
 476
 477 =item * For dynamic extensions
 478
 479 by the DynaLoader when the shared object is loaded. See BSLOADLIBS
 480 below.
 481
 482 =back
 483
 484 =head2 EXTRALIBS
 485
 486 List of libraries that need to be linked with when linking a perl
 487 binary which includes this extension Only those libraries that
 488 actually exist are included.  These are written to a file and used
 489 when linking perl.
 490
 491 =head2 LDLOADLIBS and LD_RUN_PATH
 492
 493 List of those libraries which can or must be linked into the shared
 494 library when created using ld. These may be static or dynamic
 495 libraries.  LD_RUN_PATH is a colon separated list of the directories
 496 in LDLOADLIBS. It is passed as an environment variable to the process
 497 that links the shared library.
 498
 499 =head2 BSLOADLIBS
 500
 501 List of those libraries that are needed but can be linked in
 502 dynamically at run time on this platform.  SunOS/Solaris does not need
 503 this because ld records the information (from LDLOADLIBS) into the
 504 object file.  This list is used to create a .bs (bootstrap) file.
 505
 506 =head1 PORTABILITY
 507
 508 This module deals with a lot of system dependencies and has quite a
 509 few architecture specific B<if>s in the code.
 510
 511 =head2 VMS implementation
 512
 513 The version of ext() which is executed under VMS differs from the
 514 Unix-OS/2 version in several respects:
 515
 516 =over 2
 517
 518 =item *
 519
 520 Input library and path specifications are accepted with or without the
 521 C<-l> and C<-L> prefices used by Unix linkers.  If neither prefix is
 522 present, a token is considered a directory to search if it is in fact
 523 a directory, and a library to search for otherwise.  Authors who wish
 524 their extensions to be portable to Unix or OS/2 should use the Unix
 525 prefixes, since the Unix-OS/2 version of ext() requires them.
 526
 527 =item *
 528
 529 Wherever possible, shareable images are preferred to object libraries,
 530 and object libraries to plain object files.  In accordance with VMS
 531 naming conventions, ext() looks for files named I<lib>shr and I<lib>rtl;
 532 it also looks for I<lib>lib and libI<lib> to accomodate Unix conventions
 533 used in some ported software.
 534
 535 =item *
 536
 537 For each library that is found, an appropriate directive for a linker options
 538 file is generated.  The return values are space-separated strings of
 539 these directives, rather than elements used on the linker command line.
 540
 541 =item *
 542
 543 LDLOADLIBS contains both the libraries found based on C<$potential_libs> and
 544 the CRTLs, if any, specified in Config.pm.  EXTRALIBS contains just those
 545 libraries found based on C<$potential_libs>.  BSLOADLIBS and LD_RUN_PATH
 546 are always empty.
 547
 548 =back
 549
 550 In addition, an attempt is made to recognize several common Unix library
 551 names, and filter them out or convert them to their VMS equivalents, as
 552 appropriate.
 553
 554 In general, the VMS version of ext() should properly handle input from
 555 extensions originally designed for a Unix or VMS environment.  If you
 556 encounter problems, or discover cases where the search could be improved,
 557 please let us know.
 558
 559 =head2 Win32 implementation
 560
 561 The version of ext() which is executed under Win32 differs from the
 562 Unix-OS/2 version in several respects:
 563
 564 =over 2
 565
 566 =item *
 567
 568 Input library and path specifications are accepted with or without the
 569 C<-l> and C<-L> prefices used by Unix linkers.  C<-lfoo> specifies the
 570 library C<libfoo.lib> (unless C<foo> already starts with C<lib>), and
 571 C<-Ls:ome\dir> specifies a directory to look for the libraries that follow.
 572 If neither prefix is present, a token is considered a directory to search
 573 if it is in fact a directory, and a library to search for otherwise.  The
 574 C<$Config{lib_ext}> suffix will be appended to any entries that are not
 575 directories and don't already have the suffix.  Authors who wish their
 576 extensions to be portable to Unix or OS/2 should use the Unix prefixes,
 577 since the Unix-OS/2 version of ext() requires them.
 578
 579 =item *
 580
 581 Entries cannot be plain object files, as many Win32 compilers will
 582 not handle object files in the place of libraries.
 583
 584 =item *
 585
 586 If C<$potential_libs> is empty, the return value will be empty.
 587 Otherwise, the libraries specified by C<$Config{libs}> (see Config.pm)
 588 will be appended to the list of C<$potential_libs>.  The libraries
 589 will be searched for in the directories specified in C<$potential_libs>
 590 as well as in C<$Config{libpth}>. For each library that is found,  a
 591 space-separated list of fully qualified library pathnames is generated.
 592 You may specify an entry that matches C</:nodefault/i> in
 593 C<$potential_libs> to disable the appending of default libraries
 594 found in C<$Config{libs}> (this should be only needed very rarely).
 595
 596 =item *
 597
 598 The libraries specified may be a mixture of static libraries and
 599 import libraries (to link with DLLs).  Since both kinds are used
 600 pretty transparently on the win32 platform, we do not attempt to
 601 distinguish between them.
 602
 603 =item *
 604
 605 LDLOADLIBS and EXTRALIBS are always identical under Win32, and BSLOADLIBS
 606 and LD_RUN_PATH are always empty (this may change in future).
 607
 608 =item *
 609
 610 You must make sure that any paths and path components are properly
 611 surrounded with double-quotes if they contain spaces. For example,
 612 C<$potential_libs> could be (literally):
 613
 614         "-Lc:\Program Files\vc\lib" msvcrt.lib "la test\foo bar.lib"
 615
 616 Note how the first and last entries are protected by quotes in order
 617 to protect the spaces.
 618
 619 =back
 620
 621
 622 =head1 SEE ALSO
 623
 624 L<ExtUtils::MakeMaker>
 625
 626 =cut
 627