lib/Data/Query/Renderer/SQL/Slice/FetchFirst.pm

   1 package Data::Query::Renderer::SQL::Slice::FetchFirst;
   2
   3 use Data::Query::ExprHelpers;
   4 use Moo::Role;
   5
   6 with 'Data::Query::Renderer::SQL::Slice::SubqueryRemap';
   7
   8 sub _render_slice_limit {
   9   my ($self, $dq) = @_;
  10   return [
  11     ($dq->{from} ? $self->_render($dq->{from}) : ()),
  12     $self->_format_keyword('FETCH FIRST'),
  13     sprintf("%i", $dq->{limit}{value}),
  14     $self->_format_keyword('ROWS ONLY')
  15   ];
  16 }
  17
  18 sub slice_subquery {
  19   (offset => 1);
  20 }
  21
  22 sub slice_stability {
  23   (offset => 'requires');
  24 }
  25
  26 sub _slice_type { 'FetchFirst' }
  27
  28 sub _render_slice {
  29   my ($self, $dq) = @_;
  30   unless ($dq->{offset}) {
  31     return $self->_render_slice_limit($dq);
  32   }
  33   unless ($dq->{order_is_stable}) {
  34     die $self->_slice_type." limit style requires a stable order";
  35   }
  36   die "Slice's inner is not a Select"
  37     unless is_Select my $orig_select = $dq->{from};
  38
  39   my %remapped = $self->_subquery_remap($orig_select);
  40
  41   my @inside_select_list = @{$remapped{inside_select_list}};
  42   my @outside_select_list = @{$remapped{outside_select_list}};
  43   my @inside_order = @{$remapped{inside_order}};
  44   my @outside_order = @{$remapped{outside_order}};
  45   my $default_inside_alias = $remapped{default_inside_alias};
  46   my $inner_body = $remapped{inner_body};
  47
  48   my $limit_plus_offset = +{
  49     %{$dq->{limit}}, value => $dq->{limit}{value} + $dq->{offset}{value}
  50   };
  51
  52   return $self->_render(
  53     map {
  54       ($dq->{preserve_order} and @outside_order)
  55         ? Select(
  56           \@outside_select_list,
  57           compose {
  58             Order($b->{by}, $b->{reverse}, $b->{nulls}, $a)
  59           } (
  60             @outside_order,
  61             Alias($default_inside_alias, $_)
  62           )
  63         )
  64         : $_
  65     } (
  66       Slice(
  67         undef, $dq->{limit},
  68         Select(
  69           [
  70             @outside_select_list,
  71             $dq->{preserve_order}
  72               ? (grep @{$_->{elements}} == 1,
  73                   map $_->{by}, @outside_order)
  74               : (),
  75           ],
  76           compose {
  77             Order($b->{by}, !$b->{reverse}, -($b->{nulls}||0), $a)
  78           } (
  79             @outside_order,
  80             Alias(
  81               $default_inside_alias,
  82               Slice(
  83                 undef, $limit_plus_offset,
  84                 Select(
  85                   \@inside_select_list,
  86                   compose {
  87                     Order($b->{by}, $b->{reverse}, $b->{nulls}, $a)
  88                   } @inside_order, $inner_body
  89                 )
  90               )
  91             )
  92           )
  93         )
  94       )
  95     )
  96   );
  97 }
  98
  99 1;