lib/Exporter.pm

   1 package Exporter;
   2
   3 require 5.006;
   4
   5 use strict;
   6 no strict 'refs';
   7
   8 our $Debug = 0;
   9 our $ExportLevel = 0;
  10 our $Verbose ||= 0;
  11 our $VERSION = '5.565';
  12 $Carp::Internal{Exporter} = 1;
  13
  14 sub export_to_level {
  15   require Exporter::Heavy;
  16   goto &Exporter::Heavy::heavy_export_to_level;
  17 }
  18
  19 sub export {
  20   require Exporter::Heavy;
  21   goto &Exporter::Heavy::heavy_export;
  22 }
  23
  24 sub export_tags {
  25   require Exporter::Heavy;
  26   Exporter::Heavy::_push_tags((caller)[0], "EXPORT",    \@_);
  27 }
  28
  29 sub export_ok_tags {
  30   require Exporter::Heavy;
  31   Exporter::Heavy::_push_tags((caller)[0], "EXPORT_OK", \@_);
  32 }
  33
  34 sub import {
  35   my $pkg = shift;
  36   my $callpkg = caller($ExportLevel);
  37
  38   # We *need* to treat @{"$pkg\::EXPORT_FAIL"} since Carp uses it :-(
  39   my($exports, $export_cache, $fail)
  40     = (\@{"$pkg\::EXPORT"}, \%{"$pkg\::EXPORT"}, \@{"$pkg\::EXPORT_FAIL"});
  41   return export $pkg, $callpkg, @_
  42     if $Verbose or $Debug or @$fail > 1;
  43   my $args = @_ or @_ = @$exports;
  44
  45   local $_;
  46   if ($args and not %$export_cache) {
  47     s/^&//, $export_cache->{$_} = 1
  48       foreach (@$exports, @{"$pkg\::EXPORT_OK"});
  49   }
  50   my $heavy = $Verbose || $Debug;
  51   unless ($heavy) {
  52     # Try very hard not to use {} and hence have to  enter scope on the foreach
  53     # We bomb out of the loop with last as soon as heavy is set.
  54     ($heavy = (/\W/ or $args and not exists $export_cache->{$_}
  55               or @$fail and $_ eq $fail->[0]
  56               or (@{"$pkg\::EXPORT_OK"} and $_ eq ${"$pkg\::EXPORT_OK"}[0])))
  57     and last
  58       foreach (@_);
  59   }
  60   return export $pkg, $callpkg, ($args ? @_ : ()) if $heavy;
  61   local $SIG{__WARN__} =
  62         sub {require Carp; &Carp::carp};
  63   # shortcut for the common case of no type character
  64   *{"$callpkg\::$_"} = \&{"$pkg\::$_"} foreach @_;
  65 }
  66
  67
  68 # Default methods
  69
  70 sub export_fail {
  71     my $self = shift;
  72     @_;
  73 }
  74
  75
  76 sub require_version {
  77     require Exporter::Heavy;
  78     goto &Exporter::Heavy::require_version;
  79 }
  80
  81
  82 1;
  83 __END__
  84
  85 =head1 NAME
  86
  87 Exporter - Implements default import method for modules
  88
  89 =head1 SYNOPSIS
  90
  91 In module ModuleName.pm:
  92
  93   package ModuleName;
  94   require Exporter;
  95   @ISA = qw(Exporter);
  96
  97   @EXPORT = qw(...);            # symbols to export by default
  98   @EXPORT_OK = qw(...);         # symbols to export on request
  99   %EXPORT_TAGS = tag => [...];  # define names for sets of symbols
 100
 101 In other files which wish to use ModuleName:
 102
 103   use ModuleName;               # import default symbols into my package
 104
 105   use ModuleName qw(...);       # import listed symbols into my package
 106
 107   use ModuleName ();            # do not import any symbols
 108
 109 =head1 DESCRIPTION
 110
 111 The Exporter module implements a default C<import> method which
 112 many modules choose to inherit rather than implement their own.
 113
 114 Perl automatically calls the C<import> method when processing a
 115 C<use> statement for a module. Modules and C<use> are documented
 116 in L<perlfunc> and L<perlmod>. Understanding the concept of
 117 modules and how the C<use> statement operates is important to
 118 understanding the Exporter.
 119
 120 =head2 How to Export
 121
 122 The arrays C<@EXPORT> and C<@EXPORT_OK> in a module hold lists of
 123 symbols that are going to be exported into the users name space by
 124 default, or which they can request to be exported, respectively.  The
 125 symbols can represent functions, scalars, arrays, hashes, or typeglobs.
 126 The symbols must be given by full name with the exception that the
 127 ampersand in front of a function is optional, e.g.
 128
 129     @EXPORT    = qw(afunc $scalar @array);   # afunc is a function
 130     @EXPORT_OK = qw(&bfunc %hash *typeglob); # explicit prefix on &bfunc
 131
 132 =head2 Selecting What To Export
 133
 134 Do B<not> export method names!
 135
 136 Do B<not> export anything else by default without a good reason!
 137
 138 Exports pollute the namespace of the module user.  If you must export
 139 try to use @EXPORT_OK in preference to @EXPORT and avoid short or
 140 common symbol names to reduce the risk of name clashes.
 141
 142 Generally anything not exported is still accessible from outside the
 143 module using the ModuleName::item_name (or $blessed_ref-E<gt>method)
 144 syntax.  By convention you can use a leading underscore on names to
 145 informally indicate that they are 'internal' and not for public use.
 146
 147 (It is actually possible to get private functions by saying:
 148
 149   my $subref = sub { ... };
 150   $subref->(@args);            # Call it as a function
 151   $obj->$subref(@args);        # Use it as a method
 152
 153 However if you use them for methods it is up to you to figure out
 154 how to make inheritance work.)
 155
 156 As a general rule, if the module is trying to be object oriented
 157 then export nothing. If it's just a collection of functions then
 158 @EXPORT_OK anything but use @EXPORT with caution.
 159
 160 Other module design guidelines can be found in L<perlmod>.
 161
 162 =head2 Specialised Import Lists
 163
 164 If the first entry in an import list begins with !, : or / then the
 165 list is treated as a series of specifications which either add to or
 166 delete from the list of names to import. They are processed left to
 167 right. Specifications are in the form:
 168
 169     [!]name         This name only
 170     [!]:DEFAULT     All names in @EXPORT
 171     [!]:tag         All names in $EXPORT_TAGS{tag} anonymous list
 172     [!]/pattern/    All names in @EXPORT and @EXPORT_OK which match
 173
 174 A leading ! indicates that matching names should be deleted from the
 175 list of names to import.  If the first specification is a deletion it
 176 is treated as though preceded by :DEFAULT. If you just want to import
 177 extra names in addition to the default set you will still need to
 178 include :DEFAULT explicitly.
 179
 180 e.g., Module.pm defines:
 181
 182     @EXPORT      = qw(A1 A2 A3 A4 A5);
 183     @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
 184     %EXPORT_TAGS = (T1 => [qw(A1 A2 B1 B2)], T2 => [qw(A1 A2 B3 B4)]);
 185
 186     Note that you cannot use tags in @EXPORT or @EXPORT_OK.
 187     Names in EXPORT_TAGS must also appear in @EXPORT or @EXPORT_OK.
 188
 189 An application using Module can say something like:
 190
 191     use Module qw(:DEFAULT :T2 !B3 A3);
 192
 193 Other examples include:
 194
 195     use Socket qw(!/^[AP]F_/ !SOMAXCONN !SOL_SOCKET);
 196     use POSIX  qw(:errno_h :termios_h !TCSADRAIN !/^EXIT/);
 197
 198 Remember that most patterns (using //) will need to be anchored
 199 with a leading ^, e.g., C</^EXIT/> rather than C</EXIT/>.
 200
 201 You can say C<BEGIN { $Exporter::Verbose=1 }> to see how the
 202 specifications are being processed and what is actually being imported
 203 into modules.
 204
 205 =head2 Exporting without using Export's import method
 206
 207 Exporter has a special method, 'export_to_level' which is used in situations
 208 where you can't directly call Export's import method. The export_to_level
 209 method looks like:
 210
 211 MyPackage->export_to_level($where_to_export, $package, @what_to_export);
 212
 213 where $where_to_export is an integer telling how far up the calling stack
 214 to export your symbols, and @what_to_export is an array telling what
 215 symbols *to* export (usually this is @_).  The $package argument is
 216 currently unused.
 217
 218 For example, suppose that you have a module, A, which already has an
 219 import function:
 220
 221 package A;
 222
 223 @ISA = qw(Exporter);
 224 @EXPORT_OK = qw ($b);
 225
 226 sub import
 227 {
 228     $A::b = 1;     # not a very useful import method
 229 }
 230
 231 and you want to Export symbol $A::b back to the module that called
 232 package A. Since Exporter relies on the import method to work, via
 233 inheritance, as it stands Exporter::import() will never get called.
 234 Instead, say the following:
 235
 236 package A;
 237 @ISA = qw(Exporter);
 238 @EXPORT_OK = qw ($b);
 239
 240 sub import
 241 {
 242     $A::b = 1;
 243     A->export_to_level(1, @_);
 244 }
 245
 246 This will export the symbols one level 'above' the current package - ie: to
 247 the program or module that used package A.
 248
 249 Note: Be careful not to modify '@_' at all before you call export_to_level
 250 - or people using your package will get very unexplained results!
 251
 252
 253 =head2 Module Version Checking
 254
 255 The Exporter module will convert an attempt to import a number from a
 256 module into a call to $module_name-E<gt>require_version($value). This can
 257 be used to validate that the version of the module being used is
 258 greater than or equal to the required version.
 259
 260 The Exporter module supplies a default require_version method which
 261 checks the value of $VERSION in the exporting module.
 262
 263 Since the default require_version method treats the $VERSION number as
 264 a simple numeric value it will regard version 1.10 as lower than
 265 1.9. For this reason it is strongly recommended that you use numbers
 266 with at least two decimal places, e.g., 1.09.
 267
 268 =head2 Managing Unknown Symbols
 269
 270 In some situations you may want to prevent certain symbols from being
 271 exported. Typically this applies to extensions which have functions
 272 or constants that may not exist on some systems.
 273
 274 The names of any symbols that cannot be exported should be listed
 275 in the C<@EXPORT_FAIL> array.
 276
 277 If a module attempts to import any of these symbols the Exporter
 278 will give the module an opportunity to handle the situation before
 279 generating an error. The Exporter will call an export_fail method
 280 with a list of the failed symbols:
 281
 282   @failed_symbols = $module_name->export_fail(@failed_symbols);
 283
 284 If the export_fail method returns an empty list then no error is
 285 recorded and all the requested symbols are exported. If the returned
 286 list is not empty then an error is generated for each symbol and the
 287 export fails. The Exporter provides a default export_fail method which
 288 simply returns the list unchanged.
 289
 290 Uses for the export_fail method include giving better error messages
 291 for some symbols and performing lazy architectural checks (put more
 292 symbols into @EXPORT_FAIL by default and then take them out if someone
 293 actually tries to use them and an expensive check shows that they are
 294 usable on that platform).
 295
 296 =head2 Tag Handling Utility Functions
 297
 298 Since the symbols listed within %EXPORT_TAGS must also appear in either
 299 @EXPORT or @EXPORT_OK, two utility functions are provided which allow
 300 you to easily add tagged sets of symbols to @EXPORT or @EXPORT_OK:
 301
 302   %EXPORT_TAGS = (foo => [qw(aa bb cc)], bar => [qw(aa cc dd)]);
 303
 304   Exporter::export_tags('foo');     # add aa, bb and cc to @EXPORT
 305   Exporter::export_ok_tags('bar');  # add aa, cc and dd to @EXPORT_OK
 306
 307 Any names which are not tags are added to @EXPORT or @EXPORT_OK
 308 unchanged but will trigger a warning (with C<-w>) to avoid misspelt tags
 309 names being silently added to @EXPORT or @EXPORT_OK. Future versions
 310 may make this a fatal error.
 311
 312 =head2 C<AUTOLOAD>ed Constants
 313
 314 Many modules make use of C<AUTOLOAD>ing for constant subroutines to
 315 avoid having to compile and waste memory on rarely used values (see
 316 L<perlsub> for details on constant subroutines).  Calls to such
 317 constant subroutines are not optimized away at compile time because
 318 they can't be checked at compile time for constancy.
 319
 320 Even if a prototype is available at compile time, the body of the
 321 subroutine is not (it hasn't been C<AUTOLOAD>ed yet). perl needs to
 322 examine both the C<()> prototype and the body of a subroutine at
 323 compile time to detect that it can safely replace calls to that
 324 subroutine with the constant value.
 325
 326 A workaround for this is to call the constants once in a C<BEGIN> block:
 327
 328    package My ;
 329
 330    use Socket ;
 331
 332    foo( SO_LINGER );     ## SO_LINGER NOT optimized away; called at runtime
 333    BEGIN { SO_LINGER }
 334    foo( SO_LINGER );     ## SO_LINGER optimized away at compile time.
 335
 336 This forces the C<AUTOLOAD> for C<SO_LINGER> to take place before
 337 SO_LINGER is encountered later in C<My> package.
 338
 339 If you are writing a package that C<AUTOLOAD>s, consider forcing
 340 an C<AUTOLOAD> for any constants explicitly imported by other packages
 341 or which are usually used when your package is C<use>d.
 342
 343 =cut