lib/Exporter.pm

   1 package Exporter;
   2
   3 require 5.001;
   4
   5 use strict;
   6 no strict 'refs';
   7
   8 our $Debug = 0;
   9 our $ExportLevel = 0;
  10 our $Verbose ||= 0;
  11 our $VERSION = '5.564';
  12 $Carp::Internal{Exporter} = 1;
  13
  14 sub export_to_level {
  15   require Exporter::Heavy;
  16   goto &Exporter::Heavy::heavy_export_to_level;
  17 }
  18
  19 sub export {
  20   require Exporter::Heavy;
  21   goto &Exporter::Heavy::heavy_export;
  22 }
  23
  24 sub export_tags {
  25   require Exporter::Heavy;
  26   Exporter::Heavy::_push_tags((caller)[0], "EXPORT",    \@_);
  27 }
  28
  29 sub export_ok_tags {
  30   require Exporter::Heavy;
  31   Exporter::Heavy::_push_tags((caller)[0], "EXPORT_OK", \@_);
  32 }
  33
  34 sub import {
  35   my $pkg = shift;
  36   my $callpkg = caller($ExportLevel);
  37
  38   my($exports, $export_cache) = (\@{"$pkg\::EXPORT"},
  39                                  \%{"$pkg\::EXPORT"});
  40   # We *need* to treat @{"$pkg\::EXPORT_FAIL"} since Carp uses it :-(
  41   my($fail) = \@{"$pkg\::EXPORT_FAIL"};
  42   return export $pkg, $callpkg, @_
  43     if $Verbose or $Debug or @$fail > 1;
  44   my $args = @_ or @_ = @$exports;
  45
  46   if ($args and not %$export_cache) {
  47     foreach my $sym (@$exports, @{"$pkg\::EXPORT_OK"}) {
  48       $sym =~ s/^&//;
  49       $export_cache->{$sym} = 1;
  50     }
  51   }
  52   if ($Verbose or $Debug
  53       or grep {/\W/ or $args and not exists $export_cache->{$_}
  54                or @$fail and $_ eq $fail->[0]
  55                or (@{"$pkg\::EXPORT_OK"}
  56                    and $_ eq ${"$pkg\::EXPORT_OK"}[0])} @_) {
  57     return export $pkg, $callpkg, ($args ? @_ : ());
  58   }
  59   local $SIG{__WARN__} =
  60         sub {require Carp; &Carp::carp};
  61   foreach my $sym (@_) {
  62     # shortcut for the common case of no type character
  63     *{"$callpkg\::$sym"} = \&{"$pkg\::$sym"};
  64   }
  65 }
  66
  67
  68 # Default methods
  69
  70 sub export_fail {
  71     my $self = shift;
  72     @_;
  73 }
  74
  75
  76 sub require_version {
  77     require Exporter::Heavy;
  78     goto &Exporter::Heavy::require_version;
  79 }
  80
  81
  82 1;
  83
  84
  85 =head1 NAME
  86
  87 Exporter - Implements default import method for modules
  88
  89 =head1 SYNOPSIS
  90
  91 In module ModuleName.pm:
  92
  93   package ModuleName;
  94   require Exporter;
  95   @ISA = qw(Exporter);
  96
  97   @EXPORT = qw(...);            # symbols to export by default
  98   @EXPORT_OK = qw(...);         # symbols to export on request
  99   %EXPORT_TAGS = tag => [...];  # define names for sets of symbols
 100
 101 In other files which wish to use ModuleName:
 102
 103   use ModuleName;               # import default symbols into my package
 104
 105   use ModuleName qw(...);       # import listed symbols into my package
 106
 107   use ModuleName ();            # do not import any symbols
 108
 109 =head1 DESCRIPTION
 110
 111 The Exporter module implements a default C<import> method which
 112 many modules choose to inherit rather than implement their own.
 113
 114 Perl automatically calls the C<import> method when processing a
 115 C<use> statement for a module. Modules and C<use> are documented
 116 in L<perlfunc> and L<perlmod>. Understanding the concept of
 117 modules and how the C<use> statement operates is important to
 118 understanding the Exporter.
 119
 120 =head2 How to Export
 121
 122 The arrays C<@EXPORT> and C<@EXPORT_OK> in a module hold lists of
 123 symbols that are going to be exported into the users name space by
 124 default, or which they can request to be exported, respectively.  The
 125 symbols can represent functions, scalars, arrays, hashes, or typeglobs.
 126 The symbols must be given by full name with the exception that the
 127 ampersand in front of a function is optional, e.g.
 128
 129     @EXPORT    = qw(afunc $scalar @array);   # afunc is a function
 130     @EXPORT_OK = qw(&bfunc %hash *typeglob); # explicit prefix on &bfunc
 131
 132 =head2 Selecting What To Export
 133
 134 Do B<not> export method names!
 135
 136 Do B<not> export anything else by default without a good reason!
 137
 138 Exports pollute the namespace of the module user.  If you must export
 139 try to use @EXPORT_OK in preference to @EXPORT and avoid short or
 140 common symbol names to reduce the risk of name clashes.
 141
 142 Generally anything not exported is still accessible from outside the
 143 module using the ModuleName::item_name (or $blessed_ref-E<gt>method)
 144 syntax.  By convention you can use a leading underscore on names to
 145 informally indicate that they are 'internal' and not for public use.
 146
 147 (It is actually possible to get private functions by saying:
 148
 149   my $subref = sub { ... };
 150   &$subref;
 151
 152 But there's no way to call that directly as a method, since a method
 153 must have a name in the symbol table.)
 154
 155 As a general rule, if the module is trying to be object oriented
 156 then export nothing. If it's just a collection of functions then
 157 @EXPORT_OK anything but use @EXPORT with caution.
 158
 159 Other module design guidelines can be found in L<perlmod>.
 160
 161 =head2 Specialised Import Lists
 162
 163 If the first entry in an import list begins with !, : or / then the
 164 list is treated as a series of specifications which either add to or
 165 delete from the list of names to import. They are processed left to
 166 right. Specifications are in the form:
 167
 168     [!]name         This name only
 169     [!]:DEFAULT     All names in @EXPORT
 170     [!]:tag         All names in $EXPORT_TAGS{tag} anonymous list
 171     [!]/pattern/    All names in @EXPORT and @EXPORT_OK which match
 172
 173 A leading ! indicates that matching names should be deleted from the
 174 list of names to import.  If the first specification is a deletion it
 175 is treated as though preceded by :DEFAULT. If you just want to import
 176 extra names in addition to the default set you will still need to
 177 include :DEFAULT explicitly.
 178
 179 e.g., Module.pm defines:
 180
 181     @EXPORT      = qw(A1 A2 A3 A4 A5);
 182     @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
 183     %EXPORT_TAGS = (T1 => [qw(A1 A2 B1 B2)], T2 => [qw(A1 A2 B3 B4)]);
 184
 185     Note that you cannot use tags in @EXPORT or @EXPORT_OK.
 186     Names in EXPORT_TAGS must also appear in @EXPORT or @EXPORT_OK.
 187
 188 An application using Module can say something like:
 189
 190     use Module qw(:DEFAULT :T2 !B3 A3);
 191
 192 Other examples include:
 193
 194     use Socket qw(!/^[AP]F_/ !SOMAXCONN !SOL_SOCKET);
 195     use POSIX  qw(:errno_h :termios_h !TCSADRAIN !/^EXIT/);
 196
 197 Remember that most patterns (using //) will need to be anchored
 198 with a leading ^, e.g., C</^EXIT/> rather than C</EXIT/>.
 199
 200 You can say C<BEGIN { $Exporter::Verbose=1 }> to see how the
 201 specifications are being processed and what is actually being imported
 202 into modules.
 203
 204 =head2 Exporting without using Export's import method
 205
 206 Exporter has a special method, 'export_to_level' which is used in situations
 207 where you can't directly call Export's import method. The export_to_level
 208 method looks like:
 209
 210 MyPackage->export_to_level($where_to_export, $package, @what_to_export);
 211
 212 where $where_to_export is an integer telling how far up the calling stack
 213 to export your symbols, and @what_to_export is an array telling what
 214 symbols *to* export (usually this is @_).  The $package argument is
 215 currently unused.
 216
 217 For example, suppose that you have a module, A, which already has an
 218 import function:
 219
 220 package A;
 221
 222 @ISA = qw(Exporter);
 223 @EXPORT_OK = qw ($b);
 224
 225 sub import
 226 {
 227     $A::b = 1;     # not a very useful import method
 228 }
 229
 230 and you want to Export symbol $A::b back to the module that called
 231 package A. Since Exporter relies on the import method to work, via
 232 inheritance, as it stands Exporter::import() will never get called.
 233 Instead, say the following:
 234
 235 package A;
 236 @ISA = qw(Exporter);
 237 @EXPORT_OK = qw ($b);
 238
 239 sub import
 240 {
 241     $A::b = 1;
 242     A->export_to_level(1, @_);
 243 }
 244
 245 This will export the symbols one level 'above' the current package - ie: to
 246 the program or module that used package A.
 247
 248 Note: Be careful not to modify '@_' at all before you call export_to_level
 249 - or people using your package will get very unexplained results!
 250
 251
 252 =head2 Module Version Checking
 253
 254 The Exporter module will convert an attempt to import a number from a
 255 module into a call to $module_name-E<gt>require_version($value). This can
 256 be used to validate that the version of the module being used is
 257 greater than or equal to the required version.
 258
 259 The Exporter module supplies a default require_version method which
 260 checks the value of $VERSION in the exporting module.
 261
 262 Since the default require_version method treats the $VERSION number as
 263 a simple numeric value it will regard version 1.10 as lower than
 264 1.9. For this reason it is strongly recommended that you use numbers
 265 with at least two decimal places, e.g., 1.09.
 266
 267 =head2 Managing Unknown Symbols
 268
 269 In some situations you may want to prevent certain symbols from being
 270 exported. Typically this applies to extensions which have functions
 271 or constants that may not exist on some systems.
 272
 273 The names of any symbols that cannot be exported should be listed
 274 in the C<@EXPORT_FAIL> array.
 275
 276 If a module attempts to import any of these symbols the Exporter
 277 will give the module an opportunity to handle the situation before
 278 generating an error. The Exporter will call an export_fail method
 279 with a list of the failed symbols:
 280
 281   @failed_symbols = $module_name->export_fail(@failed_symbols);
 282
 283 If the export_fail method returns an empty list then no error is
 284 recorded and all the requested symbols are exported. If the returned
 285 list is not empty then an error is generated for each symbol and the
 286 export fails. The Exporter provides a default export_fail method which
 287 simply returns the list unchanged.
 288
 289 Uses for the export_fail method include giving better error messages
 290 for some symbols and performing lazy architectural checks (put more
 291 symbols into @EXPORT_FAIL by default and then take them out if someone
 292 actually tries to use them and an expensive check shows that they are
 293 usable on that platform).
 294
 295 =head2 Tag Handling Utility Functions
 296
 297 Since the symbols listed within %EXPORT_TAGS must also appear in either
 298 @EXPORT or @EXPORT_OK, two utility functions are provided which allow
 299 you to easily add tagged sets of symbols to @EXPORT or @EXPORT_OK:
 300
 301   %EXPORT_TAGS = (foo => [qw(aa bb cc)], bar => [qw(aa cc dd)]);
 302
 303   Exporter::export_tags('foo');     # add aa, bb and cc to @EXPORT
 304   Exporter::export_ok_tags('bar');  # add aa, cc and dd to @EXPORT_OK
 305
 306 Any names which are not tags are added to @EXPORT or @EXPORT_OK
 307 unchanged but will trigger a warning (with C<-w>) to avoid misspelt tags
 308 names being silently added to @EXPORT or @EXPORT_OK. Future versions
 309 may make this a fatal error.
 310
 311 =head2 C<AUTOLOAD>ed Constants
 312
 313 Many modules make use of C<AUTOLOAD>ing for constant subroutines to
 314 avoid having to compile and waste memory on rarely used values (see
 315 L<perlsub> for details on constant subroutines).  Calls to such
 316 constant subroutines are not optimized away at compile time because
 317 they can't be checked at compile time for constancy.
 318
 319 Even if a prototype is available at compile time, the body of the
 320 subroutine is not (it hasn't been C<AUTOLOAD>ed yet). perl needs to
 321 examine both the C<()> prototype and the body of a subroutine at
 322 compile time to detect that it can safely replace calls to that
 323 subroutine with the constant value.
 324
 325 A workaround for this is to call the constants once in a C<BEGIN> block:
 326
 327    package My ;
 328
 329    use Socket ;
 330
 331    foo( SO_LINGER );     ## SO_LINGER NOT optimized away; called at runtime
 332    BEGIN { SO_LINGER }
 333    foo( SO_LINGER );     ## SO_LINGER optimized away at compile time.
 334
 335 This forces the C<AUTOLOAD> for C<SO_LINGER> to take place before
 336 SO_LINGER is encountered later in C<My> package.
 337
 338 If you are writing a package that C<AUTOLOAD>s, consider forcing
 339 an C<AUTOLOAD> for any constants explicitly imported by other packages
 340 or which are usually used when your package is C<use>d.
 341
 342 =cut