lib/Distar.pm

   1 package Distar;
   2
   3 use strictures 1;
   4 use base qw(Exporter);
   5
   6 our @EXPORT = qw(
   7   author manifest_include run_preflight
   8 );
   9
  10 sub import {
  11   strictures->import;
  12   shift->export_to_level(1,@_);
  13 }
  14
  15 sub author { our $Author = shift }
  16
  17 our @Manifest = (
  18   'lib' => '.pm',
  19   't' => '.t',
  20   't/lib' => '.pm',
  21   'xt' => '.t',
  22   'xt/lib' => '.pm',
  23   '' => '.PL',
  24   '' => qr{Changes|MANIFEST|README|META\.yml},
  25   'maint' => qr{[^.].*},
  26 );
  27
  28 sub manifest_include {
  29   push @Manifest, @_;
  30 }
  31
  32 sub write_manifest_skip {
  33   use autodie;
  34   my @files = @Manifest;
  35   my @parts;
  36   while (my ($dir, $spec) = splice(@files, 0, 2)) {
  37     my $re = ($dir ? $dir.'/' : '').
  38       ((ref($spec) eq 'Regexp')
  39         ? $spec
  40         : !ref($spec)
  41           ? ".*\Q${spec}\E"
  42             # print ref as well as stringification in case of overload ""
  43           : die "spec must be string or regexp, was: ${spec} (${\ref $spec})");
  44     push @parts, $re;
  45   }
  46   my $final = '^(?!'.join('|', map "${_}\$", @parts).')';
  47   open my $skip, '>', 'MANIFEST.SKIP';
  48   print $skip "${final}\n";
  49   close $skip;
  50 }
  51
  52 sub run_preflight {
  53   system("git fetch");
  54
  55   for (scalar `git status`) {
  56     /Your branch is (behind|ahead of)/ && die "Not synced with upstream";
  57   }
  58
  59   for (scalar `git diff`) {
  60     length && die "Oustanding changes";
  61   }
  62   my @cached = grep /^\+/, `git diff --cached -U0`;
  63   @cached == 2 or die "Pre-commit Changes not just Changes line";
  64   $cached[0] eq "+++ b/Changes\n" or die "Changes not changed";
  65   my $ymd = sprintf(
  66     "%i-%02i-%02i", (localtime)[5]+1900, (localtime)[4]+1, (localtime)[3]
  67   );
  68   $cached[1] eq "+$ARGV[0] - $ymd\n" or die "Changes new line should be: \n\n$ARGV[0] - $ymd\n ";
  69 }
  70
  71 sub MY::postamble { <<'END'; }
  72 preflight:
  73         perl -Idistar/lib -MDistar -erun_preflight $(VERSION)
  74 upload: preflight $(DISTVNAME).tar$(SUFFIX)
  75         cpan-upload $(DISTVNAME).tar$(SUFFIX)
  76 release: upload
  77         git commit -a -m "Release commit for $(VERSION)"
  78         git tag release_$(VERSION)
  79         git push
  80         git push --tags
  81 distdir: readmefile
  82 readmefile: create_distdir
  83         pod2text $(VERSION_FROM) >$(DISTVNAME)/README
  84 END
  85
  86 {
  87   no warnings 'redefine';
  88   sub main::WriteMakefile {
  89     my %args = @_;
  90     ExtUtils::MakeMaker::WriteMakefile(
  91       LICENSE => 'perl',
  92       @_, AUTHOR => our $Author, ABSTRACT_FROM => $args{VERSION_FROM},
  93       test => { TESTS => ($args{test}{TESTS}||'').' xt/*.t' },
  94     );
  95   }
  96 }
  97
  98 END {
  99   write_manifest_skip()
 100 }
 101
 102 1;