lib/Distar.pm

   1 package Distar;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5 use base qw(Exporter);
   6 use ExtUtils::MakeMaker ();
   7 use ExtUtils::MM ();
   8
   9 use Config;
  10 use File::Spec;
  11
  12 our $VERSION = '0.001000';
  13 $VERSION = eval $VERSION;
  14
  15 our @EXPORT = qw(
  16   author manifest_include run_preflight
  17 );
  18
  19 sub import {
  20   strict->import;
  21   warnings->import(FATAL => 'all');
  22   shift->export_to_level(1,@_);
  23 }
  24
  25 sub author { our $Author = shift }
  26
  27 our $Ran_Preflight;
  28
  29 our @Manifest = (
  30   'lib' => '.pm',
  31   't' => '.t',
  32   't/lib' => '.pm',
  33   'xt' => '.t',
  34   'xt/lib' => '.pm',
  35   '' => qr{[^/]*\.PL},
  36   '' => qr{Changes|MANIFEST|README|META\.yml},
  37   'maint' => qr{[^.].*},
  38 );
  39
  40 sub manifest_include {
  41   push @Manifest, @_;
  42 }
  43
  44 sub write_manifest_skip {
  45   my @files = @Manifest;
  46   my @parts;
  47   while (my ($dir, $spec) = splice(@files, 0, 2)) {
  48     my $re = ($dir ? $dir.'/' : '').
  49       ((ref($spec) eq 'Regexp')
  50         ? $spec
  51         : !ref($spec)
  52           ? ".*\Q${spec}\E"
  53             # print ref as well as stringification in case of overload ""
  54           : die "spec must be string or regexp, was: ${spec} (${\ref $spec})");
  55     push @parts, $re;
  56   }
  57   my $final = '^(?!'.join('|', map "${_}\$", @parts).')';
  58   open my $skip, '>', 'MANIFEST.SKIP'
  59     or die "can't open MANIFEST.SKIP: $!";
  60   print $skip "${final}\n";
  61   close $skip;
  62 }
  63
  64 sub run_preflight {
  65   $Ran_Preflight = 1;
  66   my $version = $ARGV[0];
  67
  68   my $make = $Config{make};
  69   my $null = File::Spec->devnull;
  70
  71   system("git fetch");
  72   if (system("git rev-parse --quiet --verify v$version >$null") == 0) {
  73     die "Tag v$version already exists!";
  74   }
  75
  76   require File::Find;
  77   File::Find::find({ no_chdir => 1, wanted => sub {
  78     return
  79       unless -f && /\.pm$/;
  80     my $file_version = MM->parse_version($_);
  81     die "Module $_ version $file_version doesn't match dist version $version"
  82       unless $file_version eq 'undef' || $file_version eq $version;
  83   }}, 'lib');
  84
  85   for (scalar `"$make" manifest 2>&1 >$null`) {
  86     $_ && die "$make manifest changed:\n$_ Go check it and retry";
  87   }
  88
  89   for (scalar `git status`) {
  90     /^(?:# )?On branch master/ || die "Not on master. EEEK";
  91     /Your branch is behind|Your branch and .*? have diverged/ && die "Not synced with upstream";
  92   }
  93
  94   for (scalar `git diff`) {
  95     length && die "Outstanding changes";
  96   }
  97   my $ymd = sprintf(
  98     "%i-%02i-%02i", (localtime)[5]+1900, (localtime)[4]+1, (localtime)[3]
  99   );
 100   my $changes_line = "$version - $ymd\n";
 101   my @cached = grep /^\+/, `git diff --cached -U0`;
 102   @cached > 0 or die "Please add:\n\n$changes_line\nto Changes stage Changes (git add Changes)";
 103   @cached == 2 or die "Pre-commit Changes not just Changes line";
 104   $cached[0] =~ /^\+\+\+ .\/Changes\n/ or die "Changes not changed";
 105   $cached[1] eq "+$changes_line" or die "Changes new line should be: \n\n$changes_line ";
 106
 107   { no warnings 'exec'; `cpan-upload -h`; }
 108   $? and die "cpan-upload not available";
 109 }
 110
 111 {
 112   package Distar::MM;
 113   our @ISA = @ExtUtils::MM::ISA;
 114   @ExtUtils::MM::ISA = (__PACKAGE__);
 115
 116   sub new {
 117     my ($class, $args) = @_;
 118     return $class->SUPER::new({
 119       LICENSE => 'perl',
 120       %$args,
 121       AUTHOR => $Distar::Author,
 122       ABSTRACT_FROM => $args->{VERSION_FROM},
 123       test => { TESTS => ($args->{test}{TESTS}||'t/*.t').' xt/*.t xt/*/*.t' },
 124     });
 125   }
 126
 127   sub dist_test {
 128     my $self = shift;
 129     my $dist_test = $self->SUPER::dist_test(@_) . <<'END';
 130
 131 # --- Distar section:
 132 preflight:
 133         perl -IDistar/lib -MDistar -erun_preflight $(VERSION)
 134 release: preflight
 135         $(MAKE) disttest
 136         rm -rf $(DISTVNAME)
 137         $(MAKE) $(DISTVNAME).tar$(SUFFIX)
 138         git commit -a -m "Release commit for $(VERSION)"
 139         git tag v$(VERSION) -m "release v$(VERSION)"
 140         cpan-upload $(DISTVNAME).tar$(SUFFIX)
 141         git push origin v$(VERSION) HEAD
 142 distdir: readmefile
 143 readmefile: create_distdir
 144         pod2text $(VERSION_FROM) >$(DISTVNAME)/README
 145         $(NOECHO) cd $(DISTVNAME) && $(ABSPERLRUN) ../Distar/helpers/add-readme-to-manifest
 146 disttest: distmanicheck
 147 distmanicheck: create_distdir
 148         cd $(DISTVNAME) && $(ABSPERLRUN) "-MExtUtils::Manifest=manicheck" -e "exit manicheck"
 149
 150 END
 151     if (open my $fh, '<', 'maint/Makefile.include') {
 152       $dist_test .= do { local $/; <$fh> };
 153     }
 154     return $dist_test;
 155   }
 156 }
 157
 158 END {
 159   write_manifest_skip() unless $Ran_Preflight
 160 }
 161
 162 1;