lib/Exporter.pm

   1 package Exporter;
   2
   3 require 5.006;
   4
   5 use strict;
   6 no strict 'refs';
   7
   8 our $Debug = 0;
   9 our $ExportLevel = 0;
  10 our $Verbose ||= 0;
  11 our $VERSION = '5.565';
  12 $Carp::Internal{Exporter} = 1;
  13
  14 sub export_to_level {
  15   require Exporter::Heavy;
  16   goto &Exporter::Heavy::heavy_export_to_level;
  17 }
  18
  19 sub export {
  20   require Exporter::Heavy;
  21   goto &Exporter::Heavy::heavy_export;
  22 }
  23
  24 sub export_tags {
  25   require Exporter::Heavy;
  26   Exporter::Heavy::_push_tags((caller)[0], "EXPORT",    \@_);
  27 }
  28
  29 sub export_ok_tags {
  30   require Exporter::Heavy;
  31   Exporter::Heavy::_push_tags((caller)[0], "EXPORT_OK", \@_);
  32 }
  33
  34 sub import {
  35   my $pkg = shift;
  36   my $callpkg = caller($ExportLevel);
  37
  38   # We *need* to treat @{"$pkg\::EXPORT_FAIL"} since Carp uses it :-(
  39   my($exports, $export_cache, $fail)
  40     = (\@{"$pkg\::EXPORT"}, \%{"$pkg\::EXPORT"}, \@{"$pkg\::EXPORT_FAIL"});
  41   return export $pkg, $callpkg, @_
  42     if $Verbose or $Debug or @$fail > 1;
  43   my $args = @_ or @_ = @$exports;
  44
  45   local $_;
  46   if ($args and not %$export_cache) {
  47     s/^&//, $export_cache->{$_} = 1
  48       foreach (@$exports, @{"$pkg\::EXPORT_OK"});
  49   }
  50   my $heavy;
  51   # Try very hard not to use {} and hence have to  enter scope on the foreach
  52   # We bomb out of the loop with last as soon as heavy is set.
  53   if ($args or $fail) {
  54     ($heavy = (/\W/ or $args and not exists $export_cache->{$_}
  55                or @$fail and $_ eq $fail->[0])) and last
  56                  foreach (@_);
  57   } else {
  58     ($heavy = /\W/) and last
  59       foreach (@_);
  60   }
  61   return export $pkg, $callpkg, ($args ? @_ : ()) if $heavy;
  62   local $SIG{__WARN__} =
  63         sub {require Carp; &Carp::carp};
  64   # shortcut for the common case of no type character
  65   *{"$callpkg\::$_"} = \&{"$pkg\::$_"} foreach @_;
  66 }
  67
  68
  69 # Default methods
  70
  71 sub export_fail {
  72     my $self = shift;
  73     @_;
  74 }
  75
  76
  77 sub require_version {
  78     require Exporter::Heavy;
  79     goto &Exporter::Heavy::require_version;
  80 }
  81
  82
  83 1;
  84 __END__
  85
  86 =head1 NAME
  87
  88 Exporter - Implements default import method for modules
  89
  90 =head1 SYNOPSIS
  91
  92 In module ModuleName.pm:
  93
  94   package ModuleName;
  95   require Exporter;
  96   @ISA = qw(Exporter);
  97
  98   @EXPORT = qw(...);            # symbols to export by default
  99   @EXPORT_OK = qw(...);         # symbols to export on request
 100   %EXPORT_TAGS = tag => [...];  # define names for sets of symbols
 101
 102 In other files which wish to use ModuleName:
 103
 104   use ModuleName;               # import default symbols into my package
 105
 106   use ModuleName qw(...);       # import listed symbols into my package
 107
 108   use ModuleName ();            # do not import any symbols
 109
 110 =head1 DESCRIPTION
 111
 112 The Exporter module implements a default C<import> method which
 113 many modules choose to inherit rather than implement their own.
 114
 115 Perl automatically calls the C<import> method when processing a
 116 C<use> statement for a module. Modules and C<use> are documented
 117 in L<perlfunc> and L<perlmod>. Understanding the concept of
 118 modules and how the C<use> statement operates is important to
 119 understanding the Exporter.
 120
 121 =head2 How to Export
 122
 123 The arrays C<@EXPORT> and C<@EXPORT_OK> in a module hold lists of
 124 symbols that are going to be exported into the users name space by
 125 default, or which they can request to be exported, respectively.  The
 126 symbols can represent functions, scalars, arrays, hashes, or typeglobs.
 127 The symbols must be given by full name with the exception that the
 128 ampersand in front of a function is optional, e.g.
 129
 130     @EXPORT    = qw(afunc $scalar @array);   # afunc is a function
 131     @EXPORT_OK = qw(&bfunc %hash *typeglob); # explicit prefix on &bfunc
 132
 133 =head2 Selecting What To Export
 134
 135 Do B<not> export method names!
 136
 137 Do B<not> export anything else by default without a good reason!
 138
 139 Exports pollute the namespace of the module user.  If you must export
 140 try to use @EXPORT_OK in preference to @EXPORT and avoid short or
 141 common symbol names to reduce the risk of name clashes.
 142
 143 Generally anything not exported is still accessible from outside the
 144 module using the ModuleName::item_name (or $blessed_ref-E<gt>method)
 145 syntax.  By convention you can use a leading underscore on names to
 146 informally indicate that they are 'internal' and not for public use.
 147
 148 (It is actually possible to get private functions by saying:
 149
 150   my $subref = sub { ... };
 151   $subref->(@args);            # Call it as a function
 152   $obj->$subref(@args);        # Use it as a method
 153
 154 However if you use them for methods it is up to you to figure out
 155 how to make inheritance work.)
 156
 157 As a general rule, if the module is trying to be object oriented
 158 then export nothing. If it's just a collection of functions then
 159 @EXPORT_OK anything but use @EXPORT with caution.
 160
 161 Other module design guidelines can be found in L<perlmod>.
 162
 163 =head2 Specialised Import Lists
 164
 165 If the first entry in an import list begins with !, : or / then the
 166 list is treated as a series of specifications which either add to or
 167 delete from the list of names to import. They are processed left to
 168 right. Specifications are in the form:
 169
 170     [!]name         This name only
 171     [!]:DEFAULT     All names in @EXPORT
 172     [!]:tag         All names in $EXPORT_TAGS{tag} anonymous list
 173     [!]/pattern/    All names in @EXPORT and @EXPORT_OK which match
 174
 175 A leading ! indicates that matching names should be deleted from the
 176 list of names to import.  If the first specification is a deletion it
 177 is treated as though preceded by :DEFAULT. If you just want to import
 178 extra names in addition to the default set you will still need to
 179 include :DEFAULT explicitly.
 180
 181 e.g., Module.pm defines:
 182
 183     @EXPORT      = qw(A1 A2 A3 A4 A5);
 184     @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
 185     %EXPORT_TAGS = (T1 => [qw(A1 A2 B1 B2)], T2 => [qw(A1 A2 B3 B4)]);
 186
 187     Note that you cannot use tags in @EXPORT or @EXPORT_OK.
 188     Names in EXPORT_TAGS must also appear in @EXPORT or @EXPORT_OK.
 189
 190 An application using Module can say something like:
 191
 192     use Module qw(:DEFAULT :T2 !B3 A3);
 193
 194 Other examples include:
 195
 196     use Socket qw(!/^[AP]F_/ !SOMAXCONN !SOL_SOCKET);
 197     use POSIX  qw(:errno_h :termios_h !TCSADRAIN !/^EXIT/);
 198
 199 Remember that most patterns (using //) will need to be anchored
 200 with a leading ^, e.g., C</^EXIT/> rather than C</EXIT/>.
 201
 202 You can say C<BEGIN { $Exporter::Verbose=1 }> to see how the
 203 specifications are being processed and what is actually being imported
 204 into modules.
 205
 206 =head2 Exporting without using Export's import method
 207
 208 Exporter has a special method, 'export_to_level' which is used in situations
 209 where you can't directly call Export's import method. The export_to_level
 210 method looks like:
 211
 212 MyPackage->export_to_level($where_to_export, $package, @what_to_export);
 213
 214 where $where_to_export is an integer telling how far up the calling stack
 215 to export your symbols, and @what_to_export is an array telling what
 216 symbols *to* export (usually this is @_).  The $package argument is
 217 currently unused.
 218
 219 For example, suppose that you have a module, A, which already has an
 220 import function:
 221
 222 package A;
 223
 224 @ISA = qw(Exporter);
 225 @EXPORT_OK = qw ($b);
 226
 227 sub import
 228 {
 229     $A::b = 1;     # not a very useful import method
 230 }
 231
 232 and you want to Export symbol $A::b back to the module that called
 233 package A. Since Exporter relies on the import method to work, via
 234 inheritance, as it stands Exporter::import() will never get called.
 235 Instead, say the following:
 236
 237 package A;
 238 @ISA = qw(Exporter);
 239 @EXPORT_OK = qw ($b);
 240
 241 sub import
 242 {
 243     $A::b = 1;
 244     A->export_to_level(1, @_);
 245 }
 246
 247 This will export the symbols one level 'above' the current package - ie: to
 248 the program or module that used package A.
 249
 250 Note: Be careful not to modify '@_' at all before you call export_to_level
 251 - or people using your package will get very unexplained results!
 252
 253
 254 =head2 Module Version Checking
 255
 256 The Exporter module will convert an attempt to import a number from a
 257 module into a call to $module_name-E<gt>require_version($value). This can
 258 be used to validate that the version of the module being used is
 259 greater than or equal to the required version.
 260
 261 The Exporter module supplies a default require_version method which
 262 checks the value of $VERSION in the exporting module.
 263
 264 Since the default require_version method treats the $VERSION number as
 265 a simple numeric value it will regard version 1.10 as lower than
 266 1.9. For this reason it is strongly recommended that you use numbers
 267 with at least two decimal places, e.g., 1.09.
 268
 269 =head2 Managing Unknown Symbols
 270
 271 In some situations you may want to prevent certain symbols from being
 272 exported. Typically this applies to extensions which have functions
 273 or constants that may not exist on some systems.
 274
 275 The names of any symbols that cannot be exported should be listed
 276 in the C<@EXPORT_FAIL> array.
 277
 278 If a module attempts to import any of these symbols the Exporter
 279 will give the module an opportunity to handle the situation before
 280 generating an error. The Exporter will call an export_fail method
 281 with a list of the failed symbols:
 282
 283   @failed_symbols = $module_name->export_fail(@failed_symbols);
 284
 285 If the export_fail method returns an empty list then no error is
 286 recorded and all the requested symbols are exported. If the returned
 287 list is not empty then an error is generated for each symbol and the
 288 export fails. The Exporter provides a default export_fail method which
 289 simply returns the list unchanged.
 290
 291 Uses for the export_fail method include giving better error messages
 292 for some symbols and performing lazy architectural checks (put more
 293 symbols into @EXPORT_FAIL by default and then take them out if someone
 294 actually tries to use them and an expensive check shows that they are
 295 usable on that platform).
 296
 297 =head2 Tag Handling Utility Functions
 298
 299 Since the symbols listed within %EXPORT_TAGS must also appear in either
 300 @EXPORT or @EXPORT_OK, two utility functions are provided which allow
 301 you to easily add tagged sets of symbols to @EXPORT or @EXPORT_OK:
 302
 303   %EXPORT_TAGS = (foo => [qw(aa bb cc)], bar => [qw(aa cc dd)]);
 304
 305   Exporter::export_tags('foo');     # add aa, bb and cc to @EXPORT
 306   Exporter::export_ok_tags('bar');  # add aa, cc and dd to @EXPORT_OK
 307
 308 Any names which are not tags are added to @EXPORT or @EXPORT_OK
 309 unchanged but will trigger a warning (with C<-w>) to avoid misspelt tags
 310 names being silently added to @EXPORT or @EXPORT_OK. Future versions
 311 may make this a fatal error.
 312
 313 =head2 Generating combined tags
 314
 315 If several symbol categories exist in %EXPORT_TAGS, it's usually
 316 useful to create the utility ":all" to simplify "use" statements.
 317
 318 The simplest way to do this is:
 319
 320   %EXPORT_TAGS = (foo => [qw(aa bb cc)], bar => [qw(aa cc dd)]);
 321
 322   # add all the other ":class" tags to the ":all" class,
 323   # deleting duplicates
 324   {
 325     my %seen;
 326
 327     push @{$EXPORT_TAGS{all}},
 328       grep {!$seen{$_}++} @{$EXPORT_TAGS{$_}} foreach keys %EXPORT_TAGS;
 329   }
 330
 331 CGI.pm creates an ":all" tag which contains some (but not really
 332 all) of its categories.  That could be done with one small
 333 change:
 334
 335   # add some of the other ":class" tags to the ":all" class,
 336   # deleting duplicates
 337   {
 338     my %seen;
 339
 340     push @{$EXPORT_TAGS{all}},
 341       grep {!$seen{$_}++} @{$EXPORT_TAGS{$_}}
 342         foreach qw/html2 html3 netscape form cgi internal/;
 343   }
 344
 345 Note that the tag names in %EXPORT_TAGS don't have the leading ':'.
 346
 347 =head2 C<AUTOLOAD>ed Constants
 348
 349 Many modules make use of C<AUTOLOAD>ing for constant subroutines to
 350 avoid having to compile and waste memory on rarely used values (see
 351 L<perlsub> for details on constant subroutines).  Calls to such
 352 constant subroutines are not optimized away at compile time because
 353 they can't be checked at compile time for constancy.
 354
 355 Even if a prototype is available at compile time, the body of the
 356 subroutine is not (it hasn't been C<AUTOLOAD>ed yet). perl needs to
 357 examine both the C<()> prototype and the body of a subroutine at
 358 compile time to detect that it can safely replace calls to that
 359 subroutine with the constant value.
 360
 361 A workaround for this is to call the constants once in a C<BEGIN> block:
 362
 363    package My ;
 364
 365    use Socket ;
 366
 367    foo( SO_LINGER );     ## SO_LINGER NOT optimized away; called at runtime
 368    BEGIN { SO_LINGER }
 369    foo( SO_LINGER );     ## SO_LINGER optimized away at compile time.
 370
 371 This forces the C<AUTOLOAD> for C<SO_LINGER> to take place before
 372 SO_LINGER is encountered later in C<My> package.
 373
 374 If you are writing a package that C<AUTOLOAD>s, consider forcing
 375 an C<AUTOLOAD> for any constants explicitly imported by other packages
 376 or which are usually used when your package is C<use>d.
 377
 378 =cut