lib/Exporter.pm

   1 package Exporter;
   2
   3 require 5.001;
   4
   5 $ExportLevel = 0;
   6 $Verbose ||= 0;
   7 $VERSION = '5.562';
   8
   9 sub export_to_level {
  10   require Exporter::Heavy;
  11   goto &heavy_export_to_level;
  12 }
  13
  14 sub export {
  15   require Exporter::Heavy;
  16   goto &heavy_export;
  17 }
  18
  19 sub export_tags {
  20   require Exporter::Heavy;
  21   _push_tags((caller)[0], "EXPORT",    \@_);
  22 }
  23
  24 sub export_ok_tags {
  25   require Exporter::Heavy;
  26   _push_tags((caller)[0], "EXPORT_OK", \@_);
  27 }
  28
  29 sub import {
  30   my $pkg = shift;
  31   my $callpkg = caller($ExportLevel);
  32   *exports = *{"$pkg\::EXPORT"};
  33   # We *need* to treat @{"$pkg\::EXPORT_FAIL"} since Carp uses it :-(
  34   *fail = *{"$pkg\::EXPORT_FAIL"};
  35   return export $pkg, $callpkg, @_
  36     if $Verbose or $Debug or @fail > 1;
  37   my $args = @_ or @_ = @exports;
  38
  39   if ($args and not %exports) {
  40     foreach my $sym (@exports, @{"$pkg\::EXPORT_OK"}) {
  41       $sym =~ s/^&//;
  42       $exports{$sym} = 1;
  43     }
  44   }
  45   for (@_) {
  46       #need to match first to avoid "Modification of a read-only value attempted"
  47       if (/^\+/ and s/^\+//) {
  48           (\&{"$pkg\::$_"})->(); #try AUTOLOAD now so calls are inlined
  49       }
  50   }
  51   if ($Verbose or $Debug
  52       or grep {/\W/ or $args and not exists $exports{$_}
  53                or @fail and $_ eq $fail[0]
  54                or (@{"$pkg\::EXPORT_OK"}
  55                    and $_ eq ${"$pkg\::EXPORT_OK"}[0])} @_) {
  56     return export $pkg, $callpkg, ($args ? @_ : ());
  57   }
  58   #local $SIG{__WARN__} = sub {require Carp; goto &Carp::carp};
  59   local $SIG{__WARN__} =
  60         sub {require Carp; local $Carp::CarpLevel = 1; &Carp::carp};
  61   foreach $sym (@_) {
  62     # shortcut for the common case of no type character
  63     *{"$callpkg\::$sym"} = \&{"$pkg\::$sym"};
  64   }
  65 }
  66
  67 1;
  68
  69 # A simple self test harness. Change 'require Carp' to 'use Carp ()' for testing.
  70 # package main; eval(join('',<DATA>)) or die $@ unless caller;
  71 __END__
  72 package Test;
  73 $INC{'Exporter.pm'} = 1;
  74 @ISA = qw(Exporter);
  75 @EXPORT      = qw(A1 A2 A3 A4 A5);
  76 @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
  77 %EXPORT_TAGS = (T1=>[qw(A1 A2 B1 B2)], T2=>[qw(A1 A2 B3 B4)], T3=>[qw(X3)]);
  78 @EXPORT_FAIL = qw(B4);
  79 Exporter::export_ok_tags('T3', 'unknown_tag');
  80 sub export_fail {
  81     map { "Test::$_" } @_       # edit symbols just as an example
  82 }
  83
  84 package main;
  85 $Exporter::Verbose = 1;
  86 #import Test;
  87 #import Test qw(X3);            # export ok via export_ok_tags()
  88 #import Test qw(:T1 !A2 /5/ !/3/ B5);
  89 import Test qw(:T2 !B4);
  90 import Test qw(:T2);            # should fail
  91 1;
  92
  93 =head1 NAME
  94
  95 Exporter - Implements default import method for modules
  96
  97 =head1 SYNOPSIS
  98
  99 In module ModuleName.pm:
 100
 101   package ModuleName;
 102   require Exporter;
 103   @ISA = qw(Exporter);
 104
 105   @EXPORT = qw(...);            # symbols to export by default
 106   @EXPORT_OK = qw(...);         # symbols to export on request
 107   %EXPORT_TAGS = tag => [...];  # define names for sets of symbols
 108
 109 In other files which wish to use ModuleName:
 110
 111   use ModuleName;               # import default symbols into my package
 112
 113   use ModuleName qw(...);       # import listed symbols into my package
 114
 115   use ModuleName ();            # do not import any symbols
 116
 117 =head1 DESCRIPTION
 118
 119 The Exporter module implements a default C<import> method which
 120 many modules choose to inherit rather than implement their own.
 121
 122 Perl automatically calls the C<import> method when processing a
 123 C<use> statement for a module. Modules and C<use> are documented
 124 in L<perlfunc> and L<perlmod>. Understanding the concept of
 125 modules and how the C<use> statement operates is important to
 126 understanding the Exporter.
 127
 128 =head2 How to Export
 129
 130 The arrays C<@EXPORT> and C<@EXPORT_OK> in a module hold lists of
 131 symbols that are going to be exported into the users name space by
 132 default, or which they can request to be exported, respectively.  The
 133 symbols can represent functions, scalars, arrays, hashes, or typeglobs.
 134 The symbols must be given by full name with the exception that the
 135 ampersand in front of a function is optional, e.g.
 136
 137     @EXPORT    = qw(afunc $scalar @array);   # afunc is a function
 138     @EXPORT_OK = qw(&bfunc %hash *typeglob); # explicit prefix on &bfunc
 139
 140 =head2 Selecting What To Export
 141
 142 Do B<not> export method names!
 143
 144 Do B<not> export anything else by default without a good reason!
 145
 146 Exports pollute the namespace of the module user.  If you must export
 147 try to use @EXPORT_OK in preference to @EXPORT and avoid short or
 148 common symbol names to reduce the risk of name clashes.
 149
 150 Generally anything not exported is still accessible from outside the
 151 module using the ModuleName::item_name (or $blessed_ref-E<gt>method)
 152 syntax.  By convention you can use a leading underscore on names to
 153 informally indicate that they are 'internal' and not for public use.
 154
 155 (It is actually possible to get private functions by saying:
 156
 157   my $subref = sub { ... };
 158   &$subref;
 159
 160 But there's no way to call that directly as a method, since a method
 161 must have a name in the symbol table.)
 162
 163 As a general rule, if the module is trying to be object oriented
 164 then export nothing. If it's just a collection of functions then
 165 @EXPORT_OK anything but use @EXPORT with caution.
 166
 167 Other module design guidelines can be found in L<perlmod>.
 168
 169 =head2 Specialised Import Lists
 170
 171 If the first entry in an import list begins with !, : or / then the
 172 list is treated as a series of specifications which either add to or
 173 delete from the list of names to import. They are processed left to
 174 right. Specifications are in the form:
 175
 176     [!]name         This name only
 177     [!]:DEFAULT     All names in @EXPORT
 178     [!]:tag         All names in $EXPORT_TAGS{tag} anonymous list
 179     [!]/pattern/    All names in @EXPORT and @EXPORT_OK which match
 180
 181 A leading ! indicates that matching names should be deleted from the
 182 list of names to import.  If the first specification is a deletion it
 183 is treated as though preceded by :DEFAULT. If you just want to import
 184 extra names in addition to the default set you will still need to
 185 include :DEFAULT explicitly.
 186
 187 e.g., Module.pm defines:
 188
 189     @EXPORT      = qw(A1 A2 A3 A4 A5);
 190     @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
 191     %EXPORT_TAGS = (T1 => [qw(A1 A2 B1 B2)], T2 => [qw(A1 A2 B3 B4)]);
 192
 193     Note that you cannot use tags in @EXPORT or @EXPORT_OK.
 194     Names in EXPORT_TAGS must also appear in @EXPORT or @EXPORT_OK.
 195
 196 An application using Module can say something like:
 197
 198     use Module qw(:DEFAULT :T2 !B3 A3);
 199
 200 Other examples include:
 201
 202     use Socket qw(!/^[AP]F_/ !SOMAXCONN !SOL_SOCKET);
 203     use POSIX  qw(:errno_h :termios_h !TCSADRAIN !/^EXIT/);
 204
 205 Remember that most patterns (using //) will need to be anchored
 206 with a leading ^, e.g., C</^EXIT/> rather than C</EXIT/>.
 207
 208 You can say C<BEGIN { $Exporter::Verbose=1 }> to see how the
 209 specifications are being processed and what is actually being imported
 210 into modules.
 211
 212 =head2 Exporting without using Export's import method
 213
 214 Exporter has a special method, 'export_to_level' which is used in situations
 215 where you can't directly call Export's import method. The export_to_level
 216 method looks like:
 217
 218 MyPackage->export_to_level($where_to_export, $package, @what_to_export);
 219
 220 where $where_to_export is an integer telling how far up the calling stack
 221 to export your symbols, and @what_to_export is an array telling what
 222 symbols *to* export (usually this is @_).  The $package argument is
 223 currently unused.
 224
 225 For example, suppose that you have a module, A, which already has an
 226 import function:
 227
 228 package A;
 229
 230 @ISA = qw(Exporter);
 231 @EXPORT_OK = qw ($b);
 232
 233 sub import
 234 {
 235     $A::b = 1;     # not a very useful import method
 236 }
 237
 238 and you want to Export symbol $A::b back to the module that called
 239 package A. Since Exporter relies on the import method to work, via
 240 inheritance, as it stands Exporter::import() will never get called.
 241 Instead, say the following:
 242
 243 package A;
 244 @ISA = qw(Exporter);
 245 @EXPORT_OK = qw ($b);
 246
 247 sub import
 248 {
 249     $A::b = 1;
 250     A->export_to_level(1, @_);
 251 }
 252
 253 This will export the symbols one level 'above' the current package - ie: to
 254 the program or module that used package A.
 255
 256 Note: Be careful not to modify '@_' at all before you call export_to_level
 257 - or people using your package will get very unexplained results!
 258
 259
 260 =head2 Module Version Checking
 261
 262 The Exporter module will convert an attempt to import a number from a
 263 module into a call to $module_name-E<gt>require_version($value). This can
 264 be used to validate that the version of the module being used is
 265 greater than or equal to the required version.
 266
 267 The Exporter module supplies a default require_version method which
 268 checks the value of $VERSION in the exporting module.
 269
 270 Since the default require_version method treats the $VERSION number as
 271 a simple numeric value it will regard version 1.10 as lower than
 272 1.9. For this reason it is strongly recommended that you use numbers
 273 with at least two decimal places, e.g., 1.09.
 274
 275 =head2 Managing Unknown Symbols
 276
 277 In some situations you may want to prevent certain symbols from being
 278 exported. Typically this applies to extensions which have functions
 279 or constants that may not exist on some systems.
 280
 281 The names of any symbols that cannot be exported should be listed
 282 in the C<@EXPORT_FAIL> array.
 283
 284 If a module attempts to import any of these symbols the Exporter
 285 will give the module an opportunity to handle the situation before
 286 generating an error. The Exporter will call an export_fail method
 287 with a list of the failed symbols:
 288
 289   @failed_symbols = $module_name->export_fail(@failed_symbols);
 290
 291 If the export_fail method returns an empty list then no error is
 292 recorded and all the requested symbols are exported. If the returned
 293 list is not empty then an error is generated for each symbol and the
 294 export fails. The Exporter provides a default export_fail method which
 295 simply returns the list unchanged.
 296
 297 Uses for the export_fail method include giving better error messages
 298 for some symbols and performing lazy architectural checks (put more
 299 symbols into @EXPORT_FAIL by default and then take them out if someone
 300 actually tries to use them and an expensive check shows that they are
 301 usable on that platform).
 302
 303 =head2 Tag Handling Utility Functions
 304
 305 Since the symbols listed within %EXPORT_TAGS must also appear in either
 306 @EXPORT or @EXPORT_OK, two utility functions are provided which allow
 307 you to easily add tagged sets of symbols to @EXPORT or @EXPORT_OK:
 308
 309   %EXPORT_TAGS = (foo => [qw(aa bb cc)], bar => [qw(aa cc dd)]);
 310
 311   Exporter::export_tags('foo');     # add aa, bb and cc to @EXPORT
 312   Exporter::export_ok_tags('bar');  # add aa, cc and dd to @EXPORT_OK
 313
 314 Any names which are not tags are added to @EXPORT or @EXPORT_OK
 315 unchanged but will trigger a warning (with C<-w>) to avoid misspelt tags
 316 names being silently added to @EXPORT or @EXPORT_OK. Future versions
 317 may make this a fatal error.
 318
 319 =cut