lib/Data/Query/Renderer/SQL/Naive.pm

   1 package Data::Query::Renderer::SQL::Naive;
   2
   3 use strictures 1;
   4 use SQL::ReservedWords;
   5 use Data::Query::Constants qw(
   6   DQ_IDENTIFIER DQ_OPERATOR DQ_VALUE DQ_JOIN DQ_ALIAS DQ_ORDER
   7 );
   8
   9 sub new {
  10   bless({ %{$_[1]||{}} }, (ref($_[0])||$_[0]))->BUILDALL;
  11 }
  12
  13 sub BUILDALL {
  14   my $self = shift;
  15   $self->{reserved_ident_parts}
  16     ||= (
  17       our $_DEFAULT_RESERVED ||= { map +($_ => 1), SQL::ReservedWords->words }
  18     );
  19   $self->{quote_chars}||=[''];
  20   $self->{simple_ops}||=$self->_default_simple_ops;
  21   return $self;
  22 }
  23
  24 sub _default_simple_ops {
  25   +{
  26     (map +($_ => 'binop'), qw(= > < >= <= != LIKE), 'NOT LIKE' ),
  27     (map +($_ => 'unop'), qw(NOT) ),
  28     (map +($_ => 'unop_reverse'), ('IS NULL', 'IS NOT NULL')),
  29     (map +($_ => 'flatten'), qw(AND OR) ),
  30     (map +($_ => 'in'), ('IN', 'NOT IN')),
  31     (map +($_ => 'between'), ('BETWEEN', 'NOT BETWEEN'))
  32   }
  33 }
  34
  35 sub render {
  36   my $self = shift;
  37   $self->_flatten_structure($self->_render(@_))
  38 }
  39
  40 sub _flatten_structure {
  41   my ($self, $struct) = @_;
  42   my @bind;
  43   [ do {
  44       my @p = map {
  45         my $r = ref;
  46         if (!$r) { $_ }
  47         elsif ($r eq 'ARRAY') {
  48           my ($sql, @b) = @{$self->_flatten_structure($_)};
  49           push @bind, @b;
  50           $sql;
  51         }
  52         elsif ($r eq 'HASH') { push @bind, $_; () }
  53         else { die "_flatten_structure can't handle ref type $r for $_" }
  54       } @$struct;
  55       join '', map {
  56         ($p[$_], (($p[$_+1]||',') eq ',') ? () : (' '))
  57       } 0 .. $#p;
  58     },
  59     @bind
  60   ];
  61 }
  62
  63 # I present this to permit strange people to easily supply a patch to lc()
  64 # their keywords, as I have heard many desire to do, lest they infect me
  65 # with whatever malady caused this desire by their continued proximity for
  66 # want of such a feature.
  67
  68 sub _format_keyword { $_[1] }
  69
  70 sub _render {
  71   $_[0]->${\"_render_${\(lc($_[1]->{type})||'broken')}"}($_[1]);
  72 }
  73
  74 sub _render_broken {
  75   my ($self, $dq) = @_;
  76   require Data::Dumper::Concise;
  77   die "Broken DQ entry: ".Data::Dumper::Concise::Dumper($dq);
  78 }
  79
  80 sub _render_identifier {
  81   die "Unidentified identifier (SQL can no has \$_)"
  82     unless my @i = @{$_[1]->{elements}};
  83   # handle single or paired quote chars
  84   my ($q1, $q2) = @{$_[0]->{quote_chars}}[0,-1];
  85   my $always_quote = $_[0]->{always_quote};
  86   my $res_check = $_[0]->{reserved_ident_parts};
  87   return [
  88     join
  89       $_[0]->{identifier_sep}||'.',
  90       map +(
  91         $_ eq '*' # Yes, this means you can't have a column just called '*'.
  92           ? $_    # Yes, this is a feature. Go shoot the DBA if he disagrees.
  93           : ( # reserved are stored uc, quote if non-word
  94               $always_quote || $res_check->{+uc} || /\W/
  95                 ? $q1.$_.$q2
  96                 : $_
  97             )
  98       ), @i
  99   ];
 100 }
 101
 102 sub _render_value {
 103   [ '?', $_[1] ];
 104 }
 105
 106 sub _operator_type { 'SQL.Naive' }
 107
 108 sub _render_operator {
 109   my ($self, $dq) = @_;
 110   my $op = $dq->{operator};
 111   unless (exists $op->{$self->_operator_type}) {
 112     $op->{$self->_operator_type} = $self->_convert_op($dq);
 113   }
 114   my $op_name = $op->{$self->_operator_type};
 115   if (my $op_type = $self->{simple_ops}{$op_name}) {
 116     return $self->${\"_handle_op_type_${op_type}"}($op_name, $dq);
 117   } elsif (my $meth = $self->can("_handle_op_special_${op_name}")) {
 118     return $self->$meth($dq);
 119   }
 120   #die "Couldn't render operator ".$op->{$self->_operator_type};
 121   $self->_handle_op_type_binop($op_name, $dq);
 122 }
 123
 124 sub _handle_op_type_binop {
 125   my ($self, $op_name, $dq) = @_;
 126   die "${op_name} registered as binary op but args contain "
 127       .scalar(@{$dq->{args}})." entries"
 128     unless @{$dq->{args}} == 2;
 129   [
 130     $self->_render($dq->{args}[0]),
 131     $op_name,
 132     $self->_render($dq->{args}[1]),
 133   ]
 134 }
 135
 136 sub _handle_op_type_unop {
 137   my ($self, $op_name, $dq) = @_;
 138   die "${op_name} registered as unary op but args contain "
 139       .scalar(@{$dq->{args}})." entries"
 140     unless @{$dq->{args}} == 1;
 141   [
 142     '(',
 143     $op_name,
 144     $self->_render($dq->{args}[0]),
 145     ')',
 146   ]
 147 }
 148
 149 sub _handle_op_type_unop_reverse {
 150   my ($self, $op_name, $dq) = @_;
 151   die "${op_name} registered as unary op but args contain "
 152       .scalar(@{$dq->{args}})." entries"
 153     unless @{$dq->{args}} == 1;
 154   [
 155     $self->_render($dq->{args}[0]),
 156     $op_name,
 157   ]
 158 }
 159
 160 sub _handle_op_type_flatten {
 161   my ($self, $op_name, $dq) = @_;
 162   my @argq = @{$dq->{args}};
 163   my @arg_final;
 164   while (my $arg = shift @argq) {
 165
 166     unless ($arg->{type} eq DQ_OPERATOR) {
 167       push @arg_final, $arg;
 168       next;
 169     }
 170
 171     my $op = $arg->{operator};
 172     unless (exists $op->{$self->_operator_type}) {
 173       $op->{$self->_operator_type} = $self->_convert_op($arg);
 174     }
 175
 176     if ($op->{$self->_operator_type} eq $op_name) {
 177       unshift @argq, @{$arg->{args}};
 178     } else {
 179       push @arg_final, $arg;
 180     }
 181   }
 182   my @sql = ('(', map +($self->_render($_), $op_name), @arg_final);
 183   $sql[-1] = ')'; # replace final AND or whatever with )
 184   \@sql;
 185 }
 186
 187 sub _handle_op_type_in {
 188   my ($self, $op, $dq) = @_;
 189   my ($lhs, @in) = @{$dq->{args}};
 190   my @rhs = ('(', map +($self->_render($_), ','), @in);
 191   $rhs[-1] = ')';
 192   [ $self->_render($lhs), $op, @rhs ];
 193 }
 194
 195 sub _handle_op_type_between {
 196   my ($self, $op_name, $dq) = @_;
 197   my ($lhs, $rhs1, $rhs2) = (map $self->_render($_), @{$dq->{args}});
 198   [ $lhs, $op_name, $rhs1, 'AND', $rhs2 ];
 199 }
 200
 201 sub _convert_op {
 202   my ($self, $dq) = @_;
 203   if (my $perl_op = $dq->{'operator'}->{'Perl'}) {
 204     for ($perl_op) {
 205       $_ eq '==' and return '=';
 206       $_ eq 'eq' and return '=';
 207       $_ eq '!' and return 'NOT';
 208     }
 209     return uc $perl_op; # hope!
 210   }
 211   die "Can't convert non-perl op yet";
 212 }
 213
 214 sub _render_select {
 215   my ($self, $dq) = @_;
 216   die "Empty select list" unless @{$dq->{select}};
 217
 218   # it is, in fact, completely valid for there to be nothing for us
 219   # to project from since many databases handle 'SELECT 1;' fine
 220
 221   my @select = map [
 222     ($_->{type} eq DQ_ALIAS
 223       ? $self->_render_alias($_, $self->_format_keyword('AS'))
 224       : $self->_render($_)
 225     ),
 226    ','
 227   ], @{$dq->{select}};
 228
 229   # we put the commas inside the [] for each entry as a hint to the pretty
 230   # printer downstream so now we need to eliminate the comma from the last
 231   # entry - we know there always is one due to the die guard at the top
 232
 233   pop @{$select[-1]};
 234
 235   return [
 236     $self->_format_keyword('SELECT'),
 237     \@select,
 238     # if present this may be a bare FROM, a FROM+WHERE, or a FROM+WHERE+GROUP
 239     # since we're the SELECT and therefore always come first, we don't care.
 240     ($dq->{from}
 241        ? ($self->_format_keyword('FROM'), @{$self->_render($dq->{from})})
 242        : ()
 243     )
 244   ];
 245 }
 246
 247 sub _render_alias {
 248   my ($self, $dq, $as) = @_;
 249   # FROM foo foo -> FROM foo
 250   # FROM foo.bar bar -> FROM foo.bar
 251   if ($dq->{alias}{type} eq DQ_IDENTIFIER) {
 252     if ($dq->{alias}{elements}[-1] eq $dq->{as}) {
 253       return $self->_render($dq->{alias});
 254     }
 255   }
 256   return [
 257     $self->_render($dq->{alias}),
 258     $as || ' ',
 259     $self->_render_identifier({ elements => [ $dq->{as} ] })
 260   ];
 261 }
 262
 263 sub _render_literal {
 264   my ($self, $dq) = @_;
 265   unless ($dq->{subtype} eq 'SQL') {
 266     die "Can't render non-SQL literal";
 267   }
 268   return [
 269     $dq->{literal}, @{$dq->{values}||[]}
 270   ];
 271 }
 272
 273 sub _render_join {
 274   my ($self, $dq) = @_;
 275   my ($left, $right) = @{$dq->{join}};
 276   die "No support for ON yet" if $dq->{on};
 277   die "No support for LEFT/RIGHT yet" if $dq->{outer};
 278   [ $self->_render($left), ',', $self->_render($right) ];
 279 }
 280
 281 sub _render_where {
 282   my ($self, $dq) = @_;
 283   my ($from, $where) = @{$dq}{qw(from where)};
 284   [
 285     ($from ? $self->_render($from) : ()),
 286     $self->_format_keyword('WHERE'),
 287     $self->_render($where)
 288   ]
 289 }
 290
 291 sub _render_order {
 292   my ($self, $dq) = @_;
 293   my @ret = (
 294     $self->_format_keyword('ORDER BY'),
 295     $self->_render($dq->{by}),
 296     ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 297   );
 298   my $from;
 299   while ($from = $dq->{from}) {
 300     last unless $from->{type} eq DQ_ORDER;
 301     $dq = $from;
 302     push @ret, (
 303       ',',
 304       $self->_render($dq->{by}),
 305       ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 306     );
 307   }
 308   unshift @ret, $self->_render($from) if $from;
 309   \@ret;
 310 }
 311
 312 1;