lib/Exporter.pm

   1 package Exporter;
   2
   3 require 5.001;
   4
   5 $ExportLevel = 0;
   6 $Verbose ||= 0;
   7
   8 sub export_to_level {
   9   require Exporter::Heavy;
  10   goto &heavy_export_to_level;
  11 }
  12
  13 sub export {
  14   require Exporter::Heavy;
  15   goto &heavy_export;
  16 }
  17
  18 sub export_tags {
  19   require Exporter::Heavy;
  20   _push_tags((caller)[0], "EXPORT",    \@_);
  21 }
  22
  23 sub export_ok_tags {
  24   require Exporter::Heavy;
  25   _push_tags((caller)[0], "EXPORT_OK", \@_);
  26 }
  27
  28 sub import {
  29   my $pkg = shift;
  30   my $callpkg = caller($ExportLevel);
  31   *exports = *{"$pkg\::EXPORT"};
  32   # We *need* to treat @{"$pkg\::EXPORT_FAIL"} since Carp uses it :-(
  33   *fail = *{"$pkg\::EXPORT_FAIL"};
  34   return export $pkg, $callpkg, @_
  35     if $Verbose or $Debug or @fail > 1;
  36   my $args = @_ or @_ = @exports;
  37
  38   if ($args and not %exports) {
  39     foreach my $sym (@exports, @{"$pkg\::EXPORT_OK"}) {
  40       $sym =~ s/^&//;
  41       $exports{$sym} = 1;
  42     }
  43   }
  44   if ($Verbose or $Debug
  45       or grep {/\W/ or $args and not exists $exports{$_}
  46                or @fail and $_ eq $fail[0]
  47                or (@{"$pkg\::EXPORT_OK"}
  48                    and $_ eq ${"$pkg\::EXPORT_OK"}[0])} @_) {
  49     return export $pkg, $callpkg, ($args ? @_ : ());
  50   }
  51   #local $SIG{__WARN__} = sub {require Carp; goto &Carp::carp};
  52   local $SIG{__WARN__} =
  53         sub {require Carp; local $Carp::CarpLevel = 1; &Carp::carp};
  54   foreach $sym (@_) {
  55     # shortcut for the common case of no type character
  56     *{"$callpkg\::$sym"} = \&{"$pkg\::$sym"};
  57   }
  58 }
  59
  60 1;
  61
  62 # A simple self test harness. Change 'require Carp' to 'use Carp ()' for testing.
  63 # package main; eval(join('',<DATA>)) or die $@ unless caller;
  64 __END__
  65 package Test;
  66 $INC{'Exporter.pm'} = 1;
  67 @ISA = qw(Exporter);
  68 @EXPORT      = qw(A1 A2 A3 A4 A5);
  69 @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
  70 %EXPORT_TAGS = (T1=>[qw(A1 A2 B1 B2)], T2=>[qw(A1 A2 B3 B4)], T3=>[qw(X3)]);
  71 @EXPORT_FAIL = qw(B4);
  72 Exporter::export_ok_tags('T3', 'unknown_tag');
  73 sub export_fail {
  74     map { "Test::$_" } @_       # edit symbols just as an example
  75 }
  76
  77 package main;
  78 $Exporter::Verbose = 1;
  79 #import Test;
  80 #import Test qw(X3);            # export ok via export_ok_tags()
  81 #import Test qw(:T1 !A2 /5/ !/3/ B5);
  82 import Test qw(:T2 !B4);
  83 import Test qw(:T2);            # should fail
  84 1;
  85
  86 =head1 NAME
  87
  88 Exporter - Implements default import method for modules
  89
  90 =head1 SYNOPSIS
  91
  92 In module ModuleName.pm:
  93
  94   package ModuleName;
  95   require Exporter;
  96   @ISA = qw(Exporter);
  97
  98   @EXPORT = qw(...);            # symbols to export by default
  99   @EXPORT_OK = qw(...);         # symbols to export on request
 100   %EXPORT_TAGS = tag => [...];  # define names for sets of symbols
 101
 102 In other files which wish to use ModuleName:
 103
 104   use ModuleName;               # import default symbols into my package
 105
 106   use ModuleName qw(...);       # import listed symbols into my package
 107
 108   use ModuleName ();            # do not import any symbols
 109
 110 =head1 DESCRIPTION
 111
 112 The Exporter module implements a default C<import> method which
 113 many modules choose to inherit rather than implement their own.
 114
 115 Perl automatically calls the C<import> method when processing a
 116 C<use> statement for a module. Modules and C<use> are documented
 117 in L<perlfunc> and L<perlmod>. Understanding the concept of
 118 modules and how the C<use> statement operates is important to
 119 understanding the Exporter.
 120
 121 =head2 Selecting What To Export
 122
 123 Do B<not> export method names!
 124
 125 Do B<not> export anything else by default without a good reason!
 126
 127 Exports pollute the namespace of the module user.  If you must export
 128 try to use @EXPORT_OK in preference to @EXPORT and avoid short or
 129 common symbol names to reduce the risk of name clashes.
 130
 131 Generally anything not exported is still accessible from outside the
 132 module using the ModuleName::item_name (or $blessed_ref-E<gt>method)
 133 syntax.  By convention you can use a leading underscore on names to
 134 informally indicate that they are 'internal' and not for public use.
 135
 136 (It is actually possible to get private functions by saying:
 137
 138   my $subref = sub { ... };
 139   &$subref;
 140
 141 But there's no way to call that directly as a method, since a method
 142 must have a name in the symbol table.)
 143
 144 As a general rule, if the module is trying to be object oriented
 145 then export nothing. If it's just a collection of functions then
 146 @EXPORT_OK anything but use @EXPORT with caution.
 147
 148 Other module design guidelines can be found in L<perlmod>.
 149
 150 =head2 Specialised Import Lists
 151
 152 If the first entry in an import list begins with !, : or / then the
 153 list is treated as a series of specifications which either add to or
 154 delete from the list of names to import. They are processed left to
 155 right. Specifications are in the form:
 156
 157     [!]name         This name only
 158     [!]:DEFAULT     All names in @EXPORT
 159     [!]:tag         All names in $EXPORT_TAGS{tag} anonymous list
 160     [!]/pattern/    All names in @EXPORT and @EXPORT_OK which match
 161
 162 A leading ! indicates that matching names should be deleted from the
 163 list of names to import.  If the first specification is a deletion it
 164 is treated as though preceded by :DEFAULT. If you just want to import
 165 extra names in addition to the default set you will still need to
 166 include :DEFAULT explicitly.
 167
 168 e.g., Module.pm defines:
 169
 170     @EXPORT      = qw(A1 A2 A3 A4 A5);
 171     @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
 172     %EXPORT_TAGS = (T1 => [qw(A1 A2 B1 B2)], T2 => [qw(A1 A2 B3 B4)]);
 173
 174     Note that you cannot use tags in @EXPORT or @EXPORT_OK.
 175     Names in EXPORT_TAGS must also appear in @EXPORT or @EXPORT_OK.
 176
 177 An application using Module can say something like:
 178
 179     use Module qw(:DEFAULT :T2 !B3 A3);
 180
 181 Other examples include:
 182
 183     use Socket qw(!/^[AP]F_/ !SOMAXCONN !SOL_SOCKET);
 184     use POSIX  qw(:errno_h :termios_h !TCSADRAIN !/^EXIT/);
 185
 186 Remember that most patterns (using //) will need to be anchored
 187 with a leading ^, e.g., C</^EXIT/> rather than C</EXIT/>.
 188
 189 You can say C<BEGIN { $Exporter::Verbose=1 }> to see how the
 190 specifications are being processed and what is actually being imported
 191 into modules.
 192
 193 =head2 Exporting without using Export's import method
 194
 195 Exporter has a special method, 'export_to_level' which is used in situations
 196 where you can't directly call Export's import method. The export_to_level
 197 method looks like:
 198
 199 MyPackage->export_to_level($where_to_export, $package, @what_to_export);
 200
 201 where $where_to_export is an integer telling how far up the calling stack
 202 to export your symbols, and @what_to_export is an array telling what
 203 symbols *to* export (usually this is @_).  The $package argument is
 204 currently unused.
 205
 206 For example, suppose that you have a module, A, which already has an
 207 import function:
 208
 209 package A;
 210
 211 @ISA = qw(Exporter);
 212 @EXPORT_OK = qw ($b);
 213
 214 sub import
 215 {
 216     $A::b = 1;     # not a very useful import method
 217 }
 218
 219 and you want to Export symbol $A::b back to the module that called
 220 package A. Since Exporter relies on the import method to work, via
 221 inheritance, as it stands Exporter::import() will never get called.
 222 Instead, say the following:
 223
 224 package A;
 225 @ISA = qw(Exporter);
 226 @EXPORT_OK = qw ($b);
 227
 228 sub import
 229 {
 230     $A::b = 1;
 231     A->export_to_level(1, @_);
 232 }
 233
 234 This will export the symbols one level 'above' the current package - ie: to
 235 the program or module that used package A.
 236
 237 Note: Be careful not to modify '@_' at all before you call export_to_level
 238 - or people using your package will get very unexplained results!
 239
 240
 241 =head2 Module Version Checking
 242
 243 The Exporter module will convert an attempt to import a number from a
 244 module into a call to $module_name-E<gt>require_version($value). This can
 245 be used to validate that the version of the module being used is
 246 greater than or equal to the required version.
 247
 248 The Exporter module supplies a default require_version method which
 249 checks the value of $VERSION in the exporting module.
 250
 251 Since the default require_version method treats the $VERSION number as
 252 a simple numeric value it will regard version 1.10 as lower than
 253 1.9. For this reason it is strongly recommended that you use numbers
 254 with at least two decimal places, e.g., 1.09.
 255
 256 =head2 Managing Unknown Symbols
 257
 258 In some situations you may want to prevent certain symbols from being
 259 exported. Typically this applies to extensions which have functions
 260 or constants that may not exist on some systems.
 261
 262 The names of any symbols that cannot be exported should be listed
 263 in the C<@EXPORT_FAIL> array.
 264
 265 If a module attempts to import any of these symbols the Exporter
 266 will give the module an opportunity to handle the situation before
 267 generating an error. The Exporter will call an export_fail method
 268 with a list of the failed symbols:
 269
 270   @failed_symbols = $module_name->export_fail(@failed_symbols);
 271
 272 If the export_fail method returns an empty list then no error is
 273 recorded and all the requested symbols are exported. If the returned
 274 list is not empty then an error is generated for each symbol and the
 275 export fails. The Exporter provides a default export_fail method which
 276 simply returns the list unchanged.
 277
 278 Uses for the export_fail method include giving better error messages
 279 for some symbols and performing lazy architectural checks (put more
 280 symbols into @EXPORT_FAIL by default and then take them out if someone
 281 actually tries to use them and an expensive check shows that they are
 282 usable on that platform).
 283
 284 =head2 Tag Handling Utility Functions
 285
 286 Since the symbols listed within %EXPORT_TAGS must also appear in either
 287 @EXPORT or @EXPORT_OK, two utility functions are provided which allow
 288 you to easily add tagged sets of symbols to @EXPORT or @EXPORT_OK:
 289
 290   %EXPORT_TAGS = (foo => [qw(aa bb cc)], bar => [qw(aa cc dd)]);
 291
 292   Exporter::export_tags('foo');     # add aa, bb and cc to @EXPORT
 293   Exporter::export_ok_tags('bar');  # add aa, cc and dd to @EXPORT_OK
 294
 295 Any names which are not tags are added to @EXPORT or @EXPORT_OK
 296 unchanged but will trigger a warning (with C<-w>) to avoid misspelt tags
 297 names being silently added to @EXPORT or @EXPORT_OK. Future versions
 298 may make this a fatal error.
 299
 300 =cut