lib/Exporter.pm

   1 package Exporter;
   2
   3 require 5.001;
   4
   5 #
   6 # We go to a lot of trouble not to 'require Carp' at file scope,
   7 #  because Carp requires Exporter, and something has to give.
   8 #
   9
  10 $ExportLevel = 0;
  11 $Verbose = 0 unless $Verbose;
  12
  13 sub export {
  14
  15     # First make import warnings look like they're coming from the "use".
  16     local $SIG{__WARN__} = sub {
  17         my $text = shift;
  18         if ($text =~ s/ at \S*Exporter.pm line \d+.*\n//) {
  19             require Carp;
  20             local $Carp::CarpLevel = 1; # ignore package calling us too.
  21             Carp::carp($text);
  22         }
  23         else {
  24             warn $text;
  25         }
  26     };
  27     local $SIG{__DIE__} = sub {
  28         require Carp;
  29         local $Carp::CarpLevel = 1;     # ignore package calling us too.
  30         Carp::croak("$_[0]Illegal null symbol in \@${1}::EXPORT")
  31             if $_[0] =~ /^Unable to create sub named "(.*?)::"/;
  32     };
  33
  34     my($pkg, $callpkg, @imports) = @_;
  35     my($type, $sym, $oops);
  36     *exports = *{"${pkg}::EXPORT"};
  37
  38     if (@imports) {
  39         if (!%exports) {
  40             grep(s/^&//, @exports);
  41             @exports{@exports} = (1) x @exports;
  42             my $ok = \@{"${pkg}::EXPORT_OK"};
  43             if (@$ok) {
  44                 grep(s/^&//, @$ok);
  45                 @exports{@$ok} = (1) x @$ok;
  46             }
  47         }
  48
  49         if ($imports[0] =~ m#^[/!:]#){
  50             my $tagsref = \%{"${pkg}::EXPORT_TAGS"};
  51             my $tagdata;
  52             my %imports;
  53             my($remove, $spec, @names, @allexports);
  54             # negated first item implies starting with default set:
  55             unshift @imports, ':DEFAULT' if $imports[0] =~ m/^!/;
  56             foreach $spec (@imports){
  57                 $remove = $spec =~ s/^!//;
  58
  59                 if ($spec =~ s/^://){
  60                     if ($spec eq 'DEFAULT'){
  61                         @names = @exports;
  62                     }
  63                     elsif ($tagdata = $tagsref->{$spec}) {
  64                         @names = @$tagdata;
  65                     }
  66                     else {
  67                         warn qq["$spec" is not defined in %${pkg}::EXPORT_TAGS];
  68                         ++$oops;
  69                         next;
  70                     }
  71                 }
  72                 elsif ($spec =~ m:^/(.*)/$:){
  73                     my $patn = $1;
  74                     @allexports = keys %exports unless @allexports; # only do keys once
  75                     @names = grep(/$patn/, @allexports); # not anchored by default
  76                 }
  77                 else {
  78                     @names = ($spec); # is a normal symbol name
  79                 }
  80
  81                 warn "Import ".($remove ? "del":"add").": @names "
  82                     if $Verbose;
  83
  84                 if ($remove) {
  85                    foreach $sym (@names) { delete $imports{$sym} }
  86                 }
  87                 else {
  88                     @imports{@names} = (1) x @names;
  89                 }
  90             }
  91             @imports = keys %imports;
  92         }
  93
  94         foreach $sym (@imports) {
  95             if (!$exports{$sym}) {
  96                 if ($sym =~ m/^\d/) {
  97                     $pkg->require_version($sym);
  98                     # If the version number was the only thing specified
  99                     # then we should act as if nothing was specified:
 100                     if (@imports == 1) {
 101                         @imports = @exports;
 102                         last;
 103                     }
 104                     # We need a way to emulate 'use Foo ()' but still
 105                     # allow an easy version check: "use Foo 1.23, ''";
 106                     if (@imports == 2 and !$imports[1]) {
 107                         @imports = ();
 108                         last;
 109                     }
 110                 } elsif ($sym !~ s/^&// || !$exports{$sym}) {
 111                     warn qq["$sym" is not exported by the $pkg module];
 112                     $oops++;
 113                 }
 114             }
 115         }
 116         if ($oops) {
 117             require Carp;
 118             Carp::croak("Can't continue after import errors");
 119         }
 120     }
 121     else {
 122         @imports = @exports;
 123     }
 124
 125     *fail = *{"${pkg}::EXPORT_FAIL"};
 126     if (@fail) {
 127         if (!%fail) {
 128             # Build cache of symbols. Optimise the lookup by adding
 129             # barewords twice... both with and without a leading &.
 130             # (Technique could be applied to %exports cache at cost of memory)
 131             my @expanded = map { /^\w/ ? ($_, '&'.$_) : $_ } @fail;
 132             warn "${pkg}::EXPORT_FAIL cached: @expanded" if $Verbose;
 133             @fail{@expanded} = (1) x @expanded;
 134         }
 135         my @failed;
 136         foreach $sym (@imports) { push(@failed, $sym) if $fail{$sym} }
 137         if (@failed) {
 138             @failed = $pkg->export_fail(@failed);
 139             foreach $sym (@failed) {
 140                 warn qq["$sym" is not implemented by the $pkg module ],
 141                         "on this architecture";
 142             }
 143             if (@failed) {
 144                 require Carp;
 145                 Carp::croak("Can't continue after import errors");
 146             }
 147         }
 148     }
 149
 150     warn "Importing into $callpkg from $pkg: ",
 151                 join(", ",sort @imports) if $Verbose;
 152
 153     foreach $sym (@imports) {
 154         # shortcut for the common case of no type character
 155         (*{"${callpkg}::$sym"} = \&{"${pkg}::$sym"}, next)
 156             unless $sym =~ s/^(\W)//;
 157         $type = $1;
 158         *{"${callpkg}::$sym"} =
 159             $type eq '&' ? \&{"${pkg}::$sym"} :
 160             $type eq '$' ? \${"${pkg}::$sym"} :
 161             $type eq '@' ? \@{"${pkg}::$sym"} :
 162             $type eq '%' ? \%{"${pkg}::$sym"} :
 163             $type eq '*' ?  *{"${pkg}::$sym"} :
 164             do { require Carp; Carp::croak("Can't export symbol: $type$sym") };
 165     }
 166 }
 167
 168 sub import {
 169     my $pkg = shift;
 170     my $callpkg = caller($ExportLevel);
 171     export $pkg, $callpkg, @_;
 172 }
 173
 174
 175 # Utility functions
 176
 177 sub _push_tags {
 178     my($pkg, $var, $syms) = @_;
 179     my $nontag;
 180     *export_tags = \%{"${pkg}::EXPORT_TAGS"};
 181     push(@{"${pkg}::$var"},
 182         map { $export_tags{$_} ? @{$export_tags{$_}} : scalar(++$nontag,$_) }
 183                 (@$syms) ? @$syms : keys %export_tags);
 184     if ($nontag and $^W) {
 185         # This may change to a die one day
 186         require Carp;
 187         Carp::carp("Some names are not tags");
 188     }
 189 }
 190
 191 sub export_tags    { _push_tags((caller)[0], "EXPORT",    \@_) }
 192 sub export_ok_tags { _push_tags((caller)[0], "EXPORT_OK", \@_) }
 193
 194
 195 # Default methods
 196
 197 sub export_fail {
 198     my $self = shift;
 199     @_;
 200 }
 201
 202 sub require_version {
 203     my($self, $wanted) = @_;
 204     my $pkg = ref $self || $self;
 205     my $version = ${"${pkg}::VERSION"};
 206     if (!$version or $version < $wanted) {
 207         $version ||= "(undef)";
 208         my $file = $INC{"$pkg.pm"};
 209         $file &&= " ($file)";
 210         require Carp;
 211         Carp::croak("$pkg $wanted required--this is only version $version$file")
 212     }
 213     $version;
 214 }
 215
 216 1;
 217
 218 # A simple self test harness. Change 'require Carp' to 'use Carp ()' for testing.
 219 # package main; eval(join('',<DATA>)) or die $@ unless caller;
 220 __END__
 221 package Test;
 222 $INC{'Exporter.pm'} = 1;
 223 @ISA = qw(Exporter);
 224 @EXPORT      = qw(A1 A2 A3 A4 A5);
 225 @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
 226 %EXPORT_TAGS = (T1=>[qw(A1 A2 B1 B2)], T2=>[qw(A1 A2 B3 B4)], T3=>[qw(X3)]);
 227 @EXPORT_FAIL = qw(B4);
 228 Exporter::export_ok_tags('T3', 'unknown_tag');
 229 sub export_fail {
 230     map { "Test::$_" } @_       # edit symbols just as an example
 231 }
 232
 233 package main;
 234 $Exporter::Verbose = 1;
 235 #import Test;
 236 #import Test qw(X3);            # export ok via export_ok_tags()
 237 #import Test qw(:T1 !A2 /5/ !/3/ B5);
 238 import Test qw(:T2 !B4);
 239 import Test qw(:T2);            # should fail
 240 1;
 241
 242 =head1 NAME
 243
 244 Exporter - Implements default import method for modules
 245
 246 =head1 SYNOPSIS
 247
 248 In module ModuleName.pm:
 249
 250   package ModuleName;
 251   require Exporter;
 252   @ISA = qw(Exporter);
 253
 254   @EXPORT = qw(...);            # symbols to export by default
 255   @EXPORT_OK = qw(...);         # symbols to export on request
 256   %EXPORT_TAGS = tag => [...];  # define names for sets of symbols
 257
 258 In other files which wish to use ModuleName:
 259
 260   use ModuleName;               # import default symbols into my package
 261
 262   use ModuleName qw(...);       # import listed symbols into my package
 263
 264   use ModuleName ();            # do not import any symbols
 265
 266 =head1 DESCRIPTION
 267
 268 The Exporter module implements a default C<import> method which
 269 many modules choose to inherit rather than implement their own.
 270
 271 Perl automatically calls the C<import> method when processing a
 272 C<use> statement for a module. Modules and C<use> are documented
 273 in L<perlfunc> and L<perlmod>. Understanding the concept of
 274 modules and how the C<use> statement operates is important to
 275 understanding the Exporter.
 276
 277 =head2 Selecting What To Export
 278
 279 Do B<not> export method names!
 280
 281 Do B<not> export anything else by default without a good reason!
 282
 283 Exports pollute the namespace of the module user.  If you must export
 284 try to use @EXPORT_OK in preference to @EXPORT and avoid short or
 285 common symbol names to reduce the risk of name clashes.
 286
 287 Generally anything not exported is still accessible from outside the
 288 module using the ModuleName::item_name (or $blessed_ref-E<gt>method)
 289 syntax.  By convention you can use a leading underscore on names to
 290 informally indicate that they are 'internal' and not for public use.
 291
 292 (It is actually possible to get private functions by saying:
 293
 294   my $subref = sub { ... };
 295   &$subref;
 296
 297 But there's no way to call that directly as a method, since a method
 298 must have a name in the symbol table.)
 299
 300 As a general rule, if the module is trying to be object oriented
 301 then export nothing. If it's just a collection of functions then
 302 @EXPORT_OK anything but use @EXPORT with caution.
 303
 304 Other module design guidelines can be found in L<perlmod>.
 305
 306 =head2 Specialised Import Lists
 307
 308 If the first entry in an import list begins with !, : or / then the
 309 list is treated as a series of specifications which either add to or
 310 delete from the list of names to import. They are processed left to
 311 right. Specifications are in the form:
 312
 313     [!]name         This name only
 314     [!]:DEFAULT     All names in @EXPORT
 315     [!]:tag         All names in $EXPORT_TAGS{tag} anonymous list
 316     [!]/pattern/    All names in @EXPORT and @EXPORT_OK which match
 317
 318 A leading ! indicates that matching names should be deleted from the
 319 list of names to import.  If the first specification is a deletion it
 320 is treated as though preceded by :DEFAULT. If you just want to import
 321 extra names in addition to the default set you will still need to
 322 include :DEFAULT explicitly.
 323
 324 e.g., Module.pm defines:
 325
 326     @EXPORT      = qw(A1 A2 A3 A4 A5);
 327     @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
 328     %EXPORT_TAGS = (T1 => [qw(A1 A2 B1 B2)], T2 => [qw(A1 A2 B3 B4)]);
 329
 330     Note that you cannot use tags in @EXPORT or @EXPORT_OK.
 331     Names in EXPORT_TAGS must also appear in @EXPORT or @EXPORT_OK.
 332
 333 An application using Module can say something like:
 334
 335     use Module qw(:DEFAULT :T2 !B3 A3);
 336
 337 Other examples include:
 338
 339     use Socket qw(!/^[AP]F_/ !SOMAXCONN !SOL_SOCKET);
 340     use POSIX  qw(:errno_h :termios_h !TCSADRAIN !/^EXIT/);
 341
 342 Remember that most patterns (using //) will need to be anchored
 343 with a leading ^, e.g., C</^EXIT/> rather than C</EXIT/>.
 344
 345 You can say C<BEGIN { $Exporter::Verbose=1 }> to see how the
 346 specifications are being processed and what is actually being imported
 347 into modules.
 348
 349 =head2 Module Version Checking
 350
 351 The Exporter module will convert an attempt to import a number from a
 352 module into a call to $module_name-E<gt>require_version($value). This can
 353 be used to validate that the version of the module being used is
 354 greater than or equal to the required version.
 355
 356 The Exporter module supplies a default require_version method which
 357 checks the value of $VERSION in the exporting module.
 358
 359 Since the default require_version method treats the $VERSION number as
 360 a simple numeric value it will regard version 1.10 as lower than
 361 1.9. For this reason it is strongly recommended that you use numbers
 362 with at least two decimal places, e.g., 1.09.
 363
 364 =head2 Managing Unknown Symbols
 365
 366 In some situations you may want to prevent certain symbols from being
 367 exported. Typically this applies to extensions which have functions
 368 or constants that may not exist on some systems.
 369
 370 The names of any symbols that cannot be exported should be listed
 371 in the C<@EXPORT_FAIL> array.
 372
 373 If a module attempts to import any of these symbols the Exporter
 374 will give the module an opportunity to handle the situation before
 375 generating an error. The Exporter will call an export_fail method
 376 with a list of the failed symbols:
 377
 378   @failed_symbols = $module_name->export_fail(@failed_symbols);
 379
 380 If the export_fail method returns an empty list then no error is
 381 recorded and all the requested symbols are exported. If the returned
 382 list is not empty then an error is generated for each symbol and the
 383 export fails. The Exporter provides a default export_fail method which
 384 simply returns the list unchanged.
 385
 386 Uses for the export_fail method include giving better error messages
 387 for some symbols and performing lazy architectural checks (put more
 388 symbols into @EXPORT_FAIL by default and then take them out if someone
 389 actually tries to use them and an expensive check shows that they are
 390 usable on that platform).
 391
 392 =head2 Tag Handling Utility Functions
 393
 394 Since the symbols listed within %EXPORT_TAGS must also appear in either
 395 @EXPORT or @EXPORT_OK, two utility functions are provided which allow
 396 you to easily add tagged sets of symbols to @EXPORT or @EXPORT_OK:
 397
 398   %EXPORT_TAGS = (foo => [qw(aa bb cc)], bar => [qw(aa cc dd)]);
 399
 400   Exporter::export_tags('foo');     # add aa, bb and cc to @EXPORT
 401   Exporter::export_ok_tags('bar');  # add aa, cc and dd to @EXPORT_OK
 402
 403 Any names which are not tags are added to @EXPORT or @EXPORT_OK
 404 unchanged but will trigger a warning (with C<-w>) to avoid misspelt tags
 405 names being silently added to @EXPORT or @EXPORT_OK. Future versions
 406 may make this a fatal error.
 407
 408 =cut