lib/Data/Query/Renderer/SQL/Naive.pm

   1 package Data::Query::Renderer::SQL::Naive;
   2
   3 use strictures 1;
   4
   5 sub intersperse { my $i = shift; my @i = map +($_, $i), @_; pop @i; @i }
   6
   7 use SQL::ReservedWords;
   8 use Data::Query::ExprHelpers;
   9
  10 use Moo;
  11
  12 has reserved_ident_parts => (
  13   is => 'ro', default => sub {
  14     our $_DEFAULT_RESERVED ||= { map +($_ => 1), SQL::ReservedWords->words }
  15   }
  16 );
  17
  18 has quote_chars => (is => 'ro', default => sub { [''] });
  19
  20 has identifier_sep => (is => 'ro', default => sub { '.' });
  21
  22 has simple_ops => (is => 'ro', builder => '_default_simple_ops');
  23
  24 has lc_keywords => (is => 'ro', default => sub { 0 });
  25
  26 has always_quote => (is => 'ro', default => sub { 0 });
  27
  28 has collapse_aliases => (is => 'ro', default => sub { 1 });
  29
  30 sub _default_simple_ops {
  31   +{
  32     (map +($_ => 'binop'), qw(= > < >= <= != LIKE), 'NOT LIKE' ),
  33     (map +($_ => 'unop'), qw(NOT) ),
  34     (map +($_ => 'unop_reverse'), ('IS NULL', 'IS NOT NULL')),
  35     (map +($_ => 'flatten'), qw(AND OR) ),
  36     (map +($_ => 'in'), ('IN', 'NOT IN')),
  37     (map +($_ => 'between'), ('BETWEEN', 'NOT BETWEEN')),
  38     (apply => 'apply'),
  39   }
  40 }
  41
  42 sub render {
  43   my $self = shift;
  44   $self->_flatten_structure($self->_render(@_))
  45 }
  46
  47 sub _flatten_structure {
  48   my ($self, $struct) = @_;
  49   my @bind;
  50   [ do {
  51       my @p = map {
  52         my $r = ref;
  53         if (!$r) { $_ }
  54         elsif ($r eq 'ARRAY') {
  55           my ($sql, @b) = @{$self->_flatten_structure($_)};
  56           push @bind, @b;
  57           $sql;
  58         }
  59         elsif ($r eq 'HASH') { push @bind, $_; () }
  60         else { die "_flatten_structure can't handle ref type $r for $_" }
  61       } @$struct;
  62       join '', map {
  63         ($p[$_], (($p[$_+1]||',') eq ',') ? () : (' '))
  64       } 0 .. $#p;
  65     },
  66     @bind
  67   ];
  68 }
  69
  70 # I presented this to permit strange people to easily supply a patch to lc()
  71 # their keywords, as I have heard many desire to do, lest they infect me
  72 # with whatever malady caused this desire by their continued proximity for
  73 # want of such a feature.
  74 #
  75 # Then I realised that SQL::Abstract compatibility work required it.
  76 #
  77 # FEH.
  78
  79 sub _format_keyword { $_[0]->lc_keywords ? lc($_[1]) : $_[1] }
  80
  81 sub _render {
  82   unless (ref($_[1]) eq 'HASH') {
  83     die "Expected hashref, got ".(defined($_[1])?$_[1]:'undef');
  84   }
  85   $_[0]->${\"_render_${\(lc($_[1]->{type})||'broken')}"}($_[1]);
  86 }
  87
  88 sub _render_broken {
  89   my ($self, $dq) = @_;
  90   require Data::Dumper::Concise;
  91   die "Broken DQ entry: ".Data::Dumper::Concise::Dumper($dq);
  92 }
  93
  94 sub _render_identifier {
  95   die "Unidentified identifier (SQL can no has \$_)"
  96     unless my @i = @{$_[1]->{elements}};
  97   # handle single or paired quote chars
  98   my ($q1, $q2) = @{$_[0]->quote_chars}[0,-1];
  99   my $always_quote = $_[0]->always_quote;
 100   my $res_check = $_[0]->reserved_ident_parts;
 101   return [
 102     join
 103       $_[0]->identifier_sep,
 104       map +(
 105         $_ eq '*' # Yes, this means you can't have a column just called '*'.
 106           ? $_    # Yes, this is a feature. Go shoot the DBA if he disagrees.
 107           : ( # reserved are stored uc, quote if non-word
 108               ($always_quote and $q1) || $res_check->{+uc} || /\W/
 109                 ? $q1.$_.$q2
 110                 : $_
 111             )
 112       ), @i
 113   ];
 114 }
 115
 116 sub _render_value {
 117   [ '?', $_[1] ]
 118 }
 119
 120 sub _operator_type { 'SQL.Naive' }
 121
 122 sub _render_operator {
 123   my ($self, $dq) = @_;
 124   my $op = $dq->{operator};
 125   unless (exists $op->{$self->_operator_type}) {
 126     $op->{$self->_operator_type} = $self->_convert_op($dq);
 127   }
 128   my $op_name = $op->{$self->_operator_type};
 129   if (my $op_type = $self->simple_ops->{$op_name}) {
 130     return $self->${\"_handle_op_type_${op_type}"}($op_name, $dq);
 131   } elsif (my $meth = $self->can("_handle_op_special_${op_name}")) {
 132     return $self->$meth($dq);
 133   }
 134   if (my $argc = @{$dq->{args}}) {
 135     if ($argc == 1) {
 136       return $self->_handle_op_type_unop($op_name, $dq);
 137     } elsif ($argc == 2) {
 138       return $self->_handle_op_type_binop($op_name, $dq);
 139     }
 140   }
 141   die "Unsure how to handle ${op_name}";
 142 }
 143
 144 sub _maybe_parenthesise {
 145   my ($self, $dq) = @_;
 146   for ($dq) {
 147     return is_Select() || is_Group() || is_Slice() || is_Having()
 148       ? [ '(', $self->_render($dq), ')' ]
 149       : $self->_render($dq);
 150   }
 151 }
 152
 153 sub _handle_op_type_binop {
 154   my ($self, $op_name, $dq) = @_;
 155   die "${op_name} registered as binary op but args contain "
 156       .scalar(@{$dq->{args}})." entries"
 157     unless @{$dq->{args}} == 2;
 158   [
 159     $self->_maybe_parenthesise($dq->{args}[0]),
 160     $op_name,
 161     $self->_maybe_parenthesise($dq->{args}[1]),
 162   ]
 163 }
 164
 165 sub _handle_op_type_unop {
 166   my ($self, $op_name, $dq) = @_;
 167   die "${op_name} registered as unary op but args contain "
 168       .scalar(@{$dq->{args}})." entries"
 169     unless @{$dq->{args}} == 1;
 170   [
 171     '(',
 172     $op_name,
 173     $self->_render($dq->{args}[0]),
 174     ')',
 175   ]
 176 }
 177
 178 sub _handle_op_type_unop_reverse {
 179   my ($self, $op_name, $dq) = @_;
 180   die "${op_name} registered as unary op but args contain "
 181       .scalar(@{$dq->{args}})." entries"
 182     unless @{$dq->{args}} == 1;
 183   [
 184     $self->_render($dq->{args}[0]),
 185     $op_name,
 186   ]
 187 }
 188
 189 sub _handle_op_type_flatten {
 190   my ($self, $op_name, $dq) = @_;
 191   my @argq = @{$dq->{args}};
 192   my @arg_final;
 193   while (my $arg = shift @argq) {
 194
 195     unless (is_Operator($arg)) {
 196       push @arg_final, $arg;
 197       next;
 198     }
 199
 200     my $op = $arg->{operator};
 201     unless (exists $op->{$self->_operator_type}) {
 202       $op->{$self->_operator_type} = $self->_convert_op($arg);
 203     }
 204
 205     if ($op->{$self->_operator_type} eq $op_name) {
 206       unshift @argq, @{$arg->{args}};
 207     } else {
 208       push @arg_final, $arg;
 209     }
 210   }
 211   [ '(',
 212       intersperse(
 213         $self->_format_keyword($op_name),
 214         map $self->_maybe_parenthesise($_), @arg_final
 215       ),
 216     ')'
 217   ];
 218 }
 219
 220 sub _handle_op_type_in {
 221   my ($self, $op, $dq) = @_;
 222   my ($lhs, @in) = @{$dq->{args}};
 223   [ $self->_render($lhs),
 224     $op,
 225     '(',
 226       intersperse(',', map $self->_render($_), @in),
 227     ')'
 228   ];
 229 }
 230
 231 sub _handle_op_type_between {
 232   my ($self, $op_name, $dq) = @_;
 233   my @args = @{$dq->{args}};
 234   if (@args == 3) {
 235     my ($lhs, $rhs1, $rhs2) = (map $self->_maybe_parenthesise($_), @args);
 236     [ '(', $lhs, $op_name, $rhs1, 'AND', $rhs2, ')' ];
 237   } elsif (@args == 2 and is_Literal $args[1]) {
 238     my ($lhs, $rhs) = (map $self->_render($_), @args);
 239     [ '(', $lhs, $op_name, $rhs, ')' ];
 240   } else {
 241     die "Invalid args for between: ${\scalar @args} given";
 242   }
 243 }
 244
 245 sub _handle_op_type_apply {
 246   my ($self, $op_name, $dq) = @_;
 247   my ($func, @args) = @{$dq->{args}};
 248   die "Function name must be identifier"
 249     unless is_Identifier $func;
 250   my $ident = do {
 251     # The problem we have here is that built-ins can't be quoted, generally.
 252     # I rather wonder if things like MAX(...) need to -not- be handled as
 253     # an apply and instead of something else, maybe a parenop type - but
 254     # as an explicitly Naive renderer this seems like a reasonable answer.
 255     local @{$self}{qw(reserved_ident_parts always_quote)};
 256     $self->_render_identifier($func)->[0];
 257   };
 258   [
 259     "$ident(",
 260       intersperse(',', map $self->_maybe_parenthesise($_), @args),
 261     ')'
 262   ]
 263 }
 264
 265 sub _convert_op {
 266   my ($self, $dq) = @_;
 267   if (my $perl_op = $dq->{'operator'}->{'Perl'}) {
 268     for ($perl_op) {
 269       $_ eq '==' and return '=';
 270       $_ eq 'eq' and return '=';
 271       $_ eq '!' and return 'NOT';
 272     }
 273     return uc $perl_op; # hope!
 274   }
 275   die "Can't convert non-perl op yet";
 276 }
 277
 278 sub _render_select {
 279   my ($self, $dq) = @_;
 280   die "Empty select list" unless @{$dq->{select}};
 281
 282   # it is, in fact, completely valid for there to be nothing for us
 283   # to project from since many databases handle 'SELECT 1;' fine
 284
 285   my @select = intersperse(',',
 286     map +(is_Alias()
 287            ? $self->_render_alias($_, $self->_format_keyword('AS'))
 288            : $self->_render($_)), @{$dq->{select}}
 289   );
 290
 291   return [
 292     $self->_format_keyword('SELECT'),
 293     \@select,
 294     # if present this may be a bare FROM, a FROM+WHERE, or a FROM+WHERE+GROUP
 295     # since we're the SELECT and therefore always come first, we don't care.
 296     ($dq->{from}
 297        ? ($self->_format_keyword('FROM'), @{$self->_render($dq->{from})})
 298        : ()
 299     ),
 300   ];
 301 }
 302
 303 sub _render_alias {
 304   my ($self, $dq, $as) = @_;
 305   # FROM foo foo -> FROM foo
 306   # FROM foo.bar bar -> FROM foo.bar
 307   if ($self->collapse_aliases) {
 308     if (is_Identifier(my $from = $dq->{from})) {
 309       if ($from->{elements}[-1] eq $dq->{to}) {
 310         return $self->_render($from);
 311       }
 312     }
 313   }
 314   return [
 315     $self->_maybe_parenthesise($dq->{from}),
 316     $as || '',
 317     $self->_render_identifier({ elements => [ $dq->{to} ] })
 318   ];
 319 }
 320
 321 sub _render_literal {
 322   my ($self, $dq) = @_;
 323   unless ($dq->{subtype} eq 'SQL') {
 324     die "Can't render non-SQL literal";
 325   }
 326   if (defined($dq->{literal})) {
 327     return [
 328       $dq->{literal}, @{$dq->{values}||[]}
 329     ];
 330   } elsif ($dq->{parts}) {
 331     return [ map $self->_render($_), @{$dq->{parts}} ];
 332   } else {
 333     die "Invalid SQL literal - neither 'literal' nor 'parts' found";
 334   }
 335 }
 336
 337 sub _render_join {
 338   my ($self, $dq) = @_;
 339   my ($left, $right) = @{$dq}{qw(left right)};
 340   my $join = do {
 341     if ($dq->{outer}) {
 342       $self->_format_keyword(uc($dq->{outer}).' JOIN');
 343     } elsif ($dq->{on}) {
 344       $self->_format_keyword('JOIN');
 345     } else {
 346       ','
 347     }
 348   };
 349   my $rhs = $self->_render($right);
 350   [
 351     $self->_render($left), $join,
 352     (is_Join($right) ? ('(', $rhs, ')') : $rhs),
 353     ($dq->{on}
 354       ? ($self->_format_keyword('ON'), $self->_render($dq->{on}))
 355       : ())
 356   ];
 357 }
 358
 359 sub _render_where {
 360   my ($self, $dq) = @_;
 361   my ($from, $where) = @{$dq}{qw(from where)};
 362   while (is_Where $from) {
 363     $where = Operator({ 'SQL.Naive' => 'and' }, [ $where, $from->{where} ]);
 364     $from = $from->{from};
 365   }
 366   my $keyword = (is_Group($from) ? 'HAVING' : 'WHERE');
 367   [
 368     ($from ? $self->_render($from) : ()),
 369     $self->_format_keyword($keyword),
 370     $self->_render($where)
 371   ]
 372 }
 373
 374 sub _render_order {
 375   my ($self, $dq) = @_;
 376   my @ret = (
 377     $self->_format_keyword('ORDER BY'),
 378     $self->_render($dq->{by}),
 379     ($dq->{reverse}
 380       ? $self->_format_keyword('DESC')
 381       : ())
 382   );
 383   my $from;
 384   while ($from = $dq->{from}) {
 385     last unless is_Order $from;
 386     $dq = $from;
 387     push @ret, (
 388       ',',
 389       $self->_render($dq->{by}),
 390       ($dq->{reverse}
 391         ? $self->_format_keyword('DESC')
 392         : ())
 393     );
 394   }
 395   unshift @ret, $self->_render($from) if $from;
 396   \@ret;
 397 }
 398
 399 sub _render_group {
 400   my ($self, $dq) = @_;
 401   # this could also squash like order does. but I dunno whether that should
 402   # move somewhere else just yet.
 403   my @ret = (
 404     ($dq->{from} ? $self->_render($dq->{from}) : ()),
 405     (@{$dq->{by}}
 406       ? (
 407           $self->_format_keyword('GROUP BY'),
 408           intersperse(',', map $self->_render($_), @{$dq->{by}})
 409          )
 410       : ())
 411   );
 412   \@ret;
 413 }
 414
 415 sub _render_delete {
 416   my ($self, $dq) = @_;
 417   my ($target, $where) = @{$dq}{qw(target where)};
 418   [ $self->_format_keyword('DELETE FROM'),
 419     $self->_render($target),
 420     ($where
 421       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 422       : ())
 423   ];
 424 }
 425
 426 sub _render_update {
 427   my ($self, $dq) = @_;
 428   my ($target, $set, $where) = @{$dq}{qw(target set where)};
 429   unless ($set) {
 430     die "Must have set key - names+value keys not yet tested";
 431     my ($names, $value) = @{$dq}{qw(names value)};
 432     die "Must have names and value or set" unless $names and $value;
 433     die "names and value must be same size" unless @$names == @$value;
 434     $set = [ map [ $names->[$_], $value->[$_] ], 0..$#$names ];
 435   }
 436   my @rendered_set = intersperse(
 437     ',', map [ intersperse('=', map $self->_render($_), @$_) ], @{$set}
 438   );
 439   [ $self->_format_keyword('UPDATE'),
 440     $self->_render($target),
 441     $self->_format_keyword('SET'),
 442     @rendered_set,
 443     ($where
 444       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 445       : ())
 446   ];
 447 }
 448
 449 sub _render_insert {
 450   my ($self, $dq) = @_;
 451   my ($target, $names, $values, $returning)
 452     = @{$dq}{qw(target names values returning)};
 453   unless ($values) {
 454     die "Must have values key - sets key not yet implemented";
 455   }
 456   [ $self->_format_keyword('INSERT INTO'),
 457     $self->_render($target),
 458     ($names
 459       ? ('(', intersperse(',', map $self->_render($_), @$names), ')')
 460       : ()),
 461     $self->_format_keyword('VALUES'),
 462     intersperse(',',
 463       map [ '(', intersperse(',', map $self->_render($_), @$_), ')' ],
 464         @$values
 465     ),
 466     ($returning
 467       ? ($self->_format_keyword('RETURNING'),
 468          intersperse(',', map $self->_render($_), @$returning))
 469       : ()),
 470   ];
 471 }
 472
 473 1;