lib/Data/Query/Renderer/SQL/Naive.pm

   1 package Data::Query::Renderer::SQL::Naive;
   2
   3 use strictures 1;
   4
   5 sub intersperse { my $i = shift; my @i = map +($_, $i), @_; pop @i; @i }
   6
   7 use SQL::ReservedWords;
   8 use Data::Query::Constants qw(
   9   DQ_IDENTIFIER DQ_OPERATOR DQ_VALUE DQ_JOIN DQ_ALIAS DQ_ORDER DQ_LITERAL
  10 );
  11
  12 sub new {
  13   bless({ %{$_[1]||{}} }, (ref($_[0])||$_[0]))->BUILDALL;
  14 }
  15
  16 sub BUILDALL {
  17   my $self = shift;
  18   $self->{reserved_ident_parts}
  19     ||= (
  20       our $_DEFAULT_RESERVED ||= { map +($_ => 1), SQL::ReservedWords->words }
  21     );
  22   $self->{quote_chars}||=[''];
  23   $self->{simple_ops}||=$self->_default_simple_ops;
  24   return $self;
  25 }
  26
  27 sub _default_simple_ops {
  28   +{
  29     (map +($_ => 'binop'), qw(= > < >= <= != LIKE), 'NOT LIKE' ),
  30     (map +($_ => 'unop'), qw(NOT) ),
  31     (map +($_ => 'unop_reverse'), ('IS NULL', 'IS NOT NULL')),
  32     (map +($_ => 'flatten'), qw(AND OR) ),
  33     (map +($_ => 'in'), ('IN', 'NOT IN')),
  34     (map +($_ => 'between'), ('BETWEEN', 'NOT BETWEEN')),
  35     (apply => 'apply'),
  36   }
  37 }
  38
  39 sub render {
  40   my $self = shift;
  41   $self->_flatten_structure($self->_render(@_))
  42 }
  43
  44 sub _flatten_structure {
  45   my ($self, $struct) = @_;
  46   my @bind;
  47   [ do {
  48       my @p = map {
  49         my $r = ref;
  50         if (!$r) { $_ }
  51         elsif ($r eq 'ARRAY') {
  52           my ($sql, @b) = @{$self->_flatten_structure($_)};
  53           push @bind, @b;
  54           $sql;
  55         }
  56         elsif ($r eq 'HASH') { push @bind, $_; () }
  57         else { die "_flatten_structure can't handle ref type $r for $_" }
  58       } @$struct;
  59       join '', map {
  60         ($p[$_], (($p[$_+1]||',') eq ',') ? () : (' '))
  61       } 0 .. $#p;
  62     },
  63     @bind
  64   ];
  65 }
  66
  67 # I presented this to permit strange people to easily supply a patch to lc()
  68 # their keywords, as I have heard many desire to do, lest they infect me
  69 # with whatever malady caused this desire by their continued proximity for
  70 # want of such a feature.
  71 #
  72 # Then I realised that SQL::Abstract compatibility work required it.
  73 #
  74 # FEH.
  75
  76 sub _format_keyword { $_[0]->{lc_keywords} ? lc($_[1]) : $_[1] }
  77
  78 sub _render {
  79   $_[0]->${\"_render_${\(lc($_[1]->{type})||'broken')}"}($_[1]);
  80 }
  81
  82 sub _render_broken {
  83   my ($self, $dq) = @_;
  84   require Data::Dumper::Concise;
  85   die "Broken DQ entry: ".Data::Dumper::Concise::Dumper($dq);
  86 }
  87
  88 sub _render_identifier {
  89   die "Unidentified identifier (SQL can no has \$_)"
  90     unless my @i = @{$_[1]->{elements}};
  91   # handle single or paired quote chars
  92   my ($q1, $q2) = @{$_[0]->{quote_chars}}[0,-1];
  93   my $always_quote = $_[0]->{always_quote};
  94   my $res_check = $_[0]->{reserved_ident_parts};
  95   return [
  96     join
  97       $_[0]->{identifier_sep}||'.',
  98       map +(
  99         $_ eq '*' # Yes, this means you can't have a column just called '*'.
 100           ? $_    # Yes, this is a feature. Go shoot the DBA if he disagrees.
 101           : ( # reserved are stored uc, quote if non-word
 102               $always_quote || $res_check->{+uc} || /\W/
 103                 ? $q1.$_.$q2
 104                 : $_
 105             )
 106       ), @i
 107   ];
 108 }
 109
 110 sub _render_value {
 111   [ '?', $_[1] ]
 112 }
 113
 114 sub _operator_type { 'SQL.Naive' }
 115
 116 sub _render_operator {
 117   my ($self, $dq) = @_;
 118   my $op = $dq->{operator};
 119   unless (exists $op->{$self->_operator_type}) {
 120     $op->{$self->_operator_type} = $self->_convert_op($dq);
 121   }
 122   my $op_name = $op->{$self->_operator_type};
 123   if (my $op_type = $self->{simple_ops}{$op_name}) {
 124     return $self->${\"_handle_op_type_${op_type}"}($op_name, $dq);
 125   } elsif (my $meth = $self->can("_handle_op_special_${op_name}")) {
 126     return $self->$meth($dq);
 127   }
 128   if (my $argc = @{$dq->{args}}) {
 129     if ($argc == 1) {
 130       return $self->_handle_op_type_unop($op_name, $dq);
 131     } elsif ($argc == 2) {
 132       return $self->_handle_op_type_binop($op_name, $dq);
 133     }
 134   }
 135   die "Unsure how to handle ${op_name}";
 136 }
 137
 138 sub _handle_op_type_binop {
 139   my ($self, $op_name, $dq) = @_;
 140   die "${op_name} registered as binary op but args contain "
 141       .scalar(@{$dq->{args}})." entries"
 142     unless @{$dq->{args}} == 2;
 143   [
 144     $self->_render($dq->{args}[0]),
 145     $op_name,
 146     $self->_render($dq->{args}[1]),
 147   ]
 148 }
 149
 150 sub _handle_op_type_unop {
 151   my ($self, $op_name, $dq) = @_;
 152   die "${op_name} registered as unary op but args contain "
 153       .scalar(@{$dq->{args}})." entries"
 154     unless @{$dq->{args}} == 1;
 155   [
 156     '(',
 157     $op_name,
 158     $self->_render($dq->{args}[0]),
 159     ')',
 160   ]
 161 }
 162
 163 sub _handle_op_type_unop_reverse {
 164   my ($self, $op_name, $dq) = @_;
 165   die "${op_name} registered as unary op but args contain "
 166       .scalar(@{$dq->{args}})." entries"
 167     unless @{$dq->{args}} == 1;
 168   [
 169     $self->_render($dq->{args}[0]),
 170     $op_name,
 171   ]
 172 }
 173
 174 sub _handle_op_type_flatten {
 175   my ($self, $op_name, $dq) = @_;
 176   my @argq = @{$dq->{args}};
 177   my @arg_final;
 178   while (my $arg = shift @argq) {
 179
 180     unless ($arg->{type} eq DQ_OPERATOR) {
 181       push @arg_final, $arg;
 182       next;
 183     }
 184
 185     my $op = $arg->{operator};
 186     unless (exists $op->{$self->_operator_type}) {
 187       $op->{$self->_operator_type} = $self->_convert_op($arg);
 188     }
 189
 190     if ($op->{$self->_operator_type} eq $op_name) {
 191       unshift @argq, @{$arg->{args}};
 192     } else {
 193       push @arg_final, $arg;
 194     }
 195   }
 196   [ '(',
 197       intersperse(
 198         $self->_format_keyword($op_name),
 199         map $self->_render($_), @arg_final
 200       ),
 201     ')'
 202   ];
 203 }
 204
 205 sub _handle_op_type_in {
 206   my ($self, $op, $dq) = @_;
 207   my ($lhs, @in) = @{$dq->{args}};
 208   [ $self->_render($lhs),
 209     $op,
 210     '(',
 211       intersperse(',', map $self->_render($_), @in),
 212     ')'
 213   ];
 214 }
 215
 216 sub _handle_op_type_between {
 217   my ($self, $op_name, $dq) = @_;
 218   my @args = @{$dq->{args}};
 219   if (@args == 3) {
 220     my ($lhs, $rhs1, $rhs2) = (map $self->_render($_), @args);
 221     [ '(', $lhs, $op_name, $rhs1, 'AND', $rhs2, ')' ];
 222   } elsif (@args == 2 and $args[1]->{type} eq DQ_LITERAL) {
 223     my ($lhs, $rhs) = (map $self->_render($_), @args);
 224     [ '(', $lhs, $op_name, $rhs, ')' ];
 225   } else {
 226     die "Invalid args for between: ${\scalar @args} given";
 227   }
 228 }
 229
 230 sub _handle_op_type_apply {
 231   my ($self, $op_name, $dq) = @_;
 232   my ($func, @args) = @{$dq->{args}};
 233   die "Function name must be identifier"
 234     unless $func->{type} eq DQ_IDENTIFIER;
 235   my $ident = do {
 236     # The problem we have here is that built-ins can't be quoted, generally.
 237     # I rather wonder if things like MAX(...) need to -not- be handled as
 238     # an apply and instead of something else, maybe a parenop type - but
 239     # as an explicitly Naive renderer this seems like a reasonable answer.
 240     local @{$self}{qw(reserved_ident_parts always_quote)};
 241     $self->_render_identifier($func)->[0];
 242   };
 243   [
 244     "$ident(",
 245       intersperse(',', map $self->_render($_), @args),
 246     ')'
 247   ]
 248 }
 249
 250 sub _convert_op {
 251   my ($self, $dq) = @_;
 252   if (my $perl_op = $dq->{'operator'}->{'Perl'}) {
 253     for ($perl_op) {
 254       $_ eq '==' and return '=';
 255       $_ eq 'eq' and return '=';
 256       $_ eq '!' and return 'NOT';
 257     }
 258     return uc $perl_op; # hope!
 259   }
 260   die "Can't convert non-perl op yet";
 261 }
 262
 263 sub _render_select {
 264   my ($self, $dq) = @_;
 265   die "Empty select list" unless @{$dq->{select}};
 266
 267   # it is, in fact, completely valid for there to be nothing for us
 268   # to project from since many databases handle 'SELECT 1;' fine
 269
 270   my @select = intersperse(',',
 271     map +($_->{type} eq DQ_ALIAS
 272            ? $self->_render_alias($_, $self->_format_keyword('AS'))
 273            : $self->_render($_)), @{$dq->{select}}
 274   );
 275
 276   return [
 277     $self->_format_keyword('SELECT'),
 278     \@select,
 279     # if present this may be a bare FROM, a FROM+WHERE, or a FROM+WHERE+GROUP
 280     # since we're the SELECT and therefore always come first, we don't care.
 281     ($dq->{from}
 282        ? ($self->_format_keyword('FROM'), @{$self->_render($dq->{from})})
 283        : ()
 284     )
 285   ];
 286 }
 287
 288 sub _render_alias {
 289   my ($self, $dq, $as) = @_;
 290   # FROM foo foo -> FROM foo
 291   # FROM foo.bar bar -> FROM foo.bar
 292   if ($dq->{alias}{type} eq DQ_IDENTIFIER) {
 293     if ($dq->{alias}{elements}[-1] eq $dq->{as}) {
 294       return $self->_render($dq->{alias});
 295     }
 296   }
 297   return [
 298     $self->_render($dq->{alias}),
 299     $as || ' ',
 300     $self->_render_identifier({ elements => [ $dq->{as} ] })
 301   ];
 302 }
 303
 304 sub _render_literal {
 305   my ($self, $dq) = @_;
 306   unless ($dq->{subtype} eq 'SQL') {
 307     die "Can't render non-SQL literal";
 308   }
 309   if ($dq->{literal}) {
 310     return [
 311       $dq->{literal}, @{$dq->{values}||[]}
 312     ];
 313   } elsif ($dq->{parts}) {
 314     return [ map $self->_render($_), @{$dq->{parts}} ];
 315   } else {
 316     die "Invalid SQL literal - neither 'literal' nor 'parts' found";
 317   }
 318 }
 319
 320 sub _render_join {
 321   my ($self, $dq) = @_;
 322   my ($left, $right) = @{$dq->{join}};
 323   die "No support for ON yet" if $dq->{on};
 324   die "No support for LEFT/RIGHT yet" if $dq->{outer};
 325   [ $self->_render($left), ',', $self->_render($right) ];
 326 }
 327
 328 sub _render_where {
 329   my ($self, $dq) = @_;
 330   my ($from, $where) = @{$dq}{qw(from where)};
 331   [
 332     ($from ? $self->_render($from) : ()),
 333     $self->_format_keyword('WHERE'),
 334     $self->_render($where)
 335   ]
 336 }
 337
 338 sub _render_order {
 339   my ($self, $dq) = @_;
 340   my @ret = (
 341     $self->_format_keyword('ORDER BY'),
 342     $self->_render($dq->{by}),
 343     ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 344   );
 345   my $from;
 346   while ($from = $dq->{from}) {
 347     last unless $from->{type} eq DQ_ORDER;
 348     $dq = $from;
 349     push @ret, (
 350       ',',
 351       $self->_render($dq->{by}),
 352       ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 353     );
 354   }
 355   unshift @ret, $self->_render($from) if $from;
 356   \@ret;
 357 }
 358
 359 sub _render_delete {
 360   my ($self, $dq) = @_;
 361   my ($target, $where) = @{$dq}{qw(target where)};
 362   [ $self->_format_keyword('DELETE FROM'),
 363     $self->_render($target),
 364     ($where
 365       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 366       : ())
 367   ];
 368 }
 369
 370 sub _render_update {
 371   my ($self, $dq) = @_;
 372   my ($target, $set, $where) = @{$dq}{qw(target set where)};
 373   unless ($set) {
 374     die "Must have set key - names+value keys not yet tested";
 375     my ($names, $value) = @{$dq}{qw(names value)};
 376     die "Must have names and value or set" unless $names and $value;
 377     die "names and value must be same size" unless @$names == @$value;
 378     $set = [ map [ $names->[$_], $value->[$_] ], 0..$#$names ];
 379   }
 380   my @rendered_set = intersperse(
 381     ',', map [ intersperse('=', map $self->_render($_), @$_) ], @{$set}
 382   );
 383   [ $self->_format_keyword('UPDATE'),
 384     $self->_render($target),
 385     $self->_format_keyword('SET'),
 386     @rendered_set,
 387     ($where
 388       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 389       : ())
 390   ];
 391 }
 392
 393 sub _render_insert {
 394   my ($self, $dq) = @_;
 395   my ($target, $names, $values, $returning)
 396     = @{$dq}{qw(target names values returning)};
 397   unless ($values) {
 398     die "Must have values key - sets key not yet implemented";
 399   }
 400   [ $self->_format_keyword('INSERT INTO'),
 401     $self->_render($target),
 402     ($names
 403       ? ('(', intersperse(',', map $self->_render($_), @$names), ')')
 404       : ()),
 405     $self->_format_keyword('VALUES'),
 406     intersperse(',',
 407       map [ '(', intersperse(',', map $self->_render($_), @$_), ')' ],
 408         @$values
 409     ),
 410     ($returning
 411       ? ($self->_format_keyword('RETURNING'),
 412          intersperse(',', map $self->_render($_), @$returning))
 413       : ()),
 414   ];
 415 }
 416
 417 1;