lib/Distar.pm

   1 package Distar;
   2
   3 use strictures 1;
   4 use base qw(Exporter);
   5
   6 use Config;
   7 use File::Spec;
   8
   9 our @EXPORT = qw(
  10   author manifest_include run_preflight
  11 );
  12
  13 sub import {
  14   strictures->import;
  15   shift->export_to_level(1,@_);
  16 }
  17
  18 sub author { our $Author = shift }
  19
  20 our $Ran_Preflight;
  21
  22 our @Manifest = (
  23   'lib' => '.pm',
  24   't' => '.t',
  25   't/lib' => '.pm',
  26   'xt' => '.t',
  27   'xt/lib' => '.pm',
  28   '' => qr{[^/]*\.PL},
  29   '' => qr{Changes|MANIFEST|README|META\.yml},
  30   'maint' => qr{[^.].*},
  31 );
  32
  33 sub manifest_include {
  34   push @Manifest, @_;
  35 }
  36
  37 sub write_manifest_skip {
  38   use autodie;
  39   my @files = @Manifest;
  40   my @parts;
  41   while (my ($dir, $spec) = splice(@files, 0, 2)) {
  42     my $re = ($dir ? $dir.'/' : '').
  43       ((ref($spec) eq 'Regexp')
  44         ? $spec
  45         : !ref($spec)
  46           ? ".*\Q${spec}\E"
  47             # print ref as well as stringification in case of overload ""
  48           : die "spec must be string or regexp, was: ${spec} (${\ref $spec})");
  49     push @parts, $re;
  50   }
  51   my $final = '^(?!'.join('|', map "${_}\$", @parts).')';
  52   open my $skip, '>', 'MANIFEST.SKIP';
  53   print $skip "${final}\n";
  54   close $skip;
  55 }
  56
  57 sub run_preflight {
  58   $Ran_Preflight = 1;
  59
  60   system("git fetch");
  61
  62   my $make = $Config{make};
  63   my $null = File::Spec->devnull;
  64
  65   for (scalar `"$make" manifest 2>&1 >$null`) {
  66     $_ && die "$make manifest changed:\n$_ Go check it and retry";
  67   }
  68
  69   for (scalar `git status`) {
  70     /^# On branch master/ || die "Not on master. EEEK";
  71     /Your branch is behind|Your branch and .*? have diverged/ && die "Not synced with upstream";
  72   }
  73
  74   for (scalar `git diff`) {
  75     length && die "Outstanding changes";
  76   }
  77   my $ymd = sprintf(
  78     "%i-%02i-%02i", (localtime)[5]+1900, (localtime)[4]+1, (localtime)[3]
  79   );
  80   my @cached = grep /^\+/, `git diff --cached -U0`;
  81   @cached > 0 or die "Please add:\n\n$ARGV[0] - $ymd\n\nto Changes stage Changes (git add Changes)";
  82   @cached == 2 or die "Pre-commit Changes not just Changes line";
  83   $cached[0] =~ /^\+\+\+ .\/Changes\n/ or die "Changes not changed";
  84   $cached[1] eq "+$ARGV[0] - $ymd\n" or die "Changes new line should be: \n\n$ARGV[0] - $ymd\n ";
  85 }
  86
  87 sub MY::postamble {
  88     my $post = <<'END';
  89 preflight:
  90         perl -IDistar/lib -MDistar -erun_preflight $(VERSION)
  91 release: preflight
  92         $(MAKE) disttest
  93         rm -rf $(DISTVNAME)
  94         $(MAKE) $(DISTVNAME).tar$(SUFFIX)
  95         cpan-upload $(DISTVNAME).tar$(SUFFIX)
  96         git commit -a -m "Release commit for $(VERSION)"
  97         git tag v$(VERSION) -m "release v$(VERSION)"
  98         git push --tags
  99         git push
 100 distdir: readmefile
 101 readmefile: create_distdir
 102         pod2text $(VERSION_FROM) >$(DISTVNAME)/README
 103         $(NOECHO) cd $(DISTVNAME) && $(ABSPERLRUN) ../Distar/helpers/add-readme-to-manifest
 104 END
 105     if (open my $fh, '<', 'maint/Makefile.include') {
 106         $post .= do { local $/; <$fh> };
 107     }
 108     return $post;
 109 }
 110
 111 {
 112   no warnings 'redefine';
 113   sub main::WriteMakefile {
 114     my %args = @_;
 115     ExtUtils::MakeMaker::WriteMakefile(
 116       LICENSE => 'perl',
 117       @_, AUTHOR => our $Author, ABSTRACT_FROM => $args{VERSION_FROM},
 118       test => { TESTS => ($args{test}{TESTS}||'t/*.t').' xt/*.t' },
 119     );
 120   }
 121 }
 122
 123 END {
 124   write_manifest_skip() unless $Ran_Preflight
 125 }
 126
 127 1;